lib/DBIx/Class/Schema/Loader/RelBuilder.pm

   1 package DBIx::Class::Schema::Loader::RelBuilder;
   2
   3 use strict;
   4 use warnings;
   5 use base 'Class::Accessor::Grouped';
   6 use mro 'c3';
   7 use Carp::Clan qw/^DBIx::Class/;
   8 use Scalar::Util 'weaken';
   9 use DBIx::Class::Schema::Loader::Utils qw/split_name slurp_file array_eq/;
  10 use Try::Tiny;
  11 use List::Util 'first';
  12 use List::MoreUtils qw/apply uniq any none/;
  13 use namespace::clean;
  14 use Lingua::EN::Inflect::Phrase ();
  15 use Lingua::EN::Tagger ();
  16 use String::ToIdentifier::EN ();
  17 use String::ToIdentifier::EN::Unicode ();
  18 use Class::Unload ();
  19 use Class::Inspector ();
  20
  21 our $VERSION = '0.07038';
  22
  23 # Glossary:
  24 #
  25 # local_relname  -- name of relationship from the local table referring to the remote table
  26 # remote_relname -- name of relationship from the remote table referring to the local table
  27 # remote_method  -- relationship type from remote table to local table, usually has_many
  28
  29 =head1 NAME
  30
  31 DBIx::Class::Schema::Loader::RelBuilder - Builds relationships for DBIx::Class::Schema::Loader
  32
  33 =head1 SYNOPSIS
  34
  35 See L<DBIx::Class::Schema::Loader> and L<DBIx::Class::Schema::Loader::Base>.
  36
  37 =head1 DESCRIPTION
  38
  39 This class builds relationships for L<DBIx::Class::Schema::Loader>.  This
  40 is module is not (yet) for external use.
  41
  42 =head1 METHODS
  43
  44 =head2 new
  45
  46 Arguments: $loader object
  47
  48 =head2 generate_code
  49
  50 Arguments:
  51
  52     [
  53         [ local_moniker1 (scalar), fk_info1 (arrayref), uniq_info1 (arrayref) ]
  54         [ local_moniker2 (scalar), fk_info2 (arrayref), uniq_info2 (arrayref) ]
  55         ...
  56     ]
  57
  58 This generates the code for the relationships of each table.
  59
  60 C<local_moniker> is the moniker name of the table which had the REFERENCES
  61 statements.  The fk_info arrayref's contents should take the form:
  62
  63     [
  64         {
  65             local_table    => 'some_table',
  66             local_moniker  => 'SomeTable',
  67             local_columns  => [ 'col2', 'col3' ],
  68             remote_table   => 'another_table_moniker',
  69             remote_moniker => 'AnotherTableMoniker',
  70             remote_columns => [ 'col5', 'col7' ],
  71         },
  72         {
  73             local_table    => 'some_other_table',
  74             local_moniker  => 'SomeOtherTable',
  75             local_columns  => [ 'col1', 'col4' ],
  76             remote_table   => 'yet_another_table_moniker',
  77             remote_moniker => 'YetAnotherTableMoniker',
  78             remote_columns => [ 'col1', 'col2' ],
  79         },
  80         # ...
  81     ],
  82
  83 The uniq_info arrayref's contents should take the form:
  84
  85     [
  86         [
  87             uniq_constraint_name         => [ 'col1', 'col2' ],
  88         ],
  89         [
  90             another_uniq_constraint_name => [ 'col1', 'col2' ],
  91         ],
  92     ],
  93
  94 This method will return the generated relationships as a hashref keyed on the
  95 class names.  The values are arrayrefs of hashes containing method name and
  96 arguments, like so:
  97
  98   {
  99       'Some::Source::Class' => [
 100           { method => 'belongs_to', arguments => [ 'col1', 'Another::Source::Class' ],
 101           { method => 'has_many', arguments => [ 'anothers', 'Yet::Another::Source::Class', 'col15' ],
 102       ],
 103       'Another::Source::Class' => [
 104           # ...
 105       ],
 106       # ...
 107   }
 108
 109 =cut
 110
 111 __PACKAGE__->mk_group_accessors('simple', qw/
 112     loader
 113     schema
 114     inflect_plural
 115     inflect_singular
 116     relationship_attrs
 117     rel_collision_map
 118     rel_name_map
 119     _temp_classes
 120     __tagger
 121 /);
 122
 123 sub new {
 124     my ($class, $loader) = @_;
 125
 126     # from old POD about this constructor:
 127     # C<$schema_class> should be a schema class name, where the source
 128     # classes have already been set up and registered.  Column info,
 129     # primary key, and unique constraints will be drawn from this
 130     # schema for all of the existing source monikers.
 131
 132     # Options inflect_plural and inflect_singular are optional, and
 133     # are better documented in L<DBIx::Class::Schema::Loader::Base>.
 134
 135     my $self = {
 136         loader             => $loader,
 137         schema             => $loader->schema,
 138         inflect_plural     => $loader->inflect_plural,
 139         inflect_singular   => $loader->inflect_singular,
 140         relationship_attrs => $loader->relationship_attrs,
 141         rel_collision_map  => $loader->rel_collision_map,
 142         rel_name_map       => $loader->rel_name_map,
 143         _temp_classes      => [],
 144     };
 145
 146     weaken $self->{loader}; #< don't leak
 147
 148     bless $self => $class;
 149
 150     # validate the relationship_attrs arg
 151     if( defined $self->relationship_attrs ) {
 152         (ref $self->relationship_attrs eq 'HASH' || ref $self->relationship_attrs eq 'CODE')
 153             or croak "relationship_attrs must be a hashref or coderef";
 154     }
 155
 156     return $self;
 157 }
 158
 159
 160 # pluralize a relationship name
 161 sub _inflect_plural {
 162     my ($self, $relname) = @_;
 163
 164     return '' if !defined $relname || $relname eq '';
 165
 166     my $result;
 167     my $mapped = 0;
 168
 169     if( ref $self->inflect_plural eq 'HASH' ) {
 170         if (exists $self->inflect_plural->{$relname}) {
 171             $result = $self->inflect_plural->{$relname};
 172             $mapped = 1;
 173         }
 174     }
 175     elsif( ref $self->inflect_plural eq 'CODE' ) {
 176         my $inflected = $self->inflect_plural->($relname);
 177         if ($inflected) {
 178             $result = $inflected;
 179             $mapped = 1;
 180         }
 181     }
 182
 183     return ($result, $mapped) if $mapped;
 184
 185     return ($self->_to_PL($relname), 0);
 186 }
 187
 188 # Singularize a relationship name
 189 sub _inflect_singular {
 190     my ($self, $relname) = @_;
 191
 192     return '' if !defined $relname || $relname eq '';
 193
 194     my $result;
 195     my $mapped = 0;
 196
 197     if( ref $self->inflect_singular eq 'HASH' ) {
 198         if (exists $self->inflect_singular->{$relname}) {
 199             $result = $self->inflect_singular->{$relname};
 200             $mapped = 1;
 201         }
 202     }
 203     elsif( ref $self->inflect_singular eq 'CODE' ) {
 204         my $inflected = $self->inflect_singular->($relname);
 205         if ($inflected) {
 206             $result = $inflected;
 207             $mapped = 1;
 208         }
 209     }
 210
 211     return ($result, $mapped) if $mapped;
 212
 213     return ($self->_to_S($relname), 0);
 214 }
 215
 216 sub _to_PL {
 217     my ($self, $name) = @_;
 218
 219     $name =~ s/_/ /g;
 220     my $plural = Lingua::EN::Inflect::Phrase::to_PL($name);
 221     $plural =~ s/ /_/g;
 222
 223     return $plural;
 224 }
 225
 226 sub _to_S {
 227     my ($self, $name) = @_;
 228
 229     $name =~ s/_/ /g;
 230     my $singular = Lingua::EN::Inflect::Phrase::to_S($name);
 231     $singular =~ s/ /_/g;
 232
 233     return $singular;
 234 }
 235
 236 sub _default_relationship_attrs { +{
 237     has_many => {
 238         cascade_delete => 0,
 239         cascade_copy   => 0,
 240     },
 241     might_have => {
 242         cascade_delete => 0,
 243         cascade_copy   => 0,
 244     },
 245     belongs_to => {
 246         on_delete => 'CASCADE',
 247         on_update => 'CASCADE',
 248         is_deferrable => 1,
 249     },
 250 } }
 251
 252 # Accessor for options to be passed to each generated relationship type. takes
 253 # the relationship type name and optionally any attributes from the database
 254 # (such as FK ON DELETE/UPDATE and DEFERRABLE clauses), and returns a
 255 # hashref or undef if nothing is set.
 256 #
 257 # The attributes from the database override the default attributes, which in
 258 # turn are overridden by user supplied attributes.
 259 sub _relationship_attrs {
 260     my ( $self, $reltype, $db_attrs, $params ) = @_;
 261     my $r = $self->relationship_attrs;
 262
 263     my %composite = (
 264         %{ $self->_default_relationship_attrs->{$reltype} || {} },
 265         %{ $db_attrs || {} },
 266         (
 267             ref $r eq 'HASH' ? (
 268                 %{ $r->{all} || {} },
 269                 %{ $r->{$reltype} || {} },
 270             )
 271             :
 272             ()
 273         ),
 274     );
 275
 276     if (ref $r eq 'CODE') {
 277         $params->{attrs} = \%composite;
 278
 279         my %ret = %{ $r->(%$params) || {} };
 280
 281         %composite = %ret if %ret;
 282     }
 283
 284     return %composite ? \%composite : undef;
 285 }
 286
 287 sub _strip_id_postfix {
 288     my ($self, $name) = @_;
 289
 290     $name =~ s/_?(?:id|ref|cd|code|num)\z//i;
 291
 292     return $name;
 293 }
 294
 295 sub _remote_attrs {
 296     my ($self, $local_moniker, $local_cols, $fk_attrs, $params) = @_;
 297
 298     # get our set of attrs from _relationship_attrs, which uses the FK attrs if available
 299     my $attrs = $self->_relationship_attrs('belongs_to', $fk_attrs, $params) || {};
 300
 301     # If any referring column is nullable, make 'belongs_to' an
 302     # outer join, unless explicitly set by relationship_attrs
 303     my $nullable = first { $self->schema->source($local_moniker)->column_info($_)->{is_nullable} } @$local_cols;
 304     $attrs->{join_type} = 'LEFT' if $nullable && !defined $attrs->{join_type};
 305
 306     return $attrs;
 307 }
 308
 309 sub _sanitize_name {
 310     my ($self, $name) = @_;
 311
 312     $name = $self->loader->_to_identifier('relationships', $name, '_');
 313
 314     $name =~ s/\W+/_/g; # if naming >= 8 to_identifier takes care of it
 315
 316     return $name;
 317 }
 318
 319 sub _normalize_name {
 320     my ($self, $name) = @_;
 321
 322     $name = $self->_sanitize_name($name);
 323
 324     my @words = split_name $name, $self->loader->_get_naming_v('relationships');
 325
 326     return join '_', map lc, @words;
 327 }
 328
 329 sub _local_relname {
 330     my ($self, $remote_table, $cond) = @_;
 331
 332     my $local_relname;
 333     # for single-column case, set the remote relname to the column
 334     # name, to make filter accessors work, but strip trailing _id
 335     if(scalar keys %{$cond} == 1) {
 336         my ($col) = values %{$cond};
 337         $col = $self->_strip_id_postfix($self->_normalize_name($col));
 338         ($local_relname) = $self->_inflect_singular($col);
 339     }
 340     else {
 341         ($local_relname) = $self->_inflect_singular($self->_normalize_name($remote_table));
 342     }
 343
 344     return $local_relname;
 345 }
 346
 347 sub _resolve_relname_collision {
 348     my ($self, $moniker, $cols, $relname) = @_;
 349
 350     return $relname if $relname eq 'id'; # this shouldn't happen, but just in case
 351
 352     my $table = $self->loader->moniker_to_table->{$moniker};
 353
 354     if ($self->loader->_is_result_class_method($relname, $table)) {
 355         if (my $map = $self->rel_collision_map) {
 356             for my $re (keys %$map) {
 357                 if (my @matches = $relname =~ /$re/) {
 358                     return sprintf $map->{$re}, @matches;
 359                 }
 360             }
 361         }
 362
 363         my $new_relname = $relname;
 364         while ($self->loader->_is_result_class_method($new_relname, $table)) {
 365             $new_relname .= '_rel'
 366         }
 367
 368         warn <<"EOF";
 369 Relationship '$relname' in source '$moniker' for columns '@{[ join ',', @$cols ]}' collides with an inherited method. Renaming to '$new_relname'.
 370 See "RELATIONSHIP NAME COLLISIONS" in perldoc DBIx::Class::Schema::Loader::Base .
 371 EOF
 372
 373         return $new_relname;
 374     }
 375
 376     return $relname;
 377 }
 378
 379 sub generate_code {
 380     my ($self, $tables) = @_;
 381
 382     # make a copy to destroy
 383     my @tables = @$tables;
 384     my %uniq_cols = map { $_->[0] => [ map { $_->[1] } @{$_->[2]} ] } @tables;
 385
 386     my $all_code = {};
 387
 388     while (my ($local_moniker, $rels, $uniqs) = @{ shift @tables || [] }) {
 389         my $local_class = $self->schema->class($local_moniker);
 390
 391         my %counters;
 392         foreach my $rel (@$rels) {
 393             next if !$rel->{remote_source};
 394             $counters{$rel->{remote_source}}++;
 395         }
 396
 397         foreach my $rel (@$rels) {
 398             my $remote_moniker = $rel->{remote_source}
 399                 or next;
 400
 401             my $remote_class   = $self->schema->class($remote_moniker);
 402             my $remote_obj     = $self->schema->source($remote_moniker);
 403             my $remote_cols    = $rel->{remote_columns} || [ $remote_obj->primary_columns ];
 404
 405             my $local_cols     = $rel->{local_columns};
 406
 407             if($#$local_cols != $#$remote_cols) {
 408                 croak "Column count mismatch: $local_moniker (@$local_cols) "
 409                     . "$remote_moniker (@$remote_cols)";
 410             }
 411
 412             my %cond;
 413             @cond{@$remote_cols} = @$local_cols;
 414
 415             my ( $local_relname, $remote_relname, $remote_method ) =
 416                 $self->_relnames_and_method( $local_moniker, $rel, \%cond,  $uniqs, \%counters );
 417             my $local_method  = 'belongs_to';
 418
 419             ($local_relname) = $self->_rel_name_map(
 420                 $local_relname, $local_method,
 421                 $local_class, $local_moniker, $local_cols,
 422                 $remote_class, $remote_moniker, $remote_cols,
 423             );
 424             ($remote_relname) = $self->_rel_name_map(
 425                 $remote_relname, $remote_method,
 426                 $remote_class, $remote_moniker, $remote_cols,
 427                 $local_class, $local_moniker, $local_cols,
 428             );
 429
 430             $local_relname = $self->_resolve_relname_collision(
 431                 $local_moniker, $local_cols, $local_relname,
 432             );
 433             $remote_relname = $self->_resolve_relname_collision(
 434                 $remote_moniker, $remote_cols, $remote_relname,
 435             );
 436
 437             if (!$self->loader->_disable_uniq_detection
 438                 && none { array_eq($_, $remote_cols) }
 439                     [ $remote_obj->primary_columns ],
 440                     @{$uniq_cols{$remote_moniker}},
 441             ) {
 442                 warn <<"EOF";
 443 $local_method relationship '$remote_relname' in source '$local_moniker' references
 444 non-unique columns (@{[join(',', @$remote_cols)]}) in source '$remote_moniker'.
 445 EOF
 446             }
 447
 448             my $rel_attrs_params = {
 449                 rel_name      => $local_relname,
 450                 rel_type      => $local_method,
 451                 local_source  => $self->schema->source($local_moniker),
 452                 remote_source => $self->schema->source($remote_moniker),
 453                 local_table   => $rel->{local_table},
 454                 local_cols    => $local_cols,
 455                 remote_table  => $rel->{remote_table},
 456                 remote_cols   => $remote_cols,
 457             };
 458
 459             push @{$all_code->{$local_class}}, {
 460                 method => $local_method,
 461                 args => [
 462                     $local_relname,
 463                     $remote_class,
 464                     \%cond,
 465                     $self->_remote_attrs($local_moniker, $local_cols, $rel->{attrs}, $rel_attrs_params),
 466                 ],
 467                 extra => {
 468                     local_class    => $local_class,
 469                     local_moniker  => $local_moniker,
 470                     remote_moniker => $remote_moniker,
 471                 },
 472             };
 473
 474             my %rev_cond = reverse %cond;
 475             for (keys %rev_cond) {
 476                 $rev_cond{"foreign.$_"} = "self.".$rev_cond{$_};
 477                 delete $rev_cond{$_};
 478             }
 479
 480             $rel_attrs_params = {
 481                 rel_name      => $remote_relname,
 482                 rel_type      => $remote_method,
 483                 local_source  => $self->schema->source($remote_moniker),
 484                 remote_source => $self->schema->source($local_moniker),
 485                 local_table   => $rel->{remote_table},
 486                 local_cols    => $remote_cols,
 487                 remote_table  => $rel->{local_table},
 488                 remote_cols   => $local_cols,
 489             };
 490
 491             push @{$all_code->{$remote_class}}, {
 492                 method => $remote_method,
 493                 args => [
 494                     $remote_relname,
 495                     $local_class,
 496                     \%rev_cond,
 497                     $self->_relationship_attrs($remote_method, {}, $rel_attrs_params),
 498                 ],
 499                 extra => {
 500                     local_class    => $remote_class,
 501                     local_moniker  => $remote_moniker,
 502                     remote_moniker => $local_moniker,
 503                 },
 504             };
 505         }
 506     }
 507
 508     $self->_generate_m2ms($all_code);
 509
 510     # disambiguate rels with the same name
 511     foreach my $class (keys %$all_code) {
 512         my $dups = $self->_duplicates($all_code->{$class});
 513
 514         $self->_disambiguate($all_code, $class, $dups) if $dups;
 515     }
 516
 517     $self->_cleanup;
 518
 519     return $all_code;
 520 }
 521
 522 # Find classes with only 2 FKs which are the PK and make many_to_many bridges for them.
 523 sub _generate_m2ms {
 524     my ($self, $all_code) = @_;
 525
 526     while (my ($class, $rels) = each %$all_code) {
 527         next unless (grep $_->{method} eq 'belongs_to', @$rels) == 2;
 528
 529         my $class1_local_moniker  = $rels->[0]{extra}{remote_moniker};
 530         my $class1_remote_moniker = $rels->[1]{extra}{remote_moniker};
 531
 532         my $class2_local_moniker  = $rels->[1]{extra}{remote_moniker};
 533         my $class2_remote_moniker = $rels->[0]{extra}{remote_moniker};
 534
 535         my $class1 = $rels->[0]{args}[1];
 536         my $class2 = $rels->[1]{args}[1];
 537
 538         my $class1_to_link_table_rel = first {
 539             $_->{method} eq 'has_many' && $_->{args}[1] eq $class
 540         } @{ $all_code->{$class1} };
 541
 542         next unless $class1_to_link_table_rel;
 543
 544         my $class1_to_link_table_rel_name = $class1_to_link_table_rel->{args}[0];
 545
 546         my $class2_to_link_table_rel = first {
 547             $_->{method} eq 'has_many' && $_->{args}[1] eq $class
 548         } @{ $all_code->{$class2} };
 549
 550         next unless $class2_to_link_table_rel;
 551
 552         my $class2_to_link_table_rel_name = $class2_to_link_table_rel->{args}[0];
 553
 554         my $class1_link_rel = $rels->[1]{args}[0];
 555         my $class2_link_rel = $rels->[0]{args}[0];
 556
 557         my @class1_from_cols = apply { s/^self\.//i } values %{
 558             $class1_to_link_table_rel->{args}[2]
 559         };
 560
 561         my @class1_link_cols = apply { s/^self\.//i } values %{ $rels->[1]{args}[2] };
 562
 563         my @class1_to_cols = apply { s/^foreign\.//i } keys %{ $rels->[1]{args}[2] };
 564
 565         my @class2_from_cols = apply { s/^self\.//i } values %{
 566             $class2_to_link_table_rel->{args}[2]
 567         };
 568
 569         my @class2_link_cols = apply { s/^self\.//i } values %{ $rels->[0]{args}[2] };
 570
 571         my @class2_to_cols = apply { s/^foreign\.//i } keys %{ $rels->[0]{args}[2] };
 572
 573         my $link_moniker = $rels->[0]{extra}{local_moniker};
 574
 575         my @link_table_cols =
 576             @{[ $self->schema->source($link_moniker)->columns ]};
 577
 578         my @link_table_primary_cols =
 579             @{[ $self->schema->source($link_moniker)->primary_columns ]};
 580
 581         next unless @class1_link_cols + @class2_link_cols == @link_table_cols
 582             && @link_table_cols == @link_table_primary_cols;
 583
 584         my ($class1_to_class2_relname) = $self->_rel_name_map(
 585             ($self->_inflect_plural($class1_link_rel))[0],
 586             'many_to_many',
 587             $class1,
 588             $class1_local_moniker,
 589             \@class1_from_cols,
 590             $class2,
 591             $class1_remote_moniker,
 592             \@class1_to_cols,
 593             {
 594                 link_class => $class,
 595                 link_moniker => $link_moniker,
 596                 link_rel_name => $class1_to_link_table_rel_name,
 597             },
 598         );
 599
 600         $class1_to_class2_relname = $self->_resolve_relname_collision(
 601             $class1_local_moniker,
 602             \@class1_from_cols,
 603             $class1_to_class2_relname,
 604         );
 605
 606         my ($class2_to_class1_relname) = $self->_rel_name_map(
 607             ($self->_inflect_plural($class2_link_rel))[0],
 608             'many_to_many',
 609             $class1,
 610             $class2_local_moniker,
 611             \@class2_from_cols,
 612             $class2,
 613             $class2_remote_moniker,
 614             \@class2_to_cols,
 615             {
 616                 link_class => $class,
 617                 link_moniker => $link_moniker,
 618                 link_rel_name => $class2_to_link_table_rel_name,
 619             },
 620         );
 621
 622         $class2_to_class1_relname = $self->_resolve_relname_collision(
 623             $class2_local_moniker,
 624             \@class2_from_cols,
 625             $class2_to_class1_relname,
 626         );
 627
 628         push @{$all_code->{$class1}}, {
 629             method => 'many_to_many',
 630             args   => [
 631                 $class1_to_class2_relname,
 632                 $class1_to_link_table_rel_name,
 633                 $class1_link_rel,
 634                 $self->_relationship_attrs('many_to_many', {}, {
 635                     rel_type => 'many_to_many',
 636                     rel_name => $class1_to_class2_relname,
 637                     local_source => $self->schema->source($class1_local_moniker),
 638                     remote_source => $self->schema->source($class1_remote_moniker),
 639                     local_table => $self->loader->class_to_table->{$class1},
 640                     local_cols => \@class1_from_cols,
 641                     remote_table => $self->loader->class_to_table->{$class2},
 642                     remote_cols => \@class2_from_cols,
 643                 }) || (),
 644             ],
 645             extra  => {
 646                 local_class    => $class1,
 647                 link_class     => $class,
 648                 local_moniker  => $class1_local_moniker,
 649                 remote_moniker => $class1_remote_moniker,
 650             },
 651         };
 652
 653         push @{$all_code->{$class2}}, {
 654             method => 'many_to_many',
 655             args   => [
 656                 $class2_to_class1_relname,
 657                 $class2_to_link_table_rel_name,
 658                 $class2_link_rel,
 659                 $self->_relationship_attrs('many_to_many', {}, {
 660                     rel_type => 'many_to_many',
 661                     rel_name => $class2_to_class1_relname,
 662                     local_source => $self->schema->source($class2_local_moniker),
 663                     remote_source => $self->schema->source($class2_remote_moniker),
 664                     local_table => $self->loader->class_to_table->{$class2},
 665                     local_cols => \@class2_from_cols,
 666                     remote_table => $self->loader->class_to_table->{$class1},
 667                     remote_cols => \@class1_from_cols,
 668                 }) || (),
 669             ],
 670             extra  => {
 671                 local_class    => $class2,
 672                 link_class     => $class,
 673                 local_moniker  => $class2_local_moniker,
 674                 remote_moniker => $class2_remote_moniker,
 675             },
 676         };
 677     }
 678 }
 679
 680 sub _duplicates {
 681     my ($self, $rels) = @_;
 682
 683     my @rels = map [ $_->{args}[0] => $_ ], @$rels;
 684     my %rel_names;
 685     $rel_names{$_}++ foreach map $_->[0], @rels;
 686
 687     my @dups = grep $rel_names{$_} > 1, keys %rel_names;
 688
 689     my %dups;
 690
 691     foreach my $dup (@dups) {
 692         $dups{$dup} = [ map $_->[1], grep { $_->[0] eq $dup } @rels ];
 693     }
 694
 695     return if not %dups;
 696
 697     return \%dups;
 698 }
 699
 700 sub _tagger {
 701     my $self = shift;
 702
 703     $self->__tagger(Lingua::EN::Tagger->new) unless $self->__tagger;
 704
 705     return $self->__tagger;
 706 }
 707
 708 sub _adjectives {
 709     my ($self, @cols) = @_;
 710
 711     my @adjectives;
 712
 713     foreach my $col (@cols) {
 714         my @words = split_name $col;
 715
 716         my $tagged = $self->_tagger->get_readable(join ' ', @words);
 717
 718         push @adjectives, $tagged =~ m{\G(\w+)/JJ\s+}g;
 719     }
 720
 721     return @adjectives;
 722 }
 723
 724 sub _name_to_identifier {
 725     my ($self, $name) = @_;
 726
 727     my $to_identifier = $self->loader->naming->{force_ascii} ?
 728         \&String::ToIdentifier::EN::to_identifier
 729         : \&String::ToIdentifier::EN::Unicode::to_identifier;
 730
 731     return join '_', map lc, split_name $to_identifier->($name, '_');
 732 }
 733
 734 sub _disambiguate {
 735     my ($self, $all_code, $in_class, $dups) = @_;
 736
 737     DUP: foreach my $dup (keys %$dups) {
 738         my @rels = @{ $dups->{$dup} };
 739
 740         # Check if there are rels to the same table name in different
 741         # schemas/databases, if so qualify them.
 742         my @tables = map $self->loader->moniker_to_table->{$_->{extra}{remote_moniker}},
 743                         @rels;
 744
 745         # databases are different, prepend database
 746         if ($tables[0]->can('database') && (uniq map $_->database||'', @tables) > 1) {
 747             # If any rels are in the same database, we have to distinguish by
 748             # both schema and database.
 749             my %db_counts;
 750             $db_counts{$_}++ for map $_->database, @tables;
 751             my $use_schema = any { $_ > 1 } values %db_counts;
 752
 753             foreach my $i (0..$#rels) {
 754                 my $rel   = $rels[$i];
 755                 my $table = $tables[$i];
 756
 757                 $rel->{args}[0] = $self->_name_to_identifier($table->database)
 758                     . ($use_schema ? ('_' . $self->name_to_identifier($table->schema)) : '')
 759                     . '_' . $rel->{args}[0];
 760             }
 761             next DUP;
 762         }
 763         # schemas are different, prepend schema
 764         elsif ((uniq map $_->schema||'', @tables) > 1) {
 765             foreach my $i (0..$#rels) {
 766                 my $rel   = $rels[$i];
 767                 my $table = $tables[$i];
 768
 769                 $rel->{args}[0] = $self->_name_to_identifier($table->schema)
 770                     . '_' . $rel->{args}[0];
 771             }
 772             next DUP;
 773         }
 774
 775         foreach my $rel (@rels) {
 776             next if $rel->{method} =~ /^(?:belongs_to|many_to_many)\z/;
 777
 778             my @to_cols = apply { s/^foreign\.//i }
 779                 keys %{ $rel->{args}[2] };
 780
 781             my @adjectives = $self->_adjectives(@to_cols);
 782
 783             # If there are no adjectives, and there is only one might_have
 784             # rel to that class, we hardcode 'active'.
 785
 786             my $to_class = $rel->{args}[1];
 787
 788             if ((not @adjectives)
 789                 && (grep { $_->{method} eq 'might_have'
 790                            && $_->{args}[1] eq $to_class } @{ $all_code->{$in_class} }) == 1) {
 791
 792                 @adjectives = 'active';
 793             }
 794
 795             if (@adjectives) {
 796                 my $rel_name = join '_', sort(@adjectives), $rel->{args}[0];
 797
 798                 ($rel_name) = $rel->{method} eq 'might_have' ?
 799                     $self->_inflect_singular($rel_name)
 800                     :
 801                     $self->_inflect_plural($rel_name);
 802
 803                 my ($local_class, $local_moniker, $remote_moniker)
 804                     = @{ $rel->{extra} }
 805                         {qw/local_class local_moniker remote_moniker/};
 806
 807                 my @from_cols = apply { s/^self\.//i }
 808                     values %{ $rel->{args}[2] };
 809
 810                 ($rel_name) = $self->_rel_name_map($rel_name, $rel->{method}, $local_class, $local_moniker, \@from_cols, $to_class, $remote_moniker, \@to_cols);
 811
 812                 $rel_name = $self->_resolve_relname_collision($local_moniker, \@from_cols, $rel_name);
 813
 814                 $rel->{args}[0] = $rel_name;
 815             }
 816         }
 817     }
 818
 819     # Check again for duplicates, since the heuristics above may not have resolved them all.
 820
 821     if ($dups = $self->_duplicates($all_code->{$in_class})) {
 822         foreach my $dup (keys %$dups) {
 823             # sort by method
 824             my @rels = map $_->[1], sort { $a->[0] <=> $b->[0] } map [
 825                 {
 826                     belongs_to   => 3,
 827                     has_many     => 2,
 828                     might_have   => 1,
 829                     many_to_many => 0,
 830                 }->{$_->{method}}, $_
 831             ], @{ $dups->{$dup} };
 832
 833             my $rel_num = 2;
 834
 835             foreach my $rel (@rels[1 .. $#rels]) {
 836                 my $inflect_type = $rel->{method} =~ /^(?:many_to_many|has_many)\z/ ?
 837                     'inflect_plural'
 838                     :
 839                     'inflect_singular';
 840
 841                 my $inflect_method = "_$inflect_type";
 842
 843                 my $relname_new_uninflected = $rel->{args}[0] . "_$rel_num";
 844
 845                 $rel_num++;
 846
 847                 my ($local_class, $local_moniker, $remote_moniker)
 848                     = @{ $rel->{extra} }
 849                         {qw/local_class local_moniker remote_moniker/};
 850
 851                 my (@from_cols, @to_cols, $to_class);
 852
 853                 if ($rel->{method} eq 'many_to_many') {
 854                     @from_cols = apply { s/^self\.//i } values %{
 855                         (first { $_->{args}[0] eq $rel->{args}[1] } @{ $all_code->{$local_class} })
 856                             ->{args}[2]
 857                     };
 858                     @to_cols   = apply { s/^foreign\.//i } keys %{
 859                         (first { $_->{args}[0] eq $rel->{args}[2] }
 860                             @{ $all_code->{ $rel->{extra}{link_class} } })
 861                                 ->{args}[2]
 862                     };
 863                     $to_class  = $self->schema->source($remote_moniker)->result_class;
 864                 }
 865                 else {
 866                     @from_cols = apply { s/^self\.//i }    values %{ $rel->{args}[2] };
 867                     @to_cols   = apply { s/^foreign\.//i } keys   %{ $rel->{args}[2] };
 868                     $to_class  = $rel->{args}[1];
 869                 }
 870
 871                 my ($relname_new, $inflect_mapped) =
 872                     $self->$inflect_method($relname_new_uninflected);
 873
 874                 my $rel_name_mapped;
 875
 876                 ($relname_new, $rel_name_mapped) = $self->_rel_name_map($relname_new, $rel->{method}, $local_class, $local_moniker, \@from_cols, $to_class, $remote_moniker, \@to_cols);
 877
 878                 my $mapped = $inflect_mapped || $rel_name_mapped;
 879
 880                 warn <<"EOF" unless $mapped;
 881 Could not find a proper name for relationship '$relname_new' in source
 882 '$local_moniker' for columns '@{[ join ',', @from_cols ]}'. Supply a value in
 883 '$inflect_type' for '$relname_new_uninflected' or 'rel_name_map' for
 884 '$relname_new' to name this relationship.
 885 EOF
 886
 887                 $relname_new = $self->_resolve_relname_collision($local_moniker, \@from_cols, $relname_new);
 888
 889                 $rel->{args}[0] = $relname_new;
 890             }
 891         }
 892     }
 893 }
 894
 895 sub _relnames_and_method {
 896     my ( $self, $local_moniker, $rel, $cond, $uniqs, $counters ) = @_;
 897
 898     my $remote_moniker  = $rel->{remote_source};
 899     my $remote_obj      = $self->schema->source( $remote_moniker );
 900     my $remote_class    = $self->schema->class(  $remote_moniker );
 901     my $local_relname   = $self->_local_relname( $rel->{remote_table}, $cond);
 902
 903     my $local_cols      = $rel->{local_columns};
 904     my $local_table     = $rel->{local_table};
 905     my $local_class     = $self->schema->class($local_moniker);
 906     my $local_source    = $self->schema->source($local_moniker);
 907
 908     my $remote_relname_uninflected = $self->_normalize_name($local_table);
 909     my ($remote_relname) = $self->_inflect_plural($self->_normalize_name($local_table));
 910
 911     my $remote_method = 'has_many';
 912
 913     # If the local columns have a UNIQUE constraint, this is a one-to-one rel
 914     if (array_eq([ $local_source->primary_columns ], $local_cols) ||
 915             first { array_eq($_->[1], $local_cols) } @$uniqs) {
 916         $remote_method   = 'might_have';
 917         ($remote_relname) = $self->_inflect_singular($remote_relname_uninflected);
 918     }
 919
 920     # If more than one rel between this pair of tables, use the local
 921     # col names to distinguish, unless the rel was created previously.
 922     if ($counters->{$remote_moniker} > 1) {
 923         my $relationship_exists = 0;
 924
 925         if (-f (my $existing_remote_file = $self->loader->get_dump_filename($remote_class))) {
 926             my $class = "${remote_class}Temporary";
 927
 928             if (not Class::Inspector->loaded($class)) {
 929                 my $code = slurp_file $existing_remote_file;
 930
 931                 $code =~ s/(?<=package $remote_class)/Temporary/g;
 932
 933                 $code =~ s/__PACKAGE__->meta->make_immutable[^;]*;//g;
 934
 935                 eval $code;
 936                 die $@ if $@;
 937
 938                 push @{ $self->_temp_classes }, $class;
 939             }
 940
 941             if ($class->has_relationship($remote_relname)) {
 942                 my $rel_cols = [ sort { $a cmp $b } apply { s/^foreign\.//i }
 943                     (keys %{ $class->relationship_info($remote_relname)->{cond} }) ];
 944
 945                 $relationship_exists = 1 if array_eq([ sort @$local_cols ], $rel_cols);
 946             }
 947         }
 948
 949         if (not $relationship_exists) {
 950             my $colnames = q{_} . $self->_normalize_name(join '_', @$local_cols);
 951             $local_relname .= $colnames if keys %$cond > 1;
 952
 953             $remote_relname = $self->_strip_id_postfix($self->_normalize_name($local_table . $colnames));
 954
 955             $remote_relname_uninflected = $remote_relname;
 956             ($remote_relname) = $self->_inflect_plural($remote_relname);
 957
 958             # if colnames were added and this is a might_have, re-inflect
 959             if ($remote_method eq 'might_have') {
 960                 ($remote_relname) = $self->_inflect_singular($remote_relname_uninflected);
 961             }
 962         }
 963     }
 964
 965     return ($local_relname, $remote_relname, $remote_method);
 966 }
 967
 968 sub _rel_name_map {
 969     my ($self, $relname, $method, $local_class, $local_moniker, $local_cols,
 970         $remote_class, $remote_moniker, $remote_cols, $extra) = @_;
 971
 972     my $info = {
 973         %{$extra || {}},
 974         name           => $relname,
 975         type           => $method,
 976         local_class    => $local_class,
 977         local_moniker  => $local_moniker,
 978         local_columns  => $local_cols,
 979         remote_class   => $remote_class,
 980         remote_moniker => $remote_moniker,
 981         remote_columns => $remote_cols,
 982     };
 983
 984     $self->_run_user_map($self->rel_name_map, $info);
 985 }
 986
 987 sub _run_user_map {
 988     my ($self, $map, $info) = @_;
 989
 990     my $new_name = $info->{name};
 991     my $mapped = 0;
 992
 993     if ('HASH' eq ref($map)) {
 994         my $name = $info->{name};
 995         my $moniker = $info->{local_moniker};
 996         if ($map->{$moniker} and 'HASH' eq ref($map->{$moniker})
 997             and $map->{$moniker}{$name}
 998         ) {
 999             $new_name = $map->{$moniker}{$name};
1000             $mapped   = 1;
1001         }
1002         elsif ($map->{$name} and not 'HASH' eq ref($map->{$name})) {
1003             $new_name = $map->{$name};
1004             $mapped   = 1;
1005         }
1006     }
1007     elsif ('CODE' eq ref($map)) {
1008         my $cb = sub {
1009             my ($cb_map) = @_;
1010             croak "reentered rel_name_map must be a hashref"
1011                 unless 'HASH' eq ref($cb_map);
1012             my ($cb_name, $cb_mapped) = $self->_run_user_map($cb_map, $info);
1013             return $cb_mapped && $cb_name;
1014         };
1015         my $name = $map->($info, $cb);
1016         if ($name) {
1017             $new_name = $name;
1018             $mapped   = 1;
1019         }
1020     }
1021
1022     return ($new_name, $mapped);
1023 }
1024
1025 sub _cleanup {
1026     my $self = shift;
1027
1028     for my $class (@{ $self->_temp_classes }) {
1029         Class::Unload->unload($class);
1030     }
1031
1032     $self->_temp_classes([]);
1033 }
1034
1035 =head1 AUTHOR
1036
1037 See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
1038
1039 =head1 LICENSE
1040
1041 This library is free software; you can redistribute it and/or modify it under
1042 the same terms as Perl itself.
1043
1044 =cut
1045
1046 1;
1047 # vim:et sts=4 sw=4 tw=0: