lib/DBIx/Class/Schema/Loader/DBI.pm

   1 package DBIx::Class::Schema::Loader::DBI;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class::Schema::Loader::Base/;
   6 use mro 'c3';
   7 use Try::Tiny;
   8 use List::MoreUtils 'any';
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use namespace::clean;
  11 use DBIx::Class::Schema::Loader::Table ();
  12
  13 our $VERSION = '0.07040';
  14
  15 __PACKAGE__->mk_group_accessors('simple', qw/
  16     _disable_pk_detection
  17     _disable_uniq_detection
  18     _disable_fk_detection
  19     _passwords
  20     quote_char
  21     name_sep
  22 /);
  23
  24 =head1 NAME
  25
  26 DBIx::Class::Schema::Loader::DBI - DBIx::Class::Schema::Loader DBI Implementation.
  27
  28 =head1 SYNOPSIS
  29
  30 See L<DBIx::Class::Schema::Loader::Base>
  31
  32 =head1 DESCRIPTION
  33
  34 This is the base class for L<DBIx::Class::Schema::Loader::Base> classes for
  35 DBI-based storage backends, and implements the common functionality between them.
  36
  37 See L<DBIx::Class::Schema::Loader::Base> for the available options.
  38
  39 =head1 METHODS
  40
  41 =head2 new
  42
  43 Overlays L<DBIx::Class::Schema::Loader::Base/new> to do some DBI-specific
  44 things.
  45
  46 =cut
  47
  48 sub new {
  49     my $self = shift->next::method(@_);
  50
  51     # rebless to vendor-specific class if it exists and loads and we're not in a
  52     # custom class.
  53     if (not $self->loader_class) {
  54         my $driver = $self->dbh->{Driver}->{Name};
  55
  56         my $subclass = 'DBIx::Class::Schema::Loader::DBI::' . $driver;
  57         if ((not $self->isa($subclass)) && $self->load_optional_class($subclass)) {
  58             bless $self, $subclass;
  59             $self->_rebless;
  60             Class::C3::reinitialize() if $] < 5.009005;
  61         }
  62     }
  63
  64     # Set up the default quoting character and name separators
  65     $self->quote_char($self->_build_quote_char);
  66     $self->name_sep($self->_build_name_sep);
  67
  68     $self->_setup;
  69
  70     return $self;
  71 }
  72
  73 sub _build_quote_char {
  74     my $self = shift;
  75
  76     my $quote_char = $self->dbh->get_info(29)
  77            || $self->schema->storage->sql_maker->quote_char
  78            || q{"};
  79
  80     # For our usage as regex matches, concatenating multiple quote_char
  81     # values works fine (e.g. s/[\Q<>\E]// if quote_char was [ '<', '>' ])
  82     if (ref $quote_char eq 'ARRAY') {
  83         $quote_char = join '', @$quote_char;
  84     }
  85
  86     return $quote_char;
  87 }
  88
  89 sub _build_name_sep {
  90     my $self = shift;
  91     return $self->dbh->get_info(41)
  92            || $self->schema->storage->sql_maker->name_sep
  93            || '.';
  94 }
  95
  96 # Override this in vendor modules to do things at the end of ->new()
  97 sub _setup { }
  98
  99 # Override this in vendor module to load a subclass if necessary
 100 sub _rebless { }
 101
 102 sub _system_schemas {
 103     return ('information_schema');
 104 }
 105
 106 sub _system_tables {
 107     return ();
 108 }
 109
 110 sub _dbh_tables {
 111     my ($self, $schema) = (shift, shift);
 112
 113     my ($table_pattern, $table_type_pattern) = @_ ? @_ : ('%', '%');
 114
 115     return $self->dbh->tables(undef, $schema, $table_pattern, $table_type_pattern);
 116 }
 117
 118 # default to be overridden in subclasses if necessary
 119 sub _supports_db_schema { 1 }
 120
 121 # Returns an array of table objects
 122 sub _tables_list {
 123     my ($self, $opts) = (shift, shift);
 124
 125     my @tables;
 126
 127     my $qt  = qr/[\Q$self->{quote_char}\E"'`\[\]]/;
 128     my $nqt = qr/[^\Q$self->{quote_char}\E"'`\[\]]/;
 129     my $ns  = qr/[\Q$self->{name_sep}\E]/;
 130     my $nns = qr/[^\Q$self->{name_sep}\E]/;
 131
 132     foreach my $schema (@{ $self->db_schema || [undef] }) {
 133         my @raw_table_names = $self->_dbh_tables($schema, @_);
 134
 135         TABLE: foreach my $raw_table_name (@raw_table_names) {
 136             my $quoted = $raw_table_name =~ /^$qt/;
 137
 138             # These regexes are not entirely correct, but hopefully they will work
 139             # in most cases. RT reports welcome.
 140             my ($schema_name, $table_name1, $table_name2) = $quoted ?
 141                 $raw_table_name =~ /^(?:${qt}(${nqt}+?)${qt}${ns})?(?:${qt}(.+?)${qt}|(${nns}+))\z/
 142                 :
 143                 $raw_table_name =~ /^(?:(${nns}+?)${ns})?(?:${qt}(.+?)${qt}|(${nns}+))\z/;
 144
 145             my $table_name = $table_name1 || $table_name2;
 146
 147             foreach my $system_schema ($self->_system_schemas) {
 148                 if ($schema_name) {
 149                     my $matches = 0;
 150
 151                     if (ref $system_schema) {
 152                         $matches = 1
 153                             if $schema_name =~ $system_schema
 154                                  && $schema !~ $system_schema;
 155                     }
 156                     else {
 157                         $matches = 1
 158                             if $schema_name eq $system_schema
 159                                 && $schema  ne $system_schema;
 160                     }
 161
 162                     next TABLE if $matches;
 163                 }
 164             }
 165
 166             foreach my $system_table ($self->_system_tables) {
 167                 my $matches = 0;
 168
 169                 if (ref $system_table) {
 170                     $matches = 1 if $table_name =~ $system_table;
 171                 }
 172                 else {
 173                     $matches = 1 if $table_name eq $system_table
 174                 }
 175
 176                 next TABLE if $matches;
 177             }
 178
 179             $schema_name ||= $schema;
 180
 181             my $table = DBIx::Class::Schema::Loader::Table->new(
 182                 loader => $self,
 183                 name   => $table_name,
 184                 schema => $schema_name,
 185                 ($self->_supports_db_schema ? () : (
 186                     ignore_schema => 1
 187                 )),
 188             );
 189
 190             push @tables, $table;
 191         }
 192     }
 193
 194     return $self->_filter_tables(\@tables, $opts);
 195 }
 196
 197 sub _recurse_constraint {
 198     my ($constraint, @parts) = @_;
 199
 200     my $name = shift @parts;
 201
 202     # If there are any parts left, the constraint must be an arrayref
 203     croak "depth of constraint/exclude array does not match length of moniker_parts"
 204         unless !!@parts == !!(ref $constraint eq 'ARRAY');
 205
 206     # if ths is the last part, use the constraint directly
 207     return $name =~ $constraint unless @parts;
 208
 209     # recurse into the first matching subconstraint
 210     foreach (@{$constraint}) {
 211         my ($re, $sub) = @{$_};
 212         return _recurse_constraint($sub, @parts)
 213             if $name =~ $re;
 214     }
 215     return 0;
 216 }
 217
 218 sub _check_constraint {
 219     my ($include, $constraint, @tables) = @_;
 220
 221     return @tables unless defined $constraint;
 222
 223     return grep { !$include xor _recurse_constraint($constraint, @{$_}) } @tables
 224         if ref $constraint eq 'ARRAY';
 225
 226     return grep { !$include xor /$constraint/ } @tables;
 227 }
 228
 229
 230
 231 # apply constraint/exclude and ignore bad tables and views
 232 sub _filter_tables {
 233     my ($self, $tables, $opts) = @_;
 234
 235     my @tables = @$tables;
 236     my @filtered_tables;
 237
 238     $opts ||= {};
 239     @tables = _check_constraint(1, $opts->{constraint}, @tables);
 240     @tables = _check_constraint(0, $opts->{exclude}, @tables);
 241
 242     TABLE: for my $table (@tables) {
 243         try {
 244             local $^W = 0; # for ADO
 245             my $sth = $self->_sth_for($table, undef, \'1 = 0');
 246             $sth->execute;
 247             1;
 248         }
 249         catch {
 250             warn "Bad table or view '$table', ignoring: $_\n";
 251             0;
 252         } or next TABLE;
 253
 254         push @filtered_tables, $table;
 255     }
 256
 257     return @filtered_tables;
 258 }
 259
 260 =head2 load
 261
 262 We override L<DBIx::Class::Schema::Loader::Base/load> here to hook in our localized settings for C<$dbh> error handling.
 263
 264 =cut
 265
 266 sub load {
 267     my $self = shift;
 268
 269     local $self->dbh->{RaiseError} = 1;
 270     local $self->dbh->{PrintError} = 0;
 271
 272     $self->next::method(@_);
 273
 274     $self->schema->storage->disconnect unless $self->dynamic;
 275 }
 276
 277 sub _sth_for {
 278     my ($self, $table, $fields, $where) = @_;
 279
 280     my $sth = $self->dbh->prepare($self->schema->storage->sql_maker
 281         ->select(\$table->sql_name, $fields, $where));
 282
 283     return $sth;
 284 }
 285
 286 # Returns an arrayref of column names
 287 sub _table_columns {
 288     my ($self, $table) = @_;
 289
 290     my $sth = $self->_sth_for($table, undef, \'1 = 0');
 291     $sth->execute;
 292
 293     my $retval = [ map $self->_lc($_), @{$sth->{NAME}} ];
 294
 295     $sth->finish;
 296
 297     return $retval;
 298 }
 299
 300 # Returns arrayref of pk col names
 301 sub _table_pk_info {
 302     my ($self, $table) = @_;
 303
 304     return [] if $self->_disable_pk_detection;
 305
 306     my @primary = try {
 307         $self->dbh->primary_key('', $table->schema, $table->name);
 308     }
 309     catch {
 310         warn "Cannot find primary keys for this driver: $_";
 311         $self->_disable_pk_detection(1);
 312         return ();
 313     };
 314
 315     return [] if not @primary;
 316
 317     @primary = map { $self->_lc($_) } @primary;
 318     s/[\Q$self->{quote_char}\E]//g for @primary;
 319
 320     return \@primary;
 321 }
 322
 323 # Override this for vendor-specific uniq info
 324 sub _table_uniq_info {
 325     my ($self, $table) = @_;
 326
 327     return [] if $self->_disable_uniq_detection;
 328
 329     if (not $self->dbh->can('statistics_info')) {
 330         warn "No UNIQUE constraint information can be gathered for this driver";
 331         $self->_disable_uniq_detection(1);
 332         return [];
 333     }
 334
 335     my %indices;
 336     my $sth = $self->dbh->statistics_info(undef, $table->schema, $table->name, 1, 1);
 337     while(my $row = $sth->fetchrow_hashref) {
 338         # skip table-level stats, conditional indexes, and any index missing
 339         #  critical fields
 340         next if $row->{TYPE} eq 'table'
 341             || defined $row->{FILTER_CONDITION}
 342             || !$row->{INDEX_NAME}
 343             || !defined $row->{ORDINAL_POSITION};
 344
 345         $indices{$row->{INDEX_NAME}}[$row->{ORDINAL_POSITION}] = $self->_lc($row->{COLUMN_NAME} || '');
 346     }
 347     $sth->finish;
 348
 349     my @retval;
 350     foreach my $index_name (sort keys %indices) {
 351         my (undef, @cols) = @{$indices{$index_name}};
 352         # skip indexes with missing column names (e.g. expression indexes)
 353         next unless @cols == grep $_, @cols;
 354         push(@retval, [ $index_name => \@cols ]);
 355     }
 356
 357     return \@retval;
 358 }
 359
 360 sub _table_comment {
 361     my ($self, $table) = @_;
 362     my $dbh = $self->dbh;
 363
 364     my $comments_table = $table->clone;
 365     $comments_table->name($self->table_comments_table);
 366
 367     my ($comment) =
 368         (exists $self->_tables->{$comments_table->sql_name} || undef)
 369         && try { $dbh->selectrow_array(<<"EOF") };
 370 SELECT comment_text
 371 FROM @{[ $comments_table->sql_name ]}
 372 WHERE table_name = @{[ $dbh->quote($table->name) ]}
 373 EOF
 374
 375     # Failback: try the REMARKS column on table_info
 376     if (!$comment) {
 377         my $info = $self->_dbh_table_info( $dbh, $table );
 378         $comment = $info->{REMARKS} if $info;
 379     }
 380
 381     return $comment;
 382 }
 383
 384 sub _column_comment {
 385     my ($self, $table, $column_number, $column_name) = @_;
 386     my $dbh = $self->dbh;
 387
 388     my $comments_table = $table->clone;
 389     $comments_table->name($self->column_comments_table);
 390
 391     my ($comment) =
 392         (exists $self->_tables->{$comments_table->sql_name} || undef)
 393         && try { $dbh->selectrow_array(<<"EOF") };
 394 SELECT comment_text
 395 FROM @{[ $comments_table->sql_name ]}
 396 WHERE table_name = @{[ $dbh->quote($table->name) ]}
 397 AND column_name = @{[ $dbh->quote($column_name) ]}
 398 EOF
 399
 400     # Failback: try the REMARKS column on column_info
 401     if (!$comment && $dbh->can('column_info')) {
 402         if (my $sth = try { $self->_dbh_column_info( $dbh, undef, $table->schema, $table->name, $column_name ) }) {
 403             my $info = $sth->fetchrow_hashref();
 404             $comment = $info->{REMARKS};
 405         }
 406     }
 407
 408     return $comment;
 409 }
 410
 411 # Find relationships
 412 sub _table_fk_info {
 413     my ($self, $table) = @_;
 414
 415     return [] if $self->_disable_fk_detection;
 416
 417     my $sth = try {
 418         $self->dbh->foreign_key_info( '', '', '',
 419                                 '', ($table->schema || ''), $table->name );
 420     }
 421     catch {
 422         warn "Cannot introspect relationships for this driver: $_";
 423         $self->_disable_fk_detection(1);
 424         return undef;
 425     };
 426
 427     return [] if !$sth;
 428
 429     my %rels;
 430
 431     my @rules = (
 432         'CASCADE',
 433         'RESTRICT',
 434         'SET NULL',
 435         'NO ACTION',
 436         'SET DEFAULT',
 437     );
 438
 439     my $i = 1; # for unnamed rels, which hopefully have only 1 column ...
 440     REL: while(my $raw_rel = $sth->fetchrow_arrayref) {
 441         my $uk_scm  = $raw_rel->[1];
 442         my $uk_tbl  = $raw_rel->[2];
 443         my $uk_col  = $self->_lc($raw_rel->[3]);
 444         my $fk_scm  = $raw_rel->[5];
 445         my $fk_col  = $self->_lc($raw_rel->[7]);
 446         my $key_seq = $raw_rel->[8] - 1;
 447         my $relid   = ($raw_rel->[11] || ( "__dcsld__" . $i++ ));
 448
 449         my $update_rule = $raw_rel->[9];
 450         my $delete_rule = $raw_rel->[10];
 451
 452         $update_rule = $rules[$update_rule] if defined $update_rule;
 453         $delete_rule = $rules[$delete_rule] if defined $delete_rule;
 454
 455         my $is_deferrable = $raw_rel->[13];
 456
 457         ($is_deferrable = $is_deferrable == 7 ? 0 : 1)
 458             if defined $is_deferrable;
 459
 460         foreach my $var ($uk_scm, $uk_tbl, $uk_col, $fk_scm, $fk_col, $relid) {
 461             $var =~ s/[\Q$self->{quote_char}\E]//g if defined $var;
 462         }
 463
 464         if ($self->db_schema && $self->db_schema->[0] ne '%'
 465             && (not any { $_ eq $uk_scm } @{ $self->db_schema })) {
 466
 467             next REL;
 468         }
 469
 470         $rels{$relid}{tbl} ||= DBIx::Class::Schema::Loader::Table->new(
 471             loader => $self,
 472             name   => $uk_tbl,
 473             schema => $uk_scm,
 474             ($self->_supports_db_schema ? () : (
 475                 ignore_schema => 1
 476             )),
 477         );
 478
 479         $rels{$relid}{attrs}{on_delete}     = $delete_rule if $delete_rule;
 480         $rels{$relid}{attrs}{on_update}     = $update_rule if $update_rule;
 481         $rels{$relid}{attrs}{is_deferrable} = $is_deferrable if defined $is_deferrable;
 482
 483         # Add this data IN ORDER
 484         $rels{$relid}{rcols}[$key_seq] = $uk_col;
 485         $rels{$relid}{lcols}[$key_seq] = $fk_col;
 486     }
 487     $sth->finish;
 488
 489     my @rels;
 490     foreach my $relid (keys %rels) {
 491         push(@rels, {
 492             remote_columns => [ grep defined, @{ $rels{$relid}{rcols} } ],
 493             local_columns  => [ grep defined, @{ $rels{$relid}{lcols} } ],
 494             remote_table   => $rels{$relid}->{tbl},
 495             (exists $rels{$relid}{attrs} ?
 496                 (attrs => $rels{$relid}{attrs})
 497                 :
 498                 ()
 499             ),
 500             _constraint_name => $relid,
 501         });
 502     }
 503
 504     return \@rels;
 505 }
 506
 507 # ported in from DBIx::Class::Storage::DBI:
 508 sub _columns_info_for {
 509     my ($self, $table) = @_;
 510
 511     my $dbh = $self->schema->storage->dbh;
 512
 513     my %result;
 514
 515     if (my $sth = try { $self->_dbh_column_info($dbh, undef, $table->schema, $table->name, '%' ) }) {
 516         COL_INFO: while (my $info = try { $sth->fetchrow_hashref } catch { +{} }) {
 517             next COL_INFO unless %$info;
 518
 519             my $column_info = {};
 520             $column_info->{data_type}     = lc $info->{TYPE_NAME};
 521
 522             my $size = $info->{COLUMN_SIZE};
 523
 524             if (defined $size && defined $info->{DECIMAL_DIGITS}) {
 525                 $column_info->{size} = [$size, $info->{DECIMAL_DIGITS}];
 526             }
 527             elsif (defined $size) {
 528                 $column_info->{size} = $size;
 529             }
 530
 531             $column_info->{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
 532             $column_info->{default_value} = $info->{COLUMN_DEF} if defined $info->{COLUMN_DEF};
 533             my $col_name = $info->{COLUMN_NAME};
 534             $col_name =~ s/^\"(.*)\"$/$1/;
 535
 536             my $extra_info = $self->_extra_column_info(
 537                 $table, $col_name, $column_info, $info
 538             ) || {};
 539             $column_info = { %$column_info, %$extra_info };
 540
 541             $result{$col_name} = $column_info;
 542         }
 543         $sth->finish;
 544     }
 545
 546     my $sth = $self->_sth_for($table, undef, \'1 = 0');
 547     $sth->execute;
 548
 549     my @columns = @{ $sth->{NAME} };
 550
 551     COL: for my $i (0 .. $#columns) {
 552         next COL if %{ $result{ $columns[$i] }||{} };
 553
 554         my $column_info = {};
 555         $column_info->{data_type} = lc $sth->{TYPE}[$i];
 556
 557         my $size = $sth->{PRECISION}[$i];
 558
 559         if (defined $size && defined $sth->{SCALE}[$i]) {
 560             $column_info->{size} = [$size, $sth->{SCALE}[$i]];
 561         }
 562         elsif (defined $size) {
 563             $column_info->{size} = $size;
 564         }
 565
 566         $column_info->{is_nullable} = $sth->{NULLABLE}[$i] ? 1 : 0;
 567
 568         if ($column_info->{data_type} =~ m/^(.*?)\((.*?)\)$/) {
 569             $column_info->{data_type} = $1;
 570             $column_info->{size}    = $2;
 571         }
 572
 573         my $extra_info = $self->_extra_column_info($table, $columns[$i], $column_info, $sth) || {};
 574         $column_info = { %$column_info, %$extra_info };
 575
 576         $result{ $columns[$i] } = $column_info;
 577     }
 578     $sth->finish;
 579
 580     foreach my $col (keys %result) {
 581         my $colinfo = $result{$col};
 582         my $type_num = $colinfo->{data_type};
 583         my $type_name;
 584         if (defined $type_num && $type_num =~ /^-?\d+\z/ && $dbh->can('type_info')) {
 585             my $type_name = $self->_dbh_type_info_type_name($type_num);
 586             $colinfo->{data_type} = lc $type_name if $type_name;
 587         }
 588     }
 589
 590     # check for instances of the same column name with different case in preserve_case=0 mode
 591     if (not $self->preserve_case) {
 592         my %lc_colnames;
 593
 594         foreach my $col (keys %result) {
 595             push @{ $lc_colnames{lc $col} }, $col;
 596         }
 597
 598         if (keys %lc_colnames != keys %result) {
 599             my @offending_colnames = map @$_, grep @$_ > 1, values %lc_colnames;
 600
 601             my $offending_colnames = join ", ", map "'$_'", @offending_colnames;
 602
 603             croak "columns $offending_colnames in table @{[ $table->sql_name ]} collide in preserve_case=0 mode. preserve_case=1 mode required";
 604         }
 605
 606         # apply lowercasing
 607         my %lc_result;
 608
 609         while (my ($col, $info) = each %result) {
 610             $lc_result{ $self->_lc($col) } = $info;
 611         }
 612
 613         %result = %lc_result;
 614     }
 615
 616     return \%result;
 617 }
 618
 619 # Need to override this for the buggy Firebird ODBC driver.
 620 sub _dbh_type_info_type_name {
 621     my ($self, $type_num) = @_;
 622
 623     # We wrap it in a try block for MSSQL+DBD::Sybase, which can have issues.
 624     # TODO investigate further
 625     my $type_info = try { $self->dbh->type_info($type_num) };
 626
 627     return $type_info ? $type_info->{TYPE_NAME} : undef;
 628 }
 629
 630 # do not use this, override _columns_info_for instead
 631 sub _extra_column_info {}
 632
 633 # override to mask warnings if needed
 634 sub _dbh_table_info {
 635     my ($self, $dbh, $table) = (shift, shift, shift);
 636
 637     return undef if !$dbh->can('table_info');
 638     my $sth = $dbh->table_info(undef, $table->schema, $table->name);
 639     while (my $info = $sth->fetchrow_hashref) {
 640         next if !$self->_table_info_matches($table, $info);
 641         return $info;
 642     }
 643     return undef;
 644 }
 645
 646 sub _table_info_matches {
 647     my ($self, $table, $info) = @_;
 648
 649     no warnings 'uninitialized';
 650     return $info->{TABLE_SCHEM} eq $table->schema
 651         && $info->{TABLE_NAME}  eq $table->name;
 652 }
 653
 654 # override to mask warnings if needed (see mysql)
 655 sub _dbh_column_info {
 656     my ($self, $dbh) = (shift, shift);
 657
 658     return $dbh->column_info(@_);
 659 }
 660
 661 # If a coderef uses DBI->connect, this should get its connect info.
 662 sub _try_infer_connect_info_from_coderef {
 663     my ($self, $code) = @_;
 664
 665     my ($dsn, $user, $pass, $params);
 666
 667     no warnings 'redefine';
 668
 669     local *DBI::connect = sub {
 670         (undef, $dsn, $user, $pass, $params) = @_;
 671     };
 672
 673     $code->();
 674
 675     return ($dsn, $user, $pass, $params);
 676 }
 677
 678 sub dbh {
 679     my $self = shift;
 680
 681     return $self->schema->storage->dbh;
 682 }
 683
 684 sub _table_is_view {
 685     my ($self, $table) = @_;
 686
 687     my $info = $self->_dbh_table_info($self->dbh, $table)
 688         or return 0;
 689     return $info->{TABLE_TYPE} eq 'VIEW';
 690 }
 691
 692 =head1 SEE ALSO
 693
 694 L<DBIx::Class::Schema::Loader>
 695
 696 =head1 AUTHOR
 697
 698 See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
 699
 700 =head1 LICENSE
 701
 702 This library is free software; you can redistribute it and/or modify it under
 703 the same terms as Perl itself.
 704
 705 =cut
 706
 707 1;
 708 # vim:et sts=4 sw=4 tw=0: