lib/DBIx/Class/Schema/Loader/DBI.pm

   1 package DBIx::Class::Schema::Loader::DBI;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class::Schema::Loader::Base/;
   6 use Class::C3;
   7 use Carp::Clan qw/^DBIx::Class/;
   8 use UNIVERSAL::require;
   9
  10 our $VERSION = '0.04999_06';
  11
  12 =head1 NAME
  13
  14 DBIx::Class::Schema::Loader::DBI - DBIx::Class::Schema::Loader DBI Implementation.
  15
  16 =head1 SYNOPSIS
  17
  18 See L<DBIx::Class::Schema::Loader::Base>
  19
  20 =head1 DESCRIPTION
  21
  22 This is the base class for L<DBIx::Class::Schema::Loader::Base> classes for
  23 DBI-based storage backends, and implements the common functionality between them.
  24
  25 See L<DBIx::Class::Schema::Loader::Base> for the available options.
  26
  27 =head1 METHODS
  28
  29 =head2 new
  30
  31 Overlays L<DBIx::Class::Schema::Loader::Base/new> to do some DBI-specific
  32 things.
  33
  34 =cut
  35
  36 sub new {
  37     my $self = shift->next::method(@_);
  38
  39     # rebless to vendor-specific class if it exists and loads
  40     my $dbh = $self->schema->storage->dbh;
  41     my $driver = $dbh->{Driver}->{Name};
  42     my $subclass = 'DBIx::Class::Schema::Loader::DBI::' . $driver;
  43     $subclass->require;
  44     if($@ && $@ !~ /^Can't locate /) {
  45         croak "Failed to require $subclass: $@";
  46     }
  47     elsif(!$@) {
  48         bless $self, $subclass unless $self->isa($subclass);
  49     }
  50
  51     # Set up the default quoting character and name seperators
  52     $self->{_quoter} = $self->schema->storage->sql_maker->quote_char
  53                     || $dbh->get_info(29)
  54                     || q{"};
  55
  56     $self->{_namesep} = $self->schema->storage->sql_maker->name_sep
  57                      || $dbh->get_info(41)
  58                      || q{.};
  59
  60     # For our usage as regex matches, concatenating multiple quoter
  61     # values works fine (e.g. s/\Q<>\E// if quoter was [ '<', '>' ])
  62     if( ref $self->{_quoter} eq 'ARRAY') {
  63         $self->{_quoter} = join(q{}, @{$self->{_quoter}});
  64     }
  65
  66     $self->_setup;
  67
  68     $self;
  69 }
  70
  71 # Override this in vendor modules to do things at the end of ->new()
  72 sub _setup { }
  73
  74 # Returns an array of table names
  75 sub _tables_list {
  76     my $self = shift;
  77
  78     my $dbh = $self->schema->storage->dbh;
  79     my @tables = $dbh->tables(undef, $self->db_schema, '%', '%');
  80     s/\Q$self->{_quoter}\E//g for @tables;
  81     s/^.*\Q$self->{_namesep}\E// for @tables;
  82
  83     return @tables;
  84 }
  85
  86 =head2 load
  87
  88 We override L<DBIx::Class::Schema::Loader::Base/load> here to hook in our localized settings for C<$dbh> error handling.
  89
  90 =cut
  91
  92 sub load {
  93     my $self = shift;
  94
  95     local $self->schema->storage->dbh->{RaiseError} = 1;
  96     local $self->schema->storage->dbh->{PrintError} = 0;
  97     $self->next::method(@_);
  98 }
  99
 100 # Returns an arrayref of column names
 101 sub _table_columns {
 102     my ($self, $table) = @_;
 103
 104     my $dbh = $self->schema->storage->dbh;
 105
 106     if($self->{db_schema}) {
 107         $table = $self->{db_schema} . $self->{_namesep} . $table;
 108     }
 109
 110     my $sth = $dbh->prepare($self->schema->storage->sql_maker->select($table, undef, \'1 = 0'));
 111     $sth->execute;
 112     my $retval = \@{$sth->{NAME_lc}};
 113     $sth->finish;
 114
 115     $retval;
 116 }
 117
 118 # Returns arrayref of pk col names
 119 sub _table_pk_info {
 120     my ($self, $table) = @_;
 121
 122     my $dbh = $self->schema->storage->dbh;
 123
 124     my @primary = map { lc } $dbh->primary_key('', $self->db_schema, $table);
 125     s/\Q$self->{_quoter}\E//g for @primary;
 126
 127     return \@primary;
 128 }
 129
 130 # Override this for vendor-specific uniq info
 131 sub _table_uniq_info {
 132     my ($self, $table) = @_;
 133
 134     my $dbh = $self->schema->storage->dbh;
 135     if(!$dbh->can('statistics_info')) {
 136         warn "No UNIQUE constraint information can be gathered for this vendor";
 137         return [];
 138     }
 139
 140     my %indices;
 141     my $sth = $dbh->statistics_info(undef, $self->db_schema, $table, 1, 1);
 142     while(my $row = $sth->fetchrow_hashref) {
 143         # skip table-level stats, conditional indexes, and any index missing
 144         #  critical fields
 145         next if $row->{TYPE} eq 'table'
 146             || defined $row->{FILTER_CONDITION}
 147             || !$row->{INDEX_NAME}
 148             || !defined $row->{ORDINAL_POSITION}
 149             || !$row->{COLUMN_NAME};
 150
 151         $indices{$row->{INDEX_NAME}}->{$row->{ORDINAL_POSITION}} = $row->{COLUMN_NAME};
 152     }
 153     $sth->finish;
 154
 155     my @retval;
 156     foreach my $index_name (keys %indices) {
 157         my $index = $indices{$index_name};
 158         push(@retval, [ $index_name => [
 159             map { $index->{$_} }
 160                 sort keys %$index
 161         ]]);
 162     }
 163
 164     return \@retval;
 165 }
 166
 167 # Find relationships
 168 sub _table_fk_info {
 169     my ($self, $table) = @_;
 170
 171     my $dbh = $self->schema->storage->dbh;
 172     my $sth = $dbh->foreign_key_info( '', $self->db_schema, '',
 173                                       '', $self->db_schema, $table );
 174     return [] if !$sth;
 175
 176     my %rels;
 177
 178     my $i = 1; # for unnamed rels, which hopefully have only 1 column ...
 179     while(my $raw_rel = $sth->fetchrow_arrayref) {
 180         my $uk_tbl  = $raw_rel->[2];
 181         my $uk_col  = lc $raw_rel->[3];
 182         my $fk_col  = lc $raw_rel->[7];
 183         my $relid   = ($raw_rel->[11] || ( "__dcsld__" . $i++ ));
 184         $uk_tbl =~ s/\Q$self->{_quoter}\E//g;
 185         $uk_col =~ s/\Q$self->{_quoter}\E//g;
 186         $fk_col =~ s/\Q$self->{_quoter}\E//g;
 187         $relid  =~ s/\Q$self->{_quoter}\E//g;
 188         $rels{$relid}->{tbl} = $uk_tbl;
 189         $rels{$relid}->{cols}->{$uk_col} = $fk_col;
 190     }
 191     $sth->finish;
 192
 193     my @rels;
 194     foreach my $relid (keys %rels) {
 195         push(@rels, {
 196             remote_columns => [ keys   %{$rels{$relid}->{cols}} ],
 197             local_columns  => [ values %{$rels{$relid}->{cols}} ],
 198             remote_table   => $rels{$relid}->{tbl},
 199         });
 200     }
 201
 202     return \@rels;
 203 }
 204
 205 # ported in from DBIx::Class::Storage::DBI:
 206 sub _columns_info_for {
 207     my ($self, $table) = @_;
 208
 209     my $dbh = $self->schema->storage->dbh;
 210
 211     if ($dbh->can('column_info')) {
 212         my %result;
 213         eval {
 214             my $sth = $dbh->column_info( undef, $self->db_schema, $table, '%' );
 215             while ( my $info = $sth->fetchrow_hashref() ){
 216                 my %column_info;
 217                 $column_info{data_type}   = $info->{TYPE_NAME};
 218                 $column_info{size}      = $info->{COLUMN_SIZE};
 219                 $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
 220                 $column_info{default_value} = $info->{COLUMN_DEF};
 221                 my $col_name = $info->{COLUMN_NAME};
 222                 $col_name =~ s/^\"(.*)\"$/$1/;
 223
 224                 my $extra_info = $self->_extra_column_info($info) || {};
 225
 226                 $result{$col_name} = { %column_info, %$extra_info };
 227             }
 228             $sth->finish;
 229         };
 230       return \%result if !$@ && scalar keys %result;
 231     }
 232
 233     if($self->db_schema) {
 234         $table = $self->db_schema . $self->{_namesep} . $table;
 235     }
 236     my %result;
 237     my $sth = $dbh->prepare($self->schema->storage->sql_maker->select($table, undef, \'1 = 0'));
 238     $sth->execute;
 239     my @columns = @{$sth->{NAME_lc}};
 240     for my $i ( 0 .. $#columns ){
 241         my %column_info;
 242         $column_info{data_type} = $sth->{TYPE}->[$i];
 243         $column_info{size} = $sth->{PRECISION}->[$i];
 244         $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
 245
 246         if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
 247             $column_info{data_type} = $1;
 248             $column_info{size}    = $2;
 249         }
 250
 251         my $extra_info = $self->_extra_column_info($table, $columns[$i], $sth, $i) || {};
 252
 253         $result{$columns[$i]} = { %column_info, %$extra_info };
 254     }
 255     $sth->finish;
 256
 257     foreach my $col (keys %result) {
 258         my $colinfo = $result{$col};
 259         my $type_num = $colinfo->{data_type};
 260         my $type_name;
 261         if(defined $type_num && $dbh->can('type_info')) {
 262             my $type_info = $dbh->type_info($type_num);
 263             $type_name = $type_info->{TYPE_NAME} if $type_info;
 264             $colinfo->{data_type} = $type_name if $type_name;
 265         }
 266     }
 267
 268     return \%result;
 269 }
 270
 271 # Override this in vendor class to return any additional column
 272 # attributes
 273 sub _extra_column_info {}
 274
 275 =head1 SEE ALSO
 276
 277 L<DBIx::Class::Schema::Loader>
 278
 279 =cut
 280
 281 1;