lib/DBIx/Class/Schema/Loader/DBI/Oracle.pm

   1 package DBIx::Class::Schema::Loader::DBI::Oracle;
   2
   3 use strict;
   4 use warnings;
   5 use base 'DBIx::Class::Schema::Loader::DBI::Component::QuotedDefault';
   6 use mro 'c3';
   7 use Try::Tiny;
   8 use DBIx::Class::Schema::Loader::Utils qw/sigwarn_silencer/;
   9 use namespace::clean;
  10
  11 our $VERSION = '0.07042';
  12
  13 =head1 NAME
  14
  15 DBIx::Class::Schema::Loader::DBI::Oracle - DBIx::Class::Schema::Loader::DBI
  16 Oracle Implementation.
  17
  18 =head1 DESCRIPTION
  19
  20 See L<DBIx::Class::Schema::Loader> and L<DBIx::Class::Schema::Loader::Base>.
  21
  22 =cut
  23
  24 sub _setup {
  25     my $self = shift;
  26
  27     $self->next::method(@_);
  28
  29     my ($current_schema) = $self->dbh->selectrow_array('SELECT USER FROM DUAL');
  30
  31     $self->db_schema([ $current_schema ]) unless $self->db_schema;
  32
  33     if (@{ $self->db_schema } == 1 && $self->db_schema->[0] ne '%'
  34         && lc($self->db_schema->[0]) ne lc($current_schema)) {
  35         $self->dbh->do('ALTER SESSION SET current_schema=' . $self->db_schema->[0]);
  36     }
  37
  38     if (not defined $self->preserve_case) {
  39         $self->preserve_case(0);
  40     }
  41     elsif ($self->preserve_case) {
  42         $self->schema->storage->sql_maker->quote_char('"');
  43         $self->schema->storage->sql_maker->name_sep('.');
  44     }
  45 }
  46
  47 sub _build_name_sep { '.' }
  48
  49 sub _system_schemas {
  50     my $self = shift;
  51
  52     # From http://www.adp-gmbh.ch/ora/misc/known_schemas.html
  53
  54     return ($self->next::method(@_), qw/ANONYMOUS APEX_PUBLIC_USER APEX_030200 APPQOSSYS CTXSYS DBSNMP DIP DMSYS EXFSYS LBACSYS MDDATA MDSYS MGMT_VIEW OLAPSYS ORACLE_OCM ORDDATA ORDPLUGINS ORDSYS OUTLN SI_INFORMTN_SCHEMA SPATIAL_CSW_ADMIN_USR SPATIAL_WFS_ADMIN_USR SYS SYSMAN SYSTEM TRACESRV MTSSYS OASPUBLIC OWBSYS OWBSYS_AUDIT WEBSYS WK_PROXY WKSYS WK_TEST WMSYS XDB OSE$HTTP$ADMIN AURORA$JIS$UTILITY$ AURORA$ORB$UNAUTHENTICATED/, qr/^FLOWS_\d\d\d\d\d\d\z/);
  55 }
  56
  57 sub _system_tables {
  58     my $self = shift;
  59
  60     return ($self->next::method(@_), 'PLAN_TABLE');
  61 }
  62
  63 sub _dbh_tables {
  64     my ($self, $schema) = @_;
  65
  66     return $self->dbh->tables(undef, $schema, '%', 'TABLE,VIEW');
  67 }
  68
  69 sub _filter_tables {
  70     my $self = shift;
  71
  72     # silence a warning from older DBD::Oracles in tests
  73     local $SIG{__WARN__} = sigwarn_silencer(
  74         qr/^Field \d+ has an Oracle type \(\d+\) which is not explicitly supported/
  75     );
  76
  77     return $self->next::method(@_);
  78 }
  79
  80 sub _table_fk_info {
  81     my $self = shift;
  82     my ($table) = @_;
  83
  84     my $rels = $self->next::method(@_);
  85
  86     my $deferrable_sth = $self->dbh->prepare_cached(<<'EOF');
  87 select deferrable from all_constraints
  88 where owner = ? and table_name = ? and constraint_name = ?
  89 EOF
  90
  91     foreach my $rel (@$rels) {
  92         # Oracle does not have update rules
  93         $rel->{attrs}{on_update} = 'NO ACTION';;
  94
  95         # DBD::Oracle's foreign_key_info does not return DEFERRABILITY, so we get it ourselves
  96         my ($deferrable) = $self->dbh->selectrow_array(
  97             $deferrable_sth, undef, $table->schema, $table->name, $rel->{_constraint_name}
  98         );
  99
 100         $rel->{attrs}{is_deferrable} = $deferrable && $deferrable =~ /^DEFERRABLE/i ? 1 : 0;
 101     }
 102
 103     return $rels;
 104 }
 105
 106 sub _table_uniq_info {
 107     my ($self, $table) = @_;
 108
 109     my $sth = $self->dbh->prepare_cached(<<'EOF', {}, 1);
 110 SELECT ac.constraint_name, acc.column_name
 111 FROM all_constraints ac, all_cons_columns acc
 112 WHERE acc.table_name=? AND acc.owner = ?
 113     AND ac.table_name = acc.table_name AND ac.owner = acc.owner
 114     AND acc.constraint_name = ac.constraint_name
 115     AND ac.constraint_type='U'
 116 ORDER BY acc.position
 117 EOF
 118
 119     $sth->execute($table->name, $table->schema);
 120
 121     my %constr_names;
 122
 123     while(my $constr = $sth->fetchrow_arrayref) {
 124         my $constr_name = $self->_lc($constr->[0]);
 125         my $constr_col  = $self->_lc($constr->[1]);
 126         push @{$constr_names{$constr_name}}, $constr_col;
 127     }
 128
 129     return [ map { [ $_ => $constr_names{$_} ] } sort keys %constr_names ];
 130 }
 131
 132 sub _table_comment {
 133     my $self = shift;
 134     my ($table) = @_;
 135
 136     my $table_comment = $self->next::method(@_);
 137
 138     return $table_comment if $table_comment;
 139
 140     ($table_comment) = $self->dbh->selectrow_array(<<'EOF', {}, $table->schema, $table->name);
 141 SELECT comments FROM all_tab_comments
 142 WHERE owner = ?
 143   AND table_name = ?
 144   AND (table_type = 'TABLE' OR table_type = 'VIEW')
 145 EOF
 146
 147     return $table_comment
 148 }
 149
 150 sub _column_comment {
 151     my $self = shift;
 152     my ($table, $column_number, $column_name) = @_;
 153
 154     my $column_comment = $self->next::method(@_);
 155
 156     return $column_comment if $column_comment;
 157
 158     ($column_comment) = $self->dbh->selectrow_array(<<'EOF', {}, $table->schema, $table->name, $self->_uc($column_name));
 159 SELECT comments FROM all_col_comments
 160 WHERE owner = ?
 161   AND table_name = ?
 162   AND column_name = ?
 163 EOF
 164
 165     return $column_comment
 166 }
 167
 168 sub _columns_info_for {
 169     my $self = shift;
 170     my ($table) = @_;
 171
 172     my $result = $self->next::method(@_);
 173
 174     local $self->dbh->{LongReadLen} = 1_000_000;
 175     local $self->dbh->{LongTruncOk} = 1;
 176
 177     my $sth = $self->dbh->prepare_cached(<<'EOF', {}, 1);
 178 SELECT trigger_body
 179 FROM all_triggers
 180 WHERE table_name = ? AND table_owner = ?
 181 AND upper(trigger_type) LIKE '%BEFORE EACH ROW%' AND lower(triggering_event) LIKE '%insert%'
 182 EOF
 183
 184     $sth->execute($table->name, $table->schema);
 185
 186     while (my ($trigger_body) = $sth->fetchrow_array) {
 187         if (my ($seq_schema, $seq_name) = $trigger_body =~ /(?:"?(\w+)"?\.)?"?(\w+)"?\.nextval/i) {
 188             if (my ($col_name) = $trigger_body =~ /:new\.(\w+)/i) {
 189                 $col_name = $self->_lc($col_name);
 190
 191                 $result->{$col_name}{is_auto_increment} = 1;
 192
 193                 $seq_schema = $self->_lc($seq_schema || $table->schema);
 194                 $seq_name   = $self->_lc($seq_name);
 195
 196                 $result->{$col_name}{sequence} = ($self->qualify_objects ? ($seq_schema . '.') : '') . $seq_name;
 197             }
 198         }
 199     }
 200
 201     # Old DBD::Oracle report the size in (UTF-16) bytes, not characters
 202     my $nchar_size_factor = $DBD::Oracle::VERSION >= 1.52 ? 1 : 2;
 203
 204     while (my ($col, $info) = each %$result) {
 205         no warnings 'uninitialized';
 206
 207         my $sth = $self->dbh->prepare_cached(<<'EOF', {}, 1);
 208 SELECT data_type, data_length
 209 FROM all_tab_columns
 210 WHERE column_name = ? AND table_name = ? AND owner = ?
 211 EOF
 212         $sth->execute($self->_uc($col), $table->name, $table->schema);
 213         my ($data_type, $data_length) = $sth->fetchrow_array;
 214         $sth->finish;
 215         $data_type = lc $data_type;
 216
 217         if ($data_type =~ /^(?:n(?:var)?char2?|u?rowid|nclob|timestamp\(\d+\)(?: with(?: local)? time zone)?|binary_(?:float|double))\z/i) {
 218             $info->{data_type} = $data_type;
 219
 220             if ($data_type =~ /^u?rowid\z/i) {
 221                 $info->{size} = $data_length;
 222             }
 223         }
 224
 225         if ($info->{data_type} =~ /^(?:n?[cb]lob|long(?: raw)?|bfile|date|binary_(?:float|double)|rowid)\z/i) {
 226             delete $info->{size};
 227         }
 228
 229         if ($info->{data_type} =~ /^n(?:var)?char2?\z/i) {
 230             if (ref $info->{size}) {
 231                 $info->{size} = $info->{size}[0] / 8;
 232             }
 233             else {
 234                 $info->{size} = $info->{size} / $nchar_size_factor;
 235             }
 236         }
 237         elsif ($info->{data_type} =~ /^(?:var)?char2?\z/i) {
 238             if (ref $info->{size}) {
 239                 $info->{size} = $info->{size}[0];
 240             }
 241         }
 242         elsif (lc($info->{data_type}) =~ /^(?:number|decimal)\z/i) {
 243             $info->{original}{data_type} = 'number';
 244             $info->{data_type}           = 'numeric';
 245
 246             if (try { $info->{size}[0] == 38 && $info->{size}[1] == 0 }) {
 247                 $info->{original}{size} = $info->{size};
 248
 249                 $info->{data_type} = 'integer';
 250                 delete $info->{size};
 251             }
 252         }
 253         elsif (my ($precision) = $info->{data_type} =~ /^timestamp\((\d+)\)(?: with (?:local )?time zone)?\z/i) {
 254             $info->{data_type} = join ' ', $info->{data_type} =~ /[a-z]+/ig;
 255
 256             if ($precision == 6) {
 257                 delete $info->{size};
 258             }
 259             else {
 260                 $info->{size} = $precision;
 261             }
 262         }
 263         elsif ($info->{data_type} =~ /timestamp/i && ref $info->{size} && $info->{size}[0] == 0) {
 264             my $size = $info->{size}[1];
 265             delete $info->{size};
 266             $info->{size} = $size unless $size == 6;
 267         }
 268         elsif (($precision) = $info->{data_type} =~ /^interval year\((\d+)\) to month\z/i) {
 269             $info->{data_type} = join ' ', $info->{data_type} =~ /[a-z]+/ig;
 270
 271             if ($precision == 2) {
 272                 delete $info->{size};
 273             }
 274             else {
 275                 $info->{size} = $precision;
 276             }
 277         }
 278         elsif (my ($day_precision, $second_precision) = $info->{data_type} =~ /^interval day\((\d+)\) to second\((\d+)\)\z/i) {
 279             $info->{data_type} = join ' ', $info->{data_type} =~ /[a-z]+/ig;
 280
 281             if ($day_precision == 2 && $second_precision == 6) {
 282                 delete $info->{size};
 283             }
 284             else {
 285                 $info->{size} = [ $day_precision, $second_precision ];
 286             }
 287         }
 288         elsif ($info->{data_type} =~ /^interval year to month\z/i && ref $info->{size}) {
 289             my $precision = $info->{size}[0];
 290
 291             if ($precision == 2) {
 292                 delete $info->{size};
 293             }
 294             else {
 295                 $info->{size} = $precision;
 296             }
 297         }
 298         elsif ($info->{data_type} =~ /^interval day to second\z/i && ref $info->{size}) {
 299             if ($info->{size}[0] == 2 && $info->{size}[1] == 6) {
 300                 delete $info->{size};
 301             }
 302         }
 303         elsif (lc($info->{data_type}) eq 'float') {
 304             $info->{original}{data_type} = 'float';
 305             $info->{original}{size}      = $info->{size};
 306
 307             if ($info->{size} <= 63) {
 308                 $info->{data_type} = 'real';
 309             }
 310             else {
 311                 $info->{data_type} = 'double precision';
 312             }
 313             delete $info->{size};
 314         }
 315         elsif (lc($info->{data_type}) eq 'double precision') {
 316             $info->{original}{data_type} = 'float';
 317
 318             my $size = try { $info->{size}[0] };
 319
 320             $info->{original}{size} = $size;
 321
 322             if ($size <= 63) {
 323                 $info->{data_type} = 'real';
 324             }
 325             delete $info->{size};
 326         }
 327         elsif (lc($info->{data_type}) eq 'urowid' && $info->{size} == 4000) {
 328             delete $info->{size};
 329         }
 330         elsif ($info->{data_type} eq '-9104') {
 331             $info->{data_type} = 'rowid';
 332             delete $info->{size};
 333         }
 334         elsif ($info->{data_type} eq '-2') {
 335             $info->{data_type} = 'raw';
 336             $info->{size} = try { $info->{size}[0] / 2 };
 337         }
 338         elsif (lc($info->{data_type}) eq 'date') {
 339             $info->{data_type}           = 'datetime';
 340             $info->{original}{data_type} = 'date';
 341         }
 342         elsif (lc($info->{data_type}) eq 'binary_float') {
 343             $info->{data_type}           = 'real';
 344             $info->{original}{data_type} = 'binary_float';
 345         }
 346         elsif (lc($info->{data_type}) eq 'binary_double') {
 347             $info->{data_type}           = 'double precision';
 348             $info->{original}{data_type} = 'binary_double';
 349         }
 350
 351         # DEFAULT could be missed by ::DBI because of ORA-24345
 352         if (not defined $info->{default_value}) {
 353             local $self->dbh->{LongReadLen} = 1_000_000;
 354             local $self->dbh->{LongTruncOk} = 1;
 355             my $sth = $self->dbh->prepare_cached(<<'EOF', {}, 1);
 356 SELECT data_default
 357 FROM all_tab_columns
 358 WHERE column_name = ? AND table_name = ? AND owner = ?
 359 EOF
 360             $sth->execute($self->_uc($col), $table->name, $table->schema);
 361             my ($default) = $sth->fetchrow_array;
 362             $sth->finish;
 363
 364             # this is mostly copied from ::DBI::QuotedDefault
 365             if (defined $default) {
 366                 s/^\s+//, s/\s+\z// for $default;
 367
 368                 if ($default =~ /^'(.*?)'\z/) {
 369                     $info->{default_value} = $1;
 370                 }
 371                 elsif ($default =~ /^(-?\d.*?)\z/) {
 372                     $info->{default_value} = $1;
 373                 }
 374                 elsif ($default =~ /^NULL\z/i) {
 375                     my $null = 'null';
 376                     $info->{default_value} = \$null;
 377                 }
 378                 elsif ($default ne '') {
 379                     my $val = $default;
 380                     $info->{default_value} = \$val;
 381                 }
 382             }
 383         }
 384
 385         if ((try { lc(${ $info->{default_value} }) }||'') eq 'sysdate') {
 386             my $current_timestamp  = 'current_timestamp';
 387             $info->{default_value} = \$current_timestamp;
 388
 389             my $sysdate = 'sysdate';
 390             $info->{original}{default_value} = \$sysdate;
 391         }
 392     }
 393
 394     return $result;
 395 }
 396
 397 sub _dbh_column_info {
 398     my $self  = shift;
 399     my ($dbh) = @_;
 400
 401     # try to avoid ORA-24345
 402     local $dbh->{LongReadLen} = 1_000_000;
 403     local $dbh->{LongTruncOk} = 1;
 404
 405     return $self->next::method(@_);
 406 }
 407
 408 =head1 SEE ALSO
 409
 410 L<DBIx::Class::Schema::Loader>, L<DBIx::Class::Schema::Loader::Base>,
 411 L<DBIx::Class::Schema::Loader::DBI>
 412
 413 =head1 AUTHOR
 414
 415 See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
 416
 417 =head1 LICENSE
 418
 419 This library is free software; you can redistribute it and/or modify it under
 420 the same terms as Perl itself.
 421
 422 =cut
 423
 424 1;
 425 # vim:et sts=4 sw=4 tw=0: