lib/DBIx/Class/Schema/Loader/DBI/SQLite.pm

   1 package DBIx::Class::Schema::Loader::DBI::SQLite;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/
   6     DBIx::Class::Schema::Loader::DBI::Component::QuotedDefault
   7     DBIx::Class::Schema::Loader::DBI
   8 /;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Text::Balanced qw( extract_bracketed );
  11 use Class::C3;
  12
  13 our $VERSION = '0.07000';
  14
  15 =head1 NAME
  16
  17 DBIx::Class::Schema::Loader::DBI::SQLite - DBIx::Class::Schema::Loader::DBI SQLite Implementation.
  18
  19 =head1 DESCRIPTION
  20
  21 See L<DBIx::Class::Schema::Loader> and L<DBIx::Class::Schema::Loader::Base>.
  22
  23 =head1 METHODS
  24
  25 =head2 rescan
  26
  27 SQLite will fail all further commands on a connection if the underlying schema
  28 has been modified.  Therefore, any runtime changes requiring C<rescan> also
  29 require us to re-connect to the database.  The C<rescan> method here handles
  30 that reconnection for you, but beware that this must occur for any other open
  31 sqlite connections as well.
  32
  33 =cut
  34
  35 sub _setup {
  36     my $self = shift;
  37
  38     $self->next::method(@_);
  39
  40     if (not defined $self->preserve_case) {
  41         $self->preserve_case(0);
  42     }
  43 }
  44
  45 sub rescan {
  46     my ($self, $schema) = @_;
  47
  48     $schema->storage->disconnect if $schema->storage;
  49     $self->next::method($schema);
  50 }
  51
  52 sub _columns_info_for {
  53     my $self = shift;
  54     my ($table) = @_;
  55
  56     my $result = $self->next::method(@_);
  57
  58     my $dbh = $self->schema->storage->dbh;
  59     local $dbh->{FetchHashKeyName} = 'NAME_lc';
  60
  61     my $has_autoinc = eval {
  62       my $get_seq = $self->{_cache}{sqlite_sequence}
  63         ||= $dbh->prepare(q{SELECT count(*) FROM sqlite_sequence WHERE name = ?});
  64       $get_seq->execute($table);
  65       my ($ret) = $get_seq->fetchrow_array;
  66       $get_seq->finish;
  67       $ret;
  68     };
  69
  70     if (!$@ && $has_autoinc) {
  71         my $sth = $dbh->prepare(
  72             "pragma table_info(" . $dbh->quote_identifier($table) . ")"
  73         );
  74         $sth->execute;
  75         my $cols = $sth->fetchall_hashref('name');
  76
  77         while (my ($col_name, $info) = each %$result) {
  78             if ($cols->{$col_name}{pk}) {
  79                 $info->{is_auto_increment} = 1;
  80             }
  81         }
  82     }
  83
  84     while (my ($col, $info) = each %$result) {
  85         if (eval { ${ $info->{default_value} } }||'' eq 'CURRENT_TIMESTAMP') {
  86             ${ $info->{default_value} } = 'current_timestamp';
  87         }
  88     }
  89
  90     return $result;
  91 }
  92
  93 sub _table_fk_info {
  94     my ($self, $table) = @_;
  95
  96     my $dbh = $self->schema->storage->dbh;
  97     my $sth = $dbh->prepare(
  98         "pragma foreign_key_list(" . $dbh->quote_identifier($table) . ")"
  99     );
 100     $sth->execute;
 101
 102     my @rels;
 103     while (my $fk = $sth->fetchrow_hashref) {
 104         my $rel = $rels[ $fk->{id} ] ||= {
 105             local_columns => [],
 106             remote_columns => undef,
 107             remote_table => $fk->{table}
 108         };
 109
 110         push @{ $rel->{local_columns} }, $self->_lc($fk->{from});
 111         push @{ $rel->{remote_columns} }, $self->_lc($fk->{to}) if defined $fk->{to};
 112         warn "This is supposed to be the same rel but remote_table changed from ",
 113             $rel->{remote_table}, " to ", $fk->{table}
 114             if $rel->{remote_table} ne $fk->{table};
 115     }
 116     $sth->finish;
 117     return \@rels;
 118 }
 119
 120 sub _table_uniq_info {
 121     my ($self, $table) = @_;
 122
 123     my $dbh = $self->schema->storage->dbh;
 124     my $sth = $dbh->prepare(
 125         "pragma index_list(" . $dbh->quote($table) . ")"
 126     );
 127     $sth->execute;
 128
 129     my @uniqs;
 130     while (my $idx = $sth->fetchrow_hashref) {
 131         next unless $idx->{unique};
 132         my $name = $idx->{name};
 133
 134         my $get_idx_sth = $dbh->prepare("pragma index_info(" . $dbh->quote($name) . ")");
 135         $get_idx_sth->execute;
 136         my @cols;
 137         while (my $idx_row = $get_idx_sth->fetchrow_hashref) {
 138             push @cols, $self->_lc($idx_row->{name});
 139         }
 140         $get_idx_sth->finish;
 141         push @uniqs, [ $name => \@cols ];
 142     }
 143     $sth->finish;
 144     return \@uniqs;
 145 }
 146
 147 sub _tables_list {
 148     my ($self, $opts) = @_;
 149
 150     my $dbh = $self->schema->storage->dbh;
 151     my $sth = $dbh->prepare("SELECT * FROM sqlite_master");
 152     $sth->execute;
 153     my @tables;
 154     while ( my $row = $sth->fetchrow_hashref ) {
 155         next unless $row->{type} =~ /^(?:table|view)\z/i;
 156         next if $row->{tbl_name} =~ /^sqlite_/;
 157         push @tables, $row->{tbl_name};
 158     }
 159     $sth->finish;
 160     return $self->_filter_tables(\@tables, $opts);
 161 }
 162
 163 =head1 SEE ALSO
 164
 165 L<DBIx::Class::Schema::Loader>, L<DBIx::Class::Schema::Loader::Base>,
 166 L<DBIx::Class::Schema::Loader::DBI>
 167
 168 =head1 AUTHOR
 169
 170 See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
 171
 172 =head1 LICENSE
 173
 174 This library is free software; you can redistribute it and/or modify it under
 175 the same terms as Perl itself.
 176
 177 =cut
 178
 179 1;