lib/DBIx/Class/Schema/Loader/DBI/Pg.pm

   1 package DBIx::Class::Schema::Loader::DBI::Pg;
   2
   3 use strict;
   4 use warnings;
   5 use base 'DBIx::Class::Schema::Loader::DBI::Component::QuotedDefault';
   6 use mro 'c3';
   7
   8 our $VERSION = '0.07027';
   9
  10 =head1 NAME
  11
  12 DBIx::Class::Schema::Loader::DBI::Pg - DBIx::Class::Schema::Loader::DBI
  13 PostgreSQL Implementation.
  14
  15 =head1 DESCRIPTION
  16
  17 See L<DBIx::Class::Schema::Loader> and L<DBIx::Class::Schema::Loader::Base>.
  18
  19 =cut
  20
  21 sub _setup {
  22     my $self = shift;
  23
  24     $self->next::method(@_);
  25
  26     $self->{db_schema} ||= ['public'];
  27
  28     if (not defined $self->preserve_case) {
  29         $self->preserve_case(0);
  30     }
  31     elsif ($self->preserve_case) {
  32         $self->schema->storage->sql_maker->quote_char('"');
  33         $self->schema->storage->sql_maker->name_sep('.');
  34     }
  35 }
  36
  37 sub _system_schemas {
  38     my $self = shift;
  39
  40     return ($self->next::method(@_), 'pg_catalog');
  41 }
  42
  43 sub _table_fk_info {
  44     my ($self, $table) = @_;
  45
  46     my $sth = $self->dbh->prepare_cached(<<"EOF");
  47 SELECT rc.constraint_name, rc.unique_constraint_schema, uk_tc.table_name,
  48        fk_kcu.column_name, uk_kcu.column_name, rc.delete_rule, rc.update_rule,
  49        fk_tc.is_deferrable
  50 FROM INFORMATION_SCHEMA.TABLE_CONSTRAINTS fk_tc
  51 JOIN INFORMATION_SCHEMA.REFERENTIAL_CONSTRAINTS rc
  52     ON rc.constraint_name = fk_tc.constraint_name
  53         AND rc.constraint_schema = fk_tc.table_schema
  54 JOIN INFORMATION_SCHEMA.KEY_COLUMN_USAGE fk_kcu
  55     ON fk_kcu.constraint_name = fk_tc.constraint_name
  56         AND fk_kcu.table_name = fk_tc.table_name
  57         AND fk_kcu.table_schema = fk_tc.table_schema
  58 JOIN INFORMATION_SCHEMA.TABLE_CONSTRAINTS uk_tc
  59     ON uk_tc.constraint_name = rc.unique_constraint_name
  60         AND uk_tc.table_schema = rc.unique_constraint_schema
  61 JOIN INFORMATION_SCHEMA.KEY_COLUMN_USAGE uk_kcu
  62     ON uk_kcu.constraint_name = rc.unique_constraint_name
  63         AND uk_kcu.ordinal_position = fk_kcu.ordinal_position
  64         AND uk_kcu.table_name = uk_tc.table_name
  65         AND uk_kcu.table_schema = rc.unique_constraint_schema
  66 WHERE fk_tc.table_name = ?
  67     AND fk_tc.table_schema = ?
  68 ORDER BY fk_kcu.ordinal_position
  69 EOF
  70
  71     $sth->execute($table->name, $table->schema);
  72
  73     my %rels;
  74
  75     while (my ($fk, $remote_schema, $remote_table, $col, $remote_col,
  76                $delete_rule, $update_rule, $is_deferrable) = $sth->fetchrow_array) {
  77         push @{ $rels{$fk}{local_columns}  }, $self->_lc($col);
  78         push @{ $rels{$fk}{remote_columns} }, $self->_lc($remote_col);
  79
  80         $rels{$fk}{remote_table} = DBIx::Class::Schema::Loader::Table->new(
  81             loader   => $self,
  82             name     => $remote_table,
  83             schema   => $remote_schema,
  84         ) unless exists $rels{$fk}{remote_table};
  85
  86         $rels{$fk}{attrs}{on_delete} = uc $delete_rule;
  87         $rels{$fk}{attrs}{on_update} = uc $update_rule;
  88         $rels{$fk}{attrs}{is_deferrable} = uc $is_deferrable eq 'YES' ? 1 : 0;
  89     }
  90
  91     return [ values %rels ];
  92 }
  93
  94
  95 sub _table_uniq_info {
  96     my ($self, $table) = @_;
  97
  98     # Use the default support if available
  99     return $self->next::method($table)
 100         if $DBD::Pg::VERSION >= 1.50;
 101
 102     my @uniqs;
 103
 104     # Most of the SQL here is mostly based on
 105     #   Rose::DB::Object::Metadata::Auto::Pg, after some prodding from
 106     #   John Siracusa to use his superior SQL code :)
 107
 108     my $attr_sth = $self->{_cache}->{pg_attr_sth} ||= $self->dbh->prepare(
 109         q{SELECT attname FROM pg_catalog.pg_attribute
 110         WHERE attrelid = ? AND attnum = ?}
 111     );
 112
 113     my $uniq_sth = $self->{_cache}->{pg_uniq_sth} ||= $self->dbh->prepare(
 114         q{SELECT x.indrelid, i.relname, x.indkey
 115         FROM
 116           pg_catalog.pg_index x
 117           JOIN pg_catalog.pg_class c ON c.oid = x.indrelid
 118           JOIN pg_catalog.pg_class i ON i.oid = x.indexrelid
 119           JOIN pg_catalog.pg_constraint con ON con.conname = i.relname
 120           LEFT JOIN pg_catalog.pg_namespace n ON n.oid = c.relnamespace
 121         WHERE
 122           x.indisunique = 't' AND
 123           c.relkind     = 'r' AND
 124           i.relkind     = 'i' AND
 125           con.contype   = 'u' AND
 126           n.nspname     = ? AND
 127           c.relname     = ?}
 128     );
 129
 130     $uniq_sth->execute($table->schema, $table->name);
 131     while(my $row = $uniq_sth->fetchrow_arrayref) {
 132         my ($tableid, $indexname, $col_nums) = @$row;
 133         $col_nums =~ s/^\s+//;
 134         my @col_nums = split(/\s+/, $col_nums);
 135         my @col_names;
 136
 137         foreach (@col_nums) {
 138             $attr_sth->execute($tableid, $_);
 139             my $name_aref = $attr_sth->fetchrow_arrayref;
 140             push(@col_names, $self->_lc($name_aref->[0])) if $name_aref;
 141         }
 142
 143         if(!@col_names) {
 144             warn "Failed to parse UNIQUE constraint $indexname on $table";
 145         }
 146         else {
 147             push(@uniqs, [ $indexname => \@col_names ]);
 148         }
 149     }
 150
 151     return \@uniqs;
 152 }
 153
 154 sub _table_comment {
 155     my $self = shift;
 156     my ($table) = @_;
 157
 158     my $table_comment = $self->next::method(@_);
 159
 160     return $table_comment if $table_comment;
 161
 162     ($table_comment) = $self->dbh->selectrow_array(<<'EOF', {}, $table->name, $table->schema);
 163 SELECT obj_description(oid)
 164 FROM pg_class
 165 WHERE relname=? AND relnamespace=(SELECT oid FROM pg_namespace WHERE nspname=?)
 166 EOF
 167
 168     return $table_comment
 169 }
 170
 171
 172 sub _column_comment {
 173     my $self = shift;
 174     my ($table, $column_number, $column_name) = @_;
 175
 176     my $column_comment = $self->next::method(@_);
 177
 178     return $column_comment if $column_comment;
 179
 180     my ($table_oid) = $self->dbh->selectrow_array(<<'EOF', {}, $table->name, $table->schema);
 181 SELECT oid
 182 FROM pg_class
 183 WHERE relname=? AND relnamespace=(SELECT oid FROM pg_namespace WHERE nspname=?)
 184 EOF
 185
 186     return $self->dbh->selectrow_array('SELECT col_description(?,?)', {}, $table_oid, $column_number);
 187 }
 188
 189 # Make sure data_type's that don't need it don't have a 'size' column_info, and
 190 # set the correct precision for datetime and varbit types.
 191 sub _columns_info_for {
 192     my $self = shift;
 193     my ($table) = @_;
 194
 195     my $result = $self->next::method(@_);
 196
 197     while (my ($col, $info) = each %$result) {
 198         my $data_type = $info->{data_type};
 199
 200         # these types are fixed size
 201         # XXX should this be a negative match?
 202         if ($data_type =~
 203 /^(?:bigint|int8|bigserial|serial8|bool(?:ean)?|box|bytea|cidr|circle|date|double precision|float8|inet|integer|int|int4|line|lseg|macaddr|money|path|point|polygon|real|float4|smallint|int2|serial|serial4|text)\z/i) {
 204             delete $info->{size};
 205         }
 206 # for datetime types, check if it has a precision or not
 207         elsif ($data_type =~ /^(?:interval|time|timestamp)\b/i) {
 208             if (lc($data_type) eq 'timestamp without time zone') {
 209                 $info->{data_type} = 'timestamp';
 210             }
 211             elsif (lc($data_type) eq 'time without time zone') {
 212                 $info->{data_type} = 'time';
 213             }
 214
 215             my ($precision) = $self->schema->storage->dbh
 216                 ->selectrow_array(<<EOF, {}, $table->name, $col);
 217 SELECT datetime_precision
 218 FROM information_schema.columns
 219 WHERE table_name = ? and column_name = ?
 220 EOF
 221
 222             if ($data_type =~ /^time\b/i) {
 223                 if ((not $precision) || $precision !~ /^\d/) {
 224                     delete $info->{size};
 225                 }
 226                 else {
 227                     my ($integer_datetimes) = $self->dbh
 228                         ->selectrow_array('show integer_datetimes');
 229
 230                     my $max_precision =
 231                         $integer_datetimes =~ /^on\z/i ? 6 : 10;
 232
 233                     if ($precision == $max_precision) {
 234                         delete $info->{size};
 235                     }
 236                     else {
 237                         $info->{size} = $precision;
 238                     }
 239                 }
 240             }
 241             elsif ((not $precision) || $precision !~ /^\d/ || $precision == 6) {
 242                 delete $info->{size};
 243             }
 244             else {
 245                 $info->{size} = $precision;
 246             }
 247         }
 248         elsif ($data_type =~ /^(?:bit(?: varying)?|varbit)\z/i) {
 249             $info->{data_type} = 'varbit' if $data_type =~ /var/i;
 250
 251             my ($precision) = $self->dbh->selectrow_array(<<EOF, {}, $table->name, $col);
 252 SELECT character_maximum_length
 253 FROM information_schema.columns
 254 WHERE table_name = ? and column_name = ?
 255 EOF
 256
 257             $info->{size} = $precision if $precision;
 258
 259             $info->{size} = 1 if (not $precision) && lc($data_type) eq 'bit';
 260         }
 261         elsif ($data_type =~ /^(?:numeric|decimal)\z/i && (my $size = $info->{size})) {
 262             $size =~ s/\s*//g;
 263
 264             my ($scale, $precision) = split /,/, $size;
 265
 266             $info->{size} = [ $precision, $scale ];
 267         }
 268         elsif (lc($data_type) eq 'character varying') {
 269             $info->{data_type} = 'varchar';
 270
 271             if (not $info->{size}) {
 272                 $info->{data_type}           = 'text';
 273                 $info->{original}{data_type} = 'varchar';
 274             }
 275         }
 276         elsif (lc($data_type) eq 'character') {
 277             $info->{data_type} = 'char';
 278         }
 279         else {
 280             my ($typetype) = $self->schema->storage->dbh
 281                 ->selectrow_array(<<EOF, {}, $data_type);
 282 SELECT typtype
 283 FROM pg_catalog.pg_type
 284 WHERE typname = ?
 285 EOF
 286             if ($typetype && $typetype eq 'e') {
 287                 # The following will extract a list of allowed values for the
 288                 # enum.
 289                 my $typevalues = $self->dbh
 290                     ->selectall_arrayref(<<EOF, {}, $info->{data_type});
 291 SELECT e.enumlabel
 292 FROM pg_catalog.pg_enum e
 293 JOIN pg_catalog.pg_type t ON t.oid = e.enumtypid
 294 WHERE t.typname = ?
 295 EOF
 296
 297                 $info->{extra}{list} = [ map { $_->[0] } @$typevalues ];
 298
 299                 # Store its original name in extra for SQLT to pick up.
 300                 $info->{extra}{custom_type_name} = $info->{data_type};
 301
 302                 $info->{data_type} = 'enum';
 303
 304                 delete $info->{size};
 305             }
 306         }
 307
 308 # process SERIAL columns
 309         if (ref($info->{default_value}) eq 'SCALAR'
 310                 && ${ $info->{default_value} } =~ /\bnextval\('([^:]+)'/i) {
 311             $info->{is_auto_increment} = 1;
 312             $info->{sequence}          = $1;
 313             delete $info->{default_value};
 314         }
 315
 316 # alias now() to current_timestamp for deploying to other DBs
 317         if ((eval { lc ${ $info->{default_value} } }||'') eq 'now()') {
 318             # do not use a ref to a constant, that breaks Data::Dump output
 319             ${$info->{default_value}} = 'current_timestamp';
 320
 321             my $now = 'now()';
 322             $info->{original}{default_value} = \$now;
 323         }
 324
 325 # detect 0/1 for booleans and rewrite
 326         if ($data_type =~ /^bool/i && exists $info->{default_value}) {
 327             if ($info->{default_value} eq '0') {
 328                 my $false = 'false';
 329                 $info->{default_value} = \$false;
 330             }
 331             elsif ($info->{default_value} eq '1') {
 332                 my $true = 'true';
 333                 $info->{default_value} = \$true;
 334             }
 335         }
 336     }
 337
 338     return $result;
 339 }
 340
 341 =head1 SEE ALSO
 342
 343 L<DBIx::Class::Schema::Loader>, L<DBIx::Class::Schema::Loader::Base>,
 344 L<DBIx::Class::Schema::Loader::DBI>
 345
 346 =head1 AUTHOR
 347
 348 See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
 349
 350 =head1 LICENSE
 351
 352 This library is free software; you can redistribute it and/or modify it under
 353 the same terms as Perl itself.
 354
 355 =cut
 356
 357 1;