lib/DBIx/Class/Schema/Loader/DBI/Oracle.pm

   1 package DBIx::Class::Schema::Loader::DBI::Oracle;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/
   6     DBIx::Class::Schema::Loader::DBI::Component::QuotedDefault
   7     DBIx::Class::Schema::Loader::DBI
   8 /;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Class::C3;
  11
  12 our $VERSION = '0.08000';
  13
  14 =head1 NAME
  15
  16 DBIx::Class::Schema::Loader::DBI::Oracle - DBIx::Class::Schema::Loader::DBI
  17 Oracle Implementation.
  18
  19 =head1 DESCRIPTION
  20
  21 See L<DBIx::Class::Schema::Loader::Base>.
  22
  23 =cut
  24
  25 sub _setup {
  26     my $self = shift;
  27
  28     $self->next::method(@_);
  29
  30     my $dbh = $self->schema->storage->dbh;
  31
  32     my ($current_schema) = $dbh->selectrow_array('SELECT USER FROM DUAL', {});
  33
  34     $self->{db_schema} ||= $current_schema;
  35
  36     if (lc($self->db_schema) ne lc($current_schema)) {
  37         $dbh->do('ALTER SESSION SET current_schema=' . $self->db_schema);
  38     }
  39
  40     if (not defined $self->preserve_case) {
  41         $self->preserve_case(0);
  42     }
  43     elsif ($self->preserve_case) {
  44         $self->schema->storage->sql_maker->quote_char('"');
  45         $self->schema->storage->sql_maker->name_sep('.');
  46     }
  47 }
  48
  49 sub _table_as_sql {
  50     my ($self, $table) = @_;
  51
  52     return $self->_quote_table_name($table);
  53 }
  54
  55 sub _tables_list {
  56     my ($self, $opts) = @_;
  57
  58     my $dbh = $self->schema->storage->dbh;
  59
  60     my @tables;
  61     for my $table ( $dbh->tables(undef, $self->db_schema, '%', 'TABLE,VIEW') ) { #catalog, schema, table, type
  62         my $quoter = $dbh->get_info(29);
  63         $table =~ s/$quoter//g;
  64
  65         # remove "user." (schema) prefixes
  66         $table =~ s/\w+\.//;
  67
  68         next if $table eq 'PLAN_TABLE';
  69         $table = $self->_lc($table);
  70         push @tables, $1
  71           if $table =~ /\A(\w+)\z/;
  72     }
  73
  74     {
  75         # silence a warning from older DBD::Oracles in tests
  76         my $warn_handler = $SIG{__WARN__} || sub { warn @_ };
  77         local $SIG{__WARN__} = sub {
  78             $warn_handler->(@_)
  79             unless $_[0] =~ /^Field \d+ has an Oracle type \(\d+\) which is not explicitly supported/;
  80         };
  81
  82         return $self->_filter_tables(\@tables, $opts);
  83     }
  84 }
  85
  86 sub _table_columns {
  87     my ($self, $table) = @_;
  88
  89     my $dbh = $self->schema->storage->dbh;
  90
  91     my $sth = $dbh->column_info(undef, $self->db_schema, $self->_uc($table), '%');
  92
  93     return [ map $self->_lc($_->{COLUMN_NAME}), @{ $sth->fetchall_arrayref({ COLUMN_NAME => 1 }) || [] } ];
  94 }
  95
  96 sub _table_uniq_info {
  97     my ($self, $table) = @_;
  98
  99     my $dbh = $self->schema->storage->dbh;
 100
 101     my $sth = $dbh->prepare_cached(
 102         q{
 103             SELECT constraint_name, acc.column_name
 104             FROM all_constraints JOIN all_cons_columns acc USING (constraint_name)
 105             WHERE acc.table_name=? and acc.owner = ? AND constraint_type='U'
 106             ORDER BY acc.position
 107         },
 108         {}, 1);
 109
 110     $sth->execute($self->_uc($table),$self->{db_schema} );
 111     my %constr_names;
 112     while(my $constr = $sth->fetchrow_arrayref) {
 113         my $constr_name = $self->_lc($constr->[0]);
 114         my $constr_col  = $self->_lc($constr->[1]);
 115         $constr_name =~ s/\Q$self->{_quoter}\E//;
 116         $constr_col  =~ s/\Q$self->{_quoter}\E//;
 117         push @{$constr_names{$constr_name}}, $constr_col;
 118     }
 119
 120     my @uniqs = map { [ $_ => $constr_names{$_} ] } keys %constr_names;
 121     return \@uniqs;
 122 }
 123
 124 sub _table_pk_info {
 125     my ($self, $table) = (shift, shift);
 126
 127     return $self->next::method($self->_uc($table), @_);
 128 }
 129
 130 sub _table_fk_info {
 131     my ($self, $table) = (shift, shift);
 132
 133     my $rels = $self->next::method($self->_uc($table), @_);
 134
 135     foreach my $rel (@$rels) {
 136         $rel->{remote_table} = $self->_lc($rel->{remote_table});
 137     }
 138
 139     return $rels;
 140 }
 141
 142 sub _columns_info_for {
 143     my ($self, $table) = (shift, shift);
 144
 145     my $result = $self->next::method($self->_uc($table), @_);
 146
 147     my $dbh = $self->schema->storage->dbh;
 148
 149     local $dbh->{LongReadLen} = 100000;
 150     local $dbh->{LongTruncOk} = 1;
 151
 152     my $sth = $dbh->prepare_cached(q{
 153 SELECT atc.column_name, ut.trigger_body
 154 FROM all_triggers ut
 155 JOIN all_trigger_cols atc USING (trigger_name)
 156 WHERE atc.table_name = ?
 157 AND lower(column_usage) LIKE '%new%' AND lower(column_usage) LIKE '%out%'
 158 AND upper(trigger_type) LIKE '%BEFORE EACH ROW%' AND lower(triggering_event) LIKE '%insert%'
 159     }, {}, 1);
 160
 161     $sth->execute($self->_uc($table));
 162
 163     while (my ($col_name, $trigger_body) = $sth->fetchrow_array) {
 164         $col_name = $self->_lc($col_name);
 165
 166         $result->{$col_name}{is_auto_increment} = 1;
 167
 168         if (my ($seq_schema, $seq_name) = $trigger_body =~ /(?:\."?(\w+)"?)?"?(\w+)"?\.nextval/i) {
 169             $seq_schema = $self->_lc($seq_schema) || $self->db_schema;
 170             $seq_name   = $self->_lc($seq_name);
 171
 172             $result->{$col_name}{sequence} = ($self->qualify_objects ? ($seq_schema . '.') : '') . $seq_name;
 173         }
 174     }
 175
 176     while (my ($col, $info) = each %$result) {
 177         no warnings 'uninitialized';
 178
 179         if ($info->{data_type} =~ /^(?:n?[cb]lob|long(?: raw)?|bfile|date|binary_(?:float|double)|rowid)\z/i) {
 180             delete $info->{size};
 181         }
 182
 183         if ($info->{data_type} =~ /^n(?:var)?char2?\z/i) {
 184             $info->{size} = $info->{size} / 2;
 185         }
 186         elsif (lc($info->{data_type}) eq 'number') {
 187             $info->{original}{data_type} = 'number';
 188             $info->{data_type}           = 'numeric';
 189
 190             if (eval { $info->{size}[0] == 38 && $info->{size}[1] == 0 }) {
 191                 $info->{original}{size} = $info->{size};
 192
 193                 $info->{data_type} = 'integer';
 194                 delete $info->{size};
 195             }
 196         }
 197         elsif (my ($precision) = $info->{data_type} =~ /^timestamp\((\d+)\)(?: with (?:local )?time zone)?\z/i) {
 198             $info->{data_type} = join ' ', $info->{data_type} =~ /[a-z]+/ig;
 199
 200             if ($precision == 6) {
 201                 delete $info->{size};
 202             }
 203             else {
 204                 $info->{size} = $precision;
 205             }
 206         }
 207         elsif (($precision) = $info->{data_type} =~ /^interval year\((\d+)\) to month\z/i) {
 208             $info->{data_type} = join ' ', $info->{data_type} =~ /[a-z]+/ig;
 209
 210             if ($precision == 2) {
 211                 delete $info->{size};
 212             }
 213             else {
 214                 $info->{size} = $precision;
 215             }
 216         }
 217         elsif (my ($day_precision, $second_precision) = $info->{data_type} =~ /^interval day\((\d+)\) to second\((\d+)\)\z/i) {
 218             $info->{data_type} = join ' ', $info->{data_type} =~ /[a-z]+/ig;
 219
 220             if ($day_precision == 2 && $second_precision == 6) {
 221                 delete $info->{size};
 222             }
 223             else {
 224                 $info->{size} = [ $day_precision, $second_precision ];
 225             }
 226         }
 227         elsif (lc($info->{data_type}) eq 'float') {
 228             $info->{original}{data_type} = 'float';
 229             $info->{original}{size}      = $info->{size};
 230
 231             if ($info->{size} <= 63) {
 232                 $info->{data_type} = 'real';
 233             }
 234             else {
 235                 $info->{data_type} = 'double precision';
 236             }
 237             delete $info->{size};
 238         }
 239         elsif (lc($info->{data_type}) eq 'urowid' && $info->{size} == 4000) {
 240             delete $info->{size};
 241         }
 242         elsif (lc($info->{data_type}) eq 'date') {
 243             $info->{data_type}           = 'datetime';
 244             $info->{original}{data_type} = 'date';
 245         }
 246         elsif (lc($info->{data_type}) eq 'binary_float') {
 247             $info->{data_type}           = 'real';
 248             $info->{original}{data_type} = 'binary_float';
 249         }
 250         elsif (lc($info->{data_type}) eq 'binary_double') {
 251             $info->{data_type}           = 'double precision';
 252             $info->{original}{data_type} = 'binary_double';
 253         }
 254
 255         if ((eval { lc(${ $info->{default_value} }) }||'') eq 'sysdate') {
 256             my $current_timestamp  = 'current_timestamp';
 257             $info->{default_value} = \$current_timestamp;
 258
 259             my $sysdate = 'sysdate';
 260             $info->{original}{default_value} = \$sysdate;
 261         }
 262     }
 263
 264     return $result;
 265 }
 266
 267 =head1 SEE ALSO
 268
 269 L<DBIx::Class::Schema::Loader>, L<DBIx::Class::Schema::Loader::Base>,
 270 L<DBIx::Class::Schema::Loader::DBI>
 271
 272 =head1 AUTHOR
 273
 274 See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
 275
 276 =head1 LICENSE
 277
 278 This library is free software; you can redistribute it and/or modify it under
 279 the same terms as Perl itself.
 280
 281 =cut
 282
 283 1;
 284 # vim:et sts=4 sw=4 tw=0: