lib/DBIx/Class/Schema/Loader/RelBuilder.pm

   1 package DBIx::Class::Schema::Loader::RelBuilder;
   2
   3 use strict;
   4 use warnings;
   5 use base 'Class::Accessor::Grouped';
   6 use mro 'c3';
   7 use Carp::Clan qw/^DBIx::Class/;
   8 use Scalar::Util 'weaken';
   9 use DBIx::Class::Schema::Loader::Utils qw/split_name slurp_file array_eq/;
  10 use Try::Tiny;
  11 use List::Util 'first';
  12 use List::MoreUtils qw/apply uniq any/;
  13 use namespace::clean;
  14 use Lingua::EN::Inflect::Phrase ();
  15 use Lingua::EN::Tagger ();
  16 use String::ToIdentifier::EN ();
  17 use String::ToIdentifier::EN::Unicode ();
  18 use Class::Unload ();
  19 use Class::Inspector ();
  20
  21 our $VERSION = '0.07034_02';
  22
  23 # Glossary:
  24 #
  25 # remote_relname -- name of relationship from the local table referring to the remote table
  26 # local_relname  -- name of relationship from the remote table referring to the local table
  27 # remote_method  -- relationship type from remote table to local table, usually has_many
  28
  29 =head1 NAME
  30
  31 DBIx::Class::Schema::Loader::RelBuilder - Builds relationships for DBIx::Class::Schema::Loader
  32
  33 =head1 SYNOPSIS
  34
  35 See L<DBIx::Class::Schema::Loader> and L<DBIx::Class::Schema::Loader::Base>.
  36
  37 =head1 DESCRIPTION
  38
  39 This class builds relationships for L<DBIx::Class::Schema::Loader>.  This
  40 is module is not (yet) for external use.
  41
  42 =head1 METHODS
  43
  44 =head2 new
  45
  46 Arguments: $loader object
  47
  48 =head2 generate_code
  49
  50 Arguments:
  51
  52     [
  53         [ local_moniker1 (scalar), fk_info1 (arrayref), uniq_info1 (arrayref) ]
  54         [ local_moniker2 (scalar), fk_info2 (arrayref), uniq_info2 (arrayref) ]
  55         ...
  56     ]
  57
  58 This generates the code for the relationships of each table.
  59
  60 C<local_moniker> is the moniker name of the table which had the REFERENCES
  61 statements.  The fk_info arrayref's contents should take the form:
  62
  63     [
  64         {
  65             local_table    => 'some_table',
  66             local_moniker  => 'SomeTable',
  67             local_columns  => [ 'col2', 'col3' ],
  68             remote_table   => 'another_table_moniker',
  69             remote_moniker => 'AnotherTableMoniker',
  70             remote_columns => [ 'col5', 'col7' ],
  71         },
  72         {
  73             local_table    => 'some_other_table',
  74             local_moniker  => 'SomeOtherTable',
  75             local_columns  => [ 'col1', 'col4' ],
  76             remote_table   => 'yet_another_table_moniker',
  77             remote_moniker => 'YetAnotherTableMoniker',
  78             remote_columns => [ 'col1', 'col2' ],
  79         },
  80         # ...
  81     ],
  82
  83 The uniq_info arrayref's contents should take the form:
  84
  85     [
  86         [
  87             uniq_constraint_name         => [ 'col1', 'col2' ],
  88         ],
  89         [
  90             another_uniq_constraint_name => [ 'col1', 'col2' ],
  91         ],
  92     ],
  93
  94 This method will return the generated relationships as a hashref keyed on the
  95 class names.  The values are arrayrefs of hashes containing method name and
  96 arguments, like so:
  97
  98   {
  99       'Some::Source::Class' => [
 100           { method => 'belongs_to', arguments => [ 'col1', 'Another::Source::Class' ],
 101           { method => 'has_many', arguments => [ 'anothers', 'Yet::Another::Source::Class', 'col15' ],
 102       ],
 103       'Another::Source::Class' => [
 104           # ...
 105       ],
 106       # ...
 107   }
 108
 109 =cut
 110
 111 __PACKAGE__->mk_group_accessors('simple', qw/
 112     loader
 113     schema
 114     inflect_plural
 115     inflect_singular
 116     relationship_attrs
 117     rel_collision_map
 118     rel_name_map
 119     _temp_classes
 120     __tagger
 121 /);
 122
 123 sub new {
 124     my ($class, $loader) = @_;
 125
 126     # from old POD about this constructor:
 127     # C<$schema_class> should be a schema class name, where the source
 128     # classes have already been set up and registered.  Column info,
 129     # primary key, and unique constraints will be drawn from this
 130     # schema for all of the existing source monikers.
 131
 132     # Options inflect_plural and inflect_singular are optional, and
 133     # are better documented in L<DBIx::Class::Schema::Loader::Base>.
 134
 135     my $self = {
 136         loader             => $loader,
 137         schema             => $loader->schema,
 138         inflect_plural     => $loader->inflect_plural,
 139         inflect_singular   => $loader->inflect_singular,
 140         relationship_attrs => $loader->relationship_attrs,
 141         rel_collision_map  => $loader->rel_collision_map,
 142         rel_name_map       => $loader->rel_name_map,
 143         _temp_classes      => [],
 144     };
 145
 146     weaken $self->{loader}; #< don't leak
 147
 148     bless $self => $class;
 149
 150     # validate the relationship_attrs arg
 151     if( defined $self->relationship_attrs ) {
 152         (ref $self->relationship_attrs eq 'HASH' || ref $self->relationship_attrs eq 'CODE')
 153             or croak "relationship_attrs must be a hashref or coderef";
 154     }
 155
 156     return $self;
 157 }
 158
 159
 160 # pluralize a relationship name
 161 sub _inflect_plural {
 162     my ($self, $relname) = @_;
 163
 164     return '' if !defined $relname || $relname eq '';
 165
 166     my $result;
 167     my $mapped = 0;
 168
 169     if( ref $self->inflect_plural eq 'HASH' ) {
 170         if (exists $self->inflect_plural->{$relname}) {
 171             $result = $self->inflect_plural->{$relname};
 172             $mapped = 1;
 173         }
 174     }
 175     elsif( ref $self->inflect_plural eq 'CODE' ) {
 176         my $inflected = $self->inflect_plural->($relname);
 177         if ($inflected) {
 178             $result = $inflected;
 179             $mapped = 1;
 180         }
 181     }
 182
 183     return ($result, $mapped) if $mapped;
 184
 185     return ($self->_to_PL($relname), 0);
 186 }
 187
 188 # Singularize a relationship name
 189 sub _inflect_singular {
 190     my ($self, $relname) = @_;
 191
 192     return '' if !defined $relname || $relname eq '';
 193
 194     my $result;
 195     my $mapped = 0;
 196
 197     if( ref $self->inflect_singular eq 'HASH' ) {
 198         if (exists $self->inflect_singular->{$relname}) {
 199             $result = $self->inflect_singular->{$relname};
 200             $mapped = 1;
 201         }
 202     }
 203     elsif( ref $self->inflect_singular eq 'CODE' ) {
 204         my $inflected = $self->inflect_singular->($relname);
 205         if ($inflected) {
 206             $result = $inflected;
 207             $mapped = 1;
 208         }
 209     }
 210
 211     return ($result, $mapped) if $mapped;
 212
 213     return ($self->_to_S($relname), 0);
 214 }
 215
 216 sub _to_PL {
 217     my ($self, $name) = @_;
 218
 219     $name =~ s/_/ /g;
 220     my $plural = Lingua::EN::Inflect::Phrase::to_PL($name);
 221     $plural =~ s/ /_/g;
 222
 223     return $plural;
 224 }
 225
 226 sub _to_S {
 227     my ($self, $name) = @_;
 228
 229     $name =~ s/_/ /g;
 230     my $singular = Lingua::EN::Inflect::Phrase::to_S($name);
 231     $singular =~ s/ /_/g;
 232
 233     return $singular;
 234 }
 235
 236 sub _default_relationship_attrs { +{
 237     has_many => {
 238         cascade_delete => 0,
 239         cascade_copy   => 0,
 240     },
 241     might_have => {
 242         cascade_delete => 0,
 243         cascade_copy   => 0,
 244     },
 245     belongs_to => {
 246         on_delete => 'CASCADE',
 247         on_update => 'CASCADE',
 248         is_deferrable => 1,
 249     },
 250 } }
 251
 252 # Accessor for options to be passed to each generated relationship type. takes
 253 # the relationship type name and optionally any attributes from the database
 254 # (such as FK ON DELETE/UPDATE and DEFERRABLE clauses), and returns a
 255 # hashref or undef if nothing is set.
 256 #
 257 # The attributes from the database override the default attributes, which in
 258 # turn are overridden by user supplied attributes.
 259 sub _relationship_attrs {
 260     my ( $self, $reltype, $db_attrs, $params ) = @_;
 261     my $r = $self->relationship_attrs;
 262
 263     my %composite = (
 264         %{ $self->_default_relationship_attrs->{$reltype} || {} },
 265         %{ $db_attrs || {} },
 266         (
 267             ref $r eq 'HASH' ? (
 268                 %{ $r->{all} || {} },
 269                 %{ $r->{$reltype} || {} },
 270             )
 271             :
 272             ()
 273         ),
 274     );
 275
 276     if (ref $r eq 'CODE') {
 277         $params->{attrs} = \%composite;
 278
 279         my %ret = %{ $r->(%$params) || {} };
 280
 281         %composite = %ret if %ret;
 282     }
 283
 284     return %composite ? \%composite : undef;
 285 }
 286
 287 sub _strip_id_postfix {
 288     my ($self, $name) = @_;
 289
 290     $name =~ s/_?(?:id|ref|cd|code|num)\z//i;
 291
 292     return $name;
 293 }
 294
 295 sub _remote_attrs {
 296     my ($self, $local_moniker, $local_cols, $fk_attrs, $params) = @_;
 297
 298     # get our set of attrs from _relationship_attrs, which uses the FK attrs if available
 299     my $attrs = $self->_relationship_attrs('belongs_to', $fk_attrs, $params) || {};
 300
 301     # If any referring column is nullable, make 'belongs_to' an
 302     # outer join, unless explicitly set by relationship_attrs
 303     my $nullable = first { $self->schema->source($local_moniker)->column_info($_)->{is_nullable} } @$local_cols;
 304     $attrs->{join_type} = 'LEFT' if $nullable && !defined $attrs->{join_type};
 305
 306     return $attrs;
 307 }
 308
 309 sub _sanitize_name {
 310     my ($self, $name) = @_;
 311
 312     $name = $self->loader->_to_identifier('relationships', $name, '_');
 313
 314     $name =~ s/\W+/_/g; # if naming >= 8 to_identifier takes care of it
 315
 316     return $name;
 317 }
 318
 319 sub _normalize_name {
 320     my ($self, $name) = @_;
 321
 322     $name = $self->_sanitize_name($name);
 323
 324     my @words = split_name $name, $self->loader->_get_naming_v('relationships');
 325
 326     return join '_', map lc, @words;
 327 }
 328
 329 sub _remote_relname {
 330     my ($self, $remote_table, $cond) = @_;
 331
 332     my $remote_relname;
 333     # for single-column case, set the remote relname to the column
 334     # name, to make filter accessors work, but strip trailing _id
 335     if(scalar keys %{$cond} == 1) {
 336         my ($col) = values %{$cond};
 337         $col = $self->_strip_id_postfix($self->_normalize_name($col));
 338         ($remote_relname) = $self->_inflect_singular($col);
 339     }
 340     else {
 341         ($remote_relname) = $self->_inflect_singular($self->_normalize_name($remote_table));
 342     }
 343
 344     return $remote_relname;
 345 }
 346
 347 sub _resolve_relname_collision {
 348     my ($self, $moniker, $cols, $relname) = @_;
 349
 350     return $relname if $relname eq 'id'; # this shouldn't happen, but just in case
 351
 352     my $table = $self->loader->moniker_to_table->{$moniker};
 353
 354     if ($self->loader->_is_result_class_method($relname, $table)) {
 355         if (my $map = $self->rel_collision_map) {
 356             for my $re (keys %$map) {
 357                 if (my @matches = $relname =~ /$re/) {
 358                     return sprintf $map->{$re}, @matches;
 359                 }
 360             }
 361         }
 362
 363         my $new_relname = $relname;
 364         while ($self->loader->_is_result_class_method($new_relname, $table)) {
 365             $new_relname .= '_rel'
 366         }
 367
 368         warn <<"EOF";
 369 Relationship '$relname' in source '$moniker' for columns '@{[ join ',', @$cols ]}' collides with an inherited method. Renaming to '$new_relname'.
 370 See "RELATIONSHIP NAME COLLISIONS" in perldoc DBIx::Class::Schema::Loader::Base .
 371 EOF
 372
 373         return $new_relname;
 374     }
 375
 376     return $relname;
 377 }
 378
 379 sub generate_code {
 380     my ($self, $tables) = @_;
 381
 382     # make a copy to destroy
 383     my @tables = @$tables;
 384
 385     my $all_code = {};
 386
 387     while (my ($local_moniker, $rels, $uniqs) = @{ shift @tables || [] }) {
 388         my $local_class = $self->schema->class($local_moniker);
 389
 390         my %counters;
 391         foreach my $rel (@$rels) {
 392             next if !$rel->{remote_source};
 393             $counters{$rel->{remote_source}}++;
 394         }
 395
 396         foreach my $rel (@$rels) {
 397             my $remote_moniker = $rel->{remote_source}
 398                 or next;
 399
 400             my $remote_class   = $self->schema->class($remote_moniker);
 401             my $remote_obj     = $self->schema->source($remote_moniker);
 402             my $remote_cols    = $rel->{remote_columns} || [ $remote_obj->primary_columns ];
 403
 404             my $local_cols     = $rel->{local_columns};
 405
 406             if($#$local_cols != $#$remote_cols) {
 407                 croak "Column count mismatch: $local_moniker (@$local_cols) "
 408                     . "$remote_moniker (@$remote_cols)";
 409             }
 410
 411             my %cond;
 412             foreach my $i (0 .. $#$local_cols) {
 413                 $cond{$remote_cols->[$i]} = $local_cols->[$i];
 414             }
 415
 416             my ( $local_relname, $remote_relname, $remote_method ) =
 417                 $self->_relnames_and_method( $local_moniker, $rel, \%cond,  $uniqs, \%counters );
 418             my $local_method  = 'belongs_to';
 419
 420             ($remote_relname) = $self->_rel_name_map($remote_relname, $local_method, $local_class, $local_moniker, $local_cols, $remote_class, $remote_moniker, $remote_cols);
 421             ($local_relname)  = $self->_rel_name_map($local_relname, $remote_method, $remote_class, $remote_moniker, $remote_cols, $local_class, $local_moniker, $local_cols);
 422
 423             $remote_relname   = $self->_resolve_relname_collision($local_moniker,  $local_cols,  $remote_relname);
 424             $local_relname    = $self->_resolve_relname_collision($remote_moniker, $remote_cols, $local_relname);
 425
 426             my $rel_attrs_params = {
 427                 rel_name      => $remote_relname,
 428                 rel_type      => $local_method,
 429                 local_source  => $self->schema->source($local_moniker),
 430                 remote_source => $self->schema->source($remote_moniker),
 431                 local_table   => $rel->{local_table},
 432                 local_cols    => $local_cols,
 433                 remote_table  => $rel->{remote_table},
 434                 remote_cols   => $remote_cols,
 435             };
 436
 437             push(@{$all_code->{$local_class}},
 438                 { method => $local_method,
 439                   args => [ $remote_relname,
 440                             $remote_class,
 441                             \%cond,
 442                             $self->_remote_attrs($local_moniker, $local_cols, $rel->{attrs}, $rel_attrs_params),
 443                   ],
 444                   extra => {
 445                       local_class    => $local_class,
 446                       local_moniker  => $local_moniker,
 447                       remote_moniker => $remote_moniker,
 448                   },
 449                 }
 450             );
 451
 452             my %rev_cond = reverse %cond;
 453             for (keys %rev_cond) {
 454                 $rev_cond{"foreign.$_"} = "self.".$rev_cond{$_};
 455                 delete $rev_cond{$_};
 456             }
 457
 458             $rel_attrs_params = {
 459                 rel_name      => $local_relname,
 460                 rel_type      => $remote_method,
 461                 local_source  => $self->schema->source($remote_moniker),
 462                 remote_source => $self->schema->source($local_moniker),
 463                 local_table   => $rel->{remote_table},
 464                 local_cols    => $remote_cols,
 465                 remote_table  => $rel->{local_table},
 466                 remote_cols   => $local_cols,
 467             };
 468
 469             push(@{$all_code->{$remote_class}},
 470                 { method => $remote_method,
 471                   args => [ $local_relname,
 472                             $local_class,
 473                             \%rev_cond,
 474                             $self->_relationship_attrs($remote_method, {}, $rel_attrs_params),
 475                   ],
 476                   extra => {
 477                       local_class    => $remote_class,
 478                       local_moniker  => $remote_moniker,
 479                       remote_moniker => $local_moniker,
 480                   },
 481                 }
 482             );
 483         }
 484     }
 485
 486     $self->_generate_m2ms($all_code);
 487
 488     # disambiguate rels with the same name
 489     foreach my $class (keys %$all_code) {
 490         my $dups = $self->_duplicates($all_code->{$class});
 491
 492         $self->_disambiguate($all_code, $class, $dups) if $dups;
 493     }
 494
 495     $self->_cleanup;
 496
 497     return $all_code;
 498 }
 499
 500 # Find classes with only 2 FKs which are the PK and make many_to_many bridges for them.
 501 sub _generate_m2ms {
 502     my ($self, $all_code) = @_;
 503
 504     while (my ($class, $rels) = each %$all_code) {
 505         next unless (grep $_->{method} eq 'belongs_to', @$rels) == 2;
 506
 507         my $class1_local_moniker  = $rels->[0]{extra}{remote_moniker};
 508         my $class1_remote_moniker = $rels->[1]{extra}{remote_moniker};
 509
 510         my $class2_local_moniker  = $rels->[1]{extra}{remote_moniker};
 511         my $class2_remote_moniker = $rels->[0]{extra}{remote_moniker};
 512
 513         my $class1 = $rels->[0]{args}[1];
 514         my $class2 = $rels->[1]{args}[1];
 515
 516         my $class1_to_link_table_rel = first {
 517             $_->{method} eq 'has_many' && $_->{args}[1] eq $class
 518         } @{ $all_code->{$class1} };
 519
 520         my $class1_to_link_table_rel_name = $class1_to_link_table_rel->{args}[0];
 521
 522         my $class2_to_link_table_rel = first {
 523             $_->{method} eq 'has_many' && $_->{args}[1] eq $class
 524         } @{ $all_code->{$class2} };
 525
 526         my $class2_to_link_table_rel_name = $class2_to_link_table_rel->{args}[0];
 527
 528         my $class1_link_rel = $rels->[1]{args}[0];
 529         my $class2_link_rel = $rels->[0]{args}[0];
 530
 531         my @class1_from_cols = apply { s/^self\.//i } values %{
 532             $class1_to_link_table_rel->{args}[2]
 533         };
 534
 535         my @class1_link_cols = apply { s/^self\.//i } values %{ $rels->[1]{args}[2] };
 536
 537         my @class1_to_cols = apply { s/^foreign\.//i } keys %{ $rels->[1]{args}[2] };
 538
 539         my @class2_from_cols = apply { s/^self\.//i } values %{
 540             $class2_to_link_table_rel->{args}[2]
 541         };
 542
 543         my @class2_link_cols = apply { s/^self\.//i } values %{ $rels->[0]{args}[2] };
 544
 545         my @class2_to_cols = apply { s/^foreign\.//i } keys %{ $rels->[0]{args}[2] };
 546
 547         my $link_moniker = $rels->[0]{extra}{local_moniker};
 548
 549         my @link_table_cols =
 550             @{[ $self->schema->source($link_moniker)->columns ]};
 551
 552         my @link_table_primary_cols =
 553             @{[ $self->schema->source($link_moniker)->primary_columns ]};
 554
 555         next unless @class1_link_cols + @class2_link_cols == @link_table_cols
 556             && @link_table_cols == @link_table_primary_cols;
 557
 558         my ($class1_to_class2_relname) = $self->_rel_name_map(
 559             ($self->_inflect_plural($class1_link_rel))[0],
 560             'many_to_many',
 561             $class1,
 562             $class1_local_moniker,
 563             \@class1_from_cols,
 564             $class2,
 565             $class1_remote_moniker,
 566             \@class1_to_cols,
 567             {
 568                 link_class => $class,
 569                 link_moniker => $link_moniker,
 570                 link_rel_name => $class1_to_link_table_rel_name,
 571             },
 572         );
 573
 574         $class1_to_class2_relname = $self->_resolve_relname_collision(
 575             $class1_local_moniker,
 576             \@class1_from_cols,
 577             $class1_to_class2_relname,
 578         );
 579
 580         my ($class2_to_class1_relname) = $self->_rel_name_map(
 581             ($self->_inflect_plural($class2_link_rel))[0],
 582             'many_to_many',
 583             $class1,
 584             $class2_local_moniker,
 585             \@class2_from_cols,
 586             $class2,
 587             $class2_remote_moniker,
 588             \@class2_to_cols,
 589             {
 590                 link_class => $class,
 591                 link_moniker => $link_moniker,
 592                 link_rel_name => $class2_to_link_table_rel_name,
 593             },
 594         );
 595
 596         $class2_to_class1_relname = $self->_resolve_relname_collision(
 597             $class2_local_moniker,
 598             \@class2_from_cols,
 599             $class2_to_class1_relname,
 600         );
 601
 602         push @{$all_code->{$class1}}, {
 603             method => 'many_to_many',
 604             args   => [
 605                 $class1_to_class2_relname,
 606                 $class1_to_link_table_rel_name,
 607                 $class1_link_rel,
 608             ],
 609             extra  => {
 610                 local_class    => $class1,
 611                 link_class     => $class,
 612                 local_moniker  => $class1_local_moniker,
 613                 remote_moniker => $class1_remote_moniker,
 614             },
 615         };
 616
 617         push @{$all_code->{$class2}}, {
 618             method => 'many_to_many',
 619             args   => [
 620                 $class2_to_class1_relname,
 621                 $class2_to_link_table_rel_name,
 622                 $class2_link_rel,
 623             ],
 624             extra  => {
 625                 local_class    => $class2,
 626                 link_class     => $class,
 627                 local_moniker  => $class2_local_moniker,
 628                 remote_moniker => $class2_remote_moniker,
 629             },
 630         };
 631     }
 632 }
 633
 634 sub _duplicates {
 635     my ($self, $rels) = @_;
 636
 637     my @rels = map [ $_->{args}[0] => $_ ], @$rels;
 638     my %rel_names;
 639     $rel_names{$_}++ foreach map $_->[0], @rels;
 640
 641     my @dups = grep $rel_names{$_} > 1, keys %rel_names;
 642
 643     my %dups;
 644
 645     foreach my $dup (@dups) {
 646         $dups{$dup} = [ map $_->[1], grep { $_->[0] eq $dup } @rels ];
 647     }
 648
 649     return if not %dups;
 650
 651     return \%dups;
 652 }
 653
 654 sub _tagger {
 655     my $self = shift;
 656
 657     $self->__tagger(Lingua::EN::Tagger->new) unless $self->__tagger;
 658
 659     return $self->__tagger;
 660 }
 661
 662 sub _adjectives {
 663     my ($self, @cols) = @_;
 664
 665     my @adjectives;
 666
 667     foreach my $col (@cols) {
 668         my @words = split_name $col;
 669
 670         my $tagged = $self->_tagger->get_readable(join ' ', @words);
 671
 672         push @adjectives, $tagged =~ m{\G(\w+)/JJ\s+}g;
 673     }
 674
 675     return @adjectives;
 676 }
 677
 678 sub _name_to_identifier {
 679     my ($self, $name) = @_;
 680
 681     my $to_identifier = $self->loader->naming->{force_ascii} ?
 682         \&String::ToIdentifier::EN::to_identifier
 683         : \&String::ToIdentifier::EN::Unicode::to_identifier;
 684
 685     return join '_', map lc, split_name $to_identifier->($name, '_');
 686 }
 687
 688 sub _disambiguate {
 689     my ($self, $all_code, $in_class, $dups) = @_;
 690
 691     DUP: foreach my $dup (keys %$dups) {
 692         my @rels = @{ $dups->{$dup} };
 693
 694         # Check if there are rels to the same table name in different
 695         # schemas/databases, if so qualify them.
 696         my @tables = map $self->loader->moniker_to_table->{$_->{extra}{remote_moniker}},
 697                         @rels;
 698
 699         # databases are different, prepend database
 700         if ($tables[0]->can('database') && (uniq map $_->database||'', @tables) > 1) {
 701             # If any rels are in the same database, we have to distinguish by
 702             # both schema and database.
 703             my %db_counts;
 704             $db_counts{$_}++ for map $_->database, @tables;
 705             my $use_schema = any { $_ > 1 } values %db_counts;
 706
 707             foreach my $i (0..$#rels) {
 708                 my $rel   = $rels[$i];
 709                 my $table = $tables[$i];
 710
 711                 $rel->{args}[0] = $self->_name_to_identifier($table->database)
 712                     . ($use_schema ? ('_' . $self->name_to_identifier($table->schema)) : '')
 713                     . '_' . $rel->{args}[0];
 714             }
 715             next DUP;
 716         }
 717         # schemas are different, prepend schema
 718         elsif ((uniq map $_->schema||'', @tables) > 1) {
 719             foreach my $i (0..$#rels) {
 720                 my $rel   = $rels[$i];
 721                 my $table = $tables[$i];
 722
 723                 $rel->{args}[0] = $self->_name_to_identifier($table->schema)
 724                     . '_' . $rel->{args}[0];
 725             }
 726             next DUP;
 727         }
 728
 729         foreach my $rel (@rels) {
 730             next if $rel->{method} =~ /^(?:belongs_to|many_to_many)\z/;
 731
 732             my @to_cols = apply { s/^foreign\.//i }
 733                 keys %{ $rel->{args}[2] };
 734
 735             my @adjectives = $self->_adjectives(@to_cols);
 736
 737             # If there are no adjectives, and there is only one might_have
 738             # rel to that class, we hardcode 'active'.
 739
 740             my $to_class = $rel->{args}[1];
 741
 742             if ((not @adjectives)
 743                 && (grep { $_->{method} eq 'might_have'
 744                            && $_->{args}[1] eq $to_class } @{ $all_code->{$in_class} }) == 1) {
 745
 746                 @adjectives = 'active';
 747             }
 748
 749             if (@adjectives) {
 750                 my $rel_name = join '_', sort(@adjectives), $rel->{args}[0];
 751
 752                 ($rel_name) = $rel->{method} eq 'might_have' ?
 753                     $self->_inflect_singular($rel_name)
 754                     :
 755                     $self->_inflect_plural($rel_name);
 756
 757                 my ($local_class, $local_moniker, $remote_moniker)
 758                     = @{ $rel->{extra} }
 759                         {qw/local_class local_moniker remote_moniker/};
 760
 761                 my @from_cols = apply { s/^self\.//i }
 762                     values %{ $rel->{args}[2] };
 763
 764                 ($rel_name) = $self->_rel_name_map($rel_name, $rel->{method}, $local_class, $local_moniker, \@from_cols, $to_class, $remote_moniker, \@to_cols);
 765
 766                 $rel_name = $self->_resolve_relname_collision($local_moniker, \@from_cols, $rel_name);
 767
 768                 $rel->{args}[0] = $rel_name;
 769             }
 770         }
 771     }
 772
 773     # Check again for duplicates, since the heuristics above may not have resolved them all.
 774
 775     if ($dups = $self->_duplicates($all_code->{$in_class})) {
 776         foreach my $dup (keys %$dups) {
 777             # sort by method
 778             my @rels = map $_->[1], sort { $a->[0] <=> $b->[0] } map [
 779                 {
 780                     belongs_to   => 3,
 781                     has_many     => 2,
 782                     might_have   => 1,
 783                     many_to_many => 0,
 784                 }->{$_->{method}}, $_
 785             ], @{ $dups->{$dup} };
 786
 787             my $rel_num = 2;
 788
 789             foreach my $rel (@rels[1 .. $#rels]) {
 790                 my $inflect_type = $rel->{method} =~ /^(?:many_to_many|has_many)\z/ ?
 791                     'inflect_plural'
 792                     :
 793                     'inflect_singular';
 794
 795                 my $inflect_method = "_$inflect_type";
 796
 797                 my $relname_new_uninflected = $rel->{args}[0] . "_$rel_num";
 798
 799                 $rel_num++;
 800
 801                 my ($local_class, $local_moniker, $remote_moniker)
 802                     = @{ $rel->{extra} }
 803                         {qw/local_class local_moniker remote_moniker/};
 804
 805                 my (@from_cols, @to_cols, $to_class);
 806
 807                 if ($rel->{method} eq 'many_to_many') {
 808                     @from_cols = apply { s/^self\.//i } values %{
 809                         (first { $_->{args}[0] eq $rel->{args}[1] } @{ $all_code->{$local_class} })
 810                             ->{args}[2]
 811                     };
 812                     @to_cols   = apply { s/^foreign\.//i } keys %{
 813                         (first { $_->{args}[0] eq $rel->{args}[2] }
 814                             @{ $all_code->{ $rel->{extra}{link_class} } })
 815                                 ->{args}[2]
 816                     };
 817                     $to_class  = $self->schema->source($remote_moniker)->result_class;
 818                 }
 819                 else {
 820                     @from_cols = apply { s/^self\.//i }    values %{ $rel->{args}[2] };
 821                     @to_cols   = apply { s/^foreign\.//i } keys   %{ $rel->{args}[2] };
 822                     $to_class  = $rel->{args}[1];
 823                 }
 824
 825                 my ($relname_new, $inflect_mapped) =
 826                     $self->$inflect_method($relname_new_uninflected);
 827
 828                 my $rel_name_mapped;
 829
 830                 ($relname_new, $rel_name_mapped) = $self->_rel_name_map($relname_new, $rel->{method}, $local_class, $local_moniker, \@from_cols, $to_class, $remote_moniker, \@to_cols);
 831
 832                 my $mapped = $inflect_mapped || $rel_name_mapped;
 833
 834                 warn <<"EOF" unless $mapped;
 835 Could not find a proper name for relationship '$relname_new' in source
 836 '$local_moniker' for columns '@{[ join ',', @from_cols ]}'. Supply a value in
 837 '$inflect_type' for '$relname_new_uninflected' or 'rel_name_map' for
 838 '$relname_new' to name this relationship.
 839 EOF
 840
 841                 $relname_new = $self->_resolve_relname_collision($local_moniker, \@from_cols, $relname_new);
 842
 843                 $rel->{args}[0] = $relname_new;
 844             }
 845         }
 846     }
 847 }
 848
 849 sub _relnames_and_method {
 850     my ( $self, $local_moniker, $rel, $cond, $uniqs, $counters ) = @_;
 851
 852     my $remote_moniker  = $rel->{remote_source};
 853     my $remote_obj      = $self->schema->source( $remote_moniker );
 854     my $remote_class    = $self->schema->class(  $remote_moniker );
 855     my $remote_relname  = $self->_remote_relname( $rel->{remote_table}, $cond);
 856
 857     my $local_cols      = $rel->{local_columns};
 858     my $local_table     = $rel->{local_table};
 859     my $local_class     = $self->schema->class($local_moniker);
 860     my $local_source    = $self->schema->source($local_moniker);
 861
 862     my $local_relname_uninflected = $self->_normalize_name($local_table);
 863     my ($local_relname) = $self->_inflect_plural($self->_normalize_name($local_table));
 864
 865     my $remote_method = 'has_many';
 866
 867     # If the local columns have a UNIQUE constraint, this is a one-to-one rel
 868     if (array_eq([ $local_source->primary_columns ], $local_cols) ||
 869             first { array_eq($_->[1], $local_cols) } @$uniqs) {
 870         $remote_method   = 'might_have';
 871         ($local_relname) = $self->_inflect_singular($local_relname_uninflected);
 872     }
 873
 874     # If more than one rel between this pair of tables, use the local
 875     # col names to distinguish, unless the rel was created previously.
 876     if ($counters->{$remote_moniker} > 1) {
 877         my $relationship_exists = 0;
 878
 879         if (-f (my $existing_remote_file = $self->loader->get_dump_filename($remote_class))) {
 880             my $class = "${remote_class}Temporary";
 881
 882             if (not Class::Inspector->loaded($class)) {
 883                 my $code = slurp_file $existing_remote_file;
 884
 885                 $code =~ s/(?<=package $remote_class)/Temporary/g;
 886
 887                 $code =~ s/__PACKAGE__->meta->make_immutable[^;]*;//g;
 888
 889                 eval $code;
 890                 die $@ if $@;
 891
 892                 push @{ $self->_temp_classes }, $class;
 893             }
 894
 895             if ($class->has_relationship($local_relname)) {
 896                 my $rel_cols = [ sort { $a cmp $b } apply { s/^foreign\.//i }
 897                     (keys %{ $class->relationship_info($local_relname)->{cond} }) ];
 898
 899                 $relationship_exists = 1 if array_eq([ sort @$local_cols ], $rel_cols);
 900             }
 901         }
 902
 903         if (not $relationship_exists) {
 904             my $colnames = q{_} . $self->_normalize_name(join '_', @$local_cols);
 905             $remote_relname .= $colnames if keys %$cond > 1;
 906
 907             $local_relname = $self->_strip_id_postfix($self->_normalize_name($local_table . $colnames));
 908
 909             $local_relname_uninflected = $local_relname;
 910             ($local_relname) = $self->_inflect_plural($local_relname);
 911
 912             # if colnames were added and this is a might_have, re-inflect
 913             if ($remote_method eq 'might_have') {
 914                 ($local_relname) = $self->_inflect_singular($local_relname_uninflected);
 915             }
 916         }
 917     }
 918
 919     return ($local_relname, $remote_relname, $remote_method);
 920 }
 921
 922 sub _rel_name_map {
 923     my ($self, $relname, $method, $local_class, $local_moniker, $local_cols,
 924         $remote_class, $remote_moniker, $remote_cols, $extra) = @_;
 925
 926     my $info = {
 927         %{$extra || {}},
 928         name           => $relname,
 929         type           => $method,
 930         local_class    => $local_class,
 931         local_moniker  => $local_moniker,
 932         local_columns  => $local_cols,
 933         remote_class   => $remote_class,
 934         remote_moniker => $remote_moniker,
 935         remote_columns => $remote_cols,
 936     };
 937
 938     my $new_name = $relname;
 939
 940     my $map = $self->rel_name_map;
 941     my $mapped = 0;
 942
 943     if ('HASH' eq ref($map)) {
 944         my $name = $info->{name};
 945         my $moniker = $info->{local_moniker};
 946         if ($map->{$moniker} and 'HASH' eq ref($map->{$moniker})
 947             and $map->{$moniker}{$name}
 948         ) {
 949             $new_name = $map->{$moniker}{$name};
 950             $mapped   = 1;
 951         }
 952         elsif ($map->{$name} and not 'HASH' eq ref($map->{$name})) {
 953             $new_name = $map->{$name};
 954             $mapped   = 1;
 955         }
 956     }
 957     elsif ('CODE' eq ref($map)) {
 958         my $name = $map->($info);
 959         if ($name) {
 960             $new_name = $name;
 961             $mapped   = 1;
 962         }
 963     }
 964
 965     return ($new_name, $mapped);
 966 }
 967
 968 sub _cleanup {
 969     my $self = shift;
 970
 971     for my $class (@{ $self->_temp_classes }) {
 972         Class::Unload->unload($class);
 973     }
 974
 975     $self->_temp_classes([]);
 976 }
 977
 978 =head1 AUTHOR
 979
 980 See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
 981
 982 =head1 LICENSE
 983
 984 This library is free software; you can redistribute it and/or modify it under
 985 the same terms as Perl itself.
 986
 987 =cut
 988
 989 1;
 990 # vim:et sts=4 sw=4 tw=0: