lib/DBIx/Class/Schema/Loader/DBI/MSSQL.pm

   1 package DBIx::Class::Schema::Loader::DBI::MSSQL;
   2
   3 use strict;
   4 use warnings;
   5 use base 'DBIx::Class::Schema::Loader::DBI::Sybase::Common';
   6 use Carp::Clan qw/^DBIx::Class/;
   7 use Class::C3;
   8
   9 our $VERSION = '0.05003';
  10
  11 =head1 NAME
  12
  13 DBIx::Class::Schema::Loader::DBI::MSSQL - DBIx::Class::Schema::Loader::DBI MSSQL Implementation.
  14
  15 =head1 DESCRIPTION
  16
  17 Base driver for Microsoft SQL Server, used by
  18 L<DBIx::Class::Schema::Loader::DBI::Sybase::Microsoft_SQL_Server> for support
  19 via L<DBD::Sybase> and
  20 L<DBIx::Class::Schema::Loader::DBI::ODBC::Microsoft_SQL_Server> for support via
  21 L<DBD::ODBC>.
  22
  23 See L<DBIx::Class::Schema::Loader> and L<DBIx::Class::Schema::Loader::Base> for
  24 usage information.
  25
  26 =cut
  27
  28 sub _tables_list {
  29     my $self = shift;
  30
  31     my $dbh = $self->schema->storage->dbh;
  32     my $sth = $dbh->prepare(<<'EOF');
  33 select t.table_name
  34 from information_schema.tables t
  35 where t.table_schema = ?
  36 EOF
  37     $sth->execute($self->db_schema);
  38
  39     my @tables = map lc $_, map @$_, @{ $sth->fetchall_arrayref };
  40
  41     return $self->_filter_tables(@tables);
  42 }
  43
  44 sub _table_pk_info {
  45     my ($self, $table) = @_;
  46     my $dbh = $self->schema->storage->dbh;
  47     my $sth = $dbh->prepare(qq{sp_pkeys '$table'});
  48     $sth->execute;
  49
  50     my @keydata;
  51
  52     while (my $row = $sth->fetchrow_hashref) {
  53         push @keydata, lc $row->{COLUMN_NAME};
  54     }
  55
  56     return \@keydata;
  57 }
  58
  59 sub _table_fk_info {
  60     my ($self, $table) = @_;
  61
  62     my ($local_cols, $remote_cols, $remote_table, @rels);
  63     my $dbh = $self->schema->storage->dbh;
  64     my $sth = $dbh->prepare(qq{sp_fkeys \@FKTABLE_NAME = '$table'});
  65     $sth->execute;
  66
  67     while (my $row = $sth->fetchrow_hashref) {
  68         my $fk = $row->{FK_NAME};
  69         push @{$local_cols->{$fk}}, lc $row->{FKCOLUMN_NAME};
  70         push @{$remote_cols->{$fk}}, lc $row->{PKCOLUMN_NAME};
  71         $remote_table->{$fk} = $row->{PKTABLE_NAME};
  72     }
  73
  74     foreach my $fk (keys %$remote_table) {
  75         push @rels, {
  76                       local_columns => \@{$local_cols->{$fk}},
  77                       remote_columns => \@{$remote_cols->{$fk}},
  78                       remote_table => $remote_table->{$fk},
  79                     };
  80
  81     }
  82     return \@rels;
  83 }
  84
  85 sub _table_uniq_info {
  86     my ($self, $table) = @_;
  87
  88     my $dbh = $self->schema->storage->dbh;
  89     my $sth = $dbh->prepare(qq{SELECT CCU.CONSTRAINT_NAME, CCU.COLUMN_NAME FROM INFORMATION_SCHEMA.CONSTRAINT_COLUMN_USAGE CCU
  90                                JOIN INFORMATION_SCHEMA.TABLE_CONSTRAINTS TC ON (CCU.CONSTRAINT_NAME = TC.CONSTRAINT_NAME)
  91                                JOIN INFORMATION_SCHEMA.KEY_COLUMN_USAGE KCU ON (CCU.CONSTRAINT_NAME = KCU.CONSTRAINT_NAME AND CCU.COLUMN_NAME = KCU.COLUMN_NAME)
  92                                WHERE CCU.TABLE_NAME = @{[ $dbh->quote($table) ]} AND CONSTRAINT_TYPE = 'UNIQUE' ORDER BY KCU.ORDINAL_POSITION});
  93     $sth->execute;
  94     my $constraints;
  95     while (my $row = $sth->fetchrow_hashref) {
  96         my $name = lc $row->{CONSTRAINT_NAME};
  97         my $col  = lc $row->{COLUMN_NAME};
  98         push @{$constraints->{$name}}, $col;
  99     }
 100
 101     my @uniqs = map { [ $_ => $constraints->{$_} ] } keys %$constraints;
 102     return \@uniqs;
 103 }
 104
 105 sub _columns_info_for {
 106     my $self    = shift;
 107     my ($table) = @_;
 108
 109     my $result = $self->next::method(@_);
 110
 111     while (my ($col, $info) = each %$result) {
 112         my $dbh = $self->schema->storage->dbh;
 113         my $sth = $dbh->prepare(qq{
 114             SELECT COLUMN_NAME
 115             FROM INFORMATION_SCHEMA.COLUMNS
 116             WHERE COLUMNPROPERTY(object_id(@{[ $dbh->quote($table) ]}, 'U'), @{[ $dbh->quote($col) ]}, 'IsIdentity') = 1
 117               AND TABLE_NAME = @{[ $dbh->quote($table) ]} AND COLUMN_NAME = @{[ $dbh->quote($col) ]}
 118         });
 119         $sth->execute();
 120
 121         if ($sth->fetchrow_array) {
 122             $info->{is_auto_increment} = 1;
 123             $info->{data_type} =~ s/\s*identity//i;
 124             delete $info->{size};
 125         }
 126
 127 # get default
 128         $sth = $dbh->prepare(qq{
 129             SELECT COLUMN_DEFAULT
 130             FROM INFORMATION_SCHEMA.COLUMNS
 131             WHERE TABLE_NAME = @{[ $dbh->quote($table) ]} AND COLUMN_NAME = @{[ $dbh->quote($col) ]}
 132         });
 133         $sth->execute;
 134         my ($default) = $sth->fetchrow_array;
 135
 136         if (defined $default) {
 137             # strip parens
 138             $default =~ s/^\( (.*) \)\z/$1/x;
 139
 140             # Literal strings are in ''s, numbers are in ()s (in some versions of
 141             # MSSQL, in others they are unquoted) everything else is a function.
 142             $info->{default_value} =
 143                 $default =~ /^['(] (.*) [)']\z/x ? $1 :
 144                     $default =~ /^\d/ ? $default : \$default;
 145         }
 146     }
 147
 148     return $result;
 149 }
 150
 151 =head1 SEE ALSO
 152
 153 L<DBIx::Class::Schema::Loader::DBI::Sybase::Microsoft_SQL_Server>,
 154 L<DBIx::Class::Schema::Loader::DBI::ODBC::Microsoft_SQL_Server>,
 155 L<DBIx::Class::Schema::Loader>, L<DBIx::Class::Schema::Loader::Base>,
 156 L<DBIx::Class::Schema::Loader::DBI>
 157
 158 =head1 AUTHOR
 159
 160 See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
 161
 162 =head1 LICENSE
 163
 164 This library is free software; you can redistribute it and/or modify it under
 165 the same terms as Perl itself.
 166
 167 =cut
 168
 169 1;