lib/DBIx/Class/Schema/Loader/DBI.pm

   1 package DBIx::Class::Schema::Loader::DBI;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class::Schema::Loader::Base/;
   6 use Class::C3;
   7 use Carp::Clan qw/^DBIx::Class/;
   8
   9 our $VERSION = '0.04999_10';
  10
  11 =head1 NAME
  12
  13 DBIx::Class::Schema::Loader::DBI - DBIx::Class::Schema::Loader DBI Implementation.
  14
  15 =head1 SYNOPSIS
  16
  17 See L<DBIx::Class::Schema::Loader::Base>
  18
  19 =head1 DESCRIPTION
  20
  21 This is the base class for L<DBIx::Class::Schema::Loader::Base> classes for
  22 DBI-based storage backends, and implements the common functionality between them.
  23
  24 See L<DBIx::Class::Schema::Loader::Base> for the available options.
  25
  26 =head1 METHODS
  27
  28 =head2 new
  29
  30 Overlays L<DBIx::Class::Schema::Loader::Base/new> to do some DBI-specific
  31 things.
  32
  33 =cut
  34
  35 sub new {
  36     my $self = shift->next::method(@_);
  37
  38     # rebless to vendor-specific class if it exists and loads
  39     my $dbh = $self->schema->storage->dbh;
  40     my $driver = $dbh->{Driver}->{Name};
  41
  42     my $subclass = 'DBIx::Class::Schema::Loader::DBI::' . $driver;
  43     if ($self->load_optional_class($subclass)) {
  44         bless $self, $subclass unless $self->isa($subclass);
  45         $self->_rebless;
  46     }
  47
  48     # Set up the default quoting character and name seperators
  49     $self->{_quoter} = $self->_build_quoter;
  50     $self->{_namesep} = $self->_build_namesep;
  51     # For our usage as regex matches, concatenating multiple quoter
  52     # values works fine (e.g. s/\Q<>\E// if quoter was [ '<', '>' ])
  53     if( ref $self->{_quoter} eq 'ARRAY') {
  54         $self->{_quoter} = join(q{}, @{$self->{_quoter}});
  55     }
  56
  57     $self->_setup;
  58
  59     $self;
  60 }
  61
  62 sub _build_quoter {
  63     my $self = shift;
  64     my $dbh = $self->schema->storage->dbh;
  65     return $dbh->get_info(29)
  66            || $self->schema->storage->sql_maker->quote_char
  67            || q{"};
  68 }
  69
  70 sub _build_namesep {
  71     my $self = shift;
  72     my $dbh = $self->schema->storage->dbh;
  73     return $dbh->get_info(41)
  74            || $self->schema->storage->sql_maker->name_sep
  75            || q{.};
  76 }
  77
  78 # Override this in vendor modules to do things at the end of ->new()
  79 sub _setup { }
  80
  81 # Override this in vendor module to load a subclass if necessary
  82 sub _rebless { }
  83
  84 # Returns an array of table names
  85 sub _tables_list {
  86     my $self = shift;
  87
  88     my ($table, $type) = @_ ? @_ : ('%', '%');
  89
  90     my $dbh = $self->schema->storage->dbh;
  91     my @tables = $dbh->tables(undef, $self->db_schema, $table, $type);
  92
  93     my $qt = qr/\Q$self->{_quoter}\E/;
  94
  95     if ($self->{_quoter} && $tables[0] =~ /$qt/) {
  96         s/.* $qt (?= .* $qt)//xg for @tables;
  97     } else {
  98         s/^.*\Q$self->{_namesep}\E// for @tables;
  99     }
 100     s/$qt//g for @tables;
 101
 102     return @tables;
 103 }
 104
 105 =head2 load
 106
 107 We override L<DBIx::Class::Schema::Loader::Base/load> here to hook in our localized settings for C<$dbh> error handling.
 108
 109 =cut
 110
 111 sub load {
 112     my $self = shift;
 113
 114     local $self->schema->storage->dbh->{RaiseError} = 1;
 115     local $self->schema->storage->dbh->{PrintError} = 0;
 116     $self->next::method(@_);
 117 }
 118
 119 # Returns an arrayref of column names
 120 sub _table_columns {
 121     my ($self, $table) = @_;
 122
 123     my $dbh = $self->schema->storage->dbh;
 124
 125     if($self->{db_schema}) {
 126         $table = $self->{db_schema} . $self->{_namesep} .
 127             $self->_quote_table_name($table);
 128     } else {
 129         $table = $self->_quote_table_name($table);
 130     }
 131
 132     my $sth = $dbh->prepare($self->schema->storage->sql_maker->select(\$table, undef, \'1 = 0'));
 133     $sth->execute;
 134     my $retval = \@{$sth->{NAME_lc}};
 135     $sth->finish;
 136
 137     $retval;
 138 }
 139
 140 # Returns arrayref of pk col names
 141 sub _table_pk_info {
 142     my ($self, $table) = @_;
 143
 144     my $dbh = $self->schema->storage->dbh;
 145
 146     my @primary = map { lc } $dbh->primary_key('', $self->db_schema, $table);
 147     s/\Q$self->{_quoter}\E//g for @primary;
 148
 149     return \@primary;
 150 }
 151
 152 # Override this for vendor-specific uniq info
 153 sub _table_uniq_info {
 154     my ($self, $table) = @_;
 155
 156     my $dbh = $self->schema->storage->dbh;
 157     if(!$dbh->can('statistics_info')) {
 158         warn "No UNIQUE constraint information can be gathered for this vendor";
 159         return [];
 160     }
 161
 162     my %indices;
 163     my $sth = $dbh->statistics_info(undef, $self->db_schema, $table, 1, 1);
 164     while(my $row = $sth->fetchrow_hashref) {
 165         # skip table-level stats, conditional indexes, and any index missing
 166         #  critical fields
 167         next if $row->{TYPE} eq 'table'
 168             || defined $row->{FILTER_CONDITION}
 169             || !$row->{INDEX_NAME}
 170             || !defined $row->{ORDINAL_POSITION}
 171             || !$row->{COLUMN_NAME};
 172
 173         $indices{$row->{INDEX_NAME}}->{$row->{ORDINAL_POSITION}} = $row->{COLUMN_NAME};
 174     }
 175     $sth->finish;
 176
 177     my @retval;
 178     foreach my $index_name (keys %indices) {
 179         my $index = $indices{$index_name};
 180         push(@retval, [ $index_name => [
 181             map { $index->{$_} }
 182                 sort keys %$index
 183         ]]);
 184     }
 185
 186     return \@retval;
 187 }
 188
 189 # Find relationships
 190 sub _table_fk_info {
 191     my ($self, $table) = @_;
 192
 193     my $dbh = $self->schema->storage->dbh;
 194     my $sth = $dbh->foreign_key_info( '', $self->db_schema, '',
 195                                       '', $self->db_schema, $table );
 196     return [] if !$sth;
 197
 198     my %rels;
 199
 200     my $i = 1; # for unnamed rels, which hopefully have only 1 column ...
 201     while(my $raw_rel = $sth->fetchrow_arrayref) {
 202         my $uk_tbl  = $raw_rel->[2];
 203         my $uk_col  = lc $raw_rel->[3];
 204         my $fk_col  = lc $raw_rel->[7];
 205         my $relid   = ($raw_rel->[11] || ( "__dcsld__" . $i++ ));
 206         $uk_tbl =~ s/\Q$self->{_quoter}\E//g;
 207         $uk_col =~ s/\Q$self->{_quoter}\E//g;
 208         $fk_col =~ s/\Q$self->{_quoter}\E//g;
 209         $relid  =~ s/\Q$self->{_quoter}\E//g;
 210         $rels{$relid}->{tbl} = $uk_tbl;
 211         $rels{$relid}->{cols}->{$uk_col} = $fk_col;
 212     }
 213     $sth->finish;
 214
 215     my @rels;
 216     foreach my $relid (keys %rels) {
 217         push(@rels, {
 218             remote_columns => [ keys   %{$rels{$relid}->{cols}} ],
 219             local_columns  => [ values %{$rels{$relid}->{cols}} ],
 220             remote_table   => $rels{$relid}->{tbl},
 221         });
 222     }
 223
 224     return \@rels;
 225 }
 226
 227 # ported in from DBIx::Class::Storage::DBI:
 228 sub _columns_info_for {
 229     my ($self, $table) = @_;
 230
 231     my $dbh = $self->schema->storage->dbh;
 232
 233     if ($dbh->can('column_info')) {
 234         my %result;
 235         eval {
 236             my $sth = $dbh->column_info( undef, $self->db_schema, $table, '%' );
 237             while ( my $info = $sth->fetchrow_hashref() ){
 238                 my %column_info;
 239                 $column_info{data_type}   = $info->{TYPE_NAME};
 240                 $column_info{size}      = $info->{COLUMN_SIZE};
 241                 $column_info{is_nullable}   = $info->{NULLABLE} ? 1 : 0;
 242                 $column_info{default_value} = $info->{COLUMN_DEF};
 243                 my $col_name = $info->{COLUMN_NAME};
 244                 $col_name =~ s/^\"(.*)\"$/$1/;
 245
 246                 my $extra_info = $self->_extra_column_info($info) || {};
 247
 248                 $result{$col_name} = { %column_info, %$extra_info };
 249             }
 250             $sth->finish;
 251         };
 252       return \%result if !$@ && scalar keys %result;
 253     }
 254
 255     if($self->db_schema) {
 256         $table = $self->db_schema . $self->{_namesep} . $table;
 257     }
 258     my %result;
 259     my $sth = $dbh->prepare($self->schema->storage->sql_maker->select($table, undef, \'1 = 0'));
 260     $sth->execute;
 261     my @columns = @{$sth->{NAME_lc}};
 262     for my $i ( 0 .. $#columns ){
 263         my %column_info;
 264         $column_info{data_type} = $sth->{TYPE}->[$i];
 265         $column_info{size} = $sth->{PRECISION}->[$i];
 266         $column_info{is_nullable} = $sth->{NULLABLE}->[$i] ? 1 : 0;
 267
 268         if ($column_info{data_type} =~ m/^(.*?)\((.*?)\)$/) {
 269             $column_info{data_type} = $1;
 270             $column_info{size}    = $2;
 271         }
 272
 273         my $extra_info = $self->_extra_column_info($table, $columns[$i], $sth, $i) || {};
 274
 275         $result{$columns[$i]} = { %column_info, %$extra_info };
 276     }
 277     $sth->finish;
 278
 279     foreach my $col (keys %result) {
 280         my $colinfo = $result{$col};
 281         my $type_num = $colinfo->{data_type};
 282         my $type_name;
 283         if(defined $type_num && $dbh->can('type_info')) {
 284             my $type_info = $dbh->type_info($type_num);
 285             $type_name = $type_info->{TYPE_NAME} if $type_info;
 286             $colinfo->{data_type} = $type_name if $type_name;
 287         }
 288     }
 289
 290     return \%result;
 291 }
 292
 293 # Override this in vendor class to return any additional column
 294 # attributes
 295 sub _extra_column_info {}
 296
 297 =head1 SEE ALSO
 298
 299 L<DBIx::Class::Schema::Loader>
 300
 301 =cut
 302
 303 1;