lib/DBIx/Class/Schema/Loader/DBI.pm

   1 package DBIx::Class::Schema::Loader::DBI;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class::Schema::Loader::Base/;
   6 use Class::C3;
   7 use Carp::Clan qw/^DBIx::Class/;
   8
   9 our $VERSION = '0.08000';
  10
  11 =head1 NAME
  12
  13 DBIx::Class::Schema::Loader::DBI - DBIx::Class::Schema::Loader DBI Implementation.
  14
  15 =head1 SYNOPSIS
  16
  17 See L<DBIx::Class::Schema::Loader::Base>
  18
  19 =head1 DESCRIPTION
  20
  21 This is the base class for L<DBIx::Class::Schema::Loader::Base> classes for
  22 DBI-based storage backends, and implements the common functionality between them.
  23
  24 See L<DBIx::Class::Schema::Loader::Base> for the available options.
  25
  26 =head1 METHODS
  27
  28 =head2 new
  29
  30 Overlays L<DBIx::Class::Schema::Loader::Base/new> to do some DBI-specific
  31 things.
  32
  33 =cut
  34
  35 sub new {
  36     my $self = shift->next::method(@_);
  37
  38     # rebless to vendor-specific class if it exists and loads and we're not in a
  39     # custom class.
  40     if (not $self->loader_class) {
  41         my $dbh = $self->schema->storage->dbh;
  42         my $driver = $dbh->{Driver}->{Name};
  43
  44         my $subclass = 'DBIx::Class::Schema::Loader::DBI::' . $driver;
  45         if ($self->load_optional_class($subclass)) {
  46             bless $self, $subclass unless $self->isa($subclass);
  47             $self->_rebless;
  48         }
  49     }
  50
  51     # Set up the default quoting character and name seperators
  52     $self->{_quoter}  = $self->_build_quoter;
  53     $self->{_namesep} = $self->_build_namesep;
  54
  55     # For our usage as regex matches, concatenating multiple quoter
  56     # values works fine (e.g. s/\Q<>\E// if quoter was [ '<', '>' ])
  57     if( ref $self->{_quoter} eq 'ARRAY') {
  58         $self->{_quoter} = join(q{}, @{$self->{_quoter}});
  59     }
  60
  61     $self->_setup;
  62
  63     $self;
  64 }
  65
  66 sub _build_quoter {
  67     my $self = shift;
  68     my $dbh = $self->schema->storage->dbh;
  69     return $dbh->get_info(29)
  70            || $self->schema->storage->sql_maker->quote_char
  71            || q{"};
  72 }
  73
  74 sub _build_namesep {
  75     my $self = shift;
  76     my $dbh = $self->schema->storage->dbh;
  77     return $dbh->get_info(41)
  78            || $self->schema->storage->sql_maker->name_sep
  79            || q{.};
  80 }
  81
  82 # Override this in vendor modules to do things at the end of ->new()
  83 sub _setup { }
  84
  85 # Override this in vendor module to load a subclass if necessary
  86 sub _rebless { }
  87
  88 # Returns an array of table names
  89 sub _tables_list {
  90     my ($self, $opts) = (shift, shift);
  91
  92     my ($table, $type) = @_ ? @_ : ('%', '%');
  93
  94     my $dbh = $self->schema->storage->dbh;
  95     my @tables = $dbh->tables(undef, $self->db_schema, $table, $type);
  96
  97     my $qt = qr/[\Q$self->{_quoter}\E"'`\[\]]/;
  98
  99     my $all_tables_quoted = (grep /$qt/, @tables) == @tables;
 100
 101     if ($self->{_quoter} && $all_tables_quoted) {
 102         s/.* $qt (?= .* $qt)//xg for @tables;
 103     } else {
 104         s/^.*\Q$self->{_namesep}\E// for @tables;
 105     }
 106     s/$qt//g for @tables;
 107
 108     return $self->_filter_tables(\@tables, $opts);
 109 }
 110
 111 # apply constraint/exclude and ignore bad tables and views
 112 sub _filter_tables {
 113     my ($self, $tables, $opts) = @_;
 114
 115     my @tables = @$tables;
 116     my @filtered_tables;
 117
 118     $opts ||= {};
 119     my $constraint   = $opts->{constraint};
 120     my $exclude      = $opts->{exclude};
 121
 122     @tables = grep { /$constraint/ } @$tables if defined $constraint;
 123     @tables = grep { ! /$exclude/  } @$tables if defined $exclude;
 124
 125     for my $table (@tables) {
 126         eval {
 127             my $sth = $self->_sth_for($table, undef, \'1 = 0');
 128             $sth->execute;
 129         };
 130         if (not $@) {
 131             push @filtered_tables, $table;
 132         }
 133         else {
 134             warn "Bad table or view '$table', ignoring: $@\n";
 135             $self->_unregister_source_for_table($table);
 136         }
 137     }
 138
 139     return @filtered_tables;
 140 }
 141
 142 =head2 load
 143
 144 We override L<DBIx::Class::Schema::Loader::Base/load> here to hook in our localized settings for C<$dbh> error handling.
 145
 146 =cut
 147
 148 sub load {
 149     my $self = shift;
 150
 151     local $self->schema->storage->dbh->{RaiseError} = 1;
 152     local $self->schema->storage->dbh->{PrintError} = 0;
 153     $self->next::method(@_);
 154 }
 155
 156 sub _table_as_sql {
 157     my ($self, $table) = @_;
 158
 159     if($self->{db_schema}) {
 160         $table = $self->{db_schema} . $self->{_namesep} .
 161             $self->_quote_table_name($table);
 162     } else {
 163         $table = $self->_quote_table_name($table);
 164     }
 165
 166     return $table;
 167 }
 168
 169 sub _sth_for {
 170     my ($self, $table, $fields, $where) = @_;
 171
 172     my $dbh = $self->schema->storage->dbh;
 173
 174     my $sth = $dbh->prepare($self->schema->storage->sql_maker
 175         ->select(\$self->_table_as_sql($table), $fields, $where));
 176
 177     return $sth;
 178 }
 179
 180 # Returns an arrayref of column names
 181 sub _table_columns {
 182     my ($self, $table) = @_;
 183
 184     my $sth = $self->_sth_for($table, undef, \'1 = 0');
 185     $sth->execute;
 186     my $retval = $self->preserve_case ? \@{$sth->{NAME}} : \@{$sth->{NAME_lc}};
 187     $sth->finish;
 188
 189     $retval;
 190 }
 191
 192 # Returns arrayref of pk col names
 193 sub _table_pk_info {
 194     my ($self, $table) = @_;
 195
 196     my $dbh = $self->schema->storage->dbh;
 197
 198     my @primary = map { $self->_lc($_) } $dbh->primary_key('', $self->db_schema, $table);
 199     s/\Q$self->{_quoter}\E//g for @primary;
 200
 201     return \@primary;
 202 }
 203
 204 # Override this for vendor-specific uniq info
 205 sub _table_uniq_info {
 206     my ($self, $table) = @_;
 207
 208     my $dbh = $self->schema->storage->dbh;
 209     if(!$dbh->can('statistics_info')) {
 210         warn "No UNIQUE constraint information can be gathered for this vendor";
 211         return [];
 212     }
 213
 214     my %indices;
 215     my $sth = $dbh->statistics_info(undef, $self->db_schema, $table, 1, 1);
 216     while(my $row = $sth->fetchrow_hashref) {
 217         # skip table-level stats, conditional indexes, and any index missing
 218         #  critical fields
 219         next if $row->{TYPE} eq 'table'
 220             || defined $row->{FILTER_CONDITION}
 221             || !$row->{INDEX_NAME}
 222             || !defined $row->{ORDINAL_POSITION}
 223             || !$row->{COLUMN_NAME};
 224
 225         $indices{$row->{INDEX_NAME}}->{$row->{ORDINAL_POSITION}} = $row->{COLUMN_NAME};
 226     }
 227     $sth->finish;
 228
 229     my @retval;
 230     foreach my $index_name (keys %indices) {
 231         my $index = $indices{$index_name};
 232         push(@retval, [ $index_name => [
 233             map { $index->{$_} }
 234                 sort keys %$index
 235         ]]);
 236     }
 237
 238     return \@retval;
 239 }
 240
 241 # Find relationships
 242 sub _table_fk_info {
 243     my ($self, $table) = @_;
 244
 245     my $dbh = $self->schema->storage->dbh;
 246     my $sth = $dbh->foreign_key_info( '', $self->db_schema, '',
 247                                       '', $self->db_schema, $table );
 248     return [] if !$sth;
 249
 250     my %rels;
 251
 252     my $i = 1; # for unnamed rels, which hopefully have only 1 column ...
 253     while(my $raw_rel = $sth->fetchrow_arrayref) {
 254         my $uk_tbl  = $raw_rel->[2];
 255         my $uk_col  = $self->_lc($raw_rel->[3]);
 256         my $fk_col  = $self->_lc($raw_rel->[7]);
 257         my $relid   = ($raw_rel->[11] || ( "__dcsld__" . $i++ ));
 258         $uk_tbl =~ s/\Q$self->{_quoter}\E//g;
 259         $uk_col =~ s/\Q$self->{_quoter}\E//g;
 260         $fk_col =~ s/\Q$self->{_quoter}\E//g;
 261         $relid  =~ s/\Q$self->{_quoter}\E//g;
 262         $rels{$relid}->{tbl} = $uk_tbl;
 263         $rels{$relid}->{cols}{$uk_col} = $fk_col;
 264     }
 265     $sth->finish;
 266
 267     my @rels;
 268     foreach my $relid (keys %rels) {
 269         push(@rels, {
 270             remote_columns => [ keys   %{$rels{$relid}->{cols}} ],
 271             local_columns  => [ values %{$rels{$relid}->{cols}} ],
 272             remote_table   => $rels{$relid}->{tbl},
 273         });
 274     }
 275
 276     return \@rels;
 277 }
 278
 279 # ported in from DBIx::Class::Storage::DBI:
 280 sub _columns_info_for {
 281     my ($self, $table) = @_;
 282
 283     my $dbh = $self->schema->storage->dbh;
 284
 285     if ($dbh->can('column_info')) {
 286         my %result;
 287         eval {
 288             my $sth = eval { local $SIG{__WARN__} = sub {}; $dbh->column_info( undef, $self->db_schema, $table, '%' ); };
 289             while ( my $info = $sth->fetchrow_hashref() ){
 290                 my $column_info = {};
 291                 $column_info->{data_type}     = lc $info->{TYPE_NAME};
 292
 293                 my $size = $info->{COLUMN_SIZE};
 294
 295                 if (defined $size && defined $info->{DECIMAL_DIGITS}) {
 296                     $column_info->{size} = [$size, $info->{DECIMAL_DIGITS}];
 297                 }
 298                 elsif (defined $size) {
 299                     $column_info->{size} = $size;
 300                 }
 301
 302                 $column_info->{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
 303                 $column_info->{default_value} = $info->{COLUMN_DEF} if defined $info->{COLUMN_DEF};
 304                 my $col_name = $info->{COLUMN_NAME};
 305                 $col_name =~ s/^\"(.*)\"$/$1/;
 306
 307                 my $extra_info = $self->_extra_column_info(
 308                     $table, $col_name, $column_info, $info
 309                 ) || {};
 310                 $column_info = { %$column_info, %$extra_info };
 311
 312                 $result{$col_name} = $column_info;
 313             }
 314             $sth->finish;
 315         };
 316       return \%result if !$@ && scalar keys %result;
 317     }
 318
 319     my %result;
 320     my $sth = $self->_sth_for($table, undef, \'1 = 0');
 321     $sth->execute;
 322     my @columns = @{ $self->preserve_case ? $sth->{NAME} : $sth->{NAME_lc} };
 323     for my $i ( 0 .. $#columns ){
 324         my $column_info = {};
 325         $column_info->{data_type} = lc $sth->{TYPE}->[$i];
 326
 327         my $size = $sth->{PRECISION}[$i];
 328
 329         if (defined $size && defined $sth->{SCALE}[$i]) {
 330             $column_info->{size} = [$size, $sth->{SCALE}[$i]];
 331         }
 332         elsif (defined $size) {
 333             $column_info->{size} = $size;
 334         }
 335
 336         $column_info->{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
 337
 338         if ($column_info->{data_type} =~ m/^(.*?)\((.*?)\)$/) {
 339             $column_info->{data_type} = $1;
 340             $column_info->{size}    = $2;
 341         }
 342
 343         my $extra_info = $self->_extra_column_info($table, $columns[$i], $column_info) || {};
 344         $column_info = { %$column_info, %$extra_info };
 345
 346         $result{$columns[$i]} = $column_info;
 347     }
 348     $sth->finish;
 349
 350     foreach my $col (keys %result) {
 351         my $colinfo = $result{$col};
 352         my $type_num = $colinfo->{data_type};
 353         my $type_name;
 354         if(defined $type_num && $type_num =~ /^\d+\z/ && $dbh->can('type_info')) {
 355             my $type_info = $dbh->type_info($type_num);
 356             $type_name = $type_info->{TYPE_NAME} if $type_info;
 357             $colinfo->{data_type} = lc $type_name if $type_name;
 358         }
 359     }
 360
 361     return \%result;
 362 }
 363
 364 # Override this in vendor class to return any additional column
 365 # attributes
 366 sub _extra_column_info {}
 367
 368 =head1 SEE ALSO
 369
 370 L<DBIx::Class::Schema::Loader>
 371
 372 =head1 AUTHOR
 373
 374 See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
 375
 376 =head1 LICENSE
 377
 378 This library is free software; you can redistribute it and/or modify it under
 379 the same terms as Perl itself.
 380
 381 =cut
 382
 383 1;
 384 # vim:et sts=4 sw=4 tw=0: