lib/DBIx/Class/Schema/Loader/RelBuilder.pm

   1 package DBIx::Class::Schema::Loader::RelBuilder;
   2
   3 use strict;
   4 use warnings;
   5 use base 'Class::Accessor::Grouped';
   6 use mro 'c3';
   7 use Carp::Clan qw/^DBIx::Class/;
   8 use Scalar::Util 'weaken';
   9 use DBIx::Class::Schema::Loader::Utils qw/split_name slurp_file array_eq/;
  10 use Try::Tiny;
  11 use List::Util 'first';
  12 use List::MoreUtils qw/apply uniq any all/;
  13 use namespace::clean;
  14 use Lingua::EN::Inflect::Phrase ();
  15 use Lingua::EN::Tagger ();
  16 use String::ToIdentifier::EN ();
  17 use String::ToIdentifier::EN::Unicode ();
  18 use Class::Unload ();
  19 use Class::Inspector ();
  20
  21 our $VERSION = '0.07042';
  22
  23 # Glossary:
  24 #
  25 # local_relname  -- name of relationship from the local table referring to the remote table
  26 # remote_relname -- name of relationship from the remote table referring to the local table
  27 # remote_method  -- relationship type from remote table to local table, usually has_many
  28
  29 =head1 NAME
  30
  31 DBIx::Class::Schema::Loader::RelBuilder - Builds relationships for DBIx::Class::Schema::Loader
  32
  33 =head1 SYNOPSIS
  34
  35 See L<DBIx::Class::Schema::Loader> and L<DBIx::Class::Schema::Loader::Base>.
  36
  37 =head1 DESCRIPTION
  38
  39 This class builds relationships for L<DBIx::Class::Schema::Loader>.  This
  40 is module is not (yet) for external use.
  41
  42 =head1 METHODS
  43
  44 =head2 new
  45
  46 Arguments: $loader object
  47
  48 =head2 generate_code
  49
  50 Arguments:
  51
  52     [
  53         [ local_moniker1 (scalar), fk_info1 (arrayref), uniq_info1 (arrayref) ]
  54         [ local_moniker2 (scalar), fk_info2 (arrayref), uniq_info2 (arrayref) ]
  55         ...
  56     ]
  57
  58 This generates the code for the relationships of each table.
  59
  60 C<local_moniker> is the moniker name of the table which had the REFERENCES
  61 statements.  The fk_info arrayref's contents should take the form:
  62
  63     [
  64         {
  65             local_table    => 'some_table',
  66             local_moniker  => 'SomeTable',
  67             local_columns  => [ 'col2', 'col3' ],
  68             remote_table   => 'another_table_moniker',
  69             remote_moniker => 'AnotherTableMoniker',
  70             remote_columns => [ 'col5', 'col7' ],
  71         },
  72         {
  73             local_table    => 'some_other_table',
  74             local_moniker  => 'SomeOtherTable',
  75             local_columns  => [ 'col1', 'col4' ],
  76             remote_table   => 'yet_another_table_moniker',
  77             remote_moniker => 'YetAnotherTableMoniker',
  78             remote_columns => [ 'col1', 'col2' ],
  79         },
  80         # ...
  81     ],
  82
  83 The uniq_info arrayref's contents should take the form:
  84
  85     [
  86         [
  87             uniq_constraint_name         => [ 'col1', 'col2' ],
  88         ],
  89         [
  90             another_uniq_constraint_name => [ 'col1', 'col2' ],
  91         ],
  92     ],
  93
  94 This method will return the generated relationships as a hashref keyed on the
  95 class names.  The values are arrayrefs of hashes containing method name and
  96 arguments, like so:
  97
  98   {
  99       'Some::Source::Class' => [
 100           { method => 'belongs_to', arguments => [ 'col1', 'Another::Source::Class' ],
 101           { method => 'has_many', arguments => [ 'anothers', 'Yet::Another::Source::Class', 'col15' ],
 102       ],
 103       'Another::Source::Class' => [
 104           # ...
 105       ],
 106       # ...
 107   }
 108
 109 =cut
 110
 111 __PACKAGE__->mk_group_accessors('simple', qw/
 112     loader
 113     schema
 114     inflect_plural
 115     inflect_singular
 116     relationship_attrs
 117     rel_collision_map
 118     rel_name_map
 119     _temp_classes
 120     __tagger
 121 /);
 122
 123 sub new {
 124     my ($class, $loader) = @_;
 125
 126     # from old POD about this constructor:
 127     # C<$schema_class> should be a schema class name, where the source
 128     # classes have already been set up and registered.  Column info,
 129     # primary key, and unique constraints will be drawn from this
 130     # schema for all of the existing source monikers.
 131
 132     # Options inflect_plural and inflect_singular are optional, and
 133     # are better documented in L<DBIx::Class::Schema::Loader::Base>.
 134
 135     my $self = {
 136         loader             => $loader,
 137         schema             => $loader->schema,
 138         inflect_plural     => $loader->inflect_plural,
 139         inflect_singular   => $loader->inflect_singular,
 140         relationship_attrs => $loader->relationship_attrs,
 141         rel_collision_map  => $loader->rel_collision_map,
 142         rel_name_map       => $loader->rel_name_map,
 143         _temp_classes      => [],
 144     };
 145
 146     weaken $self->{loader}; #< don't leak
 147
 148     bless $self => $class;
 149
 150     # validate the relationship_attrs arg
 151     if( defined $self->relationship_attrs ) {
 152         (ref $self->relationship_attrs eq 'HASH' || ref $self->relationship_attrs eq 'CODE')
 153             or croak "relationship_attrs must be a hashref or coderef";
 154     }
 155
 156     return $self;
 157 }
 158
 159
 160 # pluralize a relationship name
 161 sub _inflect_plural {
 162     my ($self, $relname) = @_;
 163
 164     return '' if !defined $relname || $relname eq '';
 165
 166     my $result;
 167     my $mapped = 0;
 168
 169     if( ref $self->inflect_plural eq 'HASH' ) {
 170         if (exists $self->inflect_plural->{$relname}) {
 171             $result = $self->inflect_plural->{$relname};
 172             $mapped = 1;
 173         }
 174     }
 175     elsif( ref $self->inflect_plural eq 'CODE' ) {
 176         my $inflected = $self->inflect_plural->($relname);
 177         if ($inflected) {
 178             $result = $inflected;
 179             $mapped = 1;
 180         }
 181     }
 182
 183     return ($result, $mapped) if $mapped;
 184
 185     return ($self->_to_PL($relname), 0);
 186 }
 187
 188 # Singularize a relationship name
 189 sub _inflect_singular {
 190     my ($self, $relname) = @_;
 191
 192     return '' if !defined $relname || $relname eq '';
 193
 194     my $result;
 195     my $mapped = 0;
 196
 197     if( ref $self->inflect_singular eq 'HASH' ) {
 198         if (exists $self->inflect_singular->{$relname}) {
 199             $result = $self->inflect_singular->{$relname};
 200             $mapped = 1;
 201         }
 202     }
 203     elsif( ref $self->inflect_singular eq 'CODE' ) {
 204         my $inflected = $self->inflect_singular->($relname);
 205         if ($inflected) {
 206             $result = $inflected;
 207             $mapped = 1;
 208         }
 209     }
 210
 211     return ($result, $mapped) if $mapped;
 212
 213     return ($self->_to_S($relname), 0);
 214 }
 215
 216 sub _to_PL {
 217     my ($self, $name) = @_;
 218
 219     $name =~ s/_/ /g;
 220     my $plural = Lingua::EN::Inflect::Phrase::to_PL($name);
 221     $plural =~ s/ /_/g;
 222
 223     return $plural;
 224 }
 225
 226 sub _to_S {
 227     my ($self, $name) = @_;
 228
 229     $name =~ s/_/ /g;
 230     my $singular = Lingua::EN::Inflect::Phrase::to_S($name);
 231     $singular =~ s/ /_/g;
 232
 233     return $singular;
 234 }
 235
 236 sub _default_relationship_attrs { +{
 237     has_many => {
 238         cascade_delete => 0,
 239         cascade_copy   => 0,
 240     },
 241     might_have => {
 242         cascade_delete => 0,
 243         cascade_copy   => 0,
 244     },
 245     belongs_to => {
 246         on_delete => 'CASCADE',
 247         on_update => 'CASCADE',
 248         is_deferrable => 1,
 249     },
 250 } }
 251
 252 # Accessor for options to be passed to each generated relationship type. takes
 253 # the relationship type name and optionally any attributes from the database
 254 # (such as FK ON DELETE/UPDATE and DEFERRABLE clauses), and returns a
 255 # hashref or undef if nothing is set.
 256 #
 257 # The attributes from the database override the default attributes, which in
 258 # turn are overridden by user supplied attributes.
 259 sub _relationship_attrs {
 260     my ( $self, $reltype, $db_attrs, $params ) = @_;
 261     my $r = $self->relationship_attrs;
 262
 263     my %composite = (
 264         %{ $self->_default_relationship_attrs->{$reltype} || {} },
 265         %{ $db_attrs || {} },
 266         (
 267             ref $r eq 'HASH' ? (
 268                 %{ $r->{all} || {} },
 269                 %{ $r->{$reltype} || {} },
 270             )
 271             :
 272             ()
 273         ),
 274     );
 275
 276     if (ref $r eq 'CODE') {
 277         $params->{attrs} = \%composite;
 278
 279         my %ret = %{ $r->(%$params) || {} };
 280
 281         %composite = %ret if %ret;
 282     }
 283
 284     return %composite ? \%composite : undef;
 285 }
 286
 287 sub _strip_id_postfix {
 288     my ($self, $name) = @_;
 289
 290     $name =~ s/_?(?:id|ref|cd|code|num)\z//i;
 291
 292     return $name;
 293 }
 294
 295 sub _remote_attrs {
 296     my ($self, $local_moniker, $local_cols, $fk_attrs, $params) = @_;
 297
 298     # get our set of attrs from _relationship_attrs, which uses the FK attrs if available
 299     my $attrs = $self->_relationship_attrs('belongs_to', $fk_attrs, $params) || {};
 300
 301     # If any referring column is nullable, make 'belongs_to' an
 302     # outer join, unless explicitly set by relationship_attrs
 303     my $nullable = first { $self->schema->source($local_moniker)->column_info($_)->{is_nullable} } @$local_cols;
 304     $attrs->{join_type} = 'LEFT' if $nullable && !defined $attrs->{join_type};
 305
 306     return $attrs;
 307 }
 308
 309 sub _sanitize_name {
 310     my ($self, $name) = @_;
 311
 312     $name = $self->loader->_to_identifier('relationships', $name, '_');
 313
 314     $name =~ s/\W+/_/g; # if naming >= 8 to_identifier takes care of it
 315
 316     return $name;
 317 }
 318
 319 sub _normalize_name {
 320     my ($self, $name) = @_;
 321
 322     $name = $self->_sanitize_name($name);
 323
 324     my @words = split_name $name, $self->loader->_get_naming_v('relationships');
 325
 326     return join '_', map lc, @words;
 327 }
 328
 329 sub _local_relname {
 330     my ($self, $remote_table, $cond) = @_;
 331
 332     my $local_relname;
 333     # for single-column case, set the remote relname to the column
 334     # name, to make filter accessors work, but strip trailing _id
 335     if(scalar keys %{$cond} == 1) {
 336         my ($col) = values %{$cond};
 337         $col = $self->_strip_id_postfix($self->_normalize_name($col));
 338         ($local_relname) = $self->_inflect_singular($col);
 339     }
 340     else {
 341         ($local_relname) = $self->_inflect_singular($self->_normalize_name($remote_table));
 342     }
 343
 344     return $local_relname;
 345 }
 346
 347 sub _resolve_relname_collision {
 348     my ($self, $moniker, $cols, $relname) = @_;
 349
 350     return $relname if $relname eq 'id'; # this shouldn't happen, but just in case
 351
 352     my $table = $self->loader->moniker_to_table->{$moniker};
 353
 354     if ($self->loader->_is_result_class_method($relname, $table)) {
 355         if (my $map = $self->rel_collision_map) {
 356             for my $re (keys %$map) {
 357                 if (my @matches = $relname =~ /$re/) {
 358                     return sprintf $map->{$re}, @matches;
 359                 }
 360             }
 361         }
 362
 363         my $new_relname = $relname;
 364         while ($self->loader->_is_result_class_method($new_relname, $table)) {
 365             $new_relname .= '_rel'
 366         }
 367
 368         warn <<"EOF";
 369 Relationship '$relname' in source '$moniker' for columns '@{[ join ',', @$cols ]}' collides with an inherited method. Renaming to '$new_relname'.
 370 See "RELATIONSHIP NAME COLLISIONS" in perldoc DBIx::Class::Schema::Loader::Base .
 371 EOF
 372
 373         return $new_relname;
 374     }
 375
 376     return $relname;
 377 }
 378
 379 sub generate_code {
 380     my ($self, $tables) = @_;
 381
 382     # make a copy to destroy
 383     my @tables = @$tables;
 384
 385     my $all_code = {};
 386
 387     while (my ($local_moniker, $rels, $uniqs) = @{ shift @tables || [] }) {
 388         my $local_class = $self->schema->class($local_moniker);
 389
 390         my %counters;
 391         foreach my $rel (@$rels) {
 392             next if !$rel->{remote_source};
 393             $counters{$rel->{remote_source}}++;
 394         }
 395
 396         foreach my $rel (@$rels) {
 397             my $remote_moniker = $rel->{remote_source}
 398                 or next;
 399
 400             my $remote_class   = $self->schema->class($remote_moniker);
 401             my $remote_obj     = $self->schema->source($remote_moniker);
 402             my $remote_cols    = $rel->{remote_columns} || [ $remote_obj->primary_columns ];
 403
 404             my $local_cols     = $rel->{local_columns};
 405
 406             if($#$local_cols != $#$remote_cols) {
 407                 croak "Column count mismatch: $local_moniker (@$local_cols) "
 408                     . "$remote_moniker (@$remote_cols)";
 409             }
 410
 411             my %cond;
 412             @cond{@$remote_cols} = @$local_cols;
 413
 414             my ( $local_relname, $remote_relname, $remote_method ) =
 415                 $self->_relnames_and_method( $local_moniker, $rel, \%cond,  $uniqs, \%counters );
 416             my $local_method  = 'belongs_to';
 417
 418             ($local_relname) = $self->_rel_name_map(
 419                 $local_relname, $local_method,
 420                 $local_class, $local_moniker, $local_cols,
 421                 $remote_class, $remote_moniker, $remote_cols,
 422             );
 423             ($remote_relname) = $self->_rel_name_map(
 424                 $remote_relname, $remote_method,
 425                 $remote_class, $remote_moniker, $remote_cols,
 426                 $local_class, $local_moniker, $local_cols,
 427             );
 428
 429             $local_relname = $self->_resolve_relname_collision(
 430                 $local_moniker, $local_cols, $local_relname,
 431             );
 432             $remote_relname = $self->_resolve_relname_collision(
 433                 $remote_moniker, $remote_cols, $remote_relname,
 434             );
 435
 436             my $rel_attrs_params = {
 437                 rel_name      => $local_relname,
 438                 rel_type      => $local_method,
 439                 local_source  => $self->schema->source($local_moniker),
 440                 remote_source => $self->schema->source($remote_moniker),
 441                 local_table   => $rel->{local_table},
 442                 local_cols    => $local_cols,
 443                 remote_table  => $rel->{remote_table},
 444                 remote_cols   => $remote_cols,
 445             };
 446
 447             push @{$all_code->{$local_class}}, {
 448                 method => $local_method,
 449                 args => [
 450                     $local_relname,
 451                     $remote_class,
 452                     \%cond,
 453                     $self->_remote_attrs($local_moniker, $local_cols, $rel->{attrs}, $rel_attrs_params),
 454                 ],
 455                 extra => {
 456                     local_class    => $local_class,
 457                     local_moniker  => $local_moniker,
 458                     remote_moniker => $remote_moniker,
 459                 },
 460             };
 461
 462             my %rev_cond = reverse %cond;
 463             for (keys %rev_cond) {
 464                 $rev_cond{"foreign.$_"} = "self.".$rev_cond{$_};
 465                 delete $rev_cond{$_};
 466             }
 467
 468             $rel_attrs_params = {
 469                 rel_name      => $remote_relname,
 470                 rel_type      => $remote_method,
 471                 local_source  => $self->schema->source($remote_moniker),
 472                 remote_source => $self->schema->source($local_moniker),
 473                 local_table   => $rel->{remote_table},
 474                 local_cols    => $remote_cols,
 475                 remote_table  => $rel->{local_table},
 476                 remote_cols   => $local_cols,
 477             };
 478
 479             push @{$all_code->{$remote_class}}, {
 480                 method => $remote_method,
 481                 args => [
 482                     $remote_relname,
 483                     $local_class,
 484                     \%rev_cond,
 485                     $self->_relationship_attrs($remote_method, {}, $rel_attrs_params),
 486                 ],
 487                 extra => {
 488                     local_class    => $remote_class,
 489                     local_moniker  => $remote_moniker,
 490                     remote_moniker => $local_moniker,
 491                 },
 492             };
 493         }
 494     }
 495
 496     $self->_generate_m2ms($all_code);
 497
 498     # disambiguate rels with the same name
 499     foreach my $class (keys %$all_code) {
 500         my $dups = $self->_duplicates($all_code->{$class});
 501
 502         $self->_disambiguate($all_code, $class, $dups) if $dups;
 503     }
 504
 505     $self->_cleanup;
 506
 507     return $all_code;
 508 }
 509
 510 # Find classes with only 2 FKs which are the PK and make many_to_many bridges for them.
 511 sub _generate_m2ms {
 512     my ($self, $all_code) = @_;
 513
 514     LINK_CLASS:
 515     foreach my $link_class (sort keys %$all_code) {
 516         my @rels = grep $_->{method} eq 'belongs_to', @{$all_code->{$link_class}};
 517         next unless @rels == 2;
 518
 519         my @class;
 520         foreach my $this (0, 1) {
 521             my $that = $this ? 0 : 1;
 522             my %class;
 523             $class[$this] = \%class;
 524             $class{local_moniker}  = $rels[$this]{extra}{remote_moniker};
 525             $class{remote_moniker} = $rels[$that]{extra}{remote_moniker};
 526
 527             $class{class} = $rels[$this]{args}[1];
 528
 529             my %link_cols = map { $_ => 1 } apply { s/^self\.//i } values %{ $rels[$this]{args}[2] };
 530
 531             $class{link_table_rel} = first {
 532                 $_->{method} eq 'has_many'
 533                     and
 534                 $_->{args}[1] eq $link_class
 535                     and
 536                 all { $link_cols{$_} } apply { s/^foreign\.//i } keys %{$_->{args}[2]}
 537             } @{ $all_code->{$class{class}} };
 538
 539             next LINK_CLASS unless $class{link_table_rel};
 540
 541             $class{link_table_rel_name} = $class{link_table_rel}{args}[0];
 542
 543             $class{link_rel} = $rels[$that]{args}[0];
 544
 545             $class{from_cols} = [ apply { s/^self\.//i } values %{
 546                 $class{link_table_rel}->{args}[2]
 547             } ];
 548
 549             $class{to_cols} = [ apply { s/^foreign\.//i } keys %{ $rels[$that]{args}[2] } ];
 550         }
 551
 552         my $link_moniker = $rels[0]{extra}{local_moniker};
 553
 554         my @link_table_cols =
 555             @{[ $self->schema->source($link_moniker)->columns ]};
 556
 557         my @link_table_primary_cols =
 558             @{[ $self->schema->source($link_moniker)->primary_columns ]};
 559
 560         next unless @{$class[0]{to_cols}} + @{$class[1]{to_cols}} == @link_table_cols
 561             && @link_table_cols == @link_table_primary_cols;
 562
 563         foreach my $this (0, 1) {
 564             my $that = $this ? 0 : 1;
 565             ($class[$this]{m2m_relname}) = $self->_rel_name_map(
 566                 ($self->_inflect_plural($class[$this]{link_rel}))[0],
 567                 'many_to_many',
 568                 @{$class[$this]}{qw(class local_moniker from_cols)},
 569                 $class[$that]{class},
 570                 @{$class[$this]}{qw(remote_moniker to_cols)},
 571                 {
 572                     link_class => $link_class,
 573                     link_moniker => $link_moniker,
 574                     link_rel_name => $class[$this]{link_table_rel_name},
 575                 },
 576             );
 577
 578             $class[$this]{m2m_relname} = $self->_resolve_relname_collision(
 579                 @{$class[$this]}{qw(local_moniker from_cols m2m_relname)},
 580             );
 581         }
 582
 583         for my $this (0, 1) {
 584             my $that = $this ? 0 : 1;
 585
 586             push @{$all_code->{$class[$this]{class}}}, {
 587                 method => 'many_to_many',
 588                 args   => [
 589                     @{$class[$this]}{qw(m2m_relname link_table_rel_name link_rel)},
 590                     $self->_relationship_attrs('many_to_many', {}, {
 591                         rel_type => 'many_to_many',
 592                         rel_name => $class[$this]{class2_relname},
 593                         local_source => $self->schema->source($class[$this]{local_moniker}),
 594                         remote_source => $self->schema->source($class[$this]{remote_moniker}),
 595                         local_table => $self->loader->class_to_table->{$class[$this]{class}},
 596                         local_cols => $class[$this]{from_cols},
 597                         remote_table => $self->loader->class_to_table->{$class[$that]{class}},
 598                         remote_cols => $class[$that]{from_cols},
 599                     }) || (),
 600                 ],
 601                 extra  => {
 602                     local_class    => $class[$this]{class},
 603                     link_class     => $link_class,
 604                     local_moniker  => $class[$this]{local_moniker},
 605                     remote_moniker => $class[$this]{remote_moniker},
 606                 },
 607             };
 608         }
 609     }
 610 }
 611
 612 sub _duplicates {
 613     my ($self, $rels) = @_;
 614
 615     my @rels = map [ $_->{args}[0] => $_ ], @$rels;
 616     my %rel_names;
 617     $rel_names{$_}++ foreach map $_->[0], @rels;
 618
 619     my @dups = grep $rel_names{$_} > 1, keys %rel_names;
 620
 621     my %dups;
 622
 623     foreach my $dup (@dups) {
 624         $dups{$dup} = [ map $_->[1], grep { $_->[0] eq $dup } @rels ];
 625     }
 626
 627     return if not %dups;
 628
 629     return \%dups;
 630 }
 631
 632 sub _tagger {
 633     my $self = shift;
 634
 635     $self->__tagger(Lingua::EN::Tagger->new) unless $self->__tagger;
 636
 637     return $self->__tagger;
 638 }
 639
 640 sub _adjectives {
 641     my ($self, @cols) = @_;
 642
 643     my @adjectives;
 644
 645     foreach my $col (@cols) {
 646         my @words = split_name $col;
 647
 648         my $tagged = $self->_tagger->get_readable(join ' ', @words);
 649
 650         push @adjectives, $tagged =~ m{\G(\w+)/JJ\s+}g;
 651     }
 652
 653     return @adjectives;
 654 }
 655
 656 sub _name_to_identifier {
 657     my ($self, $name) = @_;
 658
 659     my $to_identifier = $self->loader->naming->{force_ascii} ?
 660         \&String::ToIdentifier::EN::to_identifier
 661         : \&String::ToIdentifier::EN::Unicode::to_identifier;
 662
 663     return join '_', map lc, split_name $to_identifier->($name, '_');
 664 }
 665
 666 sub _disambiguate {
 667     my ($self, $all_code, $in_class, $dups) = @_;
 668
 669     DUP: foreach my $dup (keys %$dups) {
 670         my @rels = @{ $dups->{$dup} };
 671
 672         # Check if there are rels to the same table name in different
 673         # schemas/databases, if so qualify them.
 674         my @tables = map $self->loader->moniker_to_table->{$_->{extra}{remote_moniker}},
 675                         @rels;
 676
 677         # databases are different, prepend database
 678         if ($tables[0]->can('database') && (uniq map $_->database||'', @tables) > 1) {
 679             # If any rels are in the same database, we have to distinguish by
 680             # both schema and database.
 681             my %db_counts;
 682             $db_counts{$_}++ for map $_->database, @tables;
 683             my $use_schema = any { $_ > 1 } values %db_counts;
 684
 685             foreach my $i (0..$#rels) {
 686                 my $rel   = $rels[$i];
 687                 my $table = $tables[$i];
 688
 689                 $rel->{args}[0] = $self->_name_to_identifier($table->database)
 690                     . ($use_schema ? ('_' . $self->name_to_identifier($table->schema)) : '')
 691                     . '_' . $rel->{args}[0];
 692             }
 693             next DUP;
 694         }
 695         # schemas are different, prepend schema
 696         elsif ((uniq map $_->schema||'', @tables) > 1) {
 697             foreach my $i (0..$#rels) {
 698                 my $rel   = $rels[$i];
 699                 my $table = $tables[$i];
 700
 701                 $rel->{args}[0] = $self->_name_to_identifier($table->schema)
 702                     . '_' . $rel->{args}[0];
 703             }
 704             next DUP;
 705         }
 706
 707         foreach my $rel (@rels) {
 708             next if $rel->{method} =~ /^(?:belongs_to|many_to_many)\z/;
 709
 710             my @to_cols = apply { s/^foreign\.//i }
 711                 keys %{ $rel->{args}[2] };
 712
 713             my @adjectives = $self->_adjectives(@to_cols);
 714
 715             # If there are no adjectives, and there is only one might_have
 716             # rel to that class, we hardcode 'active'.
 717
 718             my $to_class = $rel->{args}[1];
 719
 720             if ((not @adjectives)
 721                 && (grep { $_->{method} eq 'might_have'
 722                            && $_->{args}[1] eq $to_class } @{ $all_code->{$in_class} }) == 1) {
 723
 724                 @adjectives = 'active';
 725             }
 726
 727             if (@adjectives) {
 728                 my $rel_name = join '_', sort(@adjectives), $rel->{args}[0];
 729
 730                 ($rel_name) = $rel->{method} eq 'might_have' ?
 731                     $self->_inflect_singular($rel_name)
 732                     :
 733                     $self->_inflect_plural($rel_name);
 734
 735                 my ($local_class, $local_moniker, $remote_moniker)
 736                     = @{ $rel->{extra} }
 737                         {qw/local_class local_moniker remote_moniker/};
 738
 739                 my @from_cols = apply { s/^self\.//i }
 740                     values %{ $rel->{args}[2] };
 741
 742                 ($rel_name) = $self->_rel_name_map($rel_name, $rel->{method}, $local_class, $local_moniker, \@from_cols, $to_class, $remote_moniker, \@to_cols);
 743
 744                 $rel_name = $self->_resolve_relname_collision($local_moniker, \@from_cols, $rel_name);
 745
 746                 $rel->{args}[0] = $rel_name;
 747             }
 748         }
 749     }
 750
 751     # Check again for duplicates, since the heuristics above may not have resolved them all.
 752
 753     if ($dups = $self->_duplicates($all_code->{$in_class})) {
 754         foreach my $dup (keys %$dups) {
 755             # sort by method
 756             my @rels = map $_->[1], sort { $a->[0] <=> $b->[0] } map [
 757                 {
 758                     belongs_to   => 3,
 759                     has_many     => 2,
 760                     might_have   => 1,
 761                     many_to_many => 0,
 762                 }->{$_->{method}}, $_
 763             ], @{ $dups->{$dup} };
 764
 765             my $rel_num = 2;
 766
 767             foreach my $rel (@rels[1 .. $#rels]) {
 768                 my $inflect_type = $rel->{method} =~ /^(?:many_to_many|has_many)\z/ ?
 769                     'inflect_plural'
 770                     :
 771                     'inflect_singular';
 772
 773                 my $inflect_method = "_$inflect_type";
 774
 775                 my $relname_new_uninflected = $rel->{args}[0] . "_$rel_num";
 776
 777                 $rel_num++;
 778
 779                 my ($local_class, $local_moniker, $remote_moniker)
 780                     = @{ $rel->{extra} }
 781                         {qw/local_class local_moniker remote_moniker/};
 782
 783                 my (@from_cols, @to_cols, $to_class);
 784
 785                 if ($rel->{method} eq 'many_to_many') {
 786                     @from_cols = apply { s/^self\.//i } values %{
 787                         (first { $_->{args}[0] eq $rel->{args}[1] } @{ $all_code->{$local_class} })
 788                             ->{args}[2]
 789                     };
 790                     @to_cols   = apply { s/^foreign\.//i } keys %{
 791                         (first { $_->{args}[0] eq $rel->{args}[2] }
 792                             @{ $all_code->{ $rel->{extra}{link_class} } })
 793                                 ->{args}[2]
 794                     };
 795                     $to_class  = $self->schema->source($remote_moniker)->result_class;
 796                 }
 797                 else {
 798                     @from_cols = apply { s/^self\.//i }    values %{ $rel->{args}[2] };
 799                     @to_cols   = apply { s/^foreign\.//i } keys   %{ $rel->{args}[2] };
 800                     $to_class  = $rel->{args}[1];
 801                 }
 802
 803                 my ($relname_new, $inflect_mapped) =
 804                     $self->$inflect_method($relname_new_uninflected);
 805
 806                 my $rel_name_mapped;
 807
 808                 ($relname_new, $rel_name_mapped) = $self->_rel_name_map($relname_new, $rel->{method}, $local_class, $local_moniker, \@from_cols, $to_class, $remote_moniker, \@to_cols);
 809
 810                 my $mapped = $inflect_mapped || $rel_name_mapped;
 811
 812                 warn <<"EOF" unless $mapped;
 813 Could not find a proper name for relationship '$relname_new' in source
 814 '$local_moniker' for columns '@{[ join ',', @from_cols ]}'. Supply a value in
 815 '$inflect_type' for '$relname_new_uninflected' or 'rel_name_map' for
 816 '$relname_new' to name this relationship.
 817 EOF
 818
 819                 $relname_new = $self->_resolve_relname_collision($local_moniker, \@from_cols, $relname_new);
 820
 821                 $rel->{args}[0] = $relname_new;
 822             }
 823         }
 824     }
 825 }
 826
 827 sub _relnames_and_method {
 828     my ( $self, $local_moniker, $rel, $cond, $uniqs, $counters ) = @_;
 829
 830     my $remote_moniker  = $rel->{remote_source};
 831     my $remote_obj      = $self->schema->source( $remote_moniker );
 832     my $remote_class    = $self->schema->class(  $remote_moniker );
 833     my $local_relname   = $self->_local_relname( $rel->{remote_table}, $cond);
 834
 835     my $local_cols      = $rel->{local_columns};
 836     my $local_table     = $rel->{local_table};
 837     my $local_class     = $self->schema->class($local_moniker);
 838     my $local_source    = $self->schema->source($local_moniker);
 839
 840     my $remote_relname_uninflected = $self->_normalize_name($local_table);
 841     my ($remote_relname) = $self->_inflect_plural($self->_normalize_name($local_table));
 842
 843     my $remote_method = 'has_many';
 844
 845     # If the local columns have a UNIQUE constraint, this is a one-to-one rel
 846     if (array_eq([ $local_source->primary_columns ], $local_cols) ||
 847             first { array_eq($_->[1], $local_cols) } @$uniqs) {
 848         $remote_method   = 'might_have';
 849         ($remote_relname) = $self->_inflect_singular($remote_relname_uninflected);
 850     }
 851
 852     # If more than one rel between this pair of tables, use the local
 853     # col names to distinguish, unless the rel was created previously.
 854     if ($counters->{$remote_moniker} > 1) {
 855         my $relationship_exists = 0;
 856
 857         if (-f (my $existing_remote_file = $self->loader->get_dump_filename($remote_class))) {
 858             my $class = "${remote_class}Temporary";
 859
 860             if (not Class::Inspector->loaded($class)) {
 861                 my $code = slurp_file $existing_remote_file;
 862
 863                 $code =~ s/(?<=package $remote_class)/Temporary/g;
 864
 865                 $code =~ s/__PACKAGE__->meta->make_immutable[^;]*;//g;
 866
 867                 eval $code;
 868                 die $@ if $@;
 869
 870                 push @{ $self->_temp_classes }, $class;
 871             }
 872
 873             if ($class->has_relationship($remote_relname)) {
 874                 my $rel_cols = [ sort { $a cmp $b } apply { s/^foreign\.//i }
 875                     (keys %{ $class->relationship_info($remote_relname)->{cond} }) ];
 876
 877                 $relationship_exists = 1 if array_eq([ sort @$local_cols ], $rel_cols);
 878             }
 879         }
 880
 881         if (not $relationship_exists) {
 882             my $colnames = q{_} . $self->_normalize_name(join '_', @$local_cols);
 883             $local_relname .= $colnames if keys %$cond > 1;
 884
 885             $remote_relname = $self->_strip_id_postfix($self->_normalize_name($local_table . $colnames));
 886
 887             $remote_relname_uninflected = $remote_relname;
 888             ($remote_relname) = $self->_inflect_plural($remote_relname);
 889
 890             # if colnames were added and this is a might_have, re-inflect
 891             if ($remote_method eq 'might_have') {
 892                 ($remote_relname) = $self->_inflect_singular($remote_relname_uninflected);
 893             }
 894         }
 895     }
 896
 897     return ($local_relname, $remote_relname, $remote_method);
 898 }
 899
 900 sub _rel_name_map {
 901     my ($self, $relname, $method, $local_class, $local_moniker, $local_cols,
 902         $remote_class, $remote_moniker, $remote_cols, $extra) = @_;
 903
 904     my $info = {
 905         %{$extra || {}},
 906         name           => $relname,
 907         type           => $method,
 908         local_class    => $local_class,
 909         local_moniker  => $local_moniker,
 910         local_columns  => $local_cols,
 911         remote_class   => $remote_class,
 912         remote_moniker => $remote_moniker,
 913         remote_columns => $remote_cols,
 914     };
 915
 916     $self->_run_user_map($self->rel_name_map, $info);
 917 }
 918
 919 sub _run_user_map {
 920     my ($self, $map, $info) = @_;
 921
 922     my $new_name = $info->{name};
 923     my $mapped = 0;
 924
 925     if ('HASH' eq ref($map)) {
 926         my $name = $info->{name};
 927         my $moniker = $info->{local_moniker};
 928         if ($map->{$moniker} and 'HASH' eq ref($map->{$moniker})
 929             and $map->{$moniker}{$name}
 930         ) {
 931             $new_name = $map->{$moniker}{$name};
 932             $mapped   = 1;
 933         }
 934         elsif ($map->{$name} and not 'HASH' eq ref($map->{$name})) {
 935             $new_name = $map->{$name};
 936             $mapped   = 1;
 937         }
 938     }
 939     elsif ('CODE' eq ref($map)) {
 940         my $cb = sub {
 941             my ($cb_map) = @_;
 942             croak "reentered rel_name_map must be a hashref"
 943                 unless 'HASH' eq ref($cb_map);
 944             my ($cb_name, $cb_mapped) = $self->_run_user_map($cb_map, $info);
 945             return $cb_mapped && $cb_name;
 946         };
 947         my $name = $map->($info, $cb);
 948         if ($name) {
 949             $new_name = $name;
 950             $mapped   = 1;
 951         }
 952     }
 953
 954     return ($new_name, $mapped);
 955 }
 956
 957 sub _cleanup {
 958     my $self = shift;
 959
 960     for my $class (@{ $self->_temp_classes }) {
 961         Class::Unload->unload($class);
 962     }
 963
 964     $self->_temp_classes([]);
 965 }
 966
 967 =head1 AUTHOR
 968
 969 See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
 970
 971 =head1 LICENSE
 972
 973 This library is free software; you can redistribute it and/or modify it under
 974 the same terms as Perl itself.
 975
 976 =cut
 977
 978 1;
 979 # vim:et sts=4 sw=4 tw=0: