lib/DBIx/Class/Schema/Loader/DBI/Pg.pm

   1 package DBIx::Class::Schema::Loader::DBI::Pg;
   2
   3 use strict;
   4 use warnings;
   5 use base 'DBIx::Class::Schema::Loader::DBI::Component::QuotedDefault';
   6 use mro 'c3';
   7
   8 our $VERSION = '0.07040';
   9
  10 =head1 NAME
  11
  12 DBIx::Class::Schema::Loader::DBI::Pg - DBIx::Class::Schema::Loader::DBI
  13 PostgreSQL Implementation.
  14
  15 =head1 DESCRIPTION
  16
  17 See L<DBIx::Class::Schema::Loader> and L<DBIx::Class::Schema::Loader::Base>.
  18
  19 =cut
  20
  21 sub _setup {
  22     my $self = shift;
  23
  24     $self->next::method(@_);
  25
  26     $self->{db_schema} ||= ['public'];
  27
  28     if (not defined $self->preserve_case) {
  29         $self->preserve_case(0);
  30     }
  31     elsif ($self->preserve_case) {
  32         $self->schema->storage->sql_maker->quote_char('"');
  33         $self->schema->storage->sql_maker->name_sep('.');
  34     }
  35 }
  36
  37 sub _system_schemas {
  38     my $self = shift;
  39
  40     return ($self->next::method(@_), 'pg_catalog');
  41 }
  42
  43 my %pg_rules = (
  44     a => 'NO ACTION',
  45     r => 'RESTRICT',
  46     c => 'CASCADE',
  47     n => 'SET NULL',
  48     d => 'SET DEFAULT',
  49 );
  50
  51 sub _table_fk_info {
  52     my ($self, $table) = @_;
  53
  54     my $sth = $self->dbh->prepare_cached(<<"EOF");
  55       select constr.conname, to_ns.nspname, to_class.relname, from_col.attname, to_col.attname,
  56              constr.confdeltype, constr.confupdtype, constr.condeferrable
  57       from pg_catalog.pg_constraint constr
  58       join pg_catalog.pg_namespace from_ns on constr.connamespace = from_ns.oid
  59       join pg_catalog.pg_class from_class on constr.conrelid = from_class.oid and from_class.relnamespace = from_ns.oid
  60       join pg_catalog.pg_class to_class on constr.confrelid = to_class.oid
  61       join pg_catalog.pg_namespace to_ns on to_class.relnamespace = to_ns.oid
  62       -- can't do unnest() until 8.4, so join against a series table instead
  63       join pg_catalog.generate_series(1, pg_catalog.current_setting('max_index_keys')::integer) colnum(i)
  64            on colnum.i <= pg_catalog.array_upper(constr.conkey,1)
  65       join pg_catalog.pg_attribute to_col
  66            on to_col.attrelid = constr.confrelid
  67            and to_col.attnum = constr.confkey[colnum.i]
  68       join pg_catalog.pg_attribute from_col
  69            on from_col.attrelid = constr.conrelid
  70            and from_col.attnum = constr.conkey[colnum.i]
  71       where from_ns.nspname = ?
  72         and from_class.relname = ?
  73         and from_class.relkind = 'r'
  74         and constr.contype = 'f'
  75       order by constr.conname, colnum.i
  76 EOF
  77
  78     $sth->execute($table->schema, $table->name);
  79
  80     my %rels;
  81
  82     while (my ($fk, $remote_schema, $remote_table, $col, $remote_col,
  83                $delete_rule, $update_rule, $is_deferrable) = $sth->fetchrow_array) {
  84         push @{ $rels{$fk}{local_columns}  }, $self->_lc($col);
  85         push @{ $rels{$fk}{remote_columns} }, $self->_lc($remote_col);
  86
  87         $rels{$fk}{remote_table} = DBIx::Class::Schema::Loader::Table->new(
  88             loader   => $self,
  89             name     => $remote_table,
  90             schema   => $remote_schema,
  91         ) unless exists $rels{$fk}{remote_table};
  92
  93         $rels{$fk}{attrs} ||= {
  94             on_delete     => $pg_rules{$delete_rule},
  95             on_update     => $pg_rules{$update_rule},
  96             is_deferrable => $is_deferrable,
  97         };
  98     }
  99
 100     return [ map { $rels{$_} } sort keys %rels ];
 101 }
 102
 103
 104 sub _table_uniq_info {
 105     my ($self, $table) = @_;
 106
 107     # Use the default support if available
 108     return $self->next::method($table)
 109         if $DBD::Pg::VERSION >= 1.50;
 110
 111     my @uniqs;
 112
 113     # Most of the SQL here is mostly based on
 114     #   Rose::DB::Object::Metadata::Auto::Pg, after some prodding from
 115     #   John Siracusa to use his superior SQL code :)
 116
 117     my $attr_sth = $self->{_cache}->{pg_attr_sth} ||= $self->dbh->prepare(
 118         q{SELECT attname FROM pg_catalog.pg_attribute
 119         WHERE attrelid = ? AND attnum = ?}
 120     );
 121
 122     my $uniq_sth = $self->{_cache}->{pg_uniq_sth} ||= $self->dbh->prepare(
 123         q{SELECT x.indrelid, i.relname, x.indkey
 124         FROM
 125           pg_catalog.pg_index x
 126           JOIN pg_catalog.pg_class c ON c.oid = x.indrelid
 127           JOIN pg_catalog.pg_class i ON i.oid = x.indexrelid
 128           JOIN pg_catalog.pg_namespace n ON n.oid = c.relnamespace
 129         WHERE
 130           x.indisunique = 't' AND
 131           x.indpred     IS NULL AND
 132           c.relkind     = 'r' AND
 133           i.relkind     = 'i' AND
 134           n.nspname     = ? AND
 135           c.relname     = ?
 136         ORDER BY i.relname}
 137     );
 138
 139     $uniq_sth->execute($table->schema, $table->name);
 140     while(my $row = $uniq_sth->fetchrow_arrayref) {
 141         my ($tableid, $indexname, $col_nums) = @$row;
 142         $col_nums =~ s/^\s+//;
 143         my @col_nums = split(/\s+/, $col_nums);
 144         my @col_names;
 145
 146         foreach (@col_nums) {
 147             $attr_sth->execute($tableid, $_);
 148             my $name_aref = $attr_sth->fetchrow_arrayref;
 149             push(@col_names, $self->_lc($name_aref->[0])) if $name_aref;
 150         }
 151
 152         # skip indexes with missing column names (e.g. expression indexes)
 153         if(@col_names == @col_nums) {
 154             push(@uniqs, [ $indexname => \@col_names ]);
 155         }
 156     }
 157
 158     return \@uniqs;
 159 }
 160
 161 sub _table_comment {
 162     my $self = shift;
 163     my ($table) = @_;
 164
 165     my $table_comment = $self->next::method(@_);
 166
 167     return $table_comment if $table_comment;
 168
 169     ($table_comment) = $self->dbh->selectrow_array(<<'EOF', {}, $table->name, $table->schema);
 170 SELECT pg_catalog.obj_description(oid)
 171 FROM pg_catalog.pg_class
 172 WHERE relname=? AND relnamespace=(SELECT oid FROM pg_catalog.pg_namespace WHERE nspname=?)
 173 EOF
 174
 175     return $table_comment
 176 }
 177
 178
 179 sub _column_comment {
 180     my $self = shift;
 181     my ($table, $column_number, $column_name) = @_;
 182
 183     my $column_comment = $self->next::method(@_);
 184
 185     return $column_comment if $column_comment;
 186
 187     my ($table_oid) = $self->dbh->selectrow_array(<<'EOF', {}, $table->name, $table->schema);
 188 SELECT oid
 189 FROM pg_catalog.pg_class
 190 WHERE relname=? AND relnamespace=(SELECT oid FROM pg_catalog.pg_namespace WHERE nspname=?)
 191 EOF
 192
 193     return $self->dbh->selectrow_array('SELECT pg_catalog.col_description(?,?)', {}, $table_oid, $column_number);
 194 }
 195
 196 # Make sure data_type's that don't need it don't have a 'size' column_info, and
 197 # set the correct precision for datetime and varbit types.
 198 sub _columns_info_for {
 199     my $self = shift;
 200     my ($table) = @_;
 201
 202     my $result = $self->next::method(@_);
 203
 204     while (my ($col, $info) = each %$result) {
 205         my $data_type = $info->{data_type};
 206
 207         # these types are fixed size
 208         # XXX should this be a negative match?
 209         if ($data_type =~
 210 /^(?:bigint|int8|bigserial|serial8|bool(?:ean)?|box|bytea|cidr|circle|date|double precision|float8|inet|integer|int|int4|line|lseg|macaddr|money|path|point|polygon|real|float4|smallint|int2|serial|serial4|text)\z/i) {
 211             delete $info->{size};
 212         }
 213 # for datetime types, check if it has a precision or not
 214         elsif ($data_type =~ /^(?:interval|time|timestamp)\b/i) {
 215             if (lc($data_type) eq 'timestamp without time zone') {
 216                 $info->{data_type} = 'timestamp';
 217             }
 218             elsif (lc($data_type) eq 'time without time zone') {
 219                 $info->{data_type} = 'time';
 220             }
 221
 222             my ($precision) = $self->schema->storage->dbh
 223                 ->selectrow_array(<<EOF, {}, $table->name, $col);
 224 SELECT datetime_precision
 225 FROM information_schema.columns
 226 WHERE table_name = ? and column_name = ?
 227 EOF
 228
 229             if ($data_type =~ /^time\b/i) {
 230                 if ((not $precision) || $precision !~ /^\d/) {
 231                     delete $info->{size};
 232                 }
 233                 else {
 234                     my ($integer_datetimes) = $self->dbh
 235                         ->selectrow_array('show integer_datetimes');
 236
 237                     my $max_precision =
 238                         $integer_datetimes =~ /^on\z/i ? 6 : 10;
 239
 240                     if ($precision == $max_precision) {
 241                         delete $info->{size};
 242                     }
 243                     else {
 244                         $info->{size} = $precision;
 245                     }
 246                 }
 247             }
 248             elsif ((not $precision) || $precision !~ /^\d/ || $precision == 6) {
 249                 delete $info->{size};
 250             }
 251             else {
 252                 $info->{size} = $precision;
 253             }
 254         }
 255         elsif ($data_type =~ /^(?:bit(?: varying)?|varbit)\z/i) {
 256             $info->{data_type} = 'varbit' if $data_type =~ /var/i;
 257
 258             my ($precision) = $self->dbh->selectrow_array(<<EOF, {}, $table->name, $col);
 259 SELECT character_maximum_length
 260 FROM information_schema.columns
 261 WHERE table_name = ? and column_name = ?
 262 EOF
 263
 264             $info->{size} = $precision if $precision;
 265
 266             $info->{size} = 1 if (not $precision) && lc($data_type) eq 'bit';
 267         }
 268         elsif ($data_type =~ /^(?:numeric|decimal)\z/i && (my $size = $info->{size})) {
 269             $size =~ s/\s*//g;
 270
 271             my ($scale, $precision) = split /,/, $size;
 272
 273             $info->{size} = [ $precision, $scale ];
 274         }
 275         elsif (lc($data_type) eq 'character varying') {
 276             $info->{data_type} = 'varchar';
 277
 278             if (not $info->{size}) {
 279                 $info->{data_type}           = 'text';
 280                 $info->{original}{data_type} = 'varchar';
 281             }
 282         }
 283         elsif (lc($data_type) eq 'character') {
 284             $info->{data_type} = 'char';
 285         }
 286         else {
 287             my ($typetype) = $self->schema->storage->dbh
 288                 ->selectrow_array(<<EOF, {}, $data_type);
 289 SELECT typtype
 290 FROM pg_catalog.pg_type
 291 WHERE typname = ?
 292 EOF
 293             if ($typetype && $typetype eq 'e') {
 294                 # The following will extract a list of allowed values for the
 295                 # enum.
 296                 my $order_column = $self->dbh->{pg_server_version} >= 90100 ? 'enumsortorder' : 'oid';
 297                 my $typevalues = $self->dbh
 298                     ->selectall_arrayref(<<EOF, {}, $info->{data_type});
 299 SELECT e.enumlabel
 300 FROM pg_catalog.pg_enum e
 301 JOIN pg_catalog.pg_type t ON t.oid = e.enumtypid
 302 WHERE t.typname = ?
 303 ORDER BY e.$order_column
 304 EOF
 305
 306                 $info->{extra}{list} = [ map { $_->[0] } @$typevalues ];
 307
 308                 # Store its original name in extra for SQLT to pick up.
 309                 $info->{extra}{custom_type_name} = $info->{data_type};
 310
 311                 $info->{data_type} = 'enum';
 312
 313                 delete $info->{size};
 314             }
 315         }
 316
 317 # process SERIAL columns
 318         if (ref($info->{default_value}) eq 'SCALAR'
 319                 && ${ $info->{default_value} } =~ /\bnextval\('([^:]+)'/i) {
 320             $info->{is_auto_increment} = 1;
 321             $info->{sequence}          = $1;
 322             delete $info->{default_value};
 323         }
 324
 325 # alias now() to current_timestamp for deploying to other DBs
 326         if ((eval { lc ${ $info->{default_value} } }||'') eq 'now()') {
 327             # do not use a ref to a constant, that breaks Data::Dump output
 328             ${$info->{default_value}} = 'current_timestamp';
 329
 330             my $now = 'now()';
 331             $info->{original}{default_value} = \$now;
 332         }
 333
 334 # detect 0/1 for booleans and rewrite
 335         if ($data_type =~ /^bool/i && exists $info->{default_value}) {
 336             if ($info->{default_value} eq '0') {
 337                 my $false = 'false';
 338                 $info->{default_value} = \$false;
 339             }
 340             elsif ($info->{default_value} eq '1') {
 341                 my $true = 'true';
 342                 $info->{default_value} = \$true;
 343             }
 344         }
 345     }
 346
 347     return $result;
 348 }
 349
 350 =head1 SEE ALSO
 351
 352 L<DBIx::Class::Schema::Loader>, L<DBIx::Class::Schema::Loader::Base>,
 353 L<DBIx::Class::Schema::Loader::DBI>
 354
 355 =head1 AUTHOR
 356
 357 See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
 358
 359 =head1 LICENSE
 360
 361 This library is free software; you can redistribute it and/or modify it under
 362 the same terms as Perl itself.
 363
 364 =cut
 365
 366 1;