lib/DBIx/Class/Schema/Loader/Base.pm

   1 package DBIx::Class::Schema::Loader::Base;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/Class::Accessor::Grouped Class::C3::Componentised/;
   6 use Class::C3;
   7 use Carp::Clan qw/^DBIx::Class/;
   8 use DBIx::Class::Schema::Loader::RelBuilder;
   9 use Data::Dump qw/ dump /;
  10 use POSIX qw//;
  11 use File::Spec qw//;
  12 use Cwd qw//;
  13 use Digest::MD5 qw//;
  14 use Lingua::EN::Inflect::Number qw//;
  15 use File::Temp qw//;
  16 use Class::Unload;
  17 require DBIx::Class;
  18
  19 our $VERSION = '0.04999_12';
  20
  21 __PACKAGE__->mk_group_ro_accessors('simple', qw/
  22                                 schema
  23                                 schema_class
  24
  25                                 exclude
  26                                 constraint
  27                                 additional_classes
  28                                 additional_base_classes
  29                                 left_base_classes
  30                                 components
  31                                 resultset_components
  32                                 skip_relationships
  33                                 skip_load_external
  34                                 moniker_map
  35                                 inflect_singular
  36                                 inflect_plural
  37                                 debug
  38                                 dump_directory
  39                                 dump_overwrite
  40                                 really_erase_my_files
  41                                 use_namespaces
  42                                 result_namespace
  43                                 resultset_namespace
  44                                 default_resultset_class
  45                                 schema_base_class
  46                                 result_base_class
  47                                 overwrite_modifications
  48
  49                                 relationship_attrs
  50
  51                                 db_schema
  52                                 _tables
  53                                 classes
  54                                 _upgrading_classes
  55                                 monikers
  56                                 dynamic
  57                                 naming
  58 /);
  59
  60
  61 __PACKAGE__->mk_group_accessors('simple', qw/
  62                                 version_to_dump
  63                                 schema_version_to_dump
  64                                 _upgrading_from
  65 /);
  66
  67 =head1 NAME
  68
  69 DBIx::Class::Schema::Loader::Base - Base DBIx::Class::Schema::Loader Implementation.
  70
  71 =head1 SYNOPSIS
  72
  73 See L<DBIx::Class::Schema::Loader>
  74
  75 =head1 DESCRIPTION
  76
  77 This is the base class for the storage-specific C<DBIx::Class::Schema::*>
  78 classes, and implements the common functionality between them.
  79
  80 =head1 CONSTRUCTOR OPTIONS
  81
  82 These constructor options are the base options for
  83 L<DBIx::Class::Schema::Loader/loader_options>.  Available constructor options are:
  84
  85 =head2 skip_relationships
  86
  87 Skip setting up relationships.  The default is to attempt the loading
  88 of relationships.
  89
  90 =head2 skip_load_external
  91
  92 Skip loading of other classes in @INC. The default is to merge all other classes
  93 with the same name found in @INC into the schema file we are creating.
  94
  95 =head2 naming
  96
  97 Static schemas (ones dumped to disk) will, by default, use the new-style 0.05XXX
  98 relationship names and singularized Results, unless you're overwriting an
  99 existing dump made by a 0.04XXX version of L<DBIx::Class::Schema::Loader>, in
 100 which case the backward compatible RelBuilder will be activated, and
 101 singularization will be turned off.
 102
 103 Specifying
 104
 105     naming => 'v5'
 106
 107 will disable the backward-compatible RelBuilder and use
 108 the new-style relationship names along with singularized Results, even when
 109 overwriting a dump made with an earlier version.
 110
 111 The option also takes a hashref:
 112
 113     naming => { relationships => 'v5', monikers => 'v4' }
 114
 115 The keys are:
 116
 117 =over 4
 118
 119 =item relationships
 120
 121 How to name relationship accessors.
 122
 123 =item monikers
 124
 125 How to name Result classes.
 126
 127 =back
 128
 129 The values can be:
 130
 131 =over 4
 132
 133 =item current
 134
 135 Latest default style, whatever that happens to be.
 136
 137 =item v5
 138
 139 Version 0.05XXX style.
 140
 141 =item v4
 142
 143 Version 0.04XXX style.
 144
 145 =back
 146
 147 Dynamic schemas will always default to the 0.04XXX relationship names and won't
 148 singularize Results for backward compatibility, to activate the new RelBuilder
 149 and singularization put this in your C<Schema.pm> file:
 150
 151     __PACKAGE__->naming('current');
 152
 153 Or if you prefer to use 0.05XXX features but insure that nothing breaks in the
 154 next major version upgrade:
 155
 156     __PACKAGE__->naming('v5');
 157
 158 =head2 relationship_attrs
 159
 160 Hashref of attributes to pass to each generated relationship, listed
 161 by type.  Also supports relationship type 'all', containing options to
 162 pass to all generated relationships.  Attributes set for more specific
 163 relationship types override those set in 'all'.
 164
 165 For example:
 166
 167   relationship_attrs => {
 168     all      => { cascade_delete => 0 },
 169     has_many => { cascade_delete => 1 },
 170   },
 171
 172 will set the C<cascade_delete> option to 0 for all generated relationships,
 173 except for C<has_many>, which will have cascade_delete as 1.
 174
 175 NOTE: this option is not supported if v4 backward-compatible naming is
 176 set either globally (naming => 'v4') or just for relationships.
 177
 178 =head2 debug
 179
 180 If set to true, each constructive L<DBIx::Class> statement the loader
 181 decides to execute will be C<warn>-ed before execution.
 182
 183 =head2 db_schema
 184
 185 Set the name of the schema to load (schema in the sense that your database
 186 vendor means it).  Does not currently support loading more than one schema
 187 name.
 188
 189 =head2 constraint
 190
 191 Only load tables matching regex.  Best specified as a qr// regex.
 192
 193 =head2 exclude
 194
 195 Exclude tables matching regex.  Best specified as a qr// regex.
 196
 197 =head2 moniker_map
 198
 199 Overrides the default table name to moniker translation.  Can be either
 200 a hashref of table keys and moniker values, or a coderef for a translator
 201 function taking a single scalar table name argument and returning
 202 a scalar moniker.  If the hash entry does not exist, or the function
 203 returns a false value, the code falls back to default behavior
 204 for that table name.
 205
 206 The default behavior is to singularize the table name, and: C<join '', map
 207 ucfirst, split /[\W_]+/, lc $table>, which is to say: lowercase everything,
 208 split up the table name into chunks anywhere a non-alpha-numeric character
 209 occurs, change the case of first letter of each chunk to upper case, and put
 210 the chunks back together.  Examples:
 211
 212     Table Name  | Moniker Name
 213     ---------------------------
 214     luser       | Luser
 215     luser_group | LuserGroup
 216     luser-opts  | LuserOpts
 217
 218 =head2 inflect_plural
 219
 220 Just like L</moniker_map> above (can be hash/code-ref, falls back to default
 221 if hash key does not exist or coderef returns false), but acts as a map
 222 for pluralizing relationship names.  The default behavior is to utilize
 223 L<Lingua::EN::Inflect::Number/to_PL>.
 224
 225 =head2 inflect_singular
 226
 227 As L</inflect_plural> above, but for singularizing relationship names.
 228 Default behavior is to utilize L<Lingua::EN::Inflect::Number/to_S>.
 229
 230 =head2 schema_base_class
 231
 232 Base class for your schema classes. Defaults to 'DBIx::Class::Schema'.
 233
 234 =head2 result_base_class
 235
 236 Base class for your table classes (aka result classes). Defaults to
 237 'DBIx::Class::Core'.
 238
 239 =head2 additional_base_classes
 240
 241 List of additional base classes all of your table classes will use.
 242
 243 =head2 left_base_classes
 244
 245 List of additional base classes all of your table classes will use
 246 that need to be leftmost.
 247
 248 =head2 additional_classes
 249
 250 List of additional classes which all of your table classes will use.
 251
 252 =head2 components
 253
 254 List of additional components to be loaded into all of your table
 255 classes.  A good example would be C<ResultSetManager>.
 256
 257 =head2 resultset_components
 258
 259 List of additional ResultSet components to be loaded into your table
 260 classes.  A good example would be C<AlwaysRS>.  Component
 261 C<ResultSetManager> will be automatically added to the above
 262 C<components> list if this option is set.
 263
 264 =head2 use_namespaces
 265
 266 Generate result class names suitable for
 267 L<DBIx::Class::Schema/load_namespaces> and call that instead of
 268 L<DBIx::Class::Schema/load_classes>. When using this option you can also
 269 specify any of the options for C<load_namespaces> (i.e. C<result_namespace>,
 270 C<resultset_namespace>, C<default_resultset_class>), and they will be added
 271 to the call (and the generated result class names adjusted appropriately).
 272
 273 =head2 dump_directory
 274
 275 This option is designed to be a tool to help you transition from this
 276 loader to a manually-defined schema when you decide it's time to do so.
 277
 278 The value of this option is a perl libdir pathname.  Within
 279 that directory this module will create a baseline manual
 280 L<DBIx::Class::Schema> module set, based on what it creates at runtime
 281 in memory.
 282
 283 The created schema class will have the same classname as the one on
 284 which you are setting this option (and the ResultSource classes will be
 285 based on this name as well).
 286
 287 Normally you wouldn't hard-code this setting in your schema class, as it
 288 is meant for one-time manual usage.
 289
 290 See L<DBIx::Class::Schema::Loader/dump_to_dir> for examples of the
 291 recommended way to access this functionality.
 292
 293 =head2 dump_overwrite
 294
 295 Deprecated.  See L</really_erase_my_files> below, which does *not* mean
 296 the same thing as the old C<dump_overwrite> setting from previous releases.
 297
 298 =head2 really_erase_my_files
 299
 300 Default false.  If true, Loader will unconditionally delete any existing
 301 files before creating the new ones from scratch when dumping a schema to disk.
 302
 303 The default behavior is instead to only replace the top portion of the
 304 file, up to and including the final stanza which contains
 305 C<# DO NOT MODIFY THIS OR ANYTHING ABOVE!>
 306 leaving any customizations you placed after that as they were.
 307
 308 When C<really_erase_my_files> is not set, if the output file already exists,
 309 but the aforementioned final stanza is not found, or the checksum
 310 contained there does not match the generated contents, Loader will
 311 croak and not touch the file.
 312
 313 You should really be using version control on your schema classes (and all
 314 of the rest of your code for that matter).  Don't blame me if a bug in this
 315 code wipes something out when it shouldn't have, you've been warned.
 316
 317 =head2 overwrite_modifications
 318
 319 Default false.  If false, when updating existing files, Loader will
 320 refuse to modify any Loader-generated code that has been modified
 321 since its last run (as determined by the checksum Loader put in its
 322 comment lines).
 323
 324 If true, Loader will discard any manual modifications that have been
 325 made to Loader-generated code.
 326
 327 Again, you should be using version control on your schema classes.  Be
 328 careful with this option.
 329
 330 =head1 METHODS
 331
 332 None of these methods are intended for direct invocation by regular
 333 users of L<DBIx::Class::Schema::Loader>.  Anything you can find here
 334 can also be found via standard L<DBIx::Class::Schema> methods somehow.
 335
 336 =cut
 337
 338 use constant CURRENT_V => 'v5';
 339
 340 # ensure that a peice of object data is a valid arrayref, creating
 341 # an empty one or encapsulating whatever's there.
 342 sub _ensure_arrayref {
 343     my $self = shift;
 344
 345     foreach (@_) {
 346         $self->{$_} ||= [];
 347         $self->{$_} = [ $self->{$_} ]
 348             unless ref $self->{$_} eq 'ARRAY';
 349     }
 350 }
 351
 352 =head2 new
 353
 354 Constructor for L<DBIx::Class::Schema::Loader::Base>, used internally
 355 by L<DBIx::Class::Schema::Loader>.
 356
 357 =cut
 358
 359 sub new {
 360     my ( $class, %args ) = @_;
 361
 362     my $self = { %args };
 363
 364     bless $self => $class;
 365
 366     $self->_ensure_arrayref(qw/additional_classes
 367                                additional_base_classes
 368                                left_base_classes
 369                                components
 370                                resultset_components
 371                               /);
 372
 373     push(@{$self->{components}}, 'ResultSetManager')
 374         if @{$self->{resultset_components}};
 375
 376     $self->{monikers} = {};
 377     $self->{classes} = {};
 378     $self->{_upgrading_classes} = {};
 379
 380     $self->{schema_class} ||= ( ref $self->{schema} || $self->{schema} );
 381     $self->{schema} ||= $self->{schema_class};
 382
 383     croak "dump_overwrite is deprecated.  Please read the"
 384         . " DBIx::Class::Schema::Loader::Base documentation"
 385             if $self->{dump_overwrite};
 386
 387     $self->{dynamic} = ! $self->{dump_directory};
 388     $self->{temp_directory} ||= File::Temp::tempdir( 'dbicXXXX',
 389                                                      TMPDIR  => 1,
 390                                                      CLEANUP => 1,
 391                                                    );
 392
 393     $self->{dump_directory} ||= $self->{temp_directory};
 394
 395     $self->version_to_dump($DBIx::Class::Schema::Loader::VERSION);
 396     $self->schema_version_to_dump($DBIx::Class::Schema::Loader::VERSION);
 397
 398     if ((not ref $self->naming) && defined $self->naming) {
 399         my $naming_ver = $self->naming;
 400         $self->{naming} = {
 401             relationships => $naming_ver,
 402             monikers => $naming_ver,
 403         };
 404     }
 405
 406     if ($self->naming) {
 407         for (values %{ $self->naming }) {
 408             $_ = CURRENT_V if $_ eq 'current';
 409         }
 410     }
 411     $self->{naming} ||= {};
 412
 413     $self->_check_back_compat;
 414
 415     $self;
 416 }
 417
 418 sub _check_back_compat {
 419     my ($self) = @_;
 420
 421 # dynamic schemas will always be in 0.04006 mode, unless overridden
 422     if ($self->dynamic) {
 423 # just in case, though no one is likely to dump a dynamic schema
 424         $self->schema_version_to_dump('0.04006');
 425
 426         if (not %{ $self->naming }) {
 427             warn <<EOF unless $ENV{SCHEMA_LOADER_BACKCOMPAT};
 428
 429 Dynamic schema detected, will run in 0.04006 mode.
 430
 431 Set the 'naming' attribute or the SCHEMA_LOADER_BACKCOMPAT environment variable
 432 to disable this warning.
 433
 434 See perldoc DBIx::Class::Schema::Loader::Manual::UpgradingFromV4 for more
 435 details.
 436 EOF
 437         }
 438         else {
 439             $self->_upgrading_from('v4');
 440         }
 441
 442         $self->naming->{relationships} ||= 'v4';
 443         $self->naming->{monikers}      ||= 'v4';
 444
 445         return;
 446     }
 447
 448 # otherwise check if we need backcompat mode for a static schema
 449     my $filename = $self->_get_dump_filename($self->schema_class);
 450     return unless -e $filename;
 451
 452     open(my $fh, '<', $filename)
 453         or croak "Cannot open '$filename' for reading: $!";
 454
 455     while (<$fh>) {
 456         if (/^# Created by DBIx::Class::Schema::Loader v((\d+)\.(\d+))/) {
 457             my $real_ver = $1;
 458
 459             # XXX when we go past .0 this will need fixing
 460             my ($v) = $real_ver =~ /([1-9])/;
 461             $v = "v$v";
 462
 463             last if $v eq CURRENT_V || $real_ver =~ /^0\.04999/;
 464
 465             if (not %{ $self->naming }) {
 466                 warn <<"EOF" unless $ENV{SCHEMA_LOADER_BACKCOMPAT};
 467
 468 Version $real_ver static schema detected, turning on backcompat mode.
 469
 470 Set the 'naming' attribute or the SCHEMA_LOADER_BACKCOMPAT environment variable
 471 to disable this warning.
 472
 473 See perldoc DBIx::Class::Schema::Loader::Manual::UpgradingFromV4 for more
 474 details.
 475 EOF
 476             }
 477             else {
 478                 $self->_upgrading_from($v);
 479             }
 480
 481             $self->naming->{relationships} ||= $v;
 482             $self->naming->{monikers}      ||= $v;
 483
 484             $self->schema_version_to_dump($real_ver);
 485
 486             last;
 487         }
 488     }
 489     close $fh;
 490 }
 491
 492 sub _find_file_in_inc {
 493     my ($self, $file) = @_;
 494
 495     foreach my $prefix (@INC) {
 496         my $fullpath = File::Spec->catfile($prefix, $file);
 497         return $fullpath if -f $fullpath
 498             and Cwd::abs_path($fullpath) ne
 499                (Cwd::abs_path(File::Spec->catfile($self->dump_directory, $file)) || '');
 500     }
 501
 502     return;
 503 }
 504
 505 sub _class_path {
 506     my ($self, $class) = @_;
 507
 508     my $class_path = $class;
 509     $class_path =~ s{::}{/}g;
 510     $class_path .= '.pm';
 511
 512     return $class_path;
 513 }
 514
 515 sub _find_class_in_inc {
 516     my ($self, $class) = @_;
 517
 518     return $self->_find_file_in_inc($self->_class_path($class));
 519 }
 520
 521 sub _load_external {
 522     my ($self, $class) = @_;
 523
 524     return if $self->{skip_load_external};
 525
 526     # so that we don't load our own classes, under any circumstances
 527     local *INC = [ grep $_ ne $self->dump_directory, @INC ];
 528
 529     my $real_inc_path = $self->_find_class_in_inc($class);
 530
 531     my $old_class = $self->_upgrading_classes->{$class}
 532         if $self->_upgrading_from;
 533
 534     my $old_real_inc_path = $self->_find_class_in_inc($old_class)
 535         if $old_class && $old_class ne $class;
 536
 537     return unless $real_inc_path || $old_real_inc_path;
 538
 539     if ($real_inc_path) {
 540         # If we make it to here, we loaded an external definition
 541         warn qq/# Loaded external class definition for '$class'\n/
 542             if $self->debug;
 543
 544         open(my $fh, '<', $real_inc_path)
 545             or croak "Failed to open '$real_inc_path' for reading: $!";
 546         $self->_ext_stmt($class,
 547           qq|# These lines were loaded from '$real_inc_path' found in \@INC.\n|
 548          .qq|# They are now part of the custom portion of this file\n|
 549          .qq|# for you to hand-edit.  If you do not either delete\n|
 550          .qq|# this section or remove that file from \@INC, this section\n|
 551          .qq|# will be repeated redundantly when you re-create this\n|
 552          .qq|# file again via Loader!\n|
 553         );
 554         while(<$fh>) {
 555             chomp;
 556             $self->_ext_stmt($class, $_);
 557         }
 558         $self->_ext_stmt($class,
 559             qq|# End of lines loaded from '$real_inc_path' |
 560         );
 561         close($fh)
 562             or croak "Failed to close $real_inc_path: $!";
 563
 564         if ($self->dynamic) { # load the class too
 565             # kill redefined warnings
 566             my $warn_handler = $SIG{__WARN__} || sub { warn @_ };
 567             local $SIG{__WARN__} = sub {
 568                 $warn_handler->(@_)
 569                     unless $_[0] =~ /^Subroutine \S+ redefined/;
 570             };
 571             do $real_inc_path;
 572             die $@ if $@;
 573         }
 574     }
 575
 576     if ($old_real_inc_path) {
 577         open(my $fh, '<', $old_real_inc_path)
 578             or croak "Failed to open '$old_real_inc_path' for reading: $!";
 579         $self->_ext_stmt($class, <<"EOF");
 580
 581 # These lines were loaded from '$old_real_inc_path', based on the Result class
 582 # name that would have been created by an 0.04006 version of the Loader. For a
 583 # static schema, this happens only once during upgrade.
 584 EOF
 585         if ($self->dynamic) {
 586             warn <<"EOF";
 587
 588 Detected external content in '$old_real_inc_path', a class name that would have
 589 been used by an 0.04006 version of the Loader.
 590
 591 * PLEASE RENAME THIS CLASS: from '$old_class' to '$class', as that is the
 592 new name of the Result.
 593 EOF
 594             # kill redefined warnings
 595             my $warn_handler = $SIG{__WARN__} || sub { warn @_ };
 596             local $SIG{__WARN__} = sub {
 597                 $warn_handler->(@_)
 598                     unless $_[0] =~ /^Subroutine \S+ redefined/;
 599             };
 600             my $code = do {
 601                 local ($/, @ARGV) = (undef, $old_real_inc_path); <>
 602             };
 603             $code =~ s/$old_class/$class/g;
 604             eval $code;
 605             die $@ if $@;
 606         }
 607
 608         while(<$fh>) {
 609             chomp;
 610             $self->_ext_stmt($class, $_);
 611         }
 612         $self->_ext_stmt($class,
 613             qq|# End of lines loaded from '$old_real_inc_path' |
 614         );
 615
 616         close($fh)
 617             or croak "Failed to close $old_real_inc_path: $!";
 618     }
 619 }
 620
 621 =head2 load
 622
 623 Does the actual schema-construction work.
 624
 625 =cut
 626
 627 sub load {
 628     my $self = shift;
 629
 630     $self->_load_tables($self->_tables_list);
 631 }
 632
 633 =head2 rescan
 634
 635 Arguments: schema
 636
 637 Rescan the database for newly added tables.  Does
 638 not process drops or changes.  Returns a list of
 639 the newly added table monikers.
 640
 641 The schema argument should be the schema class
 642 or object to be affected.  It should probably
 643 be derived from the original schema_class used
 644 during L</load>.
 645
 646 =cut
 647
 648 sub rescan {
 649     my ($self, $schema) = @_;
 650
 651     $self->{schema} = $schema;
 652     $self->_relbuilder->{schema} = $schema;
 653
 654     my @created;
 655     my @current = $self->_tables_list;
 656     foreach my $table ($self->_tables_list) {
 657         if(!exists $self->{_tables}->{$table}) {
 658             push(@created, $table);
 659         }
 660     }
 661
 662     my $loaded = $self->_load_tables(@created);
 663
 664     return map { $self->monikers->{$_} } @$loaded;
 665 }
 666
 667 sub _relbuilder {
 668     no warnings 'uninitialized';
 669     my ($self) = @_;
 670
 671     return if $self->{skip_relationships};
 672
 673     if ($self->naming->{relationships} eq 'v4') {
 674         require DBIx::Class::Schema::Loader::RelBuilder::Compat::v0_040;
 675         return $self->{relbuilder} ||=
 676             DBIx::Class::Schema::Loader::RelBuilder::Compat::v0_040->new(
 677                 $self->schema, $self->inflect_plural, $self->inflect_singular
 678             );
 679     }
 680
 681     $self->{relbuilder} ||= DBIx::Class::Schema::Loader::RelBuilder->new (
 682          $self->schema,
 683          $self->inflect_plural,
 684          $self->inflect_singular,
 685          $self->relationship_attrs,
 686     );
 687 }
 688
 689 sub _load_tables {
 690     my ($self, @tables) = @_;
 691
 692     # First, use _tables_list with constraint and exclude
 693     #  to get a list of tables to operate on
 694
 695     my $constraint   = $self->constraint;
 696     my $exclude      = $self->exclude;
 697
 698     @tables = grep { /$constraint/ } @tables if $constraint;
 699     @tables = grep { ! /$exclude/ } @tables if $exclude;
 700
 701     # Save the new tables to the tables list
 702     foreach (@tables) {
 703         $self->{_tables}->{$_} = 1;
 704     }
 705
 706     $self->_make_src_class($_) for @tables;
 707     $self->_setup_src_meta($_) for @tables;
 708
 709     if(!$self->skip_relationships) {
 710         # The relationship loader needs a working schema
 711         $self->{quiet} = 1;
 712         local $self->{dump_directory} = $self->{temp_directory};
 713         $self->_reload_classes(\@tables);
 714         $self->_load_relationships($_) for @tables;
 715         $self->{quiet} = 0;
 716
 717         # Remove that temp dir from INC so it doesn't get reloaded
 718         @INC = grep $_ ne $self->dump_directory, @INC;
 719     }
 720
 721     $self->_load_external($_)
 722         for map { $self->classes->{$_} } @tables;
 723
 724     # Reload without unloading first to preserve any symbols from external
 725     # packages.
 726     $self->_reload_classes(\@tables, 0);
 727
 728     # Drop temporary cache
 729     delete $self->{_cache};
 730
 731     return \@tables;
 732 }
 733
 734 sub _reload_classes {
 735     my ($self, $tables, $unload) = @_;
 736
 737     my @tables = @$tables;
 738     $unload = 1 unless defined $unload;
 739
 740     # so that we don't repeat custom sections
 741     @INC = grep $_ ne $self->dump_directory, @INC;
 742
 743     $self->_dump_to_dir(map { $self->classes->{$_} } @tables);
 744
 745     unshift @INC, $self->dump_directory;
 746
 747     my @to_register;
 748     my %have_source = map { $_ => $self->schema->source($_) }
 749         $self->schema->sources;
 750
 751     for my $table (@tables) {
 752         my $moniker = $self->monikers->{$table};
 753         my $class = $self->classes->{$table};
 754
 755         {
 756             no warnings 'redefine';
 757             local *Class::C3::reinitialize = sub {};
 758             use warnings;
 759
 760             Class::Unload->unload($class) if $unload;
 761             my ($source, $resultset_class);
 762             if (
 763                 ($source = $have_source{$moniker})
 764                 && ($resultset_class = $source->resultset_class)
 765                 && ($resultset_class ne 'DBIx::Class::ResultSet')
 766             ) {
 767                 my $has_file = Class::Inspector->loaded_filename($resultset_class);
 768                 Class::Unload->unload($resultset_class) if $unload;
 769                 $self->_reload_class($resultset_class) if $has_file;
 770             }
 771             $self->_reload_class($class);
 772         }
 773         push @to_register, [$moniker, $class];
 774     }
 775
 776     Class::C3->reinitialize;
 777     for (@to_register) {
 778         $self->schema->register_class(@$_);
 779     }
 780 }
 781
 782 # We use this instead of ensure_class_loaded when there are package symbols we
 783 # want to preserve.
 784 sub _reload_class {
 785     my ($self, $class) = @_;
 786
 787     my $class_path = $self->_class_path($class);
 788     delete $INC{ $class_path };
 789
 790 # kill redefined warnings
 791     my $warn_handler = $SIG{__WARN__} || sub { warn @_ };
 792     local $SIG{__WARN__} = sub {
 793         $warn_handler->(@_)
 794             unless $_[0] =~ /^Subroutine \S+ redefined/;
 795     };
 796     eval "require $class;";
 797 }
 798
 799 sub _get_dump_filename {
 800     my ($self, $class) = (@_);
 801
 802     $class =~ s{::}{/}g;
 803     return $self->dump_directory . q{/} . $class . q{.pm};
 804 }
 805
 806 sub _ensure_dump_subdirs {
 807     my ($self, $class) = (@_);
 808
 809     my @name_parts = split(/::/, $class);
 810     pop @name_parts; # we don't care about the very last element,
 811                      # which is a filename
 812
 813     my $dir = $self->dump_directory;
 814     while (1) {
 815         if(!-d $dir) {
 816             mkdir($dir) or croak "mkdir('$dir') failed: $!";
 817         }
 818         last if !@name_parts;
 819         $dir = File::Spec->catdir($dir, shift @name_parts);
 820     }
 821 }
 822
 823 sub _dump_to_dir {
 824     my ($self, @classes) = @_;
 825
 826     my $schema_class = $self->schema_class;
 827     my $schema_base_class = $self->schema_base_class || 'DBIx::Class::Schema';
 828
 829     my $target_dir = $self->dump_directory;
 830     warn "Dumping manual schema for $schema_class to directory $target_dir ...\n"
 831         unless $self->{dynamic} or $self->{quiet};
 832
 833     my $schema_text =
 834           qq|package $schema_class;\n\n|
 835         . qq|# Created by DBIx::Class::Schema::Loader\n|
 836         . qq|# DO NOT MODIFY THE FIRST PART OF THIS FILE\n\n|
 837         . qq|use strict;\nuse warnings;\n\n|
 838         . qq|use base '$schema_base_class';\n\n|;
 839
 840     if ($self->use_namespaces) {
 841         $schema_text .= qq|__PACKAGE__->load_namespaces|;
 842         my $namespace_options;
 843         for my $attr (qw(result_namespace
 844                          resultset_namespace
 845                          default_resultset_class)) {
 846             if ($self->$attr) {
 847                 $namespace_options .= qq|    $attr => '| . $self->$attr . qq|',\n|
 848             }
 849         }
 850         $schema_text .= qq|(\n$namespace_options)| if $namespace_options;
 851         $schema_text .= qq|;\n|;
 852     }
 853     else {
 854         $schema_text .= qq|__PACKAGE__->load_classes;\n|;
 855     }
 856
 857     {
 858         local $self->{version_to_dump} = $self->schema_version_to_dump;
 859         $self->_write_classfile($schema_class, $schema_text);
 860     }
 861
 862     my $result_base_class = $self->result_base_class || 'DBIx::Class::Core';
 863
 864     foreach my $src_class (@classes) {
 865         my $src_text =
 866               qq|package $src_class;\n\n|
 867             . qq|# Created by DBIx::Class::Schema::Loader\n|
 868             . qq|# DO NOT MODIFY THE FIRST PART OF THIS FILE\n\n|
 869             . qq|use strict;\nuse warnings;\n\n|
 870             . qq|use base '$result_base_class';\n\n|;
 871
 872         $self->_write_classfile($src_class, $src_text);
 873     }
 874
 875     warn "Schema dump completed.\n" unless $self->{dynamic} or $self->{quiet};
 876
 877 }
 878
 879 sub _sig_comment {
 880     my ($self, $version, $ts) = @_;
 881     return qq|\n\n# Created by DBIx::Class::Schema::Loader|
 882          . qq| v| . $version
 883          . q| @ | . $ts
 884          . qq|\n# DO NOT MODIFY THIS OR ANYTHING ABOVE! md5sum:|;
 885 }
 886
 887 sub _write_classfile {
 888     my ($self, $class, $text) = @_;
 889
 890     my $filename = $self->_get_dump_filename($class);
 891     $self->_ensure_dump_subdirs($class);
 892
 893     if (-f $filename && $self->really_erase_my_files) {
 894         warn "Deleting existing file '$filename' due to "
 895             . "'really_erase_my_files' setting\n" unless $self->{quiet};
 896         unlink($filename);
 897     }
 898
 899     my ($custom_content, $old_md5, $old_ver, $old_ts) = $self->_get_custom_content($class, $filename);
 900
 901     if ($self->_upgrading_from) {
 902         my $old_class = $self->_upgrading_classes->{$class};
 903
 904         if ($old_class && ($old_class ne $class)) {
 905             my $old_filename = $self->_get_dump_filename($old_class);
 906
 907             my ($old_custom_content) = $self->_get_custom_content(
 908                 $old_class, $old_filename, 0 # do not add default comment
 909             );
 910
 911             $old_custom_content =~ s/\n\n# You can replace.*\n1;\n//;
 912
 913             if ($old_custom_content) {
 914                 $custom_content =
 915                     "\n" . $old_custom_content . "\n" . $custom_content;
 916             }
 917
 918             unlink $old_filename;
 919         }
 920     }
 921
 922     $text .= qq|$_\n|
 923         for @{$self->{_dump_storage}->{$class} || []};
 924
 925     # Check and see if the dump is infact differnt
 926
 927     my $compare_to;
 928     if ($old_md5) {
 929       $compare_to = $text . $self->_sig_comment($old_ver, $old_ts);
 930
 931
 932       if (Digest::MD5::md5_base64($compare_to) eq $old_md5) {
 933         return;
 934       }
 935     }
 936
 937     $text .= $self->_sig_comment(
 938       $self->version_to_dump,
 939       POSIX::strftime('%Y-%m-%d %H:%M:%S', localtime)
 940     );
 941
 942     open(my $fh, '>', $filename)
 943         or croak "Cannot open '$filename' for writing: $!";
 944
 945     # Write the top half and its MD5 sum
 946     print $fh $text . Digest::MD5::md5_base64($text) . "\n";
 947
 948     # Write out anything loaded via external partial class file in @INC
 949     print $fh qq|$_\n|
 950         for @{$self->{_ext_storage}->{$class} || []};
 951
 952     # Write out any custom content the user has added
 953     print $fh $custom_content;
 954
 955     close($fh)
 956         or croak "Error closing '$filename': $!";
 957 }
 958
 959 sub _default_custom_content {
 960     return qq|\n\n# You can replace this text with custom|
 961          . qq| content, and it will be preserved on regeneration|
 962          . qq|\n1;\n|;
 963 }
 964
 965 sub _get_custom_content {
 966     my ($self, $class, $filename, $add_default) = @_;
 967
 968     $add_default = 1 unless defined $add_default;
 969
 970     return ($self->_default_custom_content) if ! -f $filename;
 971
 972     open(my $fh, '<', $filename)
 973         or croak "Cannot open '$filename' for reading: $!";
 974
 975     my $mark_re =
 976         qr{^(# DO NOT MODIFY THIS OR ANYTHING ABOVE! md5sum:)([A-Za-z0-9/+]{22})\n};
 977
 978     my $buffer = '';
 979     my ($md5, $ts, $ver);
 980     while(<$fh>) {
 981         if(!$md5 && /$mark_re/) {
 982             $md5 = $2;
 983             my $line = $1;
 984
 985             # Pull out the previous version and timestamp
 986             ($ver, $ts) = $buffer =~ m/# Created by DBIx::Class::Schema::Loader v(.*?) @ (.*?)$/s;
 987
 988             $buffer .= $line;
 989             croak "Checksum mismatch in '$filename', the auto-generated part of the file has been modified outside of this loader.  Aborting.\nIf you want to overwrite these modifications, set the 'overwrite_modifications' loader option.\n"
 990                 if !$self->overwrite_modifications && Digest::MD5::md5_base64($buffer) ne $md5;
 991
 992             $buffer = '';
 993         }
 994         else {
 995             $buffer .= $_;
 996         }
 997     }
 998
 999     croak "Cannot not overwrite '$filename' without 'really_erase_my_files',"
1000         . " it does not appear to have been generated by Loader"
1001             if !$md5;
1002
1003     # Default custom content:
1004     $buffer ||= $self->_default_custom_content if $add_default;
1005
1006     return ($buffer, $md5, $ver, $ts);
1007 }
1008
1009 sub _use {
1010     my $self = shift;
1011     my $target = shift;
1012
1013     foreach (@_) {
1014         warn "$target: use $_;" if $self->debug;
1015         $self->_raw_stmt($target, "use $_;");
1016     }
1017 }
1018
1019 sub _inject {
1020     my $self = shift;
1021     my $target = shift;
1022     my $schema_class = $self->schema_class;
1023
1024     my $blist = join(q{ }, @_);
1025     warn "$target: use base qw/ $blist /;" if $self->debug && @_;
1026     $self->_raw_stmt($target, "use base qw/ $blist /;") if @_;
1027 }
1028
1029 # Create class with applicable bases, setup monikers, etc
1030 sub _make_src_class {
1031     my ($self, $table) = @_;
1032
1033     my $schema       = $self->schema;
1034     my $schema_class = $self->schema_class;
1035
1036     my $table_moniker = $self->_table2moniker($table);
1037     my @result_namespace = ($schema_class);
1038     if ($self->use_namespaces) {
1039         my $result_namespace = $self->result_namespace || 'Result';
1040         if ($result_namespace =~ /^\+(.*)/) {
1041             # Fully qualified namespace
1042             @result_namespace =  ($1)
1043         }
1044         else {
1045             # Relative namespace
1046             push @result_namespace, $result_namespace;
1047         }
1048     }
1049     my $table_class = join(q{::}, @result_namespace, $table_moniker);
1050
1051     if (my $upgrading_v = $self->_upgrading_from) {
1052         local $self->naming->{monikers} = $upgrading_v;
1053
1054         my $old_class = join(q{::}, @result_namespace,
1055             $self->_table2moniker($table));
1056
1057         $self->_upgrading_classes->{$table_class} = $old_class;
1058     }
1059
1060     my $table_normalized = lc $table;
1061     $self->classes->{$table} = $table_class;
1062     $self->classes->{$table_normalized} = $table_class;
1063     $self->monikers->{$table} = $table_moniker;
1064     $self->monikers->{$table_normalized} = $table_moniker;
1065
1066     $self->_use   ($table_class, @{$self->additional_classes});
1067     $self->_inject($table_class, @{$self->left_base_classes});
1068
1069     if (my @components = @{ $self->components }) {
1070         $self->_dbic_stmt($table_class, 'load_components', @components);
1071     }
1072
1073     $self->_dbic_stmt($table_class, 'load_resultset_components', @{$self->resultset_components})
1074         if @{$self->resultset_components};
1075     $self->_inject($table_class, @{$self->additional_base_classes});
1076 }
1077
1078 # Set up metadata (cols, pks, etc)
1079 sub _setup_src_meta {
1080     my ($self, $table) = @_;
1081
1082     my $schema       = $self->schema;
1083     my $schema_class = $self->schema_class;
1084
1085     my $table_class = $self->classes->{$table};
1086     my $table_moniker = $self->monikers->{$table};
1087
1088     my $table_name = $table;
1089     my $name_sep   = $self->schema->storage->sql_maker->name_sep;
1090
1091     if ($name_sep && $table_name =~ /\Q$name_sep\E/) {
1092         $table_name = \ $self->_quote_table_name($table_name);
1093     }
1094
1095     $self->_dbic_stmt($table_class,'table',$table_name);
1096
1097     my $cols = $self->_table_columns($table);
1098     my $col_info;
1099     eval { $col_info = $self->_columns_info_for($table) };
1100     if($@) {
1101         $self->_dbic_stmt($table_class,'add_columns',@$cols);
1102     }
1103     else {
1104         if ($self->_is_case_sensitive) {
1105             for my $col (keys %$col_info) {
1106                 $col_info->{$col}{accessor} = lc $col
1107                     if $col ne lc($col);
1108             }
1109         } else {
1110             $col_info = { map { lc($_), $col_info->{$_} } keys %$col_info };
1111         }
1112
1113         my $fks = $self->_table_fk_info($table);
1114
1115         for my $fkdef (@$fks) {
1116             for my $col (@{ $fkdef->{local_columns} }) {
1117                 $col_info->{$col}{is_foreign_key} = 1;
1118             }
1119         }
1120         $self->_dbic_stmt(
1121             $table_class,
1122             'add_columns',
1123             map { $_, ($col_info->{$_}||{}) } @$cols
1124         );
1125     }
1126
1127     my %uniq_tag; # used to eliminate duplicate uniqs
1128
1129     my $pks = $self->_table_pk_info($table) || [];
1130     @$pks ? $self->_dbic_stmt($table_class,'set_primary_key',@$pks)
1131           : carp("$table has no primary key");
1132     $uniq_tag{ join("\0", @$pks) }++ if @$pks; # pk is a uniq
1133
1134     my $uniqs = $self->_table_uniq_info($table) || [];
1135     for (@$uniqs) {
1136         my ($name, $cols) = @$_;
1137         next if $uniq_tag{ join("\0", @$cols) }++; # skip duplicates
1138         $self->_dbic_stmt($table_class,'add_unique_constraint', $name, $cols);
1139     }
1140
1141 }
1142
1143 =head2 tables
1144
1145 Returns a sorted list of loaded tables, using the original database table
1146 names.
1147
1148 =cut
1149
1150 sub tables {
1151     my $self = shift;
1152
1153     return keys %{$self->_tables};
1154 }
1155
1156 # Make a moniker from a table
1157 sub _default_table2moniker {
1158     no warnings 'uninitialized';
1159     my ($self, $table) = @_;
1160
1161     if ($self->naming->{monikers} eq 'v4') {
1162         return join '', map ucfirst, split /[\W_]+/, lc $table;
1163     }
1164
1165     return join '', map ucfirst, split /[\W_]+/,
1166         Lingua::EN::Inflect::Number::to_S(lc $table);
1167 }
1168
1169 sub _table2moniker {
1170     my ( $self, $table ) = @_;
1171
1172     my $moniker;
1173
1174     if( ref $self->moniker_map eq 'HASH' ) {
1175         $moniker = $self->moniker_map->{$table};
1176     }
1177     elsif( ref $self->moniker_map eq 'CODE' ) {
1178         $moniker = $self->moniker_map->($table);
1179     }
1180
1181     $moniker ||= $self->_default_table2moniker($table);
1182
1183     return $moniker;
1184 }
1185
1186 sub _load_relationships {
1187     my ($self, $table) = @_;
1188
1189     my $tbl_fk_info = $self->_table_fk_info($table);
1190     foreach my $fkdef (@$tbl_fk_info) {
1191         $fkdef->{remote_source} =
1192             $self->monikers->{delete $fkdef->{remote_table}};
1193     }
1194     my $tbl_uniq_info = $self->_table_uniq_info($table);
1195
1196     my $local_moniker = $self->monikers->{$table};
1197     my $rel_stmts = $self->_relbuilder->generate_code($local_moniker, $tbl_fk_info, $tbl_uniq_info);
1198
1199     foreach my $src_class (sort keys %$rel_stmts) {
1200         my $src_stmts = $rel_stmts->{$src_class};
1201         foreach my $stmt (@$src_stmts) {
1202             $self->_dbic_stmt($src_class,$stmt->{method},@{$stmt->{args}});
1203         }
1204     }
1205 }
1206
1207 # Overload these in driver class:
1208
1209 # Returns an arrayref of column names
1210 sub _table_columns { croak "ABSTRACT METHOD" }
1211
1212 # Returns arrayref of pk col names
1213 sub _table_pk_info { croak "ABSTRACT METHOD" }
1214
1215 # Returns an arrayref of uniqs [ [ foo => [ col1, col2 ] ], [ bar => [ ... ] ] ]
1216 sub _table_uniq_info { croak "ABSTRACT METHOD" }
1217
1218 # Returns an arrayref of foreign key constraints, each
1219 #   being a hashref with 3 keys:
1220 #   local_columns (arrayref), remote_columns (arrayref), remote_table
1221 sub _table_fk_info { croak "ABSTRACT METHOD" }
1222
1223 # Returns an array of lower case table names
1224 sub _tables_list { croak "ABSTRACT METHOD" }
1225
1226 # Execute a constructive DBIC class method, with debug/dump_to_dir hooks.
1227 sub _dbic_stmt {
1228     my $self   = shift;
1229     my $class  = shift;
1230     my $method = shift;
1231
1232     # generate the pod for this statement, storing it with $self->_pod
1233     $self->_make_pod( $class, $method, @_ );
1234
1235     my $args = dump(@_);
1236     $args = '(' . $args . ')' if @_ < 2;
1237     my $stmt = $method . $args . q{;};
1238
1239     warn qq|$class\->$stmt\n| if $self->debug;
1240     $self->_raw_stmt($class, '__PACKAGE__->' . $stmt);
1241     return;
1242 }
1243
1244 # generates the accompanying pod for a DBIC class method statement,
1245 # storing it with $self->_pod
1246 sub _make_pod {
1247     my $self   = shift;
1248     my $class  = shift;
1249     my $method = shift;
1250
1251     if ( $method eq 'table' ) {
1252         my ($table) = @_;
1253         $self->_pod( $class, "=head1 NAME" );
1254         my $table_descr = $class;
1255         if ( $self->can('_table_comment') ) {
1256             my $comment = $self->_table_comment($table);
1257             $table_descr .= " - " . $comment if $comment;
1258         }
1259         $self->{_class2table}{ $class } = $table;
1260         $self->_pod( $class, $table_descr );
1261         $self->_pod_cut( $class );
1262     } elsif ( $method eq 'add_columns' ) {
1263         $self->_pod( $class, "=head1 ACCESSORS" );
1264         my $col_counter = 0;
1265         my @cols = @_;
1266         while( my ($name,$attrs) = splice @cols,0,2 ) {
1267             $col_counter++;
1268             $self->_pod( $class, '=head2 ' . $name  );
1269             $self->_pod( $class,
1270                          join "\n", map {
1271                              my $s = $attrs->{$_};
1272                              $s = !defined $s      ? 'undef'          :
1273                                   length($s) == 0  ? '(empty string)' :
1274                                                      $s;
1275
1276                              "  $_: $s"
1277                          } sort keys %$attrs,
1278                        );
1279
1280             if( $self->can('_column_comment')
1281                 and my $comment = $self->_column_comment( $self->{_class2table}{$class}, $col_counter)
1282               ) {
1283                 $self->_pod( $class, $comment );
1284             }
1285         }
1286         $self->_pod_cut( $class );
1287     } elsif ( $method =~ /^(belongs_to|has_many|might_have)$/ ) {
1288         $self->_pod( $class, "=head1 RELATIONS" ) unless $self->{_relations_started} { $class } ;
1289         my ( $accessor, $rel_class ) = @_;
1290         $self->_pod( $class, "=head2 $accessor" );
1291         $self->_pod( $class, 'Type: ' . $method );
1292         $self->_pod( $class, "Related object: L<$rel_class>" );
1293         $self->_pod_cut( $class );
1294         $self->{_relations_started} { $class } = 1;
1295     }
1296 }
1297
1298 # Stores a POD documentation
1299 sub _pod {
1300     my ($self, $class, $stmt) = @_;
1301     $self->_raw_stmt( $class, "\n" . $stmt  );
1302 }
1303
1304 sub _pod_cut {
1305     my ($self, $class ) = @_;
1306     $self->_raw_stmt( $class, "\n=cut\n" );
1307 }
1308
1309
1310 # Store a raw source line for a class (for dumping purposes)
1311 sub _raw_stmt {
1312     my ($self, $class, $stmt) = @_;
1313     push(@{$self->{_dump_storage}->{$class}}, $stmt);
1314 }
1315
1316 # Like above, but separately for the externally loaded stuff
1317 sub _ext_stmt {
1318     my ($self, $class, $stmt) = @_;
1319     push(@{$self->{_ext_storage}->{$class}}, $stmt);
1320 }
1321
1322 sub _quote_table_name {
1323     my ($self, $table) = @_;
1324
1325     my $qt = $self->schema->storage->sql_maker->quote_char;
1326
1327     return $table unless $qt;
1328
1329     if (ref $qt) {
1330         return $qt->[0] . $table . $qt->[1];
1331     }
1332
1333     return $qt . $table . $qt;
1334 }
1335
1336 sub _is_case_sensitive { 0 }
1337
1338 # remove the dump dir from @INC on destruction
1339 sub DESTROY {
1340     my $self = shift;
1341
1342     @INC = grep $_ ne $self->dump_directory, @INC;
1343 }
1344
1345 =head2 monikers
1346
1347 Returns a hashref of loaded table to moniker mappings.  There will
1348 be two entries for each table, the original name and the "normalized"
1349 name, in the case that the two are different (such as databases
1350 that like uppercase table names, or preserve your original mixed-case
1351 definitions, or what-have-you).
1352
1353 =head2 classes
1354
1355 Returns a hashref of table to class mappings.  In some cases it will
1356 contain multiple entries per table for the original and normalized table
1357 names, as above in L</monikers>.
1358
1359 =head1 SEE ALSO
1360
1361 L<DBIx::Class::Schema::Loader>
1362
1363 =head1 AUTHOR
1364
1365 See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
1366
1367 =head1 LICENSE
1368
1369 This library is free software; you can redistribute it and/or modify it under
1370 the same terms as Perl itself.
1371
1372 =cut
1373
1374 1;