lib/DBIx/Class/Schema/Loader/DBI/SQLAnywhere.pm

   1 package DBIx::Class::Schema::Loader::DBI::SQLAnywhere;
   2
   3 use strict;
   4 use warnings;
   5 use Class::C3;
   6 use base qw/
   7     DBIx::Class::Schema::Loader::DBI::Component::QuotedDefault
   8     DBIx::Class::Schema::Loader::DBI
   9 /;
  10 use Carp::Clan qw/^DBIx::Class/;
  11
  12 our $VERSION = '0.07000';
  13
  14 =head1 NAME
  15
  16 DBIx::Class::Schema::Loader::DBI::SQLAnywhere - DBIx::Class::Schema::Loader::DBI
  17 SQL Anywhere Implementation.
  18
  19 =head1 DESCRIPTION
  20
  21 See L<DBIx::Class::Schema::Loader> and L<DBIx::Class::Schema::Loader::Base>.
  22
  23 =cut
  24
  25 sub _setup {
  26     my $self = shift;
  27
  28     $self->next::method(@_);
  29
  30     $self->{db_schema} ||=
  31         ($self->schema->storage->dbh->selectrow_array('select user'))[0];
  32
  33     if (not defined $self->preserve_case) {
  34         $self->preserve_case(0);
  35     }
  36 }
  37
  38 sub _tables_list {
  39     my ($self, $opts) = @_;
  40
  41     my $dbh = $self->schema->storage->dbh;
  42     my $sth = $dbh->prepare(<<'EOF');
  43 select t.table_name from systab t
  44 join sysuser u on u.user_id = t.creator
  45 where u.user_name = ?
  46 EOF
  47     $sth->execute($self->db_schema);
  48
  49     my @tables = map @$_, @{ $sth->fetchall_arrayref };
  50
  51     return $self->_filter_tables(\@tables, $opts);
  52 }
  53
  54 sub _columns_info_for {
  55     my $self    = shift;
  56     my ($table) = @_;
  57
  58     my $result = $self->next::method(@_);
  59
  60     my $dbh = $self->schema->storage->dbh;
  61
  62     while (my ($column, $info) = each %$result) {
  63         my $def = $info->{default_value};
  64         if (ref $def eq 'SCALAR' && $$def eq 'autoincrement') {
  65             delete $info->{default_value};
  66             $info->{is_auto_increment} = 1;
  67         }
  68
  69         my ($user_type) = $dbh->selectrow_array(<<'EOF', {}, $table, lc $column);
  70 SELECT ut.type_name
  71 FROM systabcol tc
  72 JOIN systab t ON tc.table_id = t.table_id
  73 JOIN sysusertype ut on tc.user_type = ut.type_id
  74 WHERE t.table_name = ? AND lower(tc.column_name) = ?
  75 EOF
  76         $info->{data_type} = $user_type if defined $user_type;
  77
  78         if ($info->{data_type} eq 'double') {
  79             $info->{data_type} = 'double precision';
  80         }
  81
  82         if ($info->{data_type} =~ /^(?:char|varchar|binary|varbinary)\z/ && ref($info->{size}) eq 'ARRAY') {
  83             $info->{size} = $info->{size}[0];
  84         }
  85         elsif ($info->{data_type} !~ /^(?:char|varchar|binary|varbinary|numeric|decimal)\z/) {
  86             delete $info->{size};
  87         }
  88
  89         my $sth = $dbh->prepare(<<'EOF');
  90 SELECT tc.width, tc.scale
  91 FROM systabcol tc
  92 JOIN systab t ON t.table_id = tc.table_id
  93 WHERE t.table_name = ? AND lower(tc.column_name) = ?
  94 EOF
  95         $sth->execute($table, lc $column);
  96         my ($width, $scale) = $sth->fetchrow_array;
  97         $sth->finish;
  98
  99         if ($info->{data_type} =~ /^(?:numeric|decimal)\z/) {
 100             # We do not check for the default precision/scale, because they can be changed as PUBLIC database options.
 101             $info->{size} = [$width, $scale];
 102         }
 103         elsif ($info->{data_type} =~ /^(?:n(?:varchar|char) | varbit)\z/x) {
 104             $info->{size} = $width;
 105         }
 106
 107         delete $info->{default_value} if ref($info->{default_value}) eq 'SCALAR' && ${ $info->{default_value} } eq 'NULL';
 108
 109         if (eval { lc ${ $info->{default_value} } }||'' eq 'current timestamp') {
 110             ${ $info->{default_value} } = 'current_timestamp';
 111         }
 112     }
 113
 114     return $result;
 115 }
 116
 117 sub _table_pk_info {
 118     my ($self, $table) = @_;
 119     my $dbh = $self->schema->storage->dbh;
 120     local $dbh->{FetchHashKeyName} = 'NAME_lc';
 121     my $sth = $dbh->prepare(qq{sp_pkeys ?});
 122     $sth->execute($table);
 123
 124     my @keydata;
 125
 126     while (my $row = $sth->fetchrow_hashref) {
 127         push @keydata, lc $row->{column_name};
 128     }
 129
 130     return \@keydata;
 131 }
 132
 133 sub _table_fk_info {
 134     my ($self, $table) = @_;
 135
 136     my ($local_cols, $remote_cols, $remote_table, @rels);
 137     my $dbh = $self->schema->storage->dbh;
 138     my $sth = $dbh->prepare(<<'EOF');
 139 select fki.index_name fk_name, fktc.column_name local_column, pkt.table_name remote_table, pktc.column_name remote_column
 140 from sysfkey fk
 141 join systab    pkt  on fk.primary_table_id = pkt.table_id
 142 join systab    fkt  on fk.foreign_table_id = fkt.table_id
 143 join sysidx    pki  on fk.primary_table_id = pki.table_id  and fk.primary_index_id    = pki.index_id
 144 join sysidx    fki  on fk.foreign_table_id = fki.table_id  and fk.foreign_index_id    = fki.index_id
 145 join sysidxcol fkic on fkt.table_id        = fkic.table_id and fki.index_id           = fkic.index_id
 146 join systabcol pktc on pkt.table_id        = pktc.table_id and fkic.primary_column_id = pktc.column_id
 147 join systabcol fktc on fkt.table_id        = fktc.table_id and fkic.column_id         = fktc.column_id
 148 where fkt.table_name = ?
 149 EOF
 150     $sth->execute($table);
 151
 152     while (my ($fk, $local_col, $remote_tab, $remote_col) = $sth->fetchrow_array) {
 153         push @{$local_cols->{$fk}},  lc $local_col;
 154         push @{$remote_cols->{$fk}}, lc $remote_col;
 155         $remote_table->{$fk} = lc $remote_tab;
 156     }
 157
 158     foreach my $fk (keys %$remote_table) {
 159         push @rels, {
 160             local_columns => $local_cols->{$fk},
 161             remote_columns => $remote_cols->{$fk},
 162             remote_table => $remote_table->{$fk},
 163         };
 164     }
 165     return \@rels;
 166 }
 167
 168 sub _table_uniq_info {
 169     my ($self, $table) = @_;
 170
 171     my $dbh = $self->schema->storage->dbh;
 172     my $sth = $dbh->prepare(<<'EOF');
 173 select c.constraint_name, tc.column_name
 174 from sysconstraint c
 175 join systab t on c.table_object_id = t.object_id
 176 join sysidx i on c.ref_object_id = i.object_id
 177 join sysidxcol ic on i.table_id = ic.table_id and i.index_id = ic.index_id
 178 join systabcol tc on ic.table_id = tc.table_id and ic.column_id = tc.column_id
 179 where c.constraint_type = 'U' and t.table_name = ?
 180 EOF
 181     $sth->execute($table);
 182
 183     my $constraints;
 184     while (my ($constraint_name, $column) = $sth->fetchrow_array) {
 185         push @{$constraints->{$constraint_name}}, lc $column;
 186     }
 187
 188     my @uniqs = map { [ $_ => $constraints->{$_} ] } keys %$constraints;
 189     return \@uniqs;
 190 }
 191
 192 =head1 SEE ALSO
 193
 194 L<DBIx::Class::Schema::Loader>, L<DBIx::Class::Schema::Loader::Base>,
 195 L<DBIx::Class::Schema::Loader::DBI>
 196
 197 =head1 AUTHOR
 198
 199 See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
 200
 201 =head1 LICENSE
 202
 203 This library is free software; you can redistribute it and/or modify it under
 204 the same terms as Perl itself.
 205
 206 =cut
 207
 208 1;
 209 # vim:et sw=4 sts=4 tw=0: