lib/DBIx/Class/Schema/Loader/DBI/MSSQL.pm

   1 package DBIx::Class::Schema::Loader::DBI::MSSQL;
   2
   3 use strict;
   4 use warnings;
   5 use base 'DBIx::Class::Schema::Loader::DBI::Sybase::Common';
   6 use Carp::Clan qw/^DBIx::Class/;
   7 use Class::C3;
   8
   9 our $VERSION = '0.05003';
  10
  11 =head1 NAME
  12
  13 DBIx::Class::Schema::Loader::DBI::MSSQL - DBIx::Class::Schema::Loader::DBI MSSQL Implementation.
  14
  15 =head1 DESCRIPTION
  16
  17 Base driver for Microsoft SQL Server, used by
  18 L<DBIx::Class::Schema::Loader::DBI::Sybase::Microsoft_SQL_Server> for support
  19 via L<DBD::Sybase> and
  20 L<DBIx::Class::Schema::Loader::DBI::ODBC::Microsoft_SQL_Server> for support via
  21 L<DBD::ODBC>.
  22
  23 See L<DBIx::Class::Schema::Loader> and L<DBIx::Class::Schema::Loader::Base> for
  24 usage information.
  25
  26 =cut
  27
  28 sub _tables_list {
  29     my ($self, $opts) = @_;
  30
  31     my $dbh = $self->schema->storage->dbh;
  32     my $sth = $dbh->prepare(<<'EOF');
  33 SELECT t.table_name
  34 FROM information_schema.tables t
  35 WHERE t.table_schema = ?
  36 EOF
  37     $sth->execute($self->db_schema);
  38
  39     my @tables = map @$_, @{ $sth->fetchall_arrayref };
  40
  41     return $self->_filter_tables(\@tables, $opts);
  42 }
  43
  44 sub _table_pk_info {
  45     my ($self, $table) = @_;
  46     my $dbh = $self->schema->storage->dbh;
  47     my $sth = $dbh->prepare(qq{sp_pkeys '$table'});
  48     $sth->execute;
  49
  50     my @keydata;
  51
  52     while (my $row = $sth->fetchrow_hashref) {
  53         push @keydata, lc $row->{COLUMN_NAME};
  54     }
  55
  56     return \@keydata;
  57 }
  58
  59 sub _table_fk_info {
  60     my ($self, $table) = @_;
  61
  62     my ($local_cols, $remote_cols, $remote_table, @rels);
  63     my $dbh = $self->schema->storage->dbh;
  64     my $sth = $dbh->prepare(qq{sp_fkeys \@FKTABLE_NAME = '$table'});
  65     $sth->execute;
  66
  67     while (my $row = $sth->fetchrow_hashref) {
  68         my $fk = $row->{FK_NAME};
  69         push @{$local_cols->{$fk}}, lc $row->{FKCOLUMN_NAME};
  70         push @{$remote_cols->{$fk}}, lc $row->{PKCOLUMN_NAME};
  71         $remote_table->{$fk} = $row->{PKTABLE_NAME};
  72     }
  73
  74     foreach my $fk (keys %$remote_table) {
  75         push @rels, {
  76                       local_columns => \@{$local_cols->{$fk}},
  77                       remote_columns => \@{$remote_cols->{$fk}},
  78                       remote_table => $remote_table->{$fk},
  79                     };
  80
  81     }
  82     return \@rels;
  83 }
  84
  85 sub _table_uniq_info {
  86     my ($self, $table) = @_;
  87
  88     my $dbh = $self->schema->storage->dbh;
  89     local $dbh->{FetchHashKeyName} = 'NAME_lc';
  90
  91     my $sth = $dbh->prepare(qq{
  92 SELECT ccu.constraint_name, ccu.column_name
  93 FROM information_schema.constraint_column_usage ccu
  94 JOIN information_schema.table_constraints tc on (ccu.constraint_name = tc.constraint_name)
  95 JOIN information_schema.key_column_usage kcu on (ccu.constraint_name = kcu.constraint_name and ccu.column_name = kcu.column_name)
  96 wHERE lower(ccu.table_name) = @{[ $dbh->quote(lc $table) ]} AND constraint_type = 'UNIQUE' ORDER BY kcu.ordinal_position
  97     });
  98     $sth->execute;
  99     my $constraints;
 100     while (my $row = $sth->fetchrow_hashref) {
 101         my $name = $row->{constraint_name};
 102         my $col  = lc $row->{column_name};
 103         push @{$constraints->{$name}}, $col;
 104     }
 105
 106     my @uniqs = map { [ $_ => $constraints->{$_} ] } keys %$constraints;
 107     return \@uniqs;
 108 }
 109
 110 sub _columns_info_for {
 111     my $self    = shift;
 112     my ($table) = @_;
 113
 114     my $result = $self->next::method(@_);
 115
 116     while (my ($col, $info) = each %$result) {
 117         my $dbh = $self->schema->storage->dbh;
 118
 119         my $sth = $dbh->prepare(qq{
 120 SELECT column_name
 121 FROM information_schema.columns
 122 WHERE columnproperty(object_id(@{[ $dbh->quote(lc $table) ]}, 'U'), @{[ $dbh->quote(lc $col) ]}, 'IsIdentity') = 1
 123 AND lower(table_name) = @{[ $dbh->quote(lc $table) ]} AND lower(column_name) = @{[ $dbh->quote(lc $col) ]}
 124         });
 125         if (eval { $sth->execute; $sth->fetchrow_array }) {
 126             $info->{is_auto_increment} = 1;
 127             $info->{data_type} =~ s/\s*identity//i;
 128             delete $info->{size};
 129         }
 130
 131 # get default
 132         $sth = $dbh->prepare(qq{
 133 SELECT column_default
 134 FROM information_schema.columns
 135 wHERE lower(table_name) = @{[ $dbh->quote(lc $table) ]} AND lower(column_name) = @{[ $dbh->quote(lc $col) ]}
 136         });
 137         my ($default) = eval { $sth->execute; $sth->fetchrow_array };
 138
 139         if (defined $default) {
 140             # strip parens
 141             $default =~ s/^\( (.*) \)\z/$1/x;
 142
 143             # Literal strings are in ''s, numbers are in ()s (in some versions of
 144             # MSSQL, in others they are unquoted) everything else is a function.
 145             $info->{default_value} =
 146                 $default =~ /^['(] (.*) [)']\z/x ? $1 :
 147                     $default =~ /^\d/ ? $default : \$default;
 148         }
 149     }
 150
 151     return $result;
 152 }
 153
 154 =head1 SEE ALSO
 155
 156 L<DBIx::Class::Schema::Loader::DBI::Sybase::Microsoft_SQL_Server>,
 157 L<DBIx::Class::Schema::Loader::DBI::ODBC::Microsoft_SQL_Server>,
 158 L<DBIx::Class::Schema::Loader>, L<DBIx::Class::Schema::Loader::Base>,
 159 L<DBIx::Class::Schema::Loader::DBI>
 160
 161 =head1 AUTHOR
 162
 163 See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
 164
 165 =head1 LICENSE
 166
 167 This library is free software; you can redistribute it and/or modify it under
 168 the same terms as Perl itself.
 169
 170 =cut
 171
 172 1;
 173 # vim:et sts=4 sw=4 tw=0: