lib/DBIx/Class/Schema/Loader/DBI/mysql.pm

   1 package DBIx::Class::Schema::Loader::DBI::mysql;
   2
   3 use strict;
   4 use warnings;
   5 use base 'DBIx::Class::Schema::Loader::DBI';
   6 use mro 'c3';
   7 use Carp::Clan qw/^DBIx::Class/;
   8 use List::Util 'first';
   9 use List::MoreUtils 'any';
  10 use Try::Tiny;
  11 use Scalar::Util 'blessed';
  12 use DBIx::Class::Schema::Loader::Utils qw/sigwarn_silencer/;
  13 use namespace::clean;
  14 use DBIx::Class::Schema::Loader::Table ();
  15
  16 our $VERSION = '0.07037';
  17
  18 =head1 NAME
  19
  20 DBIx::Class::Schema::Loader::DBI::mysql - DBIx::Class::Schema::Loader::DBI mysql Implementation.
  21
  22 =head1 DESCRIPTION
  23
  24 See L<DBIx::Class::Schema::Loader> and L<DBIx::Class::Schema::Loader::Base>.
  25
  26 =cut
  27
  28 sub _setup {
  29     my $self = shift;
  30
  31     $self->schema->storage->sql_maker->quote_char("`");
  32     $self->schema->storage->sql_maker->name_sep(".");
  33
  34     $self->next::method(@_);
  35
  36     if (not defined $self->preserve_case) {
  37         $self->preserve_case(0);
  38     }
  39
  40     if ($self->db_schema && $self->db_schema->[0] eq '%') {
  41         my @schemas = try {
  42             $self->_show_databases;
  43         }
  44         catch {
  45             croak "no SHOW DATABASES privileges: $_";
  46         };
  47
  48         @schemas = grep {
  49             my $schema = $_;
  50             not any { lc($schema) eq lc($_) } $self->_system_schemas
  51         } @schemas;
  52
  53         $self->db_schema(\@schemas);
  54     }
  55 }
  56
  57 sub _show_databases {
  58     my $self = shift;
  59
  60     return map $_->[0], @{ $self->dbh->selectall_arrayref('SHOW DATABASES') };
  61 }
  62
  63 sub _system_schemas {
  64     my $self = shift;
  65
  66     return ($self->next::method(@_), 'mysql');
  67 }
  68
  69 sub _tables_list {
  70     my ($self, $opts) = @_;
  71
  72     return $self->next::method($opts, undef, undef);
  73 }
  74
  75 sub _table_fk_info {
  76     my ($self, $table) = @_;
  77
  78     my $table_def_ref = eval { $self->dbh->selectrow_arrayref("SHOW CREATE TABLE ".$table->sql_name) };
  79     my $table_def = $table_def_ref->[1];
  80
  81     return [] if not $table_def;
  82
  83     my $qt  = qr/["`]/;
  84     my $nqt = qr/[^"`]/;
  85
  86     my (@reldata) = ($table_def =~
  87         /CONSTRAINT ${qt}${nqt}+${qt} FOREIGN KEY \($qt(.*)$qt\) REFERENCES (?:$qt($nqt+)$qt\.)?$qt($nqt+)$qt \($qt(.+)$qt\)\s*(.*)/ig
  88     );
  89
  90     my @rels;
  91     while (scalar @reldata > 0) {
  92         my ($cols, $f_schema, $f_table, $f_cols, $rest) = splice @reldata, 0, 5;
  93
  94         my @cols   = map { s/$qt//g; $self->_lc($_) }
  95             split(/$qt?\s*$qt?,$qt?\s*$qt?/, $cols);
  96
  97         my @f_cols = map { s/$qt//g; $self->_lc($_) }
  98             split(/$qt?\s*$qt?,$qt?\s*$qt?/, $f_cols);
  99
 100         # Match case of remote schema to that in SHOW DATABASES, if it's there
 101         # and we have permissions to run SHOW DATABASES.
 102         if ($f_schema) {
 103             my $matched = first {
 104                 lc($_) eq lc($f_schema)
 105             } try { $self->_show_databases };
 106
 107             $f_schema = $matched if $matched;
 108         }
 109
 110         my $remote_table = do {
 111             # Get ->tables_list to return tables from the remote schema, in case it is not in the db_schema list.
 112             local $self->{db_schema} = [ $f_schema ] if $f_schema;
 113
 114             first {
 115                    lc($_->name) eq lc($f_table)
 116                 && ((not $f_schema) || lc($_->schema) eq lc($f_schema))
 117             } $self->_tables_list;
 118         };
 119
 120         # The table may not be in any database, or it may not have been found by the previous code block for whatever reason.
 121         if (not $remote_table) {
 122             my $remote_schema = $f_schema || $self->db_schema && @{ $self->db_schema } == 1 && $self->db_schema->[0];
 123
 124             $remote_table = DBIx::Class::Schema::Loader::Table->new(
 125                 loader => $self,
 126                 name   => $f_table,
 127                 ($remote_schema ? (
 128                     schema => $remote_schema,
 129                 ) : ()),
 130             );
 131         }
 132
 133         my %attrs;
 134
 135         if ($rest) {
 136             my @on_clauses = $rest =~ /(ON DELETE|ON UPDATE) (RESTRICT|CASCADE|SET NULL|NO ACTION) ?/ig;
 137
 138             while (my ($clause, $value) = splice @on_clauses, 0, 2) {
 139                 $clause = lc $clause;
 140                 $clause =~ s/ /_/;
 141
 142                 $value = uc $value;
 143
 144                 $attrs{$clause} = $value;
 145             }
 146         }
 147
 148 # The default behavior is RESTRICT. Specifying RESTRICT explicitly just removes
 149 # that ON clause from the SHOW CREATE TABLE output. For this reason, even
 150 # though the default for these clauses everywhere else in Schema::Loader is
 151 # CASCADE, we change the default here to RESTRICT in order to reproduce the
 152 # schema faithfully.
 153         $attrs{on_delete}     ||= 'RESTRICT';
 154         $attrs{on_update}     ||= 'RESTRICT';
 155
 156 # MySQL does not have a DEFERRABLE attribute, but there is a way to defer FKs.
 157         $attrs{is_deferrable}   = 1;
 158
 159         push(@rels, {
 160             local_columns => \@cols,
 161             remote_columns => \@f_cols,
 162             remote_table => $remote_table,
 163             attrs => \%attrs,
 164         });
 165     }
 166
 167     return \@rels;
 168 }
 169
 170 # primary and unique info comes from the same sql statement,
 171 #   so cache it here for both routines to use
 172 sub _mysql_table_get_keys {
 173     my ($self, $table) = @_;
 174
 175     if(!exists($self->{_cache}->{_mysql_keys}->{$table->sql_name})) {
 176         my %keydata;
 177         my $sth = $self->dbh->prepare('SHOW INDEX FROM '.$table->sql_name);
 178         $sth->execute;
 179         while(my $row = $sth->fetchrow_hashref) {
 180             next if $row->{Non_unique};
 181             push(@{$keydata{$row->{Key_name}}},
 182                 [ $row->{Seq_in_index}, $self->_lc($row->{Column_name}) ]
 183             );
 184         }
 185         foreach my $keyname (keys %keydata) {
 186             my @ordered_cols = map { $_->[1] } sort { $a->[0] <=> $b->[0] }
 187                 @{$keydata{$keyname}};
 188             $keydata{$keyname} = \@ordered_cols;
 189         }
 190         $self->{_cache}->{_mysql_keys}->{$table->sql_name} = \%keydata;
 191     }
 192
 193     return $self->{_cache}->{_mysql_keys}->{$table->sql_name};
 194 }
 195
 196 sub _table_pk_info {
 197     my ( $self, $table ) = @_;
 198
 199     return $self->_mysql_table_get_keys($table)->{PRIMARY};
 200 }
 201
 202 sub _table_uniq_info {
 203     my ( $self, $table ) = @_;
 204
 205     my @uniqs;
 206     my $keydata = $self->_mysql_table_get_keys($table);
 207     foreach my $keyname (keys %$keydata) {
 208         next if $keyname eq 'PRIMARY';
 209         push(@uniqs, [ $keyname => $keydata->{$keyname} ]);
 210     }
 211
 212     return \@uniqs;
 213 }
 214
 215 sub _columns_info_for {
 216     my $self = shift;
 217     my ($table) = @_;
 218
 219     my $result = $self->next::method(@_);
 220
 221     while (my ($col, $info) = each %$result) {
 222         if ($info->{data_type} eq 'int') {
 223             $info->{data_type} = 'integer';
 224         }
 225         elsif ($info->{data_type} eq 'double') {
 226             $info->{data_type} = 'double precision';
 227         }
 228         my $data_type = $info->{data_type};
 229
 230         delete $info->{size} if $data_type !~ /^(?: (?:var)?(?:char(?:acter)?|binary) | bit | year)\z/ix;
 231
 232         # information_schema is available in 5.0+
 233         my ($precision, $scale, $column_type, $default) = eval { $self->dbh->selectrow_array(<<'EOF', {}, $table->name, lc($col)) };
 234 SELECT numeric_precision, numeric_scale, column_type, column_default
 235 FROM information_schema.columns
 236 WHERE table_name = ? AND lower(column_name) = ?
 237 EOF
 238         my $has_information_schema = not $@;
 239
 240         $column_type = '' if not defined $column_type;
 241
 242         if ($data_type eq 'bit' && (not exists $info->{size})) {
 243             $info->{size} = $precision if defined $precision;
 244         }
 245         elsif ($data_type =~ /^(?:float|double precision|decimal)\z/i) {
 246             if (defined $precision && defined $scale) {
 247                 if ($precision == 10 && $scale == 0) {
 248                     delete $info->{size};
 249                 }
 250                 else {
 251                     $info->{size} = [$precision,$scale];
 252                 }
 253             }
 254         }
 255         elsif ($data_type eq 'year') {
 256             if ($column_type =~ /\(2\)/) {
 257                 $info->{size} = 2;
 258             }
 259             elsif ($column_type =~ /\(4\)/ || $info->{size} == 4) {
 260                 delete $info->{size};
 261             }
 262         }
 263         elsif ($data_type =~ /^(?:date(?:time)?|timestamp)\z/) {
 264             if (not (defined $self->datetime_undef_if_invalid && $self->datetime_undef_if_invalid == 0)) {
 265                 $info->{datetime_undef_if_invalid} = 1;
 266             }
 267         }
 268         elsif ($data_type =~ /^(?:enum|set)\z/ && $has_information_schema
 269                && $column_type =~ /^(?:enum|set)\(/) {
 270
 271             delete $info->{extra}{list};
 272
 273             while ($column_type =~ /'((?:[^']* (?:''|\\')* [^']*)* [^\\']?)',?/xg) {
 274                 my $el = $1;
 275                 $el =~ s/''/'/g;
 276                 push @{ $info->{extra}{list} }, $el;
 277             }
 278         }
 279
 280         # Sometimes apparently there's a bug where default_value gets set to ''
 281         # for things that don't actually have or support that default (like ints.)
 282         if (exists $info->{default_value} && $info->{default_value} eq '') {
 283             if ($has_information_schema) {
 284                 if (not defined $default) {
 285                     delete $info->{default_value};
 286                 }
 287             }
 288             else { # just check if it's a char/text type, otherwise remove
 289                 delete $info->{default_value} unless $data_type =~ /char|text/i;
 290             }
 291         }
 292     }
 293
 294     return $result;
 295 }
 296
 297 sub _extra_column_info {
 298     no warnings 'uninitialized';
 299     my ($self, $table, $col, $info, $dbi_info) = @_;
 300     my %extra_info;
 301
 302     if ($dbi_info->{mysql_is_auto_increment}) {
 303         $extra_info{is_auto_increment} = 1
 304     }
 305     if ($dbi_info->{mysql_type_name} =~ /\bunsigned\b/i) {
 306         $extra_info{extra}{unsigned} = 1;
 307     }
 308     if ($dbi_info->{mysql_values}) {
 309         $extra_info{extra}{list} = $dbi_info->{mysql_values};
 310     }
 311     if ((not blessed $dbi_info) # isa $sth
 312         && lc($dbi_info->{COLUMN_DEF})      eq 'current_timestamp'
 313         && lc($dbi_info->{mysql_type_name}) eq 'timestamp') {
 314
 315         my $current_timestamp = 'current_timestamp';
 316         $extra_info{default_value} = \$current_timestamp;
 317     }
 318
 319     return \%extra_info;
 320 }
 321
 322 sub _dbh_column_info {
 323     my $self = shift;
 324
 325     local $SIG{__WARN__} = sigwarn_silencer(
 326         qr/^column_info: unrecognized column type/
 327     );
 328
 329     $self->next::method(@_);
 330 }
 331
 332 sub _table_comment {
 333     my ( $self, $table ) = @_;
 334     my $comment = $self->next::method($table);
 335     if (not $comment) {
 336         ($comment) = try { $self->schema->storage->dbh->selectrow_array(
 337             qq{SELECT table_comment
 338                 FROM information_schema.tables
 339                 WHERE table_schema = schema()
 340                   AND table_name = ?
 341             }, undef, $table->name);
 342         };
 343         # InnoDB likes to auto-append crap.
 344         if (not $comment) {
 345             # Do nothing.
 346         }
 347         elsif ($comment =~ /^InnoDB free:/) {
 348             $comment = undef;
 349         }
 350         else {
 351             $comment =~ s/; InnoDB.*//;
 352         }
 353     }
 354     return $comment;
 355 }
 356
 357 sub _column_comment {
 358     my ( $self, $table, $column_number, $column_name ) = @_;
 359     my $comment = $self->next::method($table, $column_number, $column_name);
 360     if (not $comment) {
 361         ($comment) = try { $self->schema->storage->dbh->selectrow_array(
 362             qq{SELECT column_comment
 363                 FROM information_schema.columns
 364                 WHERE table_schema = schema()
 365                   AND table_name = ?
 366                   AND lower(column_name) = ?
 367             }, undef, $table->name, lc($column_name));
 368         };
 369     }
 370     return $comment;
 371 }
 372
 373 =head1 SEE ALSO
 374
 375 L<DBIx::Class::Schema::Loader>, L<DBIx::Class::Schema::Loader::Base>,
 376 L<DBIx::Class::Schema::Loader::DBI>
 377
 378 =head1 AUTHOR
 379
 380 See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
 381
 382 =head1 LICENSE
 383
 384 This library is free software; you can redistribute it and/or modify it under
 385 the same terms as Perl itself.
 386
 387 =cut
 388
 389 1;
 390 # vim:et sw=4 sts=4 tw=0: