lib/DBIx/Class/Schema/Loader/DBI/SQLite.pm

   1 package DBIx::Class::Schema::Loader::DBI::SQLite;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/
   6     DBIx::Class::Schema::Loader::DBI::Component::QuotedDefault
   7     DBIx::Class::Schema::Loader::DBI
   8 /;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Text::Balanced qw( extract_bracketed );
  11 use Class::C3;
  12
  13 our $VERSION = '0.07000';
  14
  15 =head1 NAME
  16
  17 DBIx::Class::Schema::Loader::DBI::SQLite - DBIx::Class::Schema::Loader::DBI SQLite Implementation.
  18
  19 =head1 DESCRIPTION
  20
  21 See L<DBIx::Class::Schema::Loader> and L<DBIx::Class::Schema::Loader::Base>.
  22
  23 =head1 METHODS
  24
  25 =head2 rescan
  26
  27 SQLite will fail all further commands on a connection if the underlying schema
  28 has been modified.  Therefore, any runtime changes requiring C<rescan> also
  29 require us to re-connect to the database.  The C<rescan> method here handles
  30 that reconnection for you, but beware that this must occur for any other open
  31 sqlite connections as well.
  32
  33 =cut
  34
  35 sub _setup {
  36     my $self = shift;
  37
  38     $self->next::method(@_);
  39
  40     if (not defined $self->preserve_case) {
  41         $self->preserve_case(0);
  42     }
  43 }
  44
  45 sub rescan {
  46     my ($self, $schema) = @_;
  47
  48     $schema->storage->disconnect if $schema->storage;
  49     $self->next::method($schema);
  50 }
  51
  52 sub _columns_info_for {
  53     my $self = shift;
  54     my ($table) = @_;
  55
  56     my $result = $self->next::method(@_);
  57
  58     my $dbh = $self->schema->storage->dbh;
  59     local $dbh->{FetchHashKeyName} = 'NAME_lc';
  60
  61     my $sth = $dbh->prepare(
  62       "pragma table_info(" . $dbh->quote_identifier($table) . ")"
  63     );
  64     $sth->execute;
  65     my $cols = $sth->fetchall_hashref('name');
  66
  67     while (my ($col_name, $info) = each %$result) {
  68       if ($cols->{$col_name}{pk} && lc($cols->{$col_name}{type}) eq 'integer') {
  69         $info->{is_auto_increment} = 1;
  70       }
  71     }
  72
  73     while (my ($col, $info) = each %$result) {
  74         if ((eval { ${ $info->{default_value} } }||'') eq 'CURRENT_TIMESTAMP') {
  75             ${ $info->{default_value} } = 'current_timestamp';
  76         }
  77     }
  78
  79     return $result;
  80 }
  81
  82 sub _table_fk_info {
  83     my ($self, $table) = @_;
  84
  85     my $dbh = $self->schema->storage->dbh;
  86     my $sth = $dbh->prepare(
  87         "pragma foreign_key_list(" . $dbh->quote_identifier($table) . ")"
  88     );
  89     $sth->execute;
  90
  91     my @rels;
  92     while (my $fk = $sth->fetchrow_hashref) {
  93         my $rel = $rels[ $fk->{id} ] ||= {
  94             local_columns => [],
  95             remote_columns => undef,
  96             remote_table => $fk->{table}
  97         };
  98
  99         push @{ $rel->{local_columns} }, $self->_lc($fk->{from});
 100         push @{ $rel->{remote_columns} }, $self->_lc($fk->{to}) if defined $fk->{to};
 101         warn "This is supposed to be the same rel but remote_table changed from ",
 102             $rel->{remote_table}, " to ", $fk->{table}
 103             if $rel->{remote_table} ne $fk->{table};
 104     }
 105     $sth->finish;
 106     return \@rels;
 107 }
 108
 109 sub _table_uniq_info {
 110     my ($self, $table) = @_;
 111
 112     my $dbh = $self->schema->storage->dbh;
 113     my $sth = $dbh->prepare(
 114         "pragma index_list(" . $dbh->quote($table) . ")"
 115     );
 116     $sth->execute;
 117
 118     my @uniqs;
 119     while (my $idx = $sth->fetchrow_hashref) {
 120         next unless $idx->{unique};
 121         my $name = $idx->{name};
 122
 123         my $get_idx_sth = $dbh->prepare("pragma index_info(" . $dbh->quote($name) . ")");
 124         $get_idx_sth->execute;
 125         my @cols;
 126         while (my $idx_row = $get_idx_sth->fetchrow_hashref) {
 127             push @cols, $self->_lc($idx_row->{name});
 128         }
 129         $get_idx_sth->finish;
 130         push @uniqs, [ $name => \@cols ];
 131     }
 132     $sth->finish;
 133     return \@uniqs;
 134 }
 135
 136 sub _tables_list {
 137     my ($self, $opts) = @_;
 138
 139     my $dbh = $self->schema->storage->dbh;
 140     my $sth = $dbh->prepare("SELECT * FROM sqlite_master");
 141     $sth->execute;
 142     my @tables;
 143     while ( my $row = $sth->fetchrow_hashref ) {
 144         next unless $row->{type} =~ /^(?:table|view)\z/i;
 145         next if $row->{tbl_name} =~ /^sqlite_/;
 146         push @tables, $row->{tbl_name};
 147     }
 148     $sth->finish;
 149     return $self->_filter_tables(\@tables, $opts);
 150 }
 151
 152 =head1 SEE ALSO
 153
 154 L<DBIx::Class::Schema::Loader>, L<DBIx::Class::Schema::Loader::Base>,
 155 L<DBIx::Class::Schema::Loader::DBI>
 156
 157 =head1 AUTHOR
 158
 159 See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
 160
 161 =head1 LICENSE
 162
 163 This library is free software; you can redistribute it and/or modify it under
 164 the same terms as Perl itself.
 165
 166 =cut
 167
 168 1;