lib/DBIx/Class/Schema/Loader/DBI/SQLAnywhere.pm

   1 package DBIx::Class::Schema::Loader::DBI::SQLAnywhere;
   2
   3 use strict;
   4 use warnings;
   5 use Class::C3;
   6 use base qw/
   7     DBIx::Class::Schema::Loader::DBI::Component::QuotedDefault
   8     DBIx::Class::Schema::Loader::DBI
   9 /;
  10 use Carp::Clan qw/^DBIx::Class/;
  11
  12 our $VERSION = '0.06000';
  13
  14 =head1 NAME
  15
  16 DBIx::Class::Schema::Loader::DBI::SQLAnywhere - DBIx::Class::Schema::Loader::DBI
  17 SQL Anywhere Implementation.
  18
  19 =head1 DESCRIPTION
  20
  21 See L<DBIx::Class::Schema::Loader::Base>.
  22
  23 =cut
  24
  25 sub _setup {
  26     my $self = shift;
  27
  28     $self->{db_schema} ||=
  29         ($self->schema->storage->dbh->selectrow_array('select user'))[0];
  30 }
  31
  32 sub _tables_list {
  33     my ($self, $opts) = @_;
  34
  35     my $dbh = $self->schema->storage->dbh;
  36     my $sth = $dbh->prepare(<<'EOF');
  37 select t.table_name from systab t
  38 join sysuser u on u.user_id = t.creator
  39 where u.user_name = ?
  40 EOF
  41     $sth->execute($self->db_schema);
  42
  43     my @tables = map @$_, @{ $sth->fetchall_arrayref };
  44
  45     return $self->_filter_tables(\@tables, $opts);
  46 }
  47
  48 # check for IDENTITY columns
  49 sub _columns_info_for {
  50     my $self   = shift;
  51     my $result = $self->next::method(@_);
  52
  53     while (my ($col, $info) = each %$result) {
  54         my $def = $info->{default_value};
  55         if (ref $def eq 'SCALAR' && $$def eq 'autoincrement') {
  56             delete $info->{default_value};
  57             $info->{is_auto_increment} = 1;
  58         }
  59     }
  60
  61     return $result;
  62 }
  63
  64 sub _table_pk_info {
  65     my ($self, $table) = @_;
  66     my $dbh = $self->schema->storage->dbh;
  67     local $dbh->{FetchHashKeyName} = 'NAME_lc';
  68     my $sth = $dbh->prepare(qq{sp_pkeys ?});
  69     $sth->execute($table);
  70
  71     my @keydata;
  72
  73     while (my $row = $sth->fetchrow_hashref) {
  74         push @keydata, lc $row->{column_name};
  75     }
  76
  77     return \@keydata;
  78 }
  79
  80 sub _table_fk_info {
  81     my ($self, $table) = @_;
  82
  83     my ($local_cols, $remote_cols, $remote_table, @rels);
  84     my $dbh = $self->schema->storage->dbh;
  85     my $sth = $dbh->prepare(<<'EOF');
  86 select fki.index_name fk_name, fktc.column_name local_column, pkt.table_name remote_table, pktc.column_name remote_column
  87 from sysfkey fk
  88 join systab    pkt  on fk.primary_table_id = pkt.table_id
  89 join systab    fkt  on fk.foreign_table_id = fkt.table_id
  90 join sysidx    pki  on fk.primary_table_id = pki.table_id  and fk.primary_index_id    = pki.index_id
  91 join sysidx    fki  on fk.foreign_table_id = fki.table_id  and fk.foreign_index_id    = fki.index_id
  92 join sysidxcol fkic on fkt.table_id        = fkic.table_id and fki.index_id           = fkic.index_id
  93 join systabcol pktc on pkt.table_id        = pktc.table_id and fkic.primary_column_id = pktc.column_id
  94 join systabcol fktc on fkt.table_id        = fktc.table_id and fkic.column_id         = fktc.column_id
  95 where fkt.table_name = ?
  96 EOF
  97     $sth->execute($table);
  98
  99     while (my ($fk, $local_col, $remote_tab, $remote_col) = $sth->fetchrow_array) {
 100         push @{$local_cols->{$fk}},  lc $local_col;
 101         push @{$remote_cols->{$fk}}, lc $remote_col;
 102         $remote_table->{$fk} = lc $remote_tab;
 103     }
 104
 105     foreach my $fk (keys %$remote_table) {
 106         push @rels, {
 107             local_columns => $local_cols->{$fk},
 108             remote_columns => $remote_cols->{$fk},
 109             remote_table => $remote_table->{$fk},
 110         };
 111     }
 112     return \@rels;
 113 }
 114
 115 sub _table_uniq_info {
 116     my ($self, $table) = @_;
 117
 118     my $dbh = $self->schema->storage->dbh;
 119     my $sth = $dbh->prepare(<<'EOF');
 120 select c.constraint_name, tc.column_name
 121 from sysconstraint c
 122 join systab t on c.table_object_id = t.object_id
 123 join sysidx i on c.ref_object_id = i.object_id
 124 join sysidxcol ic on i.table_id = ic.table_id and i.index_id = ic.index_id
 125 join systabcol tc on ic.table_id = tc.table_id and ic.column_id = tc.column_id
 126 where c.constraint_type = 'U' and t.table_name = ?
 127 EOF
 128     $sth->execute($table);
 129
 130     my $constraints;
 131     while (my ($constraint_name, $column) = $sth->fetchrow_array) {
 132         push @{$constraints->{$constraint_name}}, lc $column;
 133     }
 134
 135     my @uniqs = map { [ $_ => $constraints->{$_} ] } keys %$constraints;
 136     return \@uniqs;
 137 }
 138
 139 =head1 SEE ALSO
 140
 141 L<DBIx::Class::Schema::Loader>, L<DBIx::Class::Schema::Loader::Base>,
 142 L<DBIx::Class::Schema::Loader::DBI>
 143
 144 =head1 AUTHOR
 145
 146 See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
 147
 148 =head1 LICENSE
 149
 150 This library is free software; you can redistribute it and/or modify it under
 151 the same terms as Perl itself.
 152
 153 =cut
 154
 155 1;