lib/DBIx/Class/Schema/Loader/DBI/Sybase.pm

   1 package DBIx::Class::Schema::Loader::DBI::Sybase;
   2
   3 use strict;
   4 use warnings;
   5 use base 'DBIx::Class::Schema::Loader::DBI::Sybase::Common';
   6 use Carp::Clan qw/^DBIx::Class/;
   7 use mro 'c3';
   8
   9 our $VERSION = '0.07001';
  10
  11 =head1 NAME
  12
  13 DBIx::Class::Schema::Loader::DBI::Sybase - DBIx::Class::Schema::Loader::DBI
  14 Sybase ASE Implementation.
  15
  16 =head1 DESCRIPTION
  17
  18 See L<DBIx::Class::Schema::Loader> and L<DBIx::Class::Schema::Loader::Base>.
  19
  20 =cut
  21
  22 sub _setup {
  23     my $self = shift;
  24
  25     $self->next::method(@_);
  26
  27     if (not defined $self->preserve_case) {
  28         $self->preserve_case(1);
  29     }
  30 }
  31
  32 sub _rebless {
  33     my $self = shift;
  34
  35     my $dbh = $self->schema->storage->dbh;
  36     my $DBMS_VERSION = @{$dbh->selectrow_arrayref(qq{sp_server_info \@attribute_id=1})}[2];
  37     if ($DBMS_VERSION =~ /^Microsoft /i) {
  38         $DBMS_VERSION =~ s/\s/_/g;
  39         my $subclass = "DBIx::Class::Schema::Loader::DBI::Sybase::$DBMS_VERSION";
  40         if ($self->load_optional_class($subclass) && !$self->isa($subclass)) {
  41             bless $self, $subclass;
  42             $self->_rebless;
  43       }
  44     }
  45 }
  46
  47 sub _table_columns {
  48     my ($self, $table) = @_;
  49
  50     my $dbh = $self->schema->storage->dbh;
  51     my $columns = $dbh->selectcol_arrayref(qq{
  52 SELECT c.name
  53 FROM syscolumns c JOIN sysobjects o
  54 ON c.id = o.id
  55 WHERE o.name = @{[ $dbh->quote($table) ]} AND o.type = 'U'
  56 });
  57
  58     return $columns;
  59 }
  60
  61 sub _table_pk_info {
  62     my ($self, $table) = @_;
  63
  64     my $dbh = $self->schema->storage->dbh;
  65     my $sth = $dbh->prepare(qq{sp_pkeys @{[ $dbh->quote($table) ]}});
  66     $sth->execute;
  67
  68     my @keydata;
  69
  70     while (my $row = $sth->fetchrow_hashref) {
  71         push @keydata, $row->{column_name};
  72     }
  73
  74     return \@keydata;
  75 }
  76
  77 sub _table_fk_info {
  78     my ($self, $table) = @_;
  79
  80     # check if FK_NAME is supported
  81
  82     my $dbh = $self->schema->storage->dbh;
  83     local $dbh->{FetchHashKeyName} = 'NAME_lc';
  84     # hide "Object does not exist in this database." when trying to fetch fkeys
  85     local $dbh->{syb_err_handler} = sub { return $_[0] == 17461 ? 0 : 1 };
  86     my $sth = $dbh->prepare(qq{sp_fkeys \@fktable_name = @{[ $dbh->quote($table) ]}});
  87     $sth->execute;
  88     my $row = $sth->fetchrow_hashref;
  89
  90     return unless $row;
  91
  92     if (exists $row->{fk_name}) {
  93         $sth->finish;
  94         return $self->_table_fk_info_by_name($table);
  95     }
  96
  97     $sth->finish;
  98     return $self->_table_fk_info_builder($table);
  99 }
 100
 101 sub _table_fk_info_by_name {
 102     my ($self, $table) = @_;
 103     my ($local_cols, $remote_cols, $remote_table, @rels);
 104
 105     my $dbh = $self->schema->storage->dbh;
 106     local $dbh->{FetchHashKeyName} = 'NAME_lc';
 107     # hide "Object does not exist in this database." when trying to fetch fkeys
 108     local $dbh->{syb_err_handler} = sub { return $_[0] == 17461 ? 0 : 1 };
 109     my $sth = $dbh->prepare(qq{sp_fkeys \@fktable_name = @{[ $dbh->quote($table) ]}});
 110     $sth->execute;
 111
 112     while (my $row = $sth->fetchrow_hashref) {
 113         my $fk = $row->{fk_name};
 114         next unless defined $fk;
 115
 116         push @{$local_cols->{$fk}}, $row->{fkcolumn_name};
 117         push @{$remote_cols->{$fk}}, $row->{pkcolumn_name};
 118         $remote_table->{$fk} = $row->{pktable_name};
 119     }
 120
 121     foreach my $fk (keys %$remote_table) {
 122         push @rels, {
 123                      local_columns => \@{$local_cols->{$fk}},
 124                      remote_columns => \@{$remote_cols->{$fk}},
 125                      remote_table => $remote_table->{$fk},
 126                     };
 127
 128     }
 129     return \@rels;
 130 }
 131
 132 sub _table_fk_info_builder {
 133     my ($self, $table) = @_;
 134
 135     my $dbh = $self->schema->storage->dbh;
 136     local $dbh->{FetchHashKeyName} = 'NAME_lc';
 137     # hide "Object does not exist in this database." when trying to fetch fkeys
 138     local $dbh->{syb_err_handler} = sub { return 0 if $_[0] == 17461; };
 139     my $sth = $dbh->prepare(qq{sp_fkeys \@fktable_name = @{[ $dbh->quote($table) ]}});
 140     $sth->execute;
 141
 142     my @fk_info;
 143     while (my $row = $sth->fetchrow_hashref) {
 144         (my $ksq = $row->{key_seq}) =~ s/\s+//g;
 145
 146         my @keys = qw/pktable_name pkcolumn_name fktable_name fkcolumn_name/;
 147         my %ds;
 148         @ds{@keys}   = @{$row}{@keys};
 149         $ds{key_seq} = $ksq;
 150
 151         push @{ $fk_info[$ksq] }, \%ds;
 152     }
 153
 154     my $max_keys = $#fk_info;
 155     my @rels;
 156     for my $level (reverse 1 .. $max_keys) {
 157         my @level_rels;
 158         $level_rels[$level] = splice @fk_info, $level, 1;
 159         my $count = @{ $level_rels[$level] };
 160
 161         for my $sub_level (reverse 1 .. $level-1) {
 162             my $total = @{ $fk_info[$sub_level] };
 163
 164             $level_rels[$sub_level] = [
 165                 splice @{ $fk_info[$sub_level] }, $total-$count, $count
 166             ];
 167         }
 168
 169         while (1) {
 170             my @rel = map shift @$_, @level_rels[1..$level];
 171
 172             last unless defined $rel[0];
 173
 174             my @local_columns  = map $_->{fkcolumn_name}, @rel;
 175             my @remote_columns = map $_->{pkcolumn_name}, @rel;
 176             my $remote_table   = $rel[0]->{pktable_name};
 177
 178             push @rels, {
 179                 local_columns => \@local_columns,
 180                 remote_columns => \@remote_columns,
 181                 remote_table => $remote_table
 182             };
 183         }
 184     }
 185
 186     return \@rels;
 187 }
 188
 189 sub _table_uniq_info {
 190     my ($self, $table) = @_;
 191
 192     # FIXME - remove blind mask (can't test sybase yet)
 193     local $SIG{__WARN__} = sub {};
 194
 195     my $dbh = $self->schema->storage->dbh;
 196     local $dbh->{FetchHashKeyName} = 'NAME_lc';
 197     my $sth = $dbh->prepare(qq{sp_helpconstraint \@objname=@{[ $dbh->quote($table) ]}, \@nomsg='nomsg'});
 198     eval { $sth->execute };
 199     return if $@;
 200
 201     my $constraints;
 202     while (my $row = $sth->fetchrow_hashref) {
 203         if (exists $row->{constraint_type}) {
 204             my $type = $row->{constraint_type} || '';
 205             if ($type =~ /^unique/i) {
 206                 my $name = $row->{constraint_name};
 207                 push @{$constraints->{$name}},
 208                     ( split /,/, $row->{constraint_keys} );
 209             }
 210         } else {
 211             my $def = $row->{definition} || next;
 212             next unless $def =~ /^unique/i;
 213             my $name = $row->{name};
 214             my ($keys) = $def =~ /\((.*)\)/;
 215             $keys =~ s/\s*//g;
 216             my @keys = split /,/ => $keys;
 217             push @{$constraints->{$name}}, @keys;
 218         }
 219     }
 220
 221     my @uniqs = map { [ $_ => $constraints->{$_} ] } keys %$constraints;
 222     return \@uniqs;
 223 }
 224
 225 # get the correct data types, defaults and size
 226 sub _columns_info_for {
 227     my $self    = shift;
 228     my ($table) = @_;
 229     my $result  = $self->next::method(@_);
 230
 231     my $dbh = $self->schema->storage->dbh;
 232     my $sth = $dbh->prepare(qq{
 233 SELECT c.name name, bt.name base_type, ut.name user_type, cm.text deflt, c.prec prec, c.scale scale, c.length len
 234 FROM syscolumns c
 235 JOIN sysobjects o ON c.id = o.id
 236 LEFT JOIN systypes bt ON c.type     = bt.type
 237 LEFT JOIN systypes ut ON c.usertype = ut.usertype
 238 LEFT JOIN syscomments cm
 239     ON cm.id = CASE WHEN c.cdefault = 0 THEN c.computedcol ELSE c.cdefault END
 240 WHERE o.name = @{[ $dbh->quote($table) ]} AND o.type = 'U'
 241 });
 242     $sth->execute;
 243     local $dbh->{FetchHashKeyName} = 'NAME_lc';
 244     my $info = $sth->fetchall_hashref('name');
 245
 246     while (my ($col, $res) = each %$result) {
 247         my $data_type = $res->{data_type} = $info->{$col}{user_type} || $info->{$col}{base_type};
 248
 249         if ($data_type && $data_type =~ /^timestamp\z/i) {
 250             $res->{inflate_datetime} = 0;
 251         }
 252
 253         if (my $default = $info->{$col}{deflt}) {
 254             if ($default =~ /^AS \s+ (\S+)/ix) {
 255                 my $function = $1;
 256                 $res->{default_value} = \$function;
 257
 258                 if ($function =~ /^getdate\b/) {
 259                     $res->{inflate_datetime} = 1;
 260                 }
 261
 262                 delete $res->{size};
 263                 $res->{data_type} = undef;
 264             }
 265             elsif ($default =~ /^DEFAULT \s+ (\S+)/ix) {
 266                 my ($constant_default) = $1 =~ /^['"\[\]]?(.*?)['"\[\]]?\z/;
 267                 $res->{default_value} = $constant_default;
 268             }
 269         }
 270
 271         if (my $data_type = $res->{data_type}) {
 272             if ($data_type eq 'int') {
 273                 $data_type = $res->{data_type} = 'integer';
 274             }
 275             elsif ($data_type eq 'decimal') {
 276                 $data_type = $res->{data_type} = 'numeric';
 277             }
 278
 279             if ($data_type =~ /^(?:text|unitext|image|bigint|integer|smallint|tinyint|real|double|double precision|float|date|time|datetime|smalldatetime|money|smallmoney|timestamp|bit)\z/i) {
 280                 delete $res->{size};
 281             }
 282             elsif ($data_type eq 'numeric') {
 283                 my ($prec, $scale) = @{$info->{$col}}{qw/prec scale/};
 284
 285                 if ($prec == 18 && $scale == 0) {
 286                     delete $res->{size};
 287                 }
 288                 else {
 289                     $res->{size} = [ $prec, $scale ];
 290                 }
 291             }
 292             elsif ($data_type =~ /^(?:unichar|univarchar)\z/i) {
 293                 $res->{size} /= 2;
 294             }
 295         }
 296
 297         if ($data_type eq 'float') {
 298             $res->{data_type} = $info->{$col}{len} <= 4 ? 'real' : 'double precision';
 299         }
 300     }
 301
 302     return $result;
 303 }
 304
 305 sub _extra_column_info {
 306     my ($self, $table, $column, $info, $dbi_info) = @_;
 307     my %extra_info;
 308
 309     my $dbh = $self->schema->storage->dbh;
 310     my $sth = $dbh->prepare(qq{SELECT name FROM syscolumns WHERE id = (SELECT id FROM sysobjects WHERE name = @{[ $dbh->quote($table) ]}) AND (status & 0x80) = 0x80 AND name = @{[ $dbh->quote($column) ]}});
 311     $sth->execute();
 312
 313     if ($sth->fetchrow_array) {
 314         $extra_info{is_auto_increment} = 1;
 315     }
 316
 317     return \%extra_info;
 318 }
 319
 320 =head1 SEE ALSO
 321
 322 L<DBIx::Class::Schema::Loader::DBI::Sybase::Common>,
 323 L<DBIx::Class::Schema::Loader>, L<DBIx::Class::Schema::Loader::Base>,
 324 L<DBIx::Class::Schema::Loader::DBI>
 325
 326 =head1 AUTHOR
 327
 328 See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
 329
 330 =head1 LICENSE
 331
 332 This library is free software; you can redistribute it and/or modify it under
 333 the same terms as Perl itself.
 334
 335 =cut
 336
 337 1;