lib/DBIx/Class/Schema/Loader/DBI/mysql.pm

   1 package DBIx::Class::Schema::Loader::DBI::mysql;
   2
   3 use strict;
   4 use warnings;
   5 use base 'DBIx::Class::Schema::Loader::DBI';
   6 use mro 'c3';
   7 use List::Util 'first';
   8 use namespace::clean;
   9
  10 our $VERSION = '0.07010';
  11
  12 =head1 NAME
  13
  14 DBIx::Class::Schema::Loader::DBI::mysql - DBIx::Class::Schema::Loader::DBI mysql Implementation.
  15
  16 =head1 DESCRIPTION
  17
  18 See L<DBIx::Class::Schema::Loader> and L<DBIx::Class::Schema::Loader::Base>.
  19
  20 =cut
  21
  22 sub _setup {
  23     my $self = shift;
  24
  25     $self->schema->storage->sql_maker->quote_char("`");
  26     $self->schema->storage->sql_maker->name_sep(".");
  27
  28     $self->next::method(@_);
  29
  30     if (not defined $self->preserve_case) {
  31         $self->preserve_case(0);
  32     }
  33 }
  34
  35 sub _tables_list {
  36     my ($self, $opts) = @_;
  37
  38     return $self->next::method($opts, undef, undef);
  39 }
  40
  41 sub _table_fk_info {
  42     my ($self, $table) = @_;
  43
  44     my $dbh = $self->schema->storage->dbh;
  45
  46     my $table_def_ref = eval { $dbh->selectrow_arrayref("SHOW CREATE TABLE `$table`") };
  47     my $table_def = $table_def_ref->[1];
  48
  49     return [] if not $table_def;
  50
  51     my $qt = qr/["`]/;
  52
  53     my (@reldata) = ($table_def =~
  54         /CONSTRAINT $qt.*$qt FOREIGN KEY \($qt(.*)$qt\) REFERENCES $qt(.*)$qt \($qt(.*)$qt\)/ig
  55     );
  56
  57     my @rels;
  58     while (scalar @reldata > 0) {
  59         my $cols = shift @reldata;
  60         my $f_table = shift @reldata;
  61         my $f_cols = shift @reldata;
  62
  63         my @cols   = map { s/(?: \Q$self->{_quoter}\E | $qt )//x; $self->_lc($_) }
  64             split(/$qt?\s*$qt?,$qt?\s*$qt?/, $cols);
  65
  66         my @f_cols = map { s/(?: \Q$self->{_quoter}\E | $qt )//x; $self->_lc($_) }
  67             split(/$qt?\s*$qt?,$qt?\s*$qt?/, $f_cols);
  68
  69         my $remote_table = first { $_ =~ /^${f_table}\z/i } $self->_tables_list;
  70
  71         push(@rels, {
  72             local_columns => \@cols,
  73             remote_columns => \@f_cols,
  74             remote_table => $remote_table,
  75         });
  76     }
  77
  78     return \@rels;
  79 }
  80
  81 # primary and unique info comes from the same sql statement,
  82 #   so cache it here for both routines to use
  83 sub _mysql_table_get_keys {
  84     my ($self, $table) = @_;
  85
  86     if(!exists($self->{_cache}->{_mysql_keys}->{$table})) {
  87         my %keydata;
  88         my $dbh = $self->schema->storage->dbh;
  89         my $sth = $dbh->prepare('SHOW INDEX FROM '.$self->_table_as_sql($table));
  90         $sth->execute;
  91         while(my $row = $sth->fetchrow_hashref) {
  92             next if $row->{Non_unique};
  93             push(@{$keydata{$row->{Key_name}}},
  94                 [ $row->{Seq_in_index}, $self->_lc($row->{Column_name}) ]
  95             );
  96         }
  97         foreach my $keyname (keys %keydata) {
  98             my @ordered_cols = map { $_->[1] } sort { $a->[0] <=> $b->[0] }
  99                 @{$keydata{$keyname}};
 100             $keydata{$keyname} = \@ordered_cols;
 101         }
 102         $self->{_cache}->{_mysql_keys}->{$table} = \%keydata;
 103     }
 104
 105     return $self->{_cache}->{_mysql_keys}->{$table};
 106 }
 107
 108 sub _table_pk_info {
 109     my ( $self, $table ) = @_;
 110
 111     return $self->_mysql_table_get_keys($table)->{PRIMARY};
 112 }
 113
 114 sub _table_uniq_info {
 115     my ( $self, $table ) = @_;
 116
 117     my @uniqs;
 118     my $keydata = $self->_mysql_table_get_keys($table);
 119     foreach my $keyname (keys %$keydata) {
 120         next if $keyname eq 'PRIMARY';
 121         push(@uniqs, [ $keyname => $keydata->{$keyname} ]);
 122     }
 123
 124     return \@uniqs;
 125 }
 126
 127 sub _columns_info_for {
 128     my $self = shift;
 129     my ($table) = @_;
 130
 131     my $result = $self->next::method(@_);
 132
 133     my $dbh = $self->schema->storage->dbh;
 134
 135     while (my ($col, $info) = each %$result) {
 136         if ($info->{data_type} eq 'int') {
 137             $info->{data_type} = 'integer';
 138         }
 139         elsif ($info->{data_type} eq 'double') {
 140             $info->{data_type} = 'double precision';
 141         }
 142         my $data_type = $info->{data_type};
 143
 144         delete $info->{size} if $data_type !~ /^(?: (?:var)?(?:char(?:acter)?|binary) | bit | year)\z/ix;
 145
 146         # information_schema is available in 5.0+
 147         my ($precision, $scale, $column_type, $default) = eval { $dbh->selectrow_array(<<'EOF', {}, $table, $col) };
 148 SELECT numeric_precision, numeric_scale, column_type, column_default
 149 FROM information_schema.columns
 150 WHERE table_name = ? AND column_name = ?
 151 EOF
 152         my $has_information_schema = not $@;
 153
 154         $column_type = '' if not defined $column_type;
 155
 156         if ($data_type eq 'bit' && (not exists $info->{size})) {
 157             $info->{size} = $precision if defined $precision;
 158         }
 159         elsif ($data_type =~ /^(?:float|double precision|decimal)\z/i) {
 160             if (defined $precision && defined $scale) {
 161                 if ($precision == 10 && $scale == 0) {
 162                     delete $info->{size};
 163                 }
 164                 else {
 165                     $info->{size} = [$precision,$scale];
 166                 }
 167             }
 168         }
 169         elsif ($data_type eq 'year') {
 170             if ($column_type =~ /\(2\)/) {
 171                 $info->{size} = 2;
 172             }
 173             elsif ($column_type =~ /\(4\)/ || $info->{size} == 4) {
 174                 delete $info->{size};
 175             }
 176         }
 177         elsif ($data_type =~ /^(?:date(?:time)?|timestamp)\z/) {
 178             if (not (defined $self->datetime_undef_if_invalid && $self->datetime_undef_if_invalid == 0)) {
 179                 $info->{datetime_undef_if_invalid} = 1;
 180             }
 181         }
 182         elsif ($data_type =~ /^(?:enum|set)\z/ && $has_information_schema
 183                && $column_type =~ /^(?:enum|set)\(/) {
 184
 185             delete $info->{extra}{list};
 186
 187             while ($column_type =~ /'((?:[^']* (?:''|\\')* [^']*)* [^\\'])',?/xg) {
 188                 my $el = $1;
 189                 $el =~ s/''/'/g;
 190                 push @{ $info->{extra}{list} }, $el;
 191             }
 192         }
 193
 194         # Sometimes apparently there's a bug where default_value gets set to ''
 195         # for things that don't actually have or support that default (like ints.)
 196         if (exists $info->{default_value} && $info->{default_value} eq '') {
 197             if ($has_information_schema) {
 198                 if (not defined $default) {
 199                     delete $info->{default_value};
 200                 }
 201             }
 202             else { # just check if it's a char/text type, otherwise remove
 203                 delete $info->{default_value} unless $data_type =~ /char|text/i;
 204             }
 205         }
 206     }
 207
 208     return $result;
 209 }
 210
 211 sub _extra_column_info {
 212     no warnings 'uninitialized';
 213     my ($self, $table, $col, $info, $dbi_info) = @_;
 214     my %extra_info;
 215
 216     if ($dbi_info->{mysql_is_auto_increment}) {
 217         $extra_info{is_auto_increment} = 1
 218     }
 219     if ($dbi_info->{mysql_type_name} =~ /\bunsigned\b/i) {
 220         $extra_info{extra}{unsigned} = 1;
 221     }
 222     if ($dbi_info->{mysql_values}) {
 223         $extra_info{extra}{list} = $dbi_info->{mysql_values};
 224     }
 225     if (   lc($dbi_info->{COLUMN_DEF})      eq 'current_timestamp'
 226         && lc($dbi_info->{mysql_type_name}) eq 'timestamp') {
 227
 228         my $current_timestamp = 'current_timestamp';
 229         $extra_info{default_value} = \$current_timestamp;
 230     }
 231
 232     return \%extra_info;
 233 }
 234
 235 sub _dbh_column_info {
 236     my $self = shift;
 237
 238     local $SIG{__WARN__} = sub { warn @_
 239         unless $_[0] =~ /^column_info: unrecognized column type/ };
 240
 241     $self->next::method(@_);
 242 }
 243
 244 =head1 SEE ALSO
 245
 246 L<DBIx::Class::Schema::Loader>, L<DBIx::Class::Schema::Loader::Base>,
 247 L<DBIx::Class::Schema::Loader::DBI>
 248
 249 =head1 AUTHOR
 250
 251 See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
 252
 253 =head1 LICENSE
 254
 255 This library is free software; you can redistribute it and/or modify it under
 256 the same terms as Perl itself.
 257
 258 =cut
 259
 260 1;
 261 # vim:et sw=4 sts=4 tw=0: