lib/DBIx/Class/Schema/Loader/DBI.pm

   1 package DBIx::Class::Schema::Loader::DBI;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class::Schema::Loader::Base/;
   6 use Class::C3;
   7 use Carp::Clan qw/^DBIx::Class/;
   8
   9 our $VERSION = '0.05002';
  10
  11 =head1 NAME
  12
  13 DBIx::Class::Schema::Loader::DBI - DBIx::Class::Schema::Loader DBI Implementation.
  14
  15 =head1 SYNOPSIS
  16
  17 See L<DBIx::Class::Schema::Loader::Base>
  18
  19 =head1 DESCRIPTION
  20
  21 This is the base class for L<DBIx::Class::Schema::Loader::Base> classes for
  22 DBI-based storage backends, and implements the common functionality between them.
  23
  24 See L<DBIx::Class::Schema::Loader::Base> for the available options.
  25
  26 =head1 METHODS
  27
  28 =head2 new
  29
  30 Overlays L<DBIx::Class::Schema::Loader::Base/new> to do some DBI-specific
  31 things.
  32
  33 =cut
  34
  35 sub new {
  36     my $self = shift->next::method(@_);
  37
  38     # rebless to vendor-specific class if it exists and loads
  39     my $dbh = $self->schema->storage->dbh;
  40     my $driver = $dbh->{Driver}->{Name};
  41
  42     my $subclass = 'DBIx::Class::Schema::Loader::DBI::' . $driver;
  43     if ($self->load_optional_class($subclass)) {
  44         bless $self, $subclass unless $self->isa($subclass);
  45         $self->_rebless;
  46     }
  47
  48     # Set up the default quoting character and name seperators
  49     $self->{_quoter} = $self->_build_quoter;
  50     $self->{_namesep} = $self->_build_namesep;
  51     # For our usage as regex matches, concatenating multiple quoter
  52     # values works fine (e.g. s/\Q<>\E// if quoter was [ '<', '>' ])
  53     if( ref $self->{_quoter} eq 'ARRAY') {
  54         $self->{_quoter} = join(q{}, @{$self->{_quoter}});
  55     }
  56
  57     $self->_setup;
  58
  59     $self;
  60 }
  61
  62 sub _build_quoter {
  63     my $self = shift;
  64     my $dbh = $self->schema->storage->dbh;
  65     return $dbh->get_info(29)
  66            || $self->schema->storage->sql_maker->quote_char
  67            || q{"};
  68 }
  69
  70 sub _build_namesep {
  71     my $self = shift;
  72     my $dbh = $self->schema->storage->dbh;
  73     return $dbh->get_info(41)
  74            || $self->schema->storage->sql_maker->name_sep
  75            || q{.};
  76 }
  77
  78 # Override this in vendor modules to do things at the end of ->new()
  79 sub _setup { }
  80
  81 # Override this in vendor module to load a subclass if necessary
  82 sub _rebless { }
  83
  84 # Returns an array of table names
  85 sub _tables_list {
  86     my $self = shift;
  87
  88     my ($table, $type) = @_ ? @_ : ('%', '%');
  89
  90     my $dbh = $self->schema->storage->dbh;
  91     my @tables = $dbh->tables(undef, $self->db_schema, $table, $type);
  92
  93     my $qt = qr/[\Q$self->{_quoter}\E"'`\[\]]/;
  94
  95     my $all_tables_quoted = (grep /$qt/, @tables) == @tables;
  96
  97     if ($self->{_quoter} && $all_tables_quoted) {
  98         s/.* $qt (?= .* $qt)//xg for @tables;
  99     } else {
 100         s/^.*\Q$self->{_namesep}\E// for @tables;
 101     }
 102     s/$qt//g for @tables;
 103
 104     return $self->_filter_tables(@tables);
 105 }
 106
 107 # ignore bad tables and views
 108 sub _filter_tables {
 109     my ($self, @tables) = @_;
 110
 111     my @filtered_tables;
 112
 113     for my $table (@tables) {
 114         eval {
 115             my $sth = $self->_sth_for($table, undef, \'1 = 0');
 116             $sth->execute;
 117         };
 118         if (not $@) {
 119             push @filtered_tables, $table;
 120         }
 121         else {
 122             warn "Bad table or view '$table', ignoring: $@\n";
 123             local $@;
 124             eval {
 125                 my $schema = $self->schema;
 126                 # in older DBIC it's a private method
 127                 my $unregister = $schema->can('unregister_source')
 128                     || $schema->can('_unregister_source');
 129                 $schema->$unregister($self->_table2moniker($table));
 130             };
 131         }
 132     }
 133
 134     return @filtered_tables;
 135 }
 136
 137 =head2 load
 138
 139 We override L<DBIx::Class::Schema::Loader::Base/load> here to hook in our localized settings for C<$dbh> error handling.
 140
 141 =cut
 142
 143 sub load {
 144     my $self = shift;
 145
 146     local $self->schema->storage->dbh->{RaiseError} = 1;
 147     local $self->schema->storage->dbh->{PrintError} = 0;
 148     $self->next::method(@_);
 149 }
 150
 151 sub _table_as_sql {
 152     my ($self, $table) = @_;
 153
 154     if($self->{db_schema}) {
 155         $table = $self->{db_schema} . $self->{_namesep} .
 156             $self->_quote_table_name($table);
 157     } else {
 158         $table = $self->_quote_table_name($table);
 159     }
 160
 161     return $table;
 162 }
 163
 164 sub _sth_for {
 165     my ($self, $table, $fields, $where) = @_;
 166
 167     my $dbh = $self->schema->storage->dbh;
 168
 169     my $sth = $dbh->prepare($self->schema->storage->sql_maker
 170         ->select(\$self->_table_as_sql($table), $fields, $where));
 171
 172     return $sth;
 173 }
 174
 175 # Returns an arrayref of column names
 176 sub _table_columns {
 177     my ($self, $table) = @_;
 178
 179     my $sth = $self->_sth_for($table, undef, \'1 = 0');
 180     $sth->execute;
 181     my $retval = \@{$sth->{NAME_lc}};
 182     $sth->finish;
 183
 184     $retval;
 185 }
 186
 187 # Returns arrayref of pk col names
 188 sub _table_pk_info {
 189     my ($self, $table) = @_;
 190
 191     my $dbh = $self->schema->storage->dbh;
 192
 193     my @primary = map { lc } $dbh->primary_key('', $self->db_schema, $table);
 194     s/\Q$self->{_quoter}\E//g for @primary;
 195
 196     return \@primary;
 197 }
 198
 199 # Override this for vendor-specific uniq info
 200 sub _table_uniq_info {
 201     my ($self, $table) = @_;
 202
 203     my $dbh = $self->schema->storage->dbh;
 204     if(!$dbh->can('statistics_info')) {
 205         warn "No UNIQUE constraint information can be gathered for this vendor";
 206         return [];
 207     }
 208
 209     my %indices;
 210     my $sth = $dbh->statistics_info(undef, $self->db_schema, $table, 1, 1);
 211     while(my $row = $sth->fetchrow_hashref) {
 212         # skip table-level stats, conditional indexes, and any index missing
 213         #  critical fields
 214         next if $row->{TYPE} eq 'table'
 215             || defined $row->{FILTER_CONDITION}
 216             || !$row->{INDEX_NAME}
 217             || !defined $row->{ORDINAL_POSITION}
 218             || !$row->{COLUMN_NAME};
 219
 220         $indices{$row->{INDEX_NAME}}->{$row->{ORDINAL_POSITION}} = $row->{COLUMN_NAME};
 221     }
 222     $sth->finish;
 223
 224     my @retval;
 225     foreach my $index_name (keys %indices) {
 226         my $index = $indices{$index_name};
 227         push(@retval, [ $index_name => [
 228             map { $index->{$_} }
 229                 sort keys %$index
 230         ]]);
 231     }
 232
 233     return \@retval;
 234 }
 235
 236 # Find relationships
 237 sub _table_fk_info {
 238     my ($self, $table) = @_;
 239
 240     my $dbh = $self->schema->storage->dbh;
 241     my $sth = $dbh->foreign_key_info( '', $self->db_schema, '',
 242                                       '', $self->db_schema, $table );
 243     return [] if !$sth;
 244
 245     my %rels;
 246
 247     my $i = 1; # for unnamed rels, which hopefully have only 1 column ...
 248     while(my $raw_rel = $sth->fetchrow_arrayref) {
 249         my $uk_tbl  = $raw_rel->[2];
 250         my $uk_col  = lc $raw_rel->[3];
 251         my $fk_col  = lc $raw_rel->[7];
 252         my $relid   = ($raw_rel->[11] || ( "__dcsld__" . $i++ ));
 253         $uk_tbl =~ s/\Q$self->{_quoter}\E//g;
 254         $uk_col =~ s/\Q$self->{_quoter}\E//g;
 255         $fk_col =~ s/\Q$self->{_quoter}\E//g;
 256         $relid  =~ s/\Q$self->{_quoter}\E//g;
 257         $rels{$relid}->{tbl} = $uk_tbl;
 258         $rels{$relid}->{cols}->{$uk_col} = $fk_col;
 259     }
 260     $sth->finish;
 261
 262     my @rels;
 263     foreach my $relid (keys %rels) {
 264         push(@rels, {
 265             remote_columns => [ keys   %{$rels{$relid}->{cols}} ],
 266             local_columns  => [ values %{$rels{$relid}->{cols}} ],
 267             remote_table   => $rels{$relid}->{tbl},
 268         });
 269     }
 270
 271     return \@rels;
 272 }
 273
 274 # ported in from DBIx::Class::Storage::DBI:
 275 sub _columns_info_for {
 276     my ($self, $table) = @_;
 277
 278     my $dbh = $self->schema->storage->dbh;
 279
 280     if ($dbh->can('column_info')) {
 281         my %result;
 282         eval {
 283             my $sth = $dbh->column_info( undef, $self->db_schema, $table, '%' );
 284             while ( my $info = $sth->fetchrow_hashref() ){
 285                 my $column_info = {};
 286                 $column_info->{data_type}   = $info->{TYPE_NAME};
 287                 $column_info->{size}      = $info->{COLUMN_SIZE};
 288                 $column_info->{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
 289                 $column_info->{default_value} = $info->{COLUMN_DEF};
 290                 my $col_name = $info->{COLUMN_NAME};
 291                 $col_name =~ s/^\"(.*)\"$/$1/;
 292
 293                 my $extra_info = $self->_extra_column_info($info) || {};
 294                 $column_info = { %$column_info, %$extra_info };
 295
 296                 $result{$col_name} = $column_info;
 297             }
 298             $sth->finish;
 299         };
 300       return \%result if !$@ && scalar keys %result;
 301     }
 302
 303     my %result;
 304     my $sth = $self->_sth_for($table, undef, \'1 = 0');
 305     $sth->execute;
 306     my @columns = @{$sth->{NAME_lc}};
 307     for my $i ( 0 .. $#columns ){
 308         my $column_info = {};
 309         $column_info->{data_type} = $sth->{TYPE}->[$i];
 310         $column_info->{size} = $sth->{PRECISION}->[$i];
 311         $column_info->{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
 312
 313         if ($column_info->{data_type} =~ m/^(.*?)\((.*?)\)$/) {
 314             $column_info->{data_type} = $1;
 315             $column_info->{size}    = $2;
 316         }
 317
 318         my $extra_info = $self->_extra_column_info($table, $columns[$i], $sth, $i) || {};
 319         $column_info = { %$column_info, %$extra_info };
 320
 321         $result{$columns[$i]} = $column_info;
 322     }
 323     $sth->finish;
 324
 325     foreach my $col (keys %result) {
 326         my $colinfo = $result{$col};
 327         my $type_num = $colinfo->{data_type};
 328         my $type_name;
 329         if(defined $type_num && $dbh->can('type_info')) {
 330             my $type_info = $dbh->type_info($type_num);
 331             $type_name = $type_info->{TYPE_NAME} if $type_info;
 332             $colinfo->{data_type} = $type_name if $type_name;
 333         }
 334     }
 335
 336     return \%result;
 337 }
 338
 339 # Override this in vendor class to return any additional column
 340 # attributes
 341 sub _extra_column_info {}
 342
 343 =head1 SEE ALSO
 344
 345 L<DBIx::Class::Schema::Loader>
 346
 347 =head1 AUTHOR
 348
 349 See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
 350
 351 =head1 LICENSE
 352
 353 This library is free software; you can redistribute it and/or modify it under
 354 the same terms as Perl itself.
 355
 356 =cut
 357
 358 1;