lib/DBIx/Class/Schema/Loader/DBI.pm

   1 package DBIx::Class::Schema::Loader::DBI;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class::Schema::Loader::Base/;
   6 use mro 'c3';
   7 use Carp::Clan qw/^DBIx::Class/;
   8 use Try::Tiny;
   9 use namespace::clean;
  10
  11 our $VERSION = '0.07008';
  12
  13 __PACKAGE__->mk_group_accessors('simple', qw/
  14     _disable_pk_detection
  15     _disable_uniq_detection
  16     _disable_fk_detection
  17     _passwords
  18 /);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::Schema::Loader::DBI - DBIx::Class::Schema::Loader DBI Implementation.
  23
  24 =head1 SYNOPSIS
  25
  26 See L<DBIx::Class::Schema::Loader::Base>
  27
  28 =head1 DESCRIPTION
  29
  30 This is the base class for L<DBIx::Class::Schema::Loader::Base> classes for
  31 DBI-based storage backends, and implements the common functionality between them.
  32
  33 See L<DBIx::Class::Schema::Loader::Base> for the available options.
  34
  35 =head1 METHODS
  36
  37 =head2 new
  38
  39 Overlays L<DBIx::Class::Schema::Loader::Base/new> to do some DBI-specific
  40 things.
  41
  42 =cut
  43
  44 sub new {
  45     my $self = shift->next::method(@_);
  46
  47     # rebless to vendor-specific class if it exists and loads and we're not in a
  48     # custom class.
  49     if (not $self->loader_class) {
  50         my $dbh = $self->schema->storage->dbh;
  51         my $driver = $dbh->{Driver}->{Name};
  52
  53         my $subclass = 'DBIx::Class::Schema::Loader::DBI::' . $driver;
  54         if ($self->load_optional_class($subclass)) {
  55             bless $self, $subclass unless $self->isa($subclass);
  56             $self->_rebless;
  57         }
  58     }
  59
  60     # Set up the default quoting character and name seperators
  61     $self->{_quoter}  = $self->_build_quoter;
  62     $self->{_namesep} = $self->_build_namesep;
  63
  64     # For our usage as regex matches, concatenating multiple quoter
  65     # values works fine (e.g. s/\Q<>\E// if quoter was [ '<', '>' ])
  66     if( ref $self->{_quoter} eq 'ARRAY') {
  67         $self->{_quoter} = join(q{}, @{$self->{_quoter}});
  68     }
  69
  70     $self->_setup;
  71
  72     $self;
  73 }
  74
  75 sub _build_quoter {
  76     my $self = shift;
  77     my $dbh = $self->schema->storage->dbh;
  78     return $dbh->get_info(29)
  79            || $self->schema->storage->sql_maker->quote_char
  80            || q{"};
  81 }
  82
  83 sub _build_namesep {
  84     my $self = shift;
  85     my $dbh = $self->schema->storage->dbh;
  86     return $dbh->get_info(41)
  87            || $self->schema->storage->sql_maker->name_sep
  88            || q{.};
  89 }
  90
  91 # Override this in vendor modules to do things at the end of ->new()
  92 sub _setup { }
  93
  94 # Override this in vendor module to load a subclass if necessary
  95 sub _rebless { }
  96
  97 # Returns an array of table names
  98 sub _tables_list {
  99     my ($self, $opts) = (shift, shift);
 100
 101     my ($table, $type) = @_ ? @_ : ('%', '%');
 102
 103     my $dbh = $self->schema->storage->dbh;
 104     my @tables = $dbh->tables(undef, $self->db_schema, $table, $type);
 105
 106     my $qt = qr/[\Q$self->{_quoter}\E"'`\[\]]/;
 107
 108     my $all_tables_quoted = (grep /$qt/, @tables) == @tables;
 109
 110     if ($self->{_quoter} && $all_tables_quoted) {
 111         s/.* $qt (?= .* $qt)//xg for @tables;
 112     } else {
 113         s/^.*\Q$self->{_namesep}\E// for @tables;
 114     }
 115     s/$qt//g for @tables;
 116
 117     return $self->_filter_tables(\@tables, $opts);
 118 }
 119
 120 # apply constraint/exclude and ignore bad tables and views
 121 sub _filter_tables {
 122     my ($self, $tables, $opts) = @_;
 123
 124     my @tables = @$tables;
 125     my @filtered_tables;
 126
 127     $opts ||= {};
 128     my $constraint   = $opts->{constraint};
 129     my $exclude      = $opts->{exclude};
 130
 131     @tables = grep { /$constraint/ } @$tables if defined $constraint;
 132     @tables = grep { ! /$exclude/  } @$tables if defined $exclude;
 133
 134     LOOP: for my $table (@tables) {
 135         try {
 136             local $^W = 0; # for ADO
 137             my $sth = $self->_sth_for($table, undef, \'1 = 0');
 138             $sth->execute;
 139         }
 140         catch {
 141             warn "Bad table or view '$table', ignoring: $_\n";
 142             $self->_unregister_source_for_table($table);
 143             no warnings 'exiting';
 144             next LOOP;
 145         };
 146
 147         push @filtered_tables, $table;
 148     }
 149
 150     return @filtered_tables;
 151 }
 152
 153 =head2 load
 154
 155 We override L<DBIx::Class::Schema::Loader::Base/load> here to hook in our localized settings for C<$dbh> error handling.
 156
 157 =cut
 158
 159 sub load {
 160     my $self = shift;
 161
 162     local $self->schema->storage->dbh->{RaiseError} = 1;
 163     local $self->schema->storage->dbh->{PrintError} = 0;
 164     $self->next::method(@_);
 165 }
 166
 167 sub _table_as_sql {
 168     my ($self, $table) = @_;
 169
 170     if($self->{db_schema}) {
 171         $table = $self->{db_schema} . $self->{_namesep} .
 172             $self->_quote_table_name($table);
 173     } else {
 174         $table = $self->_quote_table_name($table);
 175     }
 176
 177     return $table;
 178 }
 179
 180 sub _sth_for {
 181     my ($self, $table, $fields, $where) = @_;
 182
 183     my $dbh = $self->schema->storage->dbh;
 184
 185     my $sth = $dbh->prepare($self->schema->storage->sql_maker
 186         ->select(\$self->_table_as_sql($table), $fields, $where));
 187
 188     return $sth;
 189 }
 190
 191 # Returns an arrayref of column names
 192 sub _table_columns {
 193     my ($self, $table) = @_;
 194
 195     my $sth = $self->_sth_for($table, undef, \'1 = 0');
 196     $sth->execute;
 197     my $retval = $self->preserve_case ? \@{$sth->{NAME}} : \@{$sth->{NAME_lc}};
 198     $sth->finish;
 199
 200     $retval;
 201 }
 202
 203 # Returns arrayref of pk col names
 204 sub _table_pk_info {
 205     my ($self, $table) = @_;
 206
 207     return [] if $self->_disable_pk_detection;
 208
 209     my $dbh = $self->schema->storage->dbh;
 210
 211     my @primary = try {
 212         $dbh->primary_key('', $self->db_schema, $table);
 213     }
 214     catch {
 215         warn "Cannot find primary keys for this driver: $_";
 216         $self->_disable_pk_detection(1);
 217         return ();
 218     };
 219
 220     return [] if not @primary;
 221
 222     @primary = map { $self->_lc($_) } @primary;
 223     s/\Q$self->{_quoter}\E//g for @primary;
 224
 225     return \@primary;
 226 }
 227
 228 # Override this for vendor-specific uniq info
 229 sub _table_uniq_info {
 230     my ($self, $table) = @_;
 231
 232     return [] if $self->_disable_uniq_detection;
 233
 234     my $dbh = $self->schema->storage->dbh;
 235
 236     if (not $dbh->can('statistics_info')) {
 237         warn "No UNIQUE constraint information can be gathered for this driver";
 238         $self->_disable_uniq_detection(1);
 239         return [];
 240     }
 241
 242     my %indices;
 243     my $sth = $dbh->statistics_info(undef, $self->db_schema, $table, 1, 1);
 244     while(my $row = $sth->fetchrow_hashref) {
 245         # skip table-level stats, conditional indexes, and any index missing
 246         #  critical fields
 247         next if $row->{TYPE} eq 'table'
 248             || defined $row->{FILTER_CONDITION}
 249             || !$row->{INDEX_NAME}
 250             || !defined $row->{ORDINAL_POSITION}
 251             || !$row->{COLUMN_NAME};
 252
 253         $indices{$row->{INDEX_NAME}}[$row->{ORDINAL_POSITION}] = $self->_lc($row->{COLUMN_NAME});
 254     }
 255     $sth->finish;
 256
 257     my @retval;
 258     foreach my $index_name (keys %indices) {
 259         my $index = $indices{$index_name};
 260         push(@retval, [ $index_name => [ @$index[1..$#$index] ] ]);
 261     }
 262
 263     return \@retval;
 264 }
 265
 266 # Find relationships
 267 sub _table_fk_info {
 268     my ($self, $table) = @_;
 269
 270     return [] if $self->_disable_fk_detection;
 271
 272     my $dbh = $self->schema->storage->dbh;
 273     my $sth = try {
 274         $dbh->foreign_key_info( '', $self->db_schema, '',
 275                                 '', $self->db_schema, $table );
 276     }
 277     catch {
 278         warn "Cannot introspect relationships for this driver: $_";
 279         $self->_disable_fk_detection(1);
 280         return undef;
 281     };
 282
 283     return [] if !$sth;
 284
 285     my %rels;
 286
 287     my $i = 1; # for unnamed rels, which hopefully have only 1 column ...
 288     while(my $raw_rel = $sth->fetchrow_arrayref) {
 289         my $uk_tbl  = $raw_rel->[2];
 290         my $uk_col  = $self->_lc($raw_rel->[3]);
 291         my $fk_col  = $self->_lc($raw_rel->[7]);
 292         my $relid   = ($raw_rel->[11] || ( "__dcsld__" . $i++ ));
 293         $uk_tbl =~ s/\Q$self->{_quoter}\E//g;
 294         $uk_col =~ s/\Q$self->{_quoter}\E//g;
 295         $fk_col =~ s/\Q$self->{_quoter}\E//g;
 296         $relid  =~ s/\Q$self->{_quoter}\E//g;
 297         $rels{$relid}->{tbl} = $uk_tbl;
 298         $rels{$relid}->{cols}{$uk_col} = $fk_col;
 299     }
 300     $sth->finish;
 301
 302     my @rels;
 303     foreach my $relid (keys %rels) {
 304         push(@rels, {
 305             remote_columns => [ keys   %{$rels{$relid}->{cols}} ],
 306             local_columns  => [ values %{$rels{$relid}->{cols}} ],
 307             remote_table   => $rels{$relid}->{tbl},
 308         });
 309     }
 310
 311     return \@rels;
 312 }
 313
 314 # ported in from DBIx::Class::Storage::DBI:
 315 sub _columns_info_for {
 316     my ($self, $table) = @_;
 317
 318     my $dbh = $self->schema->storage->dbh;
 319
 320     my %result;
 321
 322     if ($dbh->can('column_info')) {
 323         my $sth = $self->_dbh_column_info($dbh, undef, $self->db_schema, $table, '%' );
 324         while ( my $info = $sth->fetchrow_hashref() ){
 325             my $column_info = {};
 326             $column_info->{data_type}     = lc $info->{TYPE_NAME};
 327
 328             my $size = $info->{COLUMN_SIZE};
 329
 330             if (defined $size && defined $info->{DECIMAL_DIGITS}) {
 331                 $column_info->{size} = [$size, $info->{DECIMAL_DIGITS}];
 332             }
 333             elsif (defined $size) {
 334                 $column_info->{size} = $size;
 335             }
 336
 337             $column_info->{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
 338             $column_info->{default_value} = $info->{COLUMN_DEF} if defined $info->{COLUMN_DEF};
 339             my $col_name = $info->{COLUMN_NAME};
 340             $col_name =~ s/^\"(.*)\"$/$1/;
 341
 342             $col_name = $self->_lc($col_name);
 343
 344             my $extra_info = $self->_extra_column_info(
 345                 $table, $col_name, $column_info, $info
 346             ) || {};
 347             $column_info = { %$column_info, %$extra_info };
 348
 349             $result{$col_name} = $column_info;
 350         }
 351         $sth->finish;
 352
 353         return \%result if %result;
 354     }
 355
 356     my $sth = $self->_sth_for($table, undef, \'1 = 0');
 357     $sth->execute;
 358
 359     my @columns = @{ $sth->{NAME} };
 360
 361     for my $i (0 .. $#columns) {
 362         my $column_info = {};
 363         $column_info->{data_type} = lc $sth->{TYPE}[$i];
 364
 365         my $size = $sth->{PRECISION}[$i];
 366
 367         if (defined $size && defined $sth->{SCALE}[$i]) {
 368             $column_info->{size} = [$size, $sth->{SCALE}[$i]];
 369         }
 370         elsif (defined $size) {
 371             $column_info->{size} = $size;
 372         }
 373
 374         $column_info->{is_nullable} = $sth->{NULLABLE}[$i] ? 1 : 0;
 375
 376         if ($column_info->{data_type} =~ m/^(.*?)\((.*?)\)$/) {
 377             $column_info->{data_type} = $1;
 378             $column_info->{size}    = $2;
 379         }
 380
 381         my $extra_info = $self->_extra_column_info($table, $columns[$i], $column_info) || {};
 382         $column_info = { %$column_info, %$extra_info };
 383
 384         $result{ $self->_lc($columns[$i]) } = $column_info;
 385     }
 386     $sth->finish;
 387
 388     foreach my $col (keys %result) {
 389         my $colinfo = $result{$col};
 390         my $type_num = $colinfo->{data_type};
 391         my $type_name;
 392         if (defined $type_num && $type_num =~ /^-?\d+\z/ && $dbh->can('type_info')) {
 393             my $type_info = $dbh->type_info($type_num);
 394             $type_name = $type_info->{TYPE_NAME} if $type_info;
 395             $colinfo->{data_type} = lc $type_name if $type_name;
 396         }
 397     }
 398
 399     return \%result;
 400 }
 401
 402 # do not use this, override _columns_info_for instead
 403 sub _extra_column_info {}
 404
 405 # override to mask warnings if needed (see mysql)
 406 sub _dbh_column_info {
 407     my ($self, $dbh) = (shift, shift);
 408
 409     return $dbh->column_info(@_);
 410 }
 411
 412 # If a coderef uses DBI->connect, this should get its connect info.
 413 sub _try_infer_connect_info_from_coderef {
 414     my ($self, $code) = @_;
 415
 416     my ($dsn, $user, $pass, $params);
 417
 418     no warnings 'redefine';
 419
 420     local *DBI::connect = sub {
 421         (undef, $dsn, $user, $pass, $params) = @_;
 422     };
 423
 424     $code->();
 425
 426     return ($dsn, $user, $pass, $params);
 427 }
 428
 429 =head1 SEE ALSO
 430
 431 L<DBIx::Class::Schema::Loader>
 432
 433 =head1 AUTHOR
 434
 435 See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
 436
 437 =head1 LICENSE
 438
 439 This library is free software; you can redistribute it and/or modify it under
 440 the same terms as Perl itself.
 441
 442 =cut
 443
 444 1;
 445 # vim:et sts=4 sw=4 tw=0: