lib/DBIx/Class/Schema/Loader/Base.pm

   1 package DBIx::Class::Schema::Loader::Base;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/Class::Accessor::Grouped Class::C3::Componentised/;
   6 use Class::C3;
   7 use Carp::Clan qw/^DBIx::Class/;
   8 use DBIx::Class::Schema::Loader::RelBuilder;
   9 use Data::Dump qw/ dump /;
  10 use POSIX qw//;
  11 use File::Spec qw//;
  12 use Cwd qw//;
  13 use Digest::MD5 qw//;
  14 use Lingua::EN::Inflect::Number qw//;
  15 use File::Temp qw//;
  16 use Class::Unload;
  17 require DBIx::Class;
  18
  19 our $VERSION = '0.04999_13';
  20
  21 __PACKAGE__->mk_group_ro_accessors('simple', qw/
  22                                 schema
  23                                 schema_class
  24
  25                                 exclude
  26                                 constraint
  27                                 additional_classes
  28                                 additional_base_classes
  29                                 left_base_classes
  30                                 components
  31                                 resultset_components
  32                                 skip_relationships
  33                                 skip_load_external
  34                                 moniker_map
  35                                 inflect_singular
  36                                 inflect_plural
  37                                 debug
  38                                 dump_directory
  39                                 dump_overwrite
  40                                 really_erase_my_files
  41                                 resultset_namespace
  42                                 default_resultset_class
  43                                 schema_base_class
  44                                 result_base_class
  45                                 overwrite_modifications
  46
  47                                 relationship_attrs
  48
  49                                 db_schema
  50                                 _tables
  51                                 classes
  52                                 _upgrading_classes
  53                                 monikers
  54                                 dynamic
  55                                 naming
  56 /);
  57
  58
  59 __PACKAGE__->mk_group_accessors('simple', qw/
  60                                 version_to_dump
  61                                 schema_version_to_dump
  62                                 _upgrading_from
  63                                 _upgrading_from_load_classes
  64                                 _downgrading_to_load_classes
  65                                 _rewriting_result_namespace
  66                                 use_namespaces
  67                                 result_namespace
  68 /);
  69
  70 =head1 NAME
  71
  72 DBIx::Class::Schema::Loader::Base - Base DBIx::Class::Schema::Loader Implementation.
  73
  74 =head1 SYNOPSIS
  75
  76 See L<DBIx::Class::Schema::Loader>
  77
  78 =head1 DESCRIPTION
  79
  80 This is the base class for the storage-specific C<DBIx::Class::Schema::*>
  81 classes, and implements the common functionality between them.
  82
  83 =head1 CONSTRUCTOR OPTIONS
  84
  85 These constructor options are the base options for
  86 L<DBIx::Class::Schema::Loader/loader_options>.  Available constructor options are:
  87
  88 =head2 skip_relationships
  89
  90 Skip setting up relationships.  The default is to attempt the loading
  91 of relationships.
  92
  93 =head2 skip_load_external
  94
  95 Skip loading of other classes in @INC. The default is to merge all other classes
  96 with the same name found in @INC into the schema file we are creating.
  97
  98 =head2 naming
  99
 100 Static schemas (ones dumped to disk) will, by default, use the new-style 0.05XXX
 101 relationship names and singularized Results, unless you're overwriting an
 102 existing dump made by a 0.04XXX version of L<DBIx::Class::Schema::Loader>, in
 103 which case the backward compatible RelBuilder will be activated, and
 104 singularization will be turned off.
 105
 106 Specifying
 107
 108     naming => 'v5'
 109
 110 will disable the backward-compatible RelBuilder and use
 111 the new-style relationship names along with singularized Results, even when
 112 overwriting a dump made with an earlier version.
 113
 114 The option also takes a hashref:
 115
 116     naming => { relationships => 'v5', monikers => 'v4' }
 117
 118 The keys are:
 119
 120 =over 4
 121
 122 =item relationships
 123
 124 How to name relationship accessors.
 125
 126 =item monikers
 127
 128 How to name Result classes.
 129
 130 =back
 131
 132 The values can be:
 133
 134 =over 4
 135
 136 =item current
 137
 138 Latest default style, whatever that happens to be.
 139
 140 =item v5
 141
 142 Version 0.05XXX style.
 143
 144 =item v4
 145
 146 Version 0.04XXX style.
 147
 148 =back
 149
 150 Dynamic schemas will always default to the 0.04XXX relationship names and won't
 151 singularize Results for backward compatibility, to activate the new RelBuilder
 152 and singularization put this in your C<Schema.pm> file:
 153
 154     __PACKAGE__->naming('current');
 155
 156 Or if you prefer to use 0.05XXX features but insure that nothing breaks in the
 157 next major version upgrade:
 158
 159     __PACKAGE__->naming('v5');
 160
 161 =head2 relationship_attrs
 162
 163 Hashref of attributes to pass to each generated relationship, listed
 164 by type.  Also supports relationship type 'all', containing options to
 165 pass to all generated relationships.  Attributes set for more specific
 166 relationship types override those set in 'all'.
 167
 168 For example:
 169
 170   relationship_attrs => {
 171     all      => { cascade_delete => 0 },
 172     has_many => { cascade_delete => 1 },
 173   },
 174
 175 will set the C<cascade_delete> option to 0 for all generated relationships,
 176 except for C<has_many>, which will have cascade_delete as 1.
 177
 178 NOTE: this option is not supported if v4 backward-compatible naming is
 179 set either globally (naming => 'v4') or just for relationships.
 180
 181 =head2 debug
 182
 183 If set to true, each constructive L<DBIx::Class> statement the loader
 184 decides to execute will be C<warn>-ed before execution.
 185
 186 =head2 db_schema
 187
 188 Set the name of the schema to load (schema in the sense that your database
 189 vendor means it).  Does not currently support loading more than one schema
 190 name.
 191
 192 =head2 constraint
 193
 194 Only load tables matching regex.  Best specified as a qr// regex.
 195
 196 =head2 exclude
 197
 198 Exclude tables matching regex.  Best specified as a qr// regex.
 199
 200 =head2 moniker_map
 201
 202 Overrides the default table name to moniker translation.  Can be either
 203 a hashref of table keys and moniker values, or a coderef for a translator
 204 function taking a single scalar table name argument and returning
 205 a scalar moniker.  If the hash entry does not exist, or the function
 206 returns a false value, the code falls back to default behavior
 207 for that table name.
 208
 209 The default behavior is to singularize the table name, and: C<join '', map
 210 ucfirst, split /[\W_]+/, lc $table>, which is to say: lowercase everything,
 211 split up the table name into chunks anywhere a non-alpha-numeric character
 212 occurs, change the case of first letter of each chunk to upper case, and put
 213 the chunks back together.  Examples:
 214
 215     Table Name  | Moniker Name
 216     ---------------------------
 217     luser       | Luser
 218     luser_group | LuserGroup
 219     luser-opts  | LuserOpt
 220
 221 =head2 inflect_plural
 222
 223 Just like L</moniker_map> above (can be hash/code-ref, falls back to default
 224 if hash key does not exist or coderef returns false), but acts as a map
 225 for pluralizing relationship names.  The default behavior is to utilize
 226 L<Lingua::EN::Inflect::Number/to_PL>.
 227
 228 =head2 inflect_singular
 229
 230 As L</inflect_plural> above, but for singularizing relationship names.
 231 Default behavior is to utilize L<Lingua::EN::Inflect::Number/to_S>.
 232
 233 =head2 schema_base_class
 234
 235 Base class for your schema classes. Defaults to 'DBIx::Class::Schema'.
 236
 237 =head2 result_base_class
 238
 239 Base class for your table classes (aka result classes). Defaults to
 240 'DBIx::Class::Core'.
 241
 242 =head2 additional_base_classes
 243
 244 List of additional base classes all of your table classes will use.
 245
 246 =head2 left_base_classes
 247
 248 List of additional base classes all of your table classes will use
 249 that need to be leftmost.
 250
 251 =head2 additional_classes
 252
 253 List of additional classes which all of your table classes will use.
 254
 255 =head2 components
 256
 257 List of additional components to be loaded into all of your table
 258 classes.  A good example would be C<ResultSetManager>.
 259
 260 =head2 resultset_components
 261
 262 List of additional ResultSet components to be loaded into your table
 263 classes.  A good example would be C<AlwaysRS>.  Component
 264 C<ResultSetManager> will be automatically added to the above
 265 C<components> list if this option is set.
 266
 267 =head2 use_namespaces
 268
 269 This is now the default, to go back to L<DBIx::Class::Schema/load_classes> pass
 270 a C<0>.
 271
 272 Generate result class names suitable for
 273 L<DBIx::Class::Schema/load_namespaces> and call that instead of
 274 L<DBIx::Class::Schema/load_classes>. When using this option you can also
 275 specify any of the options for C<load_namespaces> (i.e. C<result_namespace>,
 276 C<resultset_namespace>, C<default_resultset_class>), and they will be added
 277 to the call (and the generated result class names adjusted appropriately).
 278
 279 =head2 dump_directory
 280
 281 This option is designed to be a tool to help you transition from this
 282 loader to a manually-defined schema when you decide it's time to do so.
 283
 284 The value of this option is a perl libdir pathname.  Within
 285 that directory this module will create a baseline manual
 286 L<DBIx::Class::Schema> module set, based on what it creates at runtime
 287 in memory.
 288
 289 The created schema class will have the same classname as the one on
 290 which you are setting this option (and the ResultSource classes will be
 291 based on this name as well).
 292
 293 Normally you wouldn't hard-code this setting in your schema class, as it
 294 is meant for one-time manual usage.
 295
 296 See L<DBIx::Class::Schema::Loader/dump_to_dir> for examples of the
 297 recommended way to access this functionality.
 298
 299 =head2 dump_overwrite
 300
 301 Deprecated.  See L</really_erase_my_files> below, which does *not* mean
 302 the same thing as the old C<dump_overwrite> setting from previous releases.
 303
 304 =head2 really_erase_my_files
 305
 306 Default false.  If true, Loader will unconditionally delete any existing
 307 files before creating the new ones from scratch when dumping a schema to disk.
 308
 309 The default behavior is instead to only replace the top portion of the
 310 file, up to and including the final stanza which contains
 311 C<# DO NOT MODIFY THIS OR ANYTHING ABOVE!>
 312 leaving any customizations you placed after that as they were.
 313
 314 When C<really_erase_my_files> is not set, if the output file already exists,
 315 but the aforementioned final stanza is not found, or the checksum
 316 contained there does not match the generated contents, Loader will
 317 croak and not touch the file.
 318
 319 You should really be using version control on your schema classes (and all
 320 of the rest of your code for that matter).  Don't blame me if a bug in this
 321 code wipes something out when it shouldn't have, you've been warned.
 322
 323 =head2 overwrite_modifications
 324
 325 Default false.  If false, when updating existing files, Loader will
 326 refuse to modify any Loader-generated code that has been modified
 327 since its last run (as determined by the checksum Loader put in its
 328 comment lines).
 329
 330 If true, Loader will discard any manual modifications that have been
 331 made to Loader-generated code.
 332
 333 Again, you should be using version control on your schema classes.  Be
 334 careful with this option.
 335
 336 =head1 METHODS
 337
 338 None of these methods are intended for direct invocation by regular
 339 users of L<DBIx::Class::Schema::Loader>.  Anything you can find here
 340 can also be found via standard L<DBIx::Class::Schema> methods somehow.
 341
 342 =cut
 343
 344 use constant CURRENT_V => 'v5';
 345
 346 # ensure that a peice of object data is a valid arrayref, creating
 347 # an empty one or encapsulating whatever's there.
 348 sub _ensure_arrayref {
 349     my $self = shift;
 350
 351     foreach (@_) {
 352         $self->{$_} ||= [];
 353         $self->{$_} = [ $self->{$_} ]
 354             unless ref $self->{$_} eq 'ARRAY';
 355     }
 356 }
 357
 358 =head2 new
 359
 360 Constructor for L<DBIx::Class::Schema::Loader::Base>, used internally
 361 by L<DBIx::Class::Schema::Loader>.
 362
 363 =cut
 364
 365 sub new {
 366     my ( $class, %args ) = @_;
 367
 368     my $self = { %args };
 369
 370     bless $self => $class;
 371
 372     $self->_ensure_arrayref(qw/additional_classes
 373                                additional_base_classes
 374                                left_base_classes
 375                                components
 376                                resultset_components
 377                               /);
 378
 379     push(@{$self->{components}}, 'ResultSetManager')
 380         if @{$self->{resultset_components}};
 381
 382     $self->{monikers} = {};
 383     $self->{classes} = {};
 384     $self->{_upgrading_classes} = {};
 385
 386     $self->{schema_class} ||= ( ref $self->{schema} || $self->{schema} );
 387     $self->{schema} ||= $self->{schema_class};
 388
 389     croak "dump_overwrite is deprecated.  Please read the"
 390         . " DBIx::Class::Schema::Loader::Base documentation"
 391             if $self->{dump_overwrite};
 392
 393     $self->{dynamic} = ! $self->{dump_directory};
 394     $self->{temp_directory} ||= File::Temp::tempdir( 'dbicXXXX',
 395                                                      TMPDIR  => 1,
 396                                                      CLEANUP => 1,
 397                                                    );
 398
 399     $self->{dump_directory} ||= $self->{temp_directory};
 400
 401     $self->version_to_dump($DBIx::Class::Schema::Loader::VERSION);
 402     $self->schema_version_to_dump($DBIx::Class::Schema::Loader::VERSION);
 403
 404     if ((not ref $self->naming) && defined $self->naming) {
 405         my $naming_ver = $self->naming;
 406         $self->{naming} = {
 407             relationships => $naming_ver,
 408             monikers => $naming_ver,
 409         };
 410     }
 411
 412     if ($self->naming) {
 413         for (values %{ $self->naming }) {
 414             $_ = CURRENT_V if $_ eq 'current';
 415         }
 416     }
 417     $self->{naming} ||= {};
 418
 419     $self->_check_back_compat;
 420
 421     $self->use_namespaces(1) unless defined $self->use_namespaces;
 422
 423     $self;
 424 }
 425
 426 sub _check_back_compat {
 427     my ($self) = @_;
 428
 429 # dynamic schemas will always be in 0.04006 mode, unless overridden
 430     if ($self->dynamic) {
 431 # just in case, though no one is likely to dump a dynamic schema
 432         $self->schema_version_to_dump('0.04006');
 433
 434         if (not %{ $self->naming }) {
 435             warn <<EOF unless $ENV{SCHEMA_LOADER_BACKCOMPAT};
 436
 437 Dynamic schema detected, will run in 0.04006 mode.
 438
 439 Set the 'naming' attribute or the SCHEMA_LOADER_BACKCOMPAT environment variable
 440 to disable this warning.
 441
 442 Also consider setting 'use_namespaces => 1' if/when upgrading.
 443
 444 See perldoc DBIx::Class::Schema::Loader::Manual::UpgradingFromV4 for more
 445 details.
 446 EOF
 447         }
 448         else {
 449             $self->_upgrading_from('v4');
 450         }
 451
 452         $self->naming->{relationships} ||= 'v4';
 453         $self->naming->{monikers}      ||= 'v4';
 454
 455         if ($self->use_namespaces) {
 456             $self->_upgrading_from_load_classes(1);
 457         }
 458         else {
 459             $self->use_namespaces(0);
 460         }
 461
 462         return;
 463     }
 464
 465 # otherwise check if we need backcompat mode for a static schema
 466     my $filename = $self->_get_dump_filename($self->schema_class);
 467     return unless -e $filename;
 468
 469     open(my $fh, '<', $filename)
 470         or croak "Cannot open '$filename' for reading: $!";
 471
 472     my $load_classes     = 0;
 473     my $result_namespace = '';
 474
 475     while (<$fh>) {
 476         if (/^__PACKAGE__->load_classes;/) {
 477             $load_classes = 1;
 478         } elsif (/result_namespace => '([^']+)'/) {
 479             $result_namespace = $1;
 480         } elsif (my ($real_ver) =
 481                 /^# Created by DBIx::Class::Schema::Loader v(\d+\.\d+)/) {
 482
 483             if ($load_classes && (not defined $self->use_namespaces)) {
 484                 warn <<"EOF"  unless $ENV{SCHEMA_LOADER_BACKCOMPAT};
 485
 486 'load_classes;' static schema detected, turning off 'use_namespaces'.
 487
 488 Set the 'use_namespaces' attribute or the SCHEMA_LOADER_BACKCOMPAT environment
 489 variable to disable this warning.
 490
 491 See perldoc DBIx::Class::Schema::Loader::Manual::UpgradingFromV4 for more
 492 details.
 493 EOF
 494                 $self->use_namespaces(0);
 495             }
 496             elsif ($load_classes && $self->use_namespaces) {
 497                 $self->_upgrading_from_load_classes(1);
 498             }
 499             elsif ((not $load_classes) && defined $self->use_namespaces
 500                                        && (not $self->use_namespaces)) {
 501                 $self->_downgrading_to_load_classes(
 502                     $result_namespace || 'Result'
 503                 );
 504             }
 505             elsif ((not defined $self->use_namespaces)
 506                    || $self->use_namespaces) {
 507                 if (not $self->result_namespace) {
 508                     $self->result_namespace($result_namespace || 'Result');
 509                 }
 510                 elsif ($result_namespace ne $self->result_namespace) {
 511                     $self->_rewriting_result_namespace(
 512                         $result_namespace || 'Result'
 513                     );
 514                 }
 515             }
 516
 517             # XXX when we go past .0 this will need fixing
 518             my ($v) = $real_ver =~ /([1-9])/;
 519             $v = "v$v";
 520
 521             last if $v eq CURRENT_V || $real_ver =~ /^0\.\d\d999/;
 522
 523             if (not %{ $self->naming }) {
 524                 warn <<"EOF" unless $ENV{SCHEMA_LOADER_BACKCOMPAT};
 525
 526 Version $real_ver static schema detected, turning on backcompat mode.
 527
 528 Set the 'naming' attribute or the SCHEMA_LOADER_BACKCOMPAT environment variable
 529 to disable this warning.
 530
 531 See perldoc DBIx::Class::Schema::Loader::Manual::UpgradingFromV4 for more
 532 details.
 533 EOF
 534             }
 535             else {
 536                 $self->_upgrading_from($v);
 537                 last;
 538             }
 539
 540             $self->naming->{relationships} ||= $v;
 541             $self->naming->{monikers}      ||= $v;
 542
 543             $self->schema_version_to_dump($real_ver);
 544
 545             last;
 546         }
 547     }
 548     close $fh;
 549 }
 550
 551 sub _find_file_in_inc {
 552     my ($self, $file) = @_;
 553
 554     foreach my $prefix (@INC) {
 555         my $fullpath = File::Spec->catfile($prefix, $file);
 556         return $fullpath if -f $fullpath
 557             and Cwd::abs_path($fullpath) ne
 558                (Cwd::abs_path(File::Spec->catfile($self->dump_directory, $file)) || '');
 559     }
 560
 561     return;
 562 }
 563
 564 sub _class_path {
 565     my ($self, $class) = @_;
 566
 567     my $class_path = $class;
 568     $class_path =~ s{::}{/}g;
 569     $class_path .= '.pm';
 570
 571     return $class_path;
 572 }
 573
 574 sub _find_class_in_inc {
 575     my ($self, $class) = @_;
 576
 577     return $self->_find_file_in_inc($self->_class_path($class));
 578 }
 579
 580 sub _rewriting {
 581     my $self = shift;
 582
 583     return $self->_upgrading_from
 584         || $self->_upgrading_from_load_classes
 585         || $self->_downgrading_to_load_classes
 586         || $self->_rewriting_result_namespace
 587     ;
 588 }
 589
 590 sub _rewrite_old_classnames {
 591     my ($self, $code) = @_;
 592
 593     return $code unless $self->_rewriting;
 594
 595     my %old_classes = reverse %{ $self->_upgrading_classes };
 596
 597     my $re = join '|', keys %old_classes;
 598     $re = qr/\b($re)\b/;
 599
 600     $code =~ s/$re/$old_classes{$1} || $1/eg;
 601
 602     return $code;
 603 }
 604
 605 sub _load_external {
 606     my ($self, $class) = @_;
 607
 608     return if $self->{skip_load_external};
 609
 610     # so that we don't load our own classes, under any circumstances
 611     local *INC = [ grep $_ ne $self->dump_directory, @INC ];
 612
 613     my $real_inc_path = $self->_find_class_in_inc($class);
 614
 615     my $old_class = $self->_upgrading_classes->{$class}
 616         if $self->_rewriting;
 617
 618     my $old_real_inc_path = $self->_find_class_in_inc($old_class)
 619         if $old_class && $old_class ne $class;
 620
 621     return unless $real_inc_path || $old_real_inc_path;
 622
 623     if ($real_inc_path) {
 624         # If we make it to here, we loaded an external definition
 625         warn qq/# Loaded external class definition for '$class'\n/
 626             if $self->debug;
 627
 628         open(my $fh, '<', $real_inc_path)
 629             or croak "Failed to open '$real_inc_path' for reading: $!";
 630         my $code = do { local $/; <$fh> };
 631         close($fh)
 632             or croak "Failed to close $real_inc_path: $!";
 633         $code = $self->_rewrite_old_classnames($code);
 634
 635         if ($self->dynamic) { # load the class too
 636             # kill redefined warnings
 637             my $warn_handler = $SIG{__WARN__} || sub { warn @_ };
 638             local $SIG{__WARN__} = sub {
 639                 $warn_handler->(@_)
 640                     unless $_[0] =~ /^Subroutine \S+ redefined/;
 641             };
 642             eval $code;
 643             die $@ if $@;
 644         }
 645
 646         $self->_ext_stmt($class,
 647           qq|# These lines were loaded from '$real_inc_path' found in \@INC.\n|
 648          .qq|# They are now part of the custom portion of this file\n|
 649          .qq|# for you to hand-edit.  If you do not either delete\n|
 650          .qq|# this section or remove that file from \@INC, this section\n|
 651          .qq|# will be repeated redundantly when you re-create this\n|
 652          .qq|# file again via Loader!  See skip_load_external to disable\n|
 653          .qq|# this feature.\n|
 654         );
 655         chomp $code;
 656         $self->_ext_stmt($class, $code);
 657         $self->_ext_stmt($class,
 658             qq|# End of lines loaded from '$real_inc_path' |
 659         );
 660     }
 661
 662     if ($old_real_inc_path) {
 663         open(my $fh, '<', $old_real_inc_path)
 664             or croak "Failed to open '$old_real_inc_path' for reading: $!";
 665         $self->_ext_stmt($class, <<"EOF");
 666
 667 # These lines were loaded from '$old_real_inc_path',
 668 # based on the Result class name that would have been created by an 0.04006
 669 # version of the Loader. For a static schema, this happens only once during
 670 # upgrade. See skip_load_external to disable this feature.
 671 EOF
 672
 673         my $code = do {
 674             local ($/, @ARGV) = (undef, $old_real_inc_path); <>
 675         };
 676         $code = $self->_rewrite_old_classnames($code);
 677
 678         if ($self->dynamic) {
 679             warn <<"EOF";
 680
 681 Detected external content in '$old_real_inc_path', a class name that would have
 682 been used by an 0.04006 version of the Loader.
 683
 684 * PLEASE RENAME THIS CLASS: from '$old_class' to '$class', as that is the
 685 new name of the Result.
 686 EOF
 687             # kill redefined warnings
 688             my $warn_handler = $SIG{__WARN__} || sub { warn @_ };
 689             local $SIG{__WARN__} = sub {
 690                 $warn_handler->(@_)
 691                     unless $_[0] =~ /^Subroutine \S+ redefined/;
 692             };
 693             eval $code;
 694             die $@ if $@;
 695         }
 696
 697         chomp $code;
 698         $self->_ext_stmt($class, $code);
 699         $self->_ext_stmt($class,
 700             qq|# End of lines loaded from '$old_real_inc_path' |
 701         );
 702     }
 703 }
 704
 705 =head2 load
 706
 707 Does the actual schema-construction work.
 708
 709 =cut
 710
 711 sub load {
 712     my $self = shift;
 713
 714     $self->_load_tables($self->_tables_list);
 715 }
 716
 717 =head2 rescan
 718
 719 Arguments: schema
 720
 721 Rescan the database for newly added tables.  Does
 722 not process drops or changes.  Returns a list of
 723 the newly added table monikers.
 724
 725 The schema argument should be the schema class
 726 or object to be affected.  It should probably
 727 be derived from the original schema_class used
 728 during L</load>.
 729
 730 =cut
 731
 732 sub rescan {
 733     my ($self, $schema) = @_;
 734
 735     $self->{schema} = $schema;
 736     $self->_relbuilder->{schema} = $schema;
 737
 738     my @created;
 739     my @current = $self->_tables_list;
 740     foreach my $table ($self->_tables_list) {
 741         if(!exists $self->{_tables}->{$table}) {
 742             push(@created, $table);
 743         }
 744     }
 745
 746     my $loaded = $self->_load_tables(@created);
 747
 748     return map { $self->monikers->{$_} } @$loaded;
 749 }
 750
 751 sub _relbuilder {
 752     no warnings 'uninitialized';
 753     my ($self) = @_;
 754
 755     return if $self->{skip_relationships};
 756
 757     if ($self->naming->{relationships} eq 'v4') {
 758         require DBIx::Class::Schema::Loader::RelBuilder::Compat::v0_040;
 759         return $self->{relbuilder} ||=
 760             DBIx::Class::Schema::Loader::RelBuilder::Compat::v0_040->new(
 761                 $self->schema, $self->inflect_plural, $self->inflect_singular
 762             );
 763     }
 764
 765     $self->{relbuilder} ||= DBIx::Class::Schema::Loader::RelBuilder->new (
 766          $self->schema,
 767          $self->inflect_plural,
 768          $self->inflect_singular,
 769          $self->relationship_attrs,
 770     );
 771 }
 772
 773 sub _load_tables {
 774     my ($self, @tables) = @_;
 775
 776     # First, use _tables_list with constraint and exclude
 777     #  to get a list of tables to operate on
 778
 779     my $constraint   = $self->constraint;
 780     my $exclude      = $self->exclude;
 781
 782     @tables = grep { /$constraint/ } @tables if $constraint;
 783     @tables = grep { ! /$exclude/ } @tables if $exclude;
 784
 785     # Save the new tables to the tables list
 786     foreach (@tables) {
 787         $self->{_tables}->{$_} = 1;
 788     }
 789
 790     $self->_make_src_class($_) for @tables;
 791     $self->_setup_src_meta($_) for @tables;
 792
 793     if(!$self->skip_relationships) {
 794         # The relationship loader needs a working schema
 795         $self->{quiet} = 1;
 796         local $self->{dump_directory} = $self->{temp_directory};
 797         $self->_reload_classes(\@tables);
 798         $self->_load_relationships($_) for @tables;
 799         $self->{quiet} = 0;
 800
 801         # Remove that temp dir from INC so it doesn't get reloaded
 802         @INC = grep $_ ne $self->dump_directory, @INC;
 803     }
 804
 805     $self->_load_external($_)
 806         for map { $self->classes->{$_} } @tables;
 807
 808     # Reload without unloading first to preserve any symbols from external
 809     # packages.
 810     $self->_reload_classes(\@tables, 0);
 811
 812     # Drop temporary cache
 813     delete $self->{_cache};
 814
 815     return \@tables;
 816 }
 817
 818 sub _reload_classes {
 819     my ($self, $tables, $unload) = @_;
 820
 821     my @tables = @$tables;
 822     $unload = 1 unless defined $unload;
 823
 824     # so that we don't repeat custom sections
 825     @INC = grep $_ ne $self->dump_directory, @INC;
 826
 827     $self->_dump_to_dir(map { $self->classes->{$_} } @tables);
 828
 829     unshift @INC, $self->dump_directory;
 830
 831     my @to_register;
 832     my %have_source = map { $_ => $self->schema->source($_) }
 833         $self->schema->sources;
 834
 835     for my $table (@tables) {
 836         my $moniker = $self->monikers->{$table};
 837         my $class = $self->classes->{$table};
 838
 839         {
 840             no warnings 'redefine';
 841             local *Class::C3::reinitialize = sub {};
 842             use warnings;
 843
 844             Class::Unload->unload($class) if $unload;
 845             my ($source, $resultset_class);
 846             if (
 847                 ($source = $have_source{$moniker})
 848                 && ($resultset_class = $source->resultset_class)
 849                 && ($resultset_class ne 'DBIx::Class::ResultSet')
 850             ) {
 851                 my $has_file = Class::Inspector->loaded_filename($resultset_class);
 852                 Class::Unload->unload($resultset_class) if $unload;
 853                 $self->_reload_class($resultset_class) if $has_file;
 854             }
 855             $self->_reload_class($class);
 856         }
 857         push @to_register, [$moniker, $class];
 858     }
 859
 860     Class::C3->reinitialize;
 861     for (@to_register) {
 862         $self->schema->register_class(@$_);
 863     }
 864 }
 865
 866 # We use this instead of ensure_class_loaded when there are package symbols we
 867 # want to preserve.
 868 sub _reload_class {
 869     my ($self, $class) = @_;
 870
 871     my $class_path = $self->_class_path($class);
 872     delete $INC{ $class_path };
 873
 874 # kill redefined warnings
 875     my $warn_handler = $SIG{__WARN__} || sub { warn @_ };
 876     local $SIG{__WARN__} = sub {
 877         $warn_handler->(@_)
 878             unless $_[0] =~ /^Subroutine \S+ redefined/;
 879     };
 880     eval "require $class;";
 881 }
 882
 883 sub _get_dump_filename {
 884     my ($self, $class) = (@_);
 885
 886     $class =~ s{::}{/}g;
 887     return $self->dump_directory . q{/} . $class . q{.pm};
 888 }
 889
 890 sub _ensure_dump_subdirs {
 891     my ($self, $class) = (@_);
 892
 893     my @name_parts = split(/::/, $class);
 894     pop @name_parts; # we don't care about the very last element,
 895                      # which is a filename
 896
 897     my $dir = $self->dump_directory;
 898     while (1) {
 899         if(!-d $dir) {
 900             mkdir($dir) or croak "mkdir('$dir') failed: $!";
 901         }
 902         last if !@name_parts;
 903         $dir = File::Spec->catdir($dir, shift @name_parts);
 904     }
 905 }
 906
 907 sub _dump_to_dir {
 908     my ($self, @classes) = @_;
 909
 910     my $schema_class = $self->schema_class;
 911     my $schema_base_class = $self->schema_base_class || 'DBIx::Class::Schema';
 912
 913     my $target_dir = $self->dump_directory;
 914     warn "Dumping manual schema for $schema_class to directory $target_dir ...\n"
 915         unless $self->{dynamic} or $self->{quiet};
 916
 917     my $schema_text =
 918           qq|package $schema_class;\n\n|
 919         . qq|# Created by DBIx::Class::Schema::Loader\n|
 920         . qq|# DO NOT MODIFY THE FIRST PART OF THIS FILE\n\n|
 921         . qq|use strict;\nuse warnings;\n\n|
 922         . qq|use base '$schema_base_class';\n\n|;
 923
 924     if ($self->use_namespaces) {
 925         $schema_text .= qq|__PACKAGE__->load_namespaces|;
 926         my $namespace_options;
 927         for my $attr (qw(result_namespace
 928                          resultset_namespace
 929                          default_resultset_class)) {
 930             if ($self->$attr) {
 931                 $namespace_options .= qq|    $attr => '| . $self->$attr . qq|',\n|
 932             }
 933         }
 934         $schema_text .= qq|(\n$namespace_options)| if $namespace_options;
 935         $schema_text .= qq|;\n|;
 936     }
 937     else {
 938         $schema_text .= qq|__PACKAGE__->load_classes;\n|;
 939     }
 940
 941     {
 942         local $self->{version_to_dump} = $self->schema_version_to_dump;
 943         $self->_write_classfile($schema_class, $schema_text, 1);
 944     }
 945
 946     my $result_base_class = $self->result_base_class || 'DBIx::Class::Core';
 947
 948     foreach my $src_class (@classes) {
 949         my $src_text =
 950               qq|package $src_class;\n\n|
 951             . qq|# Created by DBIx::Class::Schema::Loader\n|
 952             . qq|# DO NOT MODIFY THE FIRST PART OF THIS FILE\n\n|
 953             . qq|use strict;\nuse warnings;\n\n|
 954             . qq|use base '$result_base_class';\n\n|;
 955
 956         $self->_write_classfile($src_class, $src_text);
 957     }
 958
 959     # remove Result dir if downgrading from use_namespaces, and there are no
 960     # files left.
 961     if (my $result_ns = $self->_downgrading_to_load_classes) {
 962         my $result_namespace = $self->_result_namespace(
 963             $schema_class,
 964             $result_ns,
 965         );
 966
 967         (my $result_dir = $result_namespace) =~ s{::}{/}g;
 968         $result_dir = $self->dump_directory . '/' . $result_dir;
 969
 970         unless (my @files = glob "$result_dir/*") {
 971             rmdir $result_dir;
 972         }
 973     }
 974
 975     warn "Schema dump completed.\n" unless $self->{dynamic} or $self->{quiet};
 976
 977 }
 978
 979 sub _sig_comment {
 980     my ($self, $version, $ts) = @_;
 981     return qq|\n\n# Created by DBIx::Class::Schema::Loader|
 982          . qq| v| . $version
 983          . q| @ | . $ts
 984          . qq|\n# DO NOT MODIFY THIS OR ANYTHING ABOVE! md5sum:|;
 985 }
 986
 987 sub _write_classfile {
 988     my ($self, $class, $text, $is_schema) = @_;
 989
 990     my $filename = $self->_get_dump_filename($class);
 991     $self->_ensure_dump_subdirs($class);
 992
 993     if (-f $filename && $self->really_erase_my_files) {
 994         warn "Deleting existing file '$filename' due to "
 995             . "'really_erase_my_files' setting\n" unless $self->{quiet};
 996         unlink($filename);
 997     }
 998
 999     my ($custom_content, $old_md5, $old_ver, $old_ts) = $self->_get_custom_content($class, $filename);
1000
1001     if (my $old_class = $self->_upgrading_classes->{$class}) {
1002         my $old_filename = $self->_get_dump_filename($old_class);
1003
1004         my ($old_custom_content) = $self->_get_custom_content(
1005             $old_class, $old_filename, 0 # do not add default comment
1006         );
1007
1008         $old_custom_content =~ s/\n\n# You can replace.*\n1;\n//;
1009
1010         if ($old_custom_content) {
1011             $custom_content =
1012                 "\n" . $old_custom_content . "\n" . $custom_content;
1013         }
1014
1015         unlink $old_filename;
1016     }
1017
1018     $custom_content = $self->_rewrite_old_classnames($custom_content);
1019
1020     $text .= qq|$_\n|
1021         for @{$self->{_dump_storage}->{$class} || []};
1022
1023     # Check and see if the dump is infact differnt
1024
1025     my $compare_to;
1026     if ($old_md5) {
1027       $compare_to = $text . $self->_sig_comment($old_ver, $old_ts);
1028
1029
1030       if (Digest::MD5::md5_base64($compare_to) eq $old_md5) {
1031         return unless $self->_upgrading_from && $is_schema;
1032       }
1033     }
1034
1035     $text .= $self->_sig_comment(
1036       $self->version_to_dump,
1037       POSIX::strftime('%Y-%m-%d %H:%M:%S', localtime)
1038     );
1039
1040     open(my $fh, '>', $filename)
1041         or croak "Cannot open '$filename' for writing: $!";
1042
1043     # Write the top half and its MD5 sum
1044     print $fh $text . Digest::MD5::md5_base64($text) . "\n";
1045
1046     # Write out anything loaded via external partial class file in @INC
1047     print $fh qq|$_\n|
1048         for @{$self->{_ext_storage}->{$class} || []};
1049
1050     # Write out any custom content the user has added
1051     print $fh $custom_content;
1052
1053     close($fh)
1054         or croak "Error closing '$filename': $!";
1055 }
1056
1057 sub _default_custom_content {
1058     return qq|\n\n# You can replace this text with custom|
1059          . qq| content, and it will be preserved on regeneration|
1060          . qq|\n1;\n|;
1061 }
1062
1063 sub _get_custom_content {
1064     my ($self, $class, $filename, $add_default) = @_;
1065
1066     $add_default = 1 unless defined $add_default;
1067
1068     return ($self->_default_custom_content) if ! -f $filename;
1069
1070     open(my $fh, '<', $filename)
1071         or croak "Cannot open '$filename' for reading: $!";
1072
1073     my $mark_re =
1074         qr{^(# DO NOT MODIFY THIS OR ANYTHING ABOVE! md5sum:)([A-Za-z0-9/+]{22})\n};
1075
1076     my $buffer = '';
1077     my ($md5, $ts, $ver);
1078     while(<$fh>) {
1079         if(!$md5 && /$mark_re/) {
1080             $md5 = $2;
1081             my $line = $1;
1082
1083             # Pull out the previous version and timestamp
1084             ($ver, $ts) = $buffer =~ m/# Created by DBIx::Class::Schema::Loader v(.*?) @ (.*?)$/s;
1085
1086             $buffer .= $line;
1087             croak "Checksum mismatch in '$filename', the auto-generated part of the file has been modified outside of this loader.  Aborting.\nIf you want to overwrite these modifications, set the 'overwrite_modifications' loader option.\n"
1088                 if !$self->overwrite_modifications && Digest::MD5::md5_base64($buffer) ne $md5;
1089
1090             $buffer = '';
1091         }
1092         else {
1093             $buffer .= $_;
1094         }
1095     }
1096
1097     croak "Cannot not overwrite '$filename' without 'really_erase_my_files',"
1098         . " it does not appear to have been generated by Loader"
1099             if !$md5;
1100
1101     # Default custom content:
1102     $buffer ||= $self->_default_custom_content if $add_default;
1103
1104     return ($buffer, $md5, $ver, $ts);
1105 }
1106
1107 sub _use {
1108     my $self = shift;
1109     my $target = shift;
1110
1111     foreach (@_) {
1112         warn "$target: use $_;" if $self->debug;
1113         $self->_raw_stmt($target, "use $_;");
1114     }
1115 }
1116
1117 sub _inject {
1118     my $self = shift;
1119     my $target = shift;
1120     my $schema_class = $self->schema_class;
1121
1122     my $blist = join(q{ }, @_);
1123     warn "$target: use base qw/ $blist /;" if $self->debug && @_;
1124     $self->_raw_stmt($target, "use base qw/ $blist /;") if @_;
1125 }
1126
1127 sub _result_namespace {
1128     my ($self, $schema_class, $ns) = @_;
1129     my @result_namespace;
1130
1131     if ($ns =~ /^\+(.*)/) {
1132         # Fully qualified namespace
1133         @result_namespace = ($1)
1134     }
1135     else {
1136         # Relative namespace
1137         @result_namespace = ($schema_class, $ns);
1138     }
1139
1140     return wantarray ? @result_namespace : join '::', @result_namespace;
1141 }
1142
1143 # Create class with applicable bases, setup monikers, etc
1144 sub _make_src_class {
1145     my ($self, $table) = @_;
1146
1147     my $schema       = $self->schema;
1148     my $schema_class = $self->schema_class;
1149
1150     my $table_moniker = $self->_table2moniker($table);
1151     my @result_namespace = ($schema_class);
1152     if ($self->use_namespaces) {
1153         my $result_namespace = $self->result_namespace || 'Result';
1154         @result_namespace = $self->_result_namespace(
1155             $schema_class,
1156             $result_namespace,
1157         );
1158     }
1159     my $table_class = join(q{::}, @result_namespace, $table_moniker);
1160
1161     if ((my $upgrading_v = $self->_upgrading_from)
1162             || $self->_rewriting) {
1163         local $self->naming->{monikers} = $upgrading_v
1164             if $upgrading_v;
1165
1166         my @result_namespace = @result_namespace;
1167         if ($self->_upgrading_from_load_classes) {
1168             @result_namespace = ($schema_class);
1169         }
1170         elsif (my $ns = $self->_downgrading_to_load_classes) {
1171             @result_namespace = $self->_result_namespace(
1172                 $schema_class,
1173                 $ns,
1174             );
1175         }
1176         elsif ($ns = $self->_rewriting_result_namespace) {
1177             @result_namespace = $self->_result_namespace(
1178                 $schema_class,
1179                 $ns,
1180             );
1181         }
1182
1183         my $old_class = join(q{::}, @result_namespace,
1184             $self->_table2moniker($table));
1185
1186         $self->_upgrading_classes->{$table_class} = $old_class
1187             unless $table_class eq $old_class;
1188     }
1189
1190     my $table_normalized = lc $table;
1191     $self->classes->{$table} = $table_class;
1192     $self->classes->{$table_normalized} = $table_class;
1193     $self->monikers->{$table} = $table_moniker;
1194     $self->monikers->{$table_normalized} = $table_moniker;
1195
1196     $self->_use   ($table_class, @{$self->additional_classes});
1197     $self->_inject($table_class, @{$self->left_base_classes});
1198
1199     if (my @components = @{ $self->components }) {
1200         $self->_dbic_stmt($table_class, 'load_components', @components);
1201     }
1202
1203     $self->_dbic_stmt($table_class, 'load_resultset_components', @{$self->resultset_components})
1204         if @{$self->resultset_components};
1205     $self->_inject($table_class, @{$self->additional_base_classes});
1206 }
1207
1208 # Set up metadata (cols, pks, etc)
1209 sub _setup_src_meta {
1210     my ($self, $table) = @_;
1211
1212     my $schema       = $self->schema;
1213     my $schema_class = $self->schema_class;
1214
1215     my $table_class = $self->classes->{$table};
1216     my $table_moniker = $self->monikers->{$table};
1217
1218     my $table_name = $table;
1219     my $name_sep   = $self->schema->storage->sql_maker->name_sep;
1220
1221     if ($name_sep && $table_name =~ /\Q$name_sep\E/) {
1222         $table_name = \ $self->_quote_table_name($table_name);
1223     }
1224
1225     $self->_dbic_stmt($table_class,'table',$table_name);
1226
1227     my $cols = $self->_table_columns($table);
1228     my $col_info;
1229     eval { $col_info = $self->_columns_info_for($table) };
1230     if($@) {
1231         $self->_dbic_stmt($table_class,'add_columns',@$cols);
1232     }
1233     else {
1234         if ($self->_is_case_sensitive) {
1235             for my $col (keys %$col_info) {
1236                 $col_info->{$col}{accessor} = lc $col
1237                     if $col ne lc($col);
1238             }
1239         } else {
1240             $col_info = { map { lc($_), $col_info->{$_} } keys %$col_info };
1241         }
1242
1243         my $fks = $self->_table_fk_info($table);
1244
1245         for my $fkdef (@$fks) {
1246             for my $col (@{ $fkdef->{local_columns} }) {
1247                 $col_info->{$col}{is_foreign_key} = 1;
1248             }
1249         }
1250         $self->_dbic_stmt(
1251             $table_class,
1252             'add_columns',
1253             map { $_, ($col_info->{$_}||{}) } @$cols
1254         );
1255     }
1256
1257     my %uniq_tag; # used to eliminate duplicate uniqs
1258
1259     my $pks = $self->_table_pk_info($table) || [];
1260     @$pks ? $self->_dbic_stmt($table_class,'set_primary_key',@$pks)
1261           : carp("$table has no primary key");
1262     $uniq_tag{ join("\0", @$pks) }++ if @$pks; # pk is a uniq
1263
1264     my $uniqs = $self->_table_uniq_info($table) || [];
1265     for (@$uniqs) {
1266         my ($name, $cols) = @$_;
1267         next if $uniq_tag{ join("\0", @$cols) }++; # skip duplicates
1268         $self->_dbic_stmt($table_class,'add_unique_constraint', $name, $cols);
1269     }
1270
1271 }
1272
1273 =head2 tables
1274
1275 Returns a sorted list of loaded tables, using the original database table
1276 names.
1277
1278 =cut
1279
1280 sub tables {
1281     my $self = shift;
1282
1283     return keys %{$self->_tables};
1284 }
1285
1286 # Make a moniker from a table
1287 sub _default_table2moniker {
1288     no warnings 'uninitialized';
1289     my ($self, $table) = @_;
1290
1291     if ($self->naming->{monikers} eq 'v4') {
1292         return join '', map ucfirst, split /[\W_]+/, lc $table;
1293     }
1294
1295     return join '', map ucfirst, split /[\W_]+/,
1296         Lingua::EN::Inflect::Number::to_S(lc $table);
1297 }
1298
1299 sub _table2moniker {
1300     my ( $self, $table ) = @_;
1301
1302     my $moniker;
1303
1304     if( ref $self->moniker_map eq 'HASH' ) {
1305         $moniker = $self->moniker_map->{$table};
1306     }
1307     elsif( ref $self->moniker_map eq 'CODE' ) {
1308         $moniker = $self->moniker_map->($table);
1309     }
1310
1311     $moniker ||= $self->_default_table2moniker($table);
1312
1313     return $moniker;
1314 }
1315
1316 sub _load_relationships {
1317     my ($self, $table) = @_;
1318
1319     my $tbl_fk_info = $self->_table_fk_info($table);
1320     foreach my $fkdef (@$tbl_fk_info) {
1321         $fkdef->{remote_source} =
1322             $self->monikers->{delete $fkdef->{remote_table}};
1323     }
1324     my $tbl_uniq_info = $self->_table_uniq_info($table);
1325
1326     my $local_moniker = $self->monikers->{$table};
1327     my $rel_stmts = $self->_relbuilder->generate_code($local_moniker, $tbl_fk_info, $tbl_uniq_info);
1328
1329     foreach my $src_class (sort keys %$rel_stmts) {
1330         my $src_stmts = $rel_stmts->{$src_class};
1331         foreach my $stmt (@$src_stmts) {
1332             $self->_dbic_stmt($src_class,$stmt->{method},@{$stmt->{args}});
1333         }
1334     }
1335 }
1336
1337 # Overload these in driver class:
1338
1339 # Returns an arrayref of column names
1340 sub _table_columns { croak "ABSTRACT METHOD" }
1341
1342 # Returns arrayref of pk col names
1343 sub _table_pk_info { croak "ABSTRACT METHOD" }
1344
1345 # Returns an arrayref of uniqs [ [ foo => [ col1, col2 ] ], [ bar => [ ... ] ] ]
1346 sub _table_uniq_info { croak "ABSTRACT METHOD" }
1347
1348 # Returns an arrayref of foreign key constraints, each
1349 #   being a hashref with 3 keys:
1350 #   local_columns (arrayref), remote_columns (arrayref), remote_table
1351 sub _table_fk_info { croak "ABSTRACT METHOD" }
1352
1353 # Returns an array of lower case table names
1354 sub _tables_list { croak "ABSTRACT METHOD" }
1355
1356 # Execute a constructive DBIC class method, with debug/dump_to_dir hooks.
1357 sub _dbic_stmt {
1358     my $self   = shift;
1359     my $class  = shift;
1360     my $method = shift;
1361
1362     # generate the pod for this statement, storing it with $self->_pod
1363     $self->_make_pod( $class, $method, @_ );
1364
1365     my $args = dump(@_);
1366     $args = '(' . $args . ')' if @_ < 2;
1367     my $stmt = $method . $args . q{;};
1368
1369     warn qq|$class\->$stmt\n| if $self->debug;
1370     $self->_raw_stmt($class, '__PACKAGE__->' . $stmt);
1371     return;
1372 }
1373
1374 # generates the accompanying pod for a DBIC class method statement,
1375 # storing it with $self->_pod
1376 sub _make_pod {
1377     my $self   = shift;
1378     my $class  = shift;
1379     my $method = shift;
1380
1381     if ( $method eq 'table' ) {
1382         my ($table) = @_;
1383         $self->_pod( $class, "=head1 NAME" );
1384         my $table_descr = $class;
1385         if ( $self->can('_table_comment') ) {
1386             my $comment = $self->_table_comment($table);
1387             $table_descr .= " - " . $comment if $comment;
1388         }
1389         $self->{_class2table}{ $class } = $table;
1390         $self->_pod( $class, $table_descr );
1391         $self->_pod_cut( $class );
1392     } elsif ( $method eq 'add_columns' ) {
1393         $self->_pod( $class, "=head1 ACCESSORS" );
1394         my $col_counter = 0;
1395         my @cols = @_;
1396         while( my ($name,$attrs) = splice @cols,0,2 ) {
1397             $col_counter++;
1398             $self->_pod( $class, '=head2 ' . $name  );
1399             $self->_pod( $class,
1400                          join "\n", map {
1401                              my $s = $attrs->{$_};
1402                              $s = !defined $s      ? 'undef'          :
1403                                   length($s) == 0  ? '(empty string)' :
1404                                                      $s;
1405
1406                              "  $_: $s"
1407                          } sort keys %$attrs,
1408                        );
1409
1410             if( $self->can('_column_comment')
1411                 and my $comment = $self->_column_comment( $self->{_class2table}{$class}, $col_counter)
1412               ) {
1413                 $self->_pod( $class, $comment );
1414             }
1415         }
1416         $self->_pod_cut( $class );
1417     } elsif ( $method =~ /^(belongs_to|has_many|might_have)$/ ) {
1418         $self->_pod( $class, "=head1 RELATIONS" ) unless $self->{_relations_started} { $class } ;
1419         my ( $accessor, $rel_class ) = @_;
1420         $self->_pod( $class, "=head2 $accessor" );
1421         $self->_pod( $class, 'Type: ' . $method );
1422         $self->_pod( $class, "Related object: L<$rel_class>" );
1423         $self->_pod_cut( $class );
1424         $self->{_relations_started} { $class } = 1;
1425     }
1426 }
1427
1428 # Stores a POD documentation
1429 sub _pod {
1430     my ($self, $class, $stmt) = @_;
1431     $self->_raw_stmt( $class, "\n" . $stmt  );
1432 }
1433
1434 sub _pod_cut {
1435     my ($self, $class ) = @_;
1436     $self->_raw_stmt( $class, "\n=cut\n" );
1437 }
1438
1439
1440 # Store a raw source line for a class (for dumping purposes)
1441 sub _raw_stmt {
1442     my ($self, $class, $stmt) = @_;
1443     push(@{$self->{_dump_storage}->{$class}}, $stmt);
1444 }
1445
1446 # Like above, but separately for the externally loaded stuff
1447 sub _ext_stmt {
1448     my ($self, $class, $stmt) = @_;
1449     push(@{$self->{_ext_storage}->{$class}}, $stmt);
1450 }
1451
1452 sub _quote_table_name {
1453     my ($self, $table) = @_;
1454
1455     my $qt = $self->schema->storage->sql_maker->quote_char;
1456
1457     return $table unless $qt;
1458
1459     if (ref $qt) {
1460         return $qt->[0] . $table . $qt->[1];
1461     }
1462
1463     return $qt . $table . $qt;
1464 }
1465
1466 sub _is_case_sensitive { 0 }
1467
1468 # remove the dump dir from @INC on destruction
1469 sub DESTROY {
1470     my $self = shift;
1471
1472     @INC = grep $_ ne $self->dump_directory, @INC;
1473 }
1474
1475 =head2 monikers
1476
1477 Returns a hashref of loaded table to moniker mappings.  There will
1478 be two entries for each table, the original name and the "normalized"
1479 name, in the case that the two are different (such as databases
1480 that like uppercase table names, or preserve your original mixed-case
1481 definitions, or what-have-you).
1482
1483 =head2 classes
1484
1485 Returns a hashref of table to class mappings.  In some cases it will
1486 contain multiple entries per table for the original and normalized table
1487 names, as above in L</monikers>.
1488
1489 =head1 SEE ALSO
1490
1491 L<DBIx::Class::Schema::Loader>
1492
1493 =head1 AUTHOR
1494
1495 See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
1496
1497 =head1 LICENSE
1498
1499 This library is free software; you can redistribute it and/or modify it under
1500 the same terms as Perl itself.
1501
1502 =cut
1503
1504 1;