lib/DBIx/Class/Schema/Loader/DBI/Pg.pm

   1 package DBIx::Class::Schema::Loader::DBI::Pg;
   2
   3 use strict;
   4 use warnings;
   5 use base 'DBIx::Class::Schema::Loader::DBI::Component::QuotedDefault';
   6 use mro 'c3';
   7
   8 our $VERSION = '0.07048_01';
   9
  10 =head1 NAME
  11
  12 DBIx::Class::Schema::Loader::DBI::Pg - DBIx::Class::Schema::Loader::DBI
  13 PostgreSQL Implementation.
  14
  15 =head1 DESCRIPTION
  16
  17 See L<DBIx::Class::Schema::Loader> and L<DBIx::Class::Schema::Loader::Base>.
  18
  19 =cut
  20
  21 sub _setup {
  22     my $self = shift;
  23
  24     $self->next::method(@_);
  25
  26     $self->{db_schema} ||= ['public'];
  27
  28     if (not defined $self->preserve_case) {
  29         $self->preserve_case(0);
  30     }
  31     elsif ($self->preserve_case) {
  32         $self->schema->storage->sql_maker->quote_char('"');
  33         $self->schema->storage->sql_maker->name_sep('.');
  34     }
  35 }
  36
  37 sub _system_schemas {
  38     my $self = shift;
  39
  40     return ($self->next::method(@_), 'pg_catalog');
  41 }
  42
  43 my %pg_rules = (
  44     a => 'NO ACTION',
  45     r => 'RESTRICT',
  46     c => 'CASCADE',
  47     n => 'SET NULL',
  48     d => 'SET DEFAULT',
  49 );
  50
  51 sub _table_fk_info {
  52     my ($self, $table) = @_;
  53
  54     my $sth = $self->dbh->prepare_cached(<<"EOF");
  55       select constr.conname, to_ns.nspname, to_class.relname, from_col.attname, to_col.attname,
  56              constr.confdeltype, constr.confupdtype, constr.condeferrable
  57       from pg_catalog.pg_constraint constr
  58       join pg_catalog.pg_namespace from_ns on constr.connamespace = from_ns.oid
  59       join pg_catalog.pg_class from_class on constr.conrelid = from_class.oid and from_class.relnamespace = from_ns.oid
  60       join pg_catalog.pg_class to_class on constr.confrelid = to_class.oid
  61       join pg_catalog.pg_namespace to_ns on to_class.relnamespace = to_ns.oid
  62       -- can't do unnest() until 8.4, so join against a series table instead
  63       join pg_catalog.generate_series(1, pg_catalog.current_setting('max_index_keys')::integer) colnum(i)
  64            on colnum.i <= pg_catalog.array_upper(constr.conkey,1)
  65       join pg_catalog.pg_attribute to_col
  66            on to_col.attrelid = constr.confrelid
  67            and to_col.attnum = constr.confkey[colnum.i]
  68       join pg_catalog.pg_attribute from_col
  69            on from_col.attrelid = constr.conrelid
  70            and from_col.attnum = constr.conkey[colnum.i]
  71       where from_ns.nspname = ?
  72         and from_class.relname = ?
  73         and from_class.relkind = 'r'
  74         and constr.contype = 'f'
  75       order by constr.conname, colnum.i
  76 EOF
  77
  78     $sth->execute($table->schema, $table->name);
  79
  80     my %rels;
  81
  82     while (my ($fk, $remote_schema, $remote_table, $col, $remote_col,
  83                $delete_rule, $update_rule, $is_deferrable) = $sth->fetchrow_array) {
  84         push @{ $rels{$fk}{local_columns}  }, $self->_lc($col);
  85         push @{ $rels{$fk}{remote_columns} }, $self->_lc($remote_col);
  86
  87         $rels{$fk}{remote_table} = DBIx::Class::Schema::Loader::Table->new(
  88             loader   => $self,
  89             name     => $remote_table,
  90             schema   => $remote_schema,
  91         ) unless exists $rels{$fk}{remote_table};
  92
  93         $rels{$fk}{attrs} ||= {
  94             on_delete     => $pg_rules{$delete_rule},
  95             on_update     => $pg_rules{$update_rule},
  96             is_deferrable => $is_deferrable,
  97         };
  98     }
  99
 100     return [ map { $rels{$_} } sort keys %rels ];
 101 }
 102
 103
 104 sub _table_uniq_info {
 105     my ($self, $table) = @_;
 106
 107     # Use the default support if available
 108     return $self->next::method($table)
 109         if $DBD::Pg::VERSION >= 1.50;
 110
 111     my @uniqs;
 112
 113     # Most of the SQL here is mostly based on
 114     #   Rose::DB::Object::Metadata::Auto::Pg, after some prodding from
 115     #   John Siracusa to use his superior SQL code :)
 116
 117     my $attr_sth = $self->{_cache}->{pg_attr_sth} ||= $self->dbh->prepare(
 118         q{SELECT attname FROM pg_catalog.pg_attribute
 119         WHERE attrelid = ? AND attnum = ?}
 120     );
 121
 122     my $uniq_sth = $self->{_cache}->{pg_uniq_sth} ||= $self->dbh->prepare(
 123         q{SELECT x.indrelid, i.relname, x.indkey
 124         FROM
 125           pg_catalog.pg_index x
 126           JOIN pg_catalog.pg_class c ON c.oid = x.indrelid
 127           JOIN pg_catalog.pg_class i ON i.oid = x.indexrelid
 128           JOIN pg_catalog.pg_namespace n ON n.oid = c.relnamespace
 129         WHERE
 130           x.indisunique = 't' AND
 131           x.indpred     IS NULL AND
 132           c.relkind     = 'r' AND
 133           i.relkind     = 'i' AND
 134           n.nspname     = ? AND
 135           c.relname     = ?
 136         ORDER BY i.relname}
 137     );
 138
 139     $uniq_sth->execute($table->schema, $table->name);
 140     while(my $row = $uniq_sth->fetchrow_arrayref) {
 141         my ($tableid, $indexname, $col_nums) = @$row;
 142         $col_nums =~ s/^\s+//;
 143         my @col_nums = split(/\s+/, $col_nums);
 144         my @col_names;
 145
 146         foreach (@col_nums) {
 147             $attr_sth->execute($tableid, $_);
 148             my $name_aref = $attr_sth->fetchrow_arrayref;
 149             push(@col_names, $self->_lc($name_aref->[0])) if $name_aref;
 150         }
 151
 152         # skip indexes with missing column names (e.g. expression indexes)
 153         if(@col_names == @col_nums) {
 154             push(@uniqs, [ $indexname => \@col_names ]);
 155         }
 156     }
 157
 158     return \@uniqs;
 159 }
 160
 161 sub _table_comment {
 162     my $self = shift;
 163     my ($table) = @_;
 164
 165     my $table_comment = $self->next::method(@_);
 166
 167     return $table_comment if $table_comment;
 168
 169     ($table_comment) = $self->dbh->selectrow_array(<<'EOF', {}, $table->name, $table->schema);
 170 SELECT pg_catalog.obj_description(oid)
 171 FROM pg_catalog.pg_class
 172 WHERE relname=? AND relnamespace=(SELECT oid FROM pg_catalog.pg_namespace WHERE nspname=?)
 173 EOF
 174
 175     return $table_comment
 176 }
 177
 178
 179 sub _column_comment {
 180     my $self = shift;
 181     my ($table, $column_number, $column_name) = @_;
 182
 183     my $column_comment = $self->next::method(@_);
 184
 185     return $column_comment if $column_comment;
 186
 187     return $self->dbh->selectrow_array(<<'EOF', {}, $column_number, $table->name, $table->schema);
 188 SELECT pg_catalog.col_description(oid, ?)
 189 FROM pg_catalog.pg_class
 190 WHERE relname=? AND relnamespace=(SELECT oid FROM pg_catalog.pg_namespace WHERE nspname=?)
 191 EOF
 192 }
 193
 194 # Make sure data_type's that don't need it don't have a 'size' column_info, and
 195 # set the correct precision for datetime and varbit types.
 196 sub _columns_info_for {
 197     my $self = shift;
 198     my ($table) = @_;
 199
 200     my $result = $self->next::method(@_);
 201
 202     while (my ($col, $info) = each %$result) {
 203         my $data_type = $info->{data_type};
 204
 205         # these types are fixed size
 206         # XXX should this be a negative match?
 207         if ($data_type =~
 208 /^(?:bigint|int8|bigserial|serial8|bool(?:ean)?|box|bytea|cidr|circle|date|double precision|float8|inet|integer|int|int4|line|lseg|macaddr|money|path|point|polygon|real|float4|smallint|int2|serial|serial4|text)\z/i) {
 209             delete $info->{size};
 210         }
 211 # for datetime types, check if it has a precision or not
 212         elsif ($data_type =~ /^(?:interval|time|timestamp)\b/i) {
 213             if (lc($data_type) eq 'timestamp without time zone') {
 214                 $info->{data_type} = 'timestamp';
 215             }
 216             elsif (lc($data_type) eq 'time without time zone') {
 217                 $info->{data_type} = 'time';
 218             }
 219
 220             my ($precision) = $self->schema->storage->dbh
 221                 ->selectrow_array(<<EOF, {}, $table->name, $col);
 222 SELECT datetime_precision
 223 FROM information_schema.columns
 224 WHERE table_name = ? and column_name = ?
 225 EOF
 226
 227             if ($data_type =~ /^time\b/i) {
 228                 if ((not defined $precision) || $precision !~ /^\d/) {
 229                     delete $info->{size};
 230                 }
 231                 else {
 232                     my ($integer_datetimes) = $self->dbh
 233                         ->selectrow_array('show integer_datetimes');
 234
 235                     my $max_precision =
 236                         $integer_datetimes =~ /^on\z/i ? 6 : 10;
 237
 238                     if ($precision == $max_precision) {
 239                         delete $info->{size};
 240                     }
 241                     else {
 242                         $info->{size} = $precision;
 243                     }
 244                 }
 245             }
 246             elsif ((not defined $precision) || $precision !~ /^\d/ || $precision == 6) {
 247                 delete $info->{size};
 248             }
 249             else {
 250                 $info->{size} = $precision;
 251             }
 252         }
 253         elsif ($data_type =~ /^(?:bit(?: varying)?|varbit)\z/i) {
 254             $info->{data_type} = 'varbit' if $data_type =~ /var/i;
 255
 256             my ($precision) = $self->dbh->selectrow_array(<<EOF, {}, $table->name, $col);
 257 SELECT character_maximum_length
 258 FROM information_schema.columns
 259 WHERE table_name = ? and column_name = ?
 260 EOF
 261
 262             $info->{size} = $precision if $precision;
 263
 264             $info->{size} = 1 if (not $precision) && lc($data_type) eq 'bit';
 265         }
 266         elsif ($data_type =~ /^(?:numeric|decimal)\z/i && (my $size = $info->{size})) {
 267             $size =~ s/\s*//g;
 268
 269             my ($scale, $precision) = split /,/, $size;
 270
 271             $info->{size} = [ $precision, $scale ];
 272         }
 273         elsif (lc($data_type) eq 'character varying') {
 274             $info->{data_type} = 'varchar';
 275
 276             if (not $info->{size}) {
 277                 $info->{data_type}           = 'text';
 278                 $info->{original}{data_type} = 'varchar';
 279             }
 280         }
 281         elsif (lc($data_type) eq 'character') {
 282             $info->{data_type} = 'char';
 283         }
 284         else {
 285             my ($typetype) = $self->schema->storage->dbh
 286                 ->selectrow_array(<<EOF, {}, $data_type);
 287 SELECT typtype
 288 FROM pg_catalog.pg_type
 289 WHERE oid = ?::regtype
 290 EOF
 291             if ($typetype && $typetype eq 'e') {
 292                 # The following will extract a list of allowed values for the enum.
 293                 my $order_column = $self->dbh->{pg_server_version} >= 90100 ? 'enumsortorder' : 'oid';
 294                 $info->{extra}{list} = $self->dbh
 295                     ->selectcol_arrayref(<<EOF, {}, $data_type);
 296 SELECT e.enumlabel
 297 FROM pg_catalog.pg_enum e
 298 WHERE e.enumtypid = ?::regtype
 299 ORDER BY e.$order_column
 300 EOF
 301
 302                 # Store its original name in extra for SQLT to pick up.
 303                 $info->{extra}{custom_type_name} = $data_type;
 304
 305                 $info->{data_type} = 'enum';
 306
 307                 delete $info->{size};
 308             }
 309         }
 310
 311         if (ref($info->{default_value}) eq 'SCALAR') {
 312             # process SERIAL columns
 313             if (${ $info->{default_value} } =~ /\bnextval\('([^:]+)'/i) {
 314                 $info->{is_auto_increment} = 1;
 315                 $info->{sequence}          = $1;
 316                 delete $info->{default_value};
 317             }
 318             # alias now() to current_timestamp for deploying to other DBs
 319             elsif (lc ${ $info->{default_value} } eq 'now()') {
 320                 # do not use a ref to a constant, that breaks Data::Dump output
 321                 ${$info->{default_value}} = 'current_timestamp';
 322
 323                 my $now = 'now()';
 324                 $info->{original}{default_value} = \$now;
 325             }
 326             elsif (${ $info->{default_value} } =~ /\bCURRENT_TIMESTAMP\b/) {
 327                 # PostgreSQL v10 upcases current_timestamp in default values
 328                 ${ $info->{default_value} } =~ s/\b(CURRENT_TIMESTAMP)\b/lc $1/ge;
 329             }
 330         }
 331
 332         # detect 0/1 for booleans and rewrite
 333         if ($data_type =~ /^bool/i && exists $info->{default_value}) {
 334             if ($info->{default_value} eq '0') {
 335                 my $false = 'false';
 336                 $info->{default_value} = \$false;
 337             }
 338             elsif ($info->{default_value} eq '1') {
 339                 my $true = 'true';
 340                 $info->{default_value} = \$true;
 341             }
 342         }
 343     }
 344
 345     return $result;
 346 }
 347
 348 sub _view_definition {
 349     my ($self, $view) = @_;
 350
 351     my $def =  $self->schema->storage->dbh->selectrow_array(<<'EOF', {}, $view->schema, $view->name);
 352 SELECT pg_catalog.pg_get_viewdef(oid)
 353 FROM pg_catalog.pg_class
 354 WHERE relnamespace = (SELECT OID FROM pg_catalog.pg_namespace WHERE nspname = ?)
 355 AND relname = ?
 356 EOF
 357     # The definition is returned as a complete statement including the
 358     # trailing semicolon, but that's not allowed in CREATE VIEW, so
 359     # strip it out
 360     $def =~ s/\s*;\s*\z//;
 361     return $def;
 362 }
 363
 364 =head1 SEE ALSO
 365
 366 L<DBIx::Class::Schema::Loader>, L<DBIx::Class::Schema::Loader::Base>,
 367 L<DBIx::Class::Schema::Loader::DBI>
 368
 369 =head1 AUTHORS
 370
 371 See L<DBIx::Class::Schema::Loader/AUTHORS>.
 372
 373 =head1 LICENSE
 374
 375 This library is free software; you can redistribute it and/or modify it under
 376 the same terms as Perl itself.
 377
 378 =cut
 379
 380 1;