lib/DBIx/Class/Schema/Loader/Base.pm

   1 package DBIx::Class::Schema::Loader::Base;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/Class::Accessor::Grouped Class::C3::Componentised/;
   6 use Class::C3;
   7 use Carp::Clan qw/^DBIx::Class/;
   8 use DBIx::Class::Schema::Loader::RelBuilder;
   9 use Data::Dump qw/ dump /;
  10 use POSIX qw//;
  11 use File::Spec qw//;
  12 use Cwd qw//;
  13 use Digest::MD5 qw//;
  14 use Lingua::EN::Inflect::Number qw//;
  15 use File::Temp qw//;
  16 use Class::Unload;
  17 require DBIx::Class;
  18
  19 our $VERSION = '0.04999_13';
  20
  21 __PACKAGE__->mk_group_ro_accessors('simple', qw/
  22                                 schema
  23                                 schema_class
  24
  25                                 exclude
  26                                 constraint
  27                                 additional_classes
  28                                 additional_base_classes
  29                                 left_base_classes
  30                                 components
  31                                 resultset_components
  32                                 skip_relationships
  33                                 skip_load_external
  34                                 moniker_map
  35                                 inflect_singular
  36                                 inflect_plural
  37                                 debug
  38                                 dump_directory
  39                                 dump_overwrite
  40                                 really_erase_my_files
  41                                 use_namespaces
  42                                 result_namespace
  43                                 resultset_namespace
  44                                 default_resultset_class
  45                                 schema_base_class
  46                                 result_base_class
  47                                 overwrite_modifications
  48
  49                                 relationship_attrs
  50
  51                                 db_schema
  52                                 _tables
  53                                 classes
  54                                 _upgrading_classes
  55                                 monikers
  56                                 dynamic
  57                                 naming
  58 /);
  59
  60
  61 __PACKAGE__->mk_group_accessors('simple', qw/
  62                                 version_to_dump
  63                                 schema_version_to_dump
  64                                 _upgrading_from
  65 /);
  66
  67 =head1 NAME
  68
  69 DBIx::Class::Schema::Loader::Base - Base DBIx::Class::Schema::Loader Implementation.
  70
  71 =head1 SYNOPSIS
  72
  73 See L<DBIx::Class::Schema::Loader>
  74
  75 =head1 DESCRIPTION
  76
  77 This is the base class for the storage-specific C<DBIx::Class::Schema::*>
  78 classes, and implements the common functionality between them.
  79
  80 =head1 CONSTRUCTOR OPTIONS
  81
  82 These constructor options are the base options for
  83 L<DBIx::Class::Schema::Loader/loader_options>.  Available constructor options are:
  84
  85 =head2 skip_relationships
  86
  87 Skip setting up relationships.  The default is to attempt the loading
  88 of relationships.
  89
  90 =head2 skip_load_external
  91
  92 Skip loading of other classes in @INC. The default is to merge all other classes
  93 with the same name found in @INC into the schema file we are creating.
  94
  95 =head2 naming
  96
  97 Static schemas (ones dumped to disk) will, by default, use the new-style 0.05XXX
  98 relationship names and singularized Results, unless you're overwriting an
  99 existing dump made by a 0.04XXX version of L<DBIx::Class::Schema::Loader>, in
 100 which case the backward compatible RelBuilder will be activated, and
 101 singularization will be turned off.
 102
 103 Specifying
 104
 105     naming => 'v5'
 106
 107 will disable the backward-compatible RelBuilder and use
 108 the new-style relationship names along with singularized Results, even when
 109 overwriting a dump made with an earlier version.
 110
 111 The option also takes a hashref:
 112
 113     naming => { relationships => 'v5', monikers => 'v4' }
 114
 115 The keys are:
 116
 117 =over 4
 118
 119 =item relationships
 120
 121 How to name relationship accessors.
 122
 123 =item monikers
 124
 125 How to name Result classes.
 126
 127 =back
 128
 129 The values can be:
 130
 131 =over 4
 132
 133 =item current
 134
 135 Latest default style, whatever that happens to be.
 136
 137 =item v5
 138
 139 Version 0.05XXX style.
 140
 141 =item v4
 142
 143 Version 0.04XXX style.
 144
 145 =back
 146
 147 Dynamic schemas will always default to the 0.04XXX relationship names and won't
 148 singularize Results for backward compatibility, to activate the new RelBuilder
 149 and singularization put this in your C<Schema.pm> file:
 150
 151     __PACKAGE__->naming('current');
 152
 153 Or if you prefer to use 0.05XXX features but insure that nothing breaks in the
 154 next major version upgrade:
 155
 156     __PACKAGE__->naming('v5');
 157
 158 =head2 relationship_attrs
 159
 160 Hashref of attributes to pass to each generated relationship, listed
 161 by type.  Also supports relationship type 'all', containing options to
 162 pass to all generated relationships.  Attributes set for more specific
 163 relationship types override those set in 'all'.
 164
 165 For example:
 166
 167   relationship_attrs => {
 168     all      => { cascade_delete => 0 },
 169     has_many => { cascade_delete => 1 },
 170   },
 171
 172 will set the C<cascade_delete> option to 0 for all generated relationships,
 173 except for C<has_many>, which will have cascade_delete as 1.
 174
 175 NOTE: this option is not supported if v4 backward-compatible naming is
 176 set either globally (naming => 'v4') or just for relationships.
 177
 178 =head2 debug
 179
 180 If set to true, each constructive L<DBIx::Class> statement the loader
 181 decides to execute will be C<warn>-ed before execution.
 182
 183 =head2 db_schema
 184
 185 Set the name of the schema to load (schema in the sense that your database
 186 vendor means it).  Does not currently support loading more than one schema
 187 name.
 188
 189 =head2 constraint
 190
 191 Only load tables matching regex.  Best specified as a qr// regex.
 192
 193 =head2 exclude
 194
 195 Exclude tables matching regex.  Best specified as a qr// regex.
 196
 197 =head2 moniker_map
 198
 199 Overrides the default table name to moniker translation.  Can be either
 200 a hashref of table keys and moniker values, or a coderef for a translator
 201 function taking a single scalar table name argument and returning
 202 a scalar moniker.  If the hash entry does not exist, or the function
 203 returns a false value, the code falls back to default behavior
 204 for that table name.
 205
 206 The default behavior is to singularize the table name, and: C<join '', map
 207 ucfirst, split /[\W_]+/, lc $table>, which is to say: lowercase everything,
 208 split up the table name into chunks anywhere a non-alpha-numeric character
 209 occurs, change the case of first letter of each chunk to upper case, and put
 210 the chunks back together.  Examples:
 211
 212     Table Name  | Moniker Name
 213     ---------------------------
 214     luser       | Luser
 215     luser_group | LuserGroup
 216     luser-opts  | LuserOpts
 217
 218 =head2 inflect_plural
 219
 220 Just like L</moniker_map> above (can be hash/code-ref, falls back to default
 221 if hash key does not exist or coderef returns false), but acts as a map
 222 for pluralizing relationship names.  The default behavior is to utilize
 223 L<Lingua::EN::Inflect::Number/to_PL>.
 224
 225 =head2 inflect_singular
 226
 227 As L</inflect_plural> above, but for singularizing relationship names.
 228 Default behavior is to utilize L<Lingua::EN::Inflect::Number/to_S>.
 229
 230 =head2 schema_base_class
 231
 232 Base class for your schema classes. Defaults to 'DBIx::Class::Schema'.
 233
 234 =head2 result_base_class
 235
 236 Base class for your table classes (aka result classes). Defaults to
 237 'DBIx::Class::Core'.
 238
 239 =head2 additional_base_classes
 240
 241 List of additional base classes all of your table classes will use.
 242
 243 =head2 left_base_classes
 244
 245 List of additional base classes all of your table classes will use
 246 that need to be leftmost.
 247
 248 =head2 additional_classes
 249
 250 List of additional classes which all of your table classes will use.
 251
 252 =head2 components
 253
 254 List of additional components to be loaded into all of your table
 255 classes.  A good example would be C<ResultSetManager>.
 256
 257 =head2 resultset_components
 258
 259 List of additional ResultSet components to be loaded into your table
 260 classes.  A good example would be C<AlwaysRS>.  Component
 261 C<ResultSetManager> will be automatically added to the above
 262 C<components> list if this option is set.
 263
 264 =head2 use_namespaces
 265
 266 Generate result class names suitable for
 267 L<DBIx::Class::Schema/load_namespaces> and call that instead of
 268 L<DBIx::Class::Schema/load_classes>. When using this option you can also
 269 specify any of the options for C<load_namespaces> (i.e. C<result_namespace>,
 270 C<resultset_namespace>, C<default_resultset_class>), and they will be added
 271 to the call (and the generated result class names adjusted appropriately).
 272
 273 =head2 dump_directory
 274
 275 This option is designed to be a tool to help you transition from this
 276 loader to a manually-defined schema when you decide it's time to do so.
 277
 278 The value of this option is a perl libdir pathname.  Within
 279 that directory this module will create a baseline manual
 280 L<DBIx::Class::Schema> module set, based on what it creates at runtime
 281 in memory.
 282
 283 The created schema class will have the same classname as the one on
 284 which you are setting this option (and the ResultSource classes will be
 285 based on this name as well).
 286
 287 Normally you wouldn't hard-code this setting in your schema class, as it
 288 is meant for one-time manual usage.
 289
 290 See L<DBIx::Class::Schema::Loader/dump_to_dir> for examples of the
 291 recommended way to access this functionality.
 292
 293 =head2 dump_overwrite
 294
 295 Deprecated.  See L</really_erase_my_files> below, which does *not* mean
 296 the same thing as the old C<dump_overwrite> setting from previous releases.
 297
 298 =head2 really_erase_my_files
 299
 300 Default false.  If true, Loader will unconditionally delete any existing
 301 files before creating the new ones from scratch when dumping a schema to disk.
 302
 303 The default behavior is instead to only replace the top portion of the
 304 file, up to and including the final stanza which contains
 305 C<# DO NOT MODIFY THIS OR ANYTHING ABOVE!>
 306 leaving any customizations you placed after that as they were.
 307
 308 When C<really_erase_my_files> is not set, if the output file already exists,
 309 but the aforementioned final stanza is not found, or the checksum
 310 contained there does not match the generated contents, Loader will
 311 croak and not touch the file.
 312
 313 You should really be using version control on your schema classes (and all
 314 of the rest of your code for that matter).  Don't blame me if a bug in this
 315 code wipes something out when it shouldn't have, you've been warned.
 316
 317 =head2 overwrite_modifications
 318
 319 Default false.  If false, when updating existing files, Loader will
 320 refuse to modify any Loader-generated code that has been modified
 321 since its last run (as determined by the checksum Loader put in its
 322 comment lines).
 323
 324 If true, Loader will discard any manual modifications that have been
 325 made to Loader-generated code.
 326
 327 Again, you should be using version control on your schema classes.  Be
 328 careful with this option.
 329
 330 =head1 METHODS
 331
 332 None of these methods are intended for direct invocation by regular
 333 users of L<DBIx::Class::Schema::Loader>.  Anything you can find here
 334 can also be found via standard L<DBIx::Class::Schema> methods somehow.
 335
 336 =cut
 337
 338 use constant CURRENT_V => 'v5';
 339
 340 # ensure that a peice of object data is a valid arrayref, creating
 341 # an empty one or encapsulating whatever's there.
 342 sub _ensure_arrayref {
 343     my $self = shift;
 344
 345     foreach (@_) {
 346         $self->{$_} ||= [];
 347         $self->{$_} = [ $self->{$_} ]
 348             unless ref $self->{$_} eq 'ARRAY';
 349     }
 350 }
 351
 352 =head2 new
 353
 354 Constructor for L<DBIx::Class::Schema::Loader::Base>, used internally
 355 by L<DBIx::Class::Schema::Loader>.
 356
 357 =cut
 358
 359 sub new {
 360     my ( $class, %args ) = @_;
 361
 362     my $self = { %args };
 363
 364     bless $self => $class;
 365
 366     $self->_ensure_arrayref(qw/additional_classes
 367                                additional_base_classes
 368                                left_base_classes
 369                                components
 370                                resultset_components
 371                               /);
 372
 373     push(@{$self->{components}}, 'ResultSetManager')
 374         if @{$self->{resultset_components}};
 375
 376     $self->{monikers} = {};
 377     $self->{classes} = {};
 378     $self->{_upgrading_classes} = {};
 379
 380     $self->{schema_class} ||= ( ref $self->{schema} || $self->{schema} );
 381     $self->{schema} ||= $self->{schema_class};
 382
 383     croak "dump_overwrite is deprecated.  Please read the"
 384         . " DBIx::Class::Schema::Loader::Base documentation"
 385             if $self->{dump_overwrite};
 386
 387     $self->{dynamic} = ! $self->{dump_directory};
 388     $self->{temp_directory} ||= File::Temp::tempdir( 'dbicXXXX',
 389                                                      TMPDIR  => 1,
 390                                                      CLEANUP => 1,
 391                                                    );
 392
 393     $self->{dump_directory} ||= $self->{temp_directory};
 394
 395     $self->version_to_dump($DBIx::Class::Schema::Loader::VERSION);
 396     $self->schema_version_to_dump($DBIx::Class::Schema::Loader::VERSION);
 397
 398     if ((not ref $self->naming) && defined $self->naming) {
 399         my $naming_ver = $self->naming;
 400         $self->{naming} = {
 401             relationships => $naming_ver,
 402             monikers => $naming_ver,
 403         };
 404     }
 405
 406     if ($self->naming) {
 407         for (values %{ $self->naming }) {
 408             $_ = CURRENT_V if $_ eq 'current';
 409         }
 410     }
 411     $self->{naming} ||= {};
 412
 413     $self->_check_back_compat;
 414
 415     $self;
 416 }
 417
 418 sub _check_back_compat {
 419     my ($self) = @_;
 420
 421 # dynamic schemas will always be in 0.04006 mode, unless overridden
 422     if ($self->dynamic) {
 423 # just in case, though no one is likely to dump a dynamic schema
 424         $self->schema_version_to_dump('0.04006');
 425
 426         if (not %{ $self->naming }) {
 427             warn <<EOF unless $ENV{SCHEMA_LOADER_BACKCOMPAT};
 428
 429 Dynamic schema detected, will run in 0.04006 mode.
 430
 431 Set the 'naming' attribute or the SCHEMA_LOADER_BACKCOMPAT environment variable
 432 to disable this warning.
 433
 434 See perldoc DBIx::Class::Schema::Loader::Manual::UpgradingFromV4 for more
 435 details.
 436 EOF
 437         }
 438         else {
 439             $self->_upgrading_from('v4');
 440         }
 441
 442         $self->naming->{relationships} ||= 'v4';
 443         $self->naming->{monikers}      ||= 'v4';
 444
 445         return;
 446     }
 447
 448 # otherwise check if we need backcompat mode for a static schema
 449     my $filename = $self->_get_dump_filename($self->schema_class);
 450     return unless -e $filename;
 451
 452     open(my $fh, '<', $filename)
 453         or croak "Cannot open '$filename' for reading: $!";
 454
 455     while (<$fh>) {
 456         if (/^# Created by DBIx::Class::Schema::Loader v((\d+)\.(\d+))/) {
 457             my $real_ver = $1;
 458
 459             # XXX when we go past .0 this will need fixing
 460             my ($v) = $real_ver =~ /([1-9])/;
 461             $v = "v$v";
 462
 463             last if $v eq CURRENT_V || $real_ver =~ /^0\.\d\d999/;
 464
 465             if (not %{ $self->naming }) {
 466                 warn <<"EOF" unless $ENV{SCHEMA_LOADER_BACKCOMPAT};
 467
 468 Version $real_ver static schema detected, turning on backcompat mode.
 469
 470 Set the 'naming' attribute or the SCHEMA_LOADER_BACKCOMPAT environment variable
 471 to disable this warning.
 472
 473 See perldoc DBIx::Class::Schema::Loader::Manual::UpgradingFromV4 for more
 474 details.
 475 EOF
 476             }
 477             else {
 478                 $self->_upgrading_from($v);
 479             }
 480
 481             $self->naming->{relationships} ||= $v;
 482             $self->naming->{monikers}      ||= $v;
 483
 484             $self->schema_version_to_dump($real_ver);
 485
 486             last;
 487         }
 488     }
 489     close $fh;
 490 }
 491
 492 sub _find_file_in_inc {
 493     my ($self, $file) = @_;
 494
 495     foreach my $prefix (@INC) {
 496         my $fullpath = File::Spec->catfile($prefix, $file);
 497         return $fullpath if -f $fullpath
 498             and Cwd::abs_path($fullpath) ne
 499                (Cwd::abs_path(File::Spec->catfile($self->dump_directory, $file)) || '');
 500     }
 501
 502     return;
 503 }
 504
 505 sub _class_path {
 506     my ($self, $class) = @_;
 507
 508     my $class_path = $class;
 509     $class_path =~ s{::}{/}g;
 510     $class_path .= '.pm';
 511
 512     return $class_path;
 513 }
 514
 515 sub _find_class_in_inc {
 516     my ($self, $class) = @_;
 517
 518     return $self->_find_file_in_inc($self->_class_path($class));
 519 }
 520
 521 sub _rewrite_old_classnames {
 522     my ($self, $code) = @_;
 523
 524     return $code unless $self->_upgrading_from;
 525
 526     my %old_classes = reverse %{ $self->_upgrading_classes };
 527
 528     my $re = join '|', keys %old_classes;
 529     $re = qr/\b($re)\b/;
 530
 531     $code =~ s/$re/$old_classes{$1}/eg;
 532
 533     return $code;
 534 }
 535
 536 sub _load_external {
 537     my ($self, $class) = @_;
 538
 539     return if $self->{skip_load_external};
 540
 541     # so that we don't load our own classes, under any circumstances
 542     local *INC = [ grep $_ ne $self->dump_directory, @INC ];
 543
 544     my $real_inc_path = $self->_find_class_in_inc($class);
 545
 546     my $old_class = $self->_upgrading_classes->{$class}
 547         if $self->_upgrading_from;
 548
 549     my $old_real_inc_path = $self->_find_class_in_inc($old_class)
 550         if $old_class && $old_class ne $class;
 551
 552     return unless $real_inc_path || $old_real_inc_path;
 553
 554     if ($real_inc_path) {
 555         # If we make it to here, we loaded an external definition
 556         warn qq/# Loaded external class definition for '$class'\n/
 557             if $self->debug;
 558
 559         open(my $fh, '<', $real_inc_path)
 560             or croak "Failed to open '$real_inc_path' for reading: $!";
 561         my $code = do { local $/; <$fh> };
 562         close($fh)
 563             or croak "Failed to close $real_inc_path: $!";
 564         $code = $self->_rewrite_old_classnames($code);
 565
 566         if ($self->dynamic) { # load the class too
 567             # kill redefined warnings
 568             my $warn_handler = $SIG{__WARN__} || sub { warn @_ };
 569             local $SIG{__WARN__} = sub {
 570                 $warn_handler->(@_)
 571                     unless $_[0] =~ /^Subroutine \S+ redefined/;
 572             };
 573             eval $code;
 574             die $@ if $@;
 575         }
 576
 577         $self->_ext_stmt($class,
 578           qq|# These lines were loaded from '$real_inc_path' found in \@INC.\n|
 579          .qq|# They are now part of the custom portion of this file\n|
 580          .qq|# for you to hand-edit.  If you do not either delete\n|
 581          .qq|# this section or remove that file from \@INC, this section\n|
 582          .qq|# will be repeated redundantly when you re-create this\n|
 583          .qq|# file again via Loader!\n|
 584         );
 585         chomp $code;
 586         $self->_ext_stmt($class, $code);
 587         $self->_ext_stmt($class,
 588             qq|# End of lines loaded from '$real_inc_path' |
 589         );
 590     }
 591
 592     if ($old_real_inc_path) {
 593         open(my $fh, '<', $old_real_inc_path)
 594             or croak "Failed to open '$old_real_inc_path' for reading: $!";
 595         $self->_ext_stmt($class, <<"EOF");
 596
 597 # These lines were loaded from '$old_real_inc_path',
 598 # based on the Result class name that would have been created by an 0.04006
 599 # version of the Loader. For a static schema, this happens only once during
 600 # upgrade.
 601 EOF
 602
 603         my $code = do {
 604             local ($/, @ARGV) = (undef, $old_real_inc_path); <>
 605         };
 606         $code = $self->_rewrite_old_classnames($code);
 607
 608         if ($self->dynamic) {
 609             warn <<"EOF";
 610
 611 Detected external content in '$old_real_inc_path', a class name that would have
 612 been used by an 0.04006 version of the Loader.
 613
 614 * PLEASE RENAME THIS CLASS: from '$old_class' to '$class', as that is the
 615 new name of the Result.
 616 EOF
 617             # kill redefined warnings
 618             my $warn_handler = $SIG{__WARN__} || sub { warn @_ };
 619             local $SIG{__WARN__} = sub {
 620                 $warn_handler->(@_)
 621                     unless $_[0] =~ /^Subroutine \S+ redefined/;
 622             };
 623             eval $code;
 624             die $@ if $@;
 625         }
 626
 627         chomp $code;
 628         $self->_ext_stmt($class, $code);
 629         $self->_ext_stmt($class,
 630             qq|# End of lines loaded from '$old_real_inc_path' |
 631         );
 632     }
 633 }
 634
 635 =head2 load
 636
 637 Does the actual schema-construction work.
 638
 639 =cut
 640
 641 sub load {
 642     my $self = shift;
 643
 644     $self->_load_tables($self->_tables_list);
 645 }
 646
 647 =head2 rescan
 648
 649 Arguments: schema
 650
 651 Rescan the database for newly added tables.  Does
 652 not process drops or changes.  Returns a list of
 653 the newly added table monikers.
 654
 655 The schema argument should be the schema class
 656 or object to be affected.  It should probably
 657 be derived from the original schema_class used
 658 during L</load>.
 659
 660 =cut
 661
 662 sub rescan {
 663     my ($self, $schema) = @_;
 664
 665     $self->{schema} = $schema;
 666     $self->_relbuilder->{schema} = $schema;
 667
 668     my @created;
 669     my @current = $self->_tables_list;
 670     foreach my $table ($self->_tables_list) {
 671         if(!exists $self->{_tables}->{$table}) {
 672             push(@created, $table);
 673         }
 674     }
 675
 676     my $loaded = $self->_load_tables(@created);
 677
 678     return map { $self->monikers->{$_} } @$loaded;
 679 }
 680
 681 sub _relbuilder {
 682     no warnings 'uninitialized';
 683     my ($self) = @_;
 684
 685     return if $self->{skip_relationships};
 686
 687     if ($self->naming->{relationships} eq 'v4') {
 688         require DBIx::Class::Schema::Loader::RelBuilder::Compat::v0_040;
 689         return $self->{relbuilder} ||=
 690             DBIx::Class::Schema::Loader::RelBuilder::Compat::v0_040->new(
 691                 $self->schema, $self->inflect_plural, $self->inflect_singular
 692             );
 693     }
 694
 695     $self->{relbuilder} ||= DBIx::Class::Schema::Loader::RelBuilder->new (
 696          $self->schema,
 697          $self->inflect_plural,
 698          $self->inflect_singular,
 699          $self->relationship_attrs,
 700     );
 701 }
 702
 703 sub _load_tables {
 704     my ($self, @tables) = @_;
 705
 706     # First, use _tables_list with constraint and exclude
 707     #  to get a list of tables to operate on
 708
 709     my $constraint   = $self->constraint;
 710     my $exclude      = $self->exclude;
 711
 712     @tables = grep { /$constraint/ } @tables if $constraint;
 713     @tables = grep { ! /$exclude/ } @tables if $exclude;
 714
 715     # Save the new tables to the tables list
 716     foreach (@tables) {
 717         $self->{_tables}->{$_} = 1;
 718     }
 719
 720     $self->_make_src_class($_) for @tables;
 721     $self->_setup_src_meta($_) for @tables;
 722
 723     if(!$self->skip_relationships) {
 724         # The relationship loader needs a working schema
 725         $self->{quiet} = 1;
 726         local $self->{dump_directory} = $self->{temp_directory};
 727         $self->_reload_classes(\@tables);
 728         $self->_load_relationships($_) for @tables;
 729         $self->{quiet} = 0;
 730
 731         # Remove that temp dir from INC so it doesn't get reloaded
 732         @INC = grep $_ ne $self->dump_directory, @INC;
 733     }
 734
 735     $self->_load_external($_)
 736         for map { $self->classes->{$_} } @tables;
 737
 738     # Reload without unloading first to preserve any symbols from external
 739     # packages.
 740     $self->_reload_classes(\@tables, 0);
 741
 742     # Drop temporary cache
 743     delete $self->{_cache};
 744
 745     return \@tables;
 746 }
 747
 748 sub _reload_classes {
 749     my ($self, $tables, $unload) = @_;
 750
 751     my @tables = @$tables;
 752     $unload = 1 unless defined $unload;
 753
 754     # so that we don't repeat custom sections
 755     @INC = grep $_ ne $self->dump_directory, @INC;
 756
 757     $self->_dump_to_dir(map { $self->classes->{$_} } @tables);
 758
 759     unshift @INC, $self->dump_directory;
 760
 761     my @to_register;
 762     my %have_source = map { $_ => $self->schema->source($_) }
 763         $self->schema->sources;
 764
 765     for my $table (@tables) {
 766         my $moniker = $self->monikers->{$table};
 767         my $class = $self->classes->{$table};
 768
 769         {
 770             no warnings 'redefine';
 771             local *Class::C3::reinitialize = sub {};
 772             use warnings;
 773
 774             Class::Unload->unload($class) if $unload;
 775             my ($source, $resultset_class);
 776             if (
 777                 ($source = $have_source{$moniker})
 778                 && ($resultset_class = $source->resultset_class)
 779                 && ($resultset_class ne 'DBIx::Class::ResultSet')
 780             ) {
 781                 my $has_file = Class::Inspector->loaded_filename($resultset_class);
 782                 Class::Unload->unload($resultset_class) if $unload;
 783                 $self->_reload_class($resultset_class) if $has_file;
 784             }
 785             $self->_reload_class($class);
 786         }
 787         push @to_register, [$moniker, $class];
 788     }
 789
 790     Class::C3->reinitialize;
 791     for (@to_register) {
 792         $self->schema->register_class(@$_);
 793     }
 794 }
 795
 796 # We use this instead of ensure_class_loaded when there are package symbols we
 797 # want to preserve.
 798 sub _reload_class {
 799     my ($self, $class) = @_;
 800
 801     my $class_path = $self->_class_path($class);
 802     delete $INC{ $class_path };
 803
 804 # kill redefined warnings
 805     my $warn_handler = $SIG{__WARN__} || sub { warn @_ };
 806     local $SIG{__WARN__} = sub {
 807         $warn_handler->(@_)
 808             unless $_[0] =~ /^Subroutine \S+ redefined/;
 809     };
 810     eval "require $class;";
 811 }
 812
 813 sub _get_dump_filename {
 814     my ($self, $class) = (@_);
 815
 816     $class =~ s{::}{/}g;
 817     return $self->dump_directory . q{/} . $class . q{.pm};
 818 }
 819
 820 sub _ensure_dump_subdirs {
 821     my ($self, $class) = (@_);
 822
 823     my @name_parts = split(/::/, $class);
 824     pop @name_parts; # we don't care about the very last element,
 825                      # which is a filename
 826
 827     my $dir = $self->dump_directory;
 828     while (1) {
 829         if(!-d $dir) {
 830             mkdir($dir) or croak "mkdir('$dir') failed: $!";
 831         }
 832         last if !@name_parts;
 833         $dir = File::Spec->catdir($dir, shift @name_parts);
 834     }
 835 }
 836
 837 sub _dump_to_dir {
 838     my ($self, @classes) = @_;
 839
 840     my $schema_class = $self->schema_class;
 841     my $schema_base_class = $self->schema_base_class || 'DBIx::Class::Schema';
 842
 843     my $target_dir = $self->dump_directory;
 844     warn "Dumping manual schema for $schema_class to directory $target_dir ...\n"
 845         unless $self->{dynamic} or $self->{quiet};
 846
 847     my $schema_text =
 848           qq|package $schema_class;\n\n|
 849         . qq|# Created by DBIx::Class::Schema::Loader\n|
 850         . qq|# DO NOT MODIFY THE FIRST PART OF THIS FILE\n\n|
 851         . qq|use strict;\nuse warnings;\n\n|
 852         . qq|use base '$schema_base_class';\n\n|;
 853
 854     if ($self->use_namespaces) {
 855         $schema_text .= qq|__PACKAGE__->load_namespaces|;
 856         my $namespace_options;
 857         for my $attr (qw(result_namespace
 858                          resultset_namespace
 859                          default_resultset_class)) {
 860             if ($self->$attr) {
 861                 $namespace_options .= qq|    $attr => '| . $self->$attr . qq|',\n|
 862             }
 863         }
 864         $schema_text .= qq|(\n$namespace_options)| if $namespace_options;
 865         $schema_text .= qq|;\n|;
 866     }
 867     else {
 868         $schema_text .= qq|__PACKAGE__->load_classes;\n|;
 869     }
 870
 871     {
 872         local $self->{version_to_dump} = $self->schema_version_to_dump;
 873         $self->_write_classfile($schema_class, $schema_text);
 874     }
 875
 876     my $result_base_class = $self->result_base_class || 'DBIx::Class::Core';
 877
 878     foreach my $src_class (@classes) {
 879         my $src_text =
 880               qq|package $src_class;\n\n|
 881             . qq|# Created by DBIx::Class::Schema::Loader\n|
 882             . qq|# DO NOT MODIFY THE FIRST PART OF THIS FILE\n\n|
 883             . qq|use strict;\nuse warnings;\n\n|
 884             . qq|use base '$result_base_class';\n\n|;
 885
 886         $self->_write_classfile($src_class, $src_text);
 887     }
 888
 889     warn "Schema dump completed.\n" unless $self->{dynamic} or $self->{quiet};
 890
 891 }
 892
 893 sub _sig_comment {
 894     my ($self, $version, $ts) = @_;
 895     return qq|\n\n# Created by DBIx::Class::Schema::Loader|
 896          . qq| v| . $version
 897          . q| @ | . $ts
 898          . qq|\n# DO NOT MODIFY THIS OR ANYTHING ABOVE! md5sum:|;
 899 }
 900
 901 sub _write_classfile {
 902     my ($self, $class, $text) = @_;
 903
 904     my $filename = $self->_get_dump_filename($class);
 905     $self->_ensure_dump_subdirs($class);
 906
 907     if (-f $filename && $self->really_erase_my_files) {
 908         warn "Deleting existing file '$filename' due to "
 909             . "'really_erase_my_files' setting\n" unless $self->{quiet};
 910         unlink($filename);
 911     }
 912
 913     my ($custom_content, $old_md5, $old_ver, $old_ts) = $self->_get_custom_content($class, $filename);
 914
 915     if ($self->_upgrading_from) {
 916         my $old_class = $self->_upgrading_classes->{$class};
 917
 918         if ($old_class && ($old_class ne $class)) {
 919             my $old_filename = $self->_get_dump_filename($old_class);
 920
 921             my ($old_custom_content) = $self->_get_custom_content(
 922                 $old_class, $old_filename, 0 # do not add default comment
 923             );
 924
 925             $old_custom_content =~ s/\n\n# You can replace.*\n1;\n//;
 926
 927             if ($old_custom_content) {
 928                 $custom_content =
 929                     "\n" . $old_custom_content . "\n" . $custom_content;
 930             }
 931
 932             unlink $old_filename;
 933         }
 934     }
 935
 936     $custom_content = $self->_rewrite_old_classnames($custom_content);
 937
 938     $text .= qq|$_\n|
 939         for @{$self->{_dump_storage}->{$class} || []};
 940
 941     # Check and see if the dump is infact differnt
 942
 943     my $compare_to;
 944     if ($old_md5) {
 945       $compare_to = $text . $self->_sig_comment($old_ver, $old_ts);
 946
 947
 948       if (Digest::MD5::md5_base64($compare_to) eq $old_md5) {
 949         return;
 950       }
 951     }
 952
 953     $text .= $self->_sig_comment(
 954       $self->version_to_dump,
 955       POSIX::strftime('%Y-%m-%d %H:%M:%S', localtime)
 956     );
 957
 958     open(my $fh, '>', $filename)
 959         or croak "Cannot open '$filename' for writing: $!";
 960
 961     # Write the top half and its MD5 sum
 962     print $fh $text . Digest::MD5::md5_base64($text) . "\n";
 963
 964     # Write out anything loaded via external partial class file in @INC
 965     print $fh qq|$_\n|
 966         for @{$self->{_ext_storage}->{$class} || []};
 967
 968     # Write out any custom content the user has added
 969     print $fh $custom_content;
 970
 971     close($fh)
 972         or croak "Error closing '$filename': $!";
 973 }
 974
 975 sub _default_custom_content {
 976     return qq|\n\n# You can replace this text with custom|
 977          . qq| content, and it will be preserved on regeneration|
 978          . qq|\n1;\n|;
 979 }
 980
 981 sub _get_custom_content {
 982     my ($self, $class, $filename, $add_default) = @_;
 983
 984     $add_default = 1 unless defined $add_default;
 985
 986     return ($self->_default_custom_content) if ! -f $filename;
 987
 988     open(my $fh, '<', $filename)
 989         or croak "Cannot open '$filename' for reading: $!";
 990
 991     my $mark_re =
 992         qr{^(# DO NOT MODIFY THIS OR ANYTHING ABOVE! md5sum:)([A-Za-z0-9/+]{22})\n};
 993
 994     my $buffer = '';
 995     my ($md5, $ts, $ver);
 996     while(<$fh>) {
 997         if(!$md5 && /$mark_re/) {
 998             $md5 = $2;
 999             my $line = $1;
1000
1001             # Pull out the previous version and timestamp
1002             ($ver, $ts) = $buffer =~ m/# Created by DBIx::Class::Schema::Loader v(.*?) @ (.*?)$/s;
1003
1004             $buffer .= $line;
1005             croak "Checksum mismatch in '$filename', the auto-generated part of the file has been modified outside of this loader.  Aborting.\nIf you want to overwrite these modifications, set the 'overwrite_modifications' loader option.\n"
1006                 if !$self->overwrite_modifications && Digest::MD5::md5_base64($buffer) ne $md5;
1007
1008             $buffer = '';
1009         }
1010         else {
1011             $buffer .= $_;
1012         }
1013     }
1014
1015     croak "Cannot not overwrite '$filename' without 'really_erase_my_files',"
1016         . " it does not appear to have been generated by Loader"
1017             if !$md5;
1018
1019     # Default custom content:
1020     $buffer ||= $self->_default_custom_content if $add_default;
1021
1022     return ($buffer, $md5, $ver, $ts);
1023 }
1024
1025 sub _use {
1026     my $self = shift;
1027     my $target = shift;
1028
1029     foreach (@_) {
1030         warn "$target: use $_;" if $self->debug;
1031         $self->_raw_stmt($target, "use $_;");
1032     }
1033 }
1034
1035 sub _inject {
1036     my $self = shift;
1037     my $target = shift;
1038     my $schema_class = $self->schema_class;
1039
1040     my $blist = join(q{ }, @_);
1041     warn "$target: use base qw/ $blist /;" if $self->debug && @_;
1042     $self->_raw_stmt($target, "use base qw/ $blist /;") if @_;
1043 }
1044
1045 # Create class with applicable bases, setup monikers, etc
1046 sub _make_src_class {
1047     my ($self, $table) = @_;
1048
1049     my $schema       = $self->schema;
1050     my $schema_class = $self->schema_class;
1051
1052     my $table_moniker = $self->_table2moniker($table);
1053     my @result_namespace = ($schema_class);
1054     if ($self->use_namespaces) {
1055         my $result_namespace = $self->result_namespace || 'Result';
1056         if ($result_namespace =~ /^\+(.*)/) {
1057             # Fully qualified namespace
1058             @result_namespace =  ($1)
1059         }
1060         else {
1061             # Relative namespace
1062             push @result_namespace, $result_namespace;
1063         }
1064     }
1065     my $table_class = join(q{::}, @result_namespace, $table_moniker);
1066
1067     if (my $upgrading_v = $self->_upgrading_from) {
1068         local $self->naming->{monikers} = $upgrading_v;
1069
1070         my $old_class = join(q{::}, @result_namespace,
1071             $self->_table2moniker($table));
1072
1073         $self->_upgrading_classes->{$table_class} = $old_class;
1074     }
1075
1076     my $table_normalized = lc $table;
1077     $self->classes->{$table} = $table_class;
1078     $self->classes->{$table_normalized} = $table_class;
1079     $self->monikers->{$table} = $table_moniker;
1080     $self->monikers->{$table_normalized} = $table_moniker;
1081
1082     $self->_use   ($table_class, @{$self->additional_classes});
1083     $self->_inject($table_class, @{$self->left_base_classes});
1084
1085     if (my @components = @{ $self->components }) {
1086         $self->_dbic_stmt($table_class, 'load_components', @components);
1087     }
1088
1089     $self->_dbic_stmt($table_class, 'load_resultset_components', @{$self->resultset_components})
1090         if @{$self->resultset_components};
1091     $self->_inject($table_class, @{$self->additional_base_classes});
1092 }
1093
1094 # Set up metadata (cols, pks, etc)
1095 sub _setup_src_meta {
1096     my ($self, $table) = @_;
1097
1098     my $schema       = $self->schema;
1099     my $schema_class = $self->schema_class;
1100
1101     my $table_class = $self->classes->{$table};
1102     my $table_moniker = $self->monikers->{$table};
1103
1104     my $table_name = $table;
1105     my $name_sep   = $self->schema->storage->sql_maker->name_sep;
1106
1107     if ($name_sep && $table_name =~ /\Q$name_sep\E/) {
1108         $table_name = \ $self->_quote_table_name($table_name);
1109     }
1110
1111     $self->_dbic_stmt($table_class,'table',$table_name);
1112
1113     my $cols = $self->_table_columns($table);
1114     my $col_info;
1115     eval { $col_info = $self->_columns_info_for($table) };
1116     if($@) {
1117         $self->_dbic_stmt($table_class,'add_columns',@$cols);
1118     }
1119     else {
1120         if ($self->_is_case_sensitive) {
1121             for my $col (keys %$col_info) {
1122                 $col_info->{$col}{accessor} = lc $col
1123                     if $col ne lc($col);
1124             }
1125         } else {
1126             $col_info = { map { lc($_), $col_info->{$_} } keys %$col_info };
1127         }
1128
1129         my $fks = $self->_table_fk_info($table);
1130
1131         for my $fkdef (@$fks) {
1132             for my $col (@{ $fkdef->{local_columns} }) {
1133                 $col_info->{$col}{is_foreign_key} = 1;
1134             }
1135         }
1136         $self->_dbic_stmt(
1137             $table_class,
1138             'add_columns',
1139             map { $_, ($col_info->{$_}||{}) } @$cols
1140         );
1141     }
1142
1143     my %uniq_tag; # used to eliminate duplicate uniqs
1144
1145     my $pks = $self->_table_pk_info($table) || [];
1146     @$pks ? $self->_dbic_stmt($table_class,'set_primary_key',@$pks)
1147           : carp("$table has no primary key");
1148     $uniq_tag{ join("\0", @$pks) }++ if @$pks; # pk is a uniq
1149
1150     my $uniqs = $self->_table_uniq_info($table) || [];
1151     for (@$uniqs) {
1152         my ($name, $cols) = @$_;
1153         next if $uniq_tag{ join("\0", @$cols) }++; # skip duplicates
1154         $self->_dbic_stmt($table_class,'add_unique_constraint', $name, $cols);
1155     }
1156
1157 }
1158
1159 =head2 tables
1160
1161 Returns a sorted list of loaded tables, using the original database table
1162 names.
1163
1164 =cut
1165
1166 sub tables {
1167     my $self = shift;
1168
1169     return keys %{$self->_tables};
1170 }
1171
1172 # Make a moniker from a table
1173 sub _default_table2moniker {
1174     no warnings 'uninitialized';
1175     my ($self, $table) = @_;
1176
1177     if ($self->naming->{monikers} eq 'v4') {
1178         return join '', map ucfirst, split /[\W_]+/, lc $table;
1179     }
1180
1181     return join '', map ucfirst, split /[\W_]+/,
1182         Lingua::EN::Inflect::Number::to_S(lc $table);
1183 }
1184
1185 sub _table2moniker {
1186     my ( $self, $table ) = @_;
1187
1188     my $moniker;
1189
1190     if( ref $self->moniker_map eq 'HASH' ) {
1191         $moniker = $self->moniker_map->{$table};
1192     }
1193     elsif( ref $self->moniker_map eq 'CODE' ) {
1194         $moniker = $self->moniker_map->($table);
1195     }
1196
1197     $moniker ||= $self->_default_table2moniker($table);
1198
1199     return $moniker;
1200 }
1201
1202 sub _load_relationships {
1203     my ($self, $table) = @_;
1204
1205     my $tbl_fk_info = $self->_table_fk_info($table);
1206     foreach my $fkdef (@$tbl_fk_info) {
1207         $fkdef->{remote_source} =
1208             $self->monikers->{delete $fkdef->{remote_table}};
1209     }
1210     my $tbl_uniq_info = $self->_table_uniq_info($table);
1211
1212     my $local_moniker = $self->monikers->{$table};
1213     my $rel_stmts = $self->_relbuilder->generate_code($local_moniker, $tbl_fk_info, $tbl_uniq_info);
1214
1215     foreach my $src_class (sort keys %$rel_stmts) {
1216         my $src_stmts = $rel_stmts->{$src_class};
1217         foreach my $stmt (@$src_stmts) {
1218             $self->_dbic_stmt($src_class,$stmt->{method},@{$stmt->{args}});
1219         }
1220     }
1221 }
1222
1223 # Overload these in driver class:
1224
1225 # Returns an arrayref of column names
1226 sub _table_columns { croak "ABSTRACT METHOD" }
1227
1228 # Returns arrayref of pk col names
1229 sub _table_pk_info { croak "ABSTRACT METHOD" }
1230
1231 # Returns an arrayref of uniqs [ [ foo => [ col1, col2 ] ], [ bar => [ ... ] ] ]
1232 sub _table_uniq_info { croak "ABSTRACT METHOD" }
1233
1234 # Returns an arrayref of foreign key constraints, each
1235 #   being a hashref with 3 keys:
1236 #   local_columns (arrayref), remote_columns (arrayref), remote_table
1237 sub _table_fk_info { croak "ABSTRACT METHOD" }
1238
1239 # Returns an array of lower case table names
1240 sub _tables_list { croak "ABSTRACT METHOD" }
1241
1242 # Execute a constructive DBIC class method, with debug/dump_to_dir hooks.
1243 sub _dbic_stmt {
1244     my $self   = shift;
1245     my $class  = shift;
1246     my $method = shift;
1247
1248     # generate the pod for this statement, storing it with $self->_pod
1249     $self->_make_pod( $class, $method, @_ );
1250
1251     my $args = dump(@_);
1252     $args = '(' . $args . ')' if @_ < 2;
1253     my $stmt = $method . $args . q{;};
1254
1255     warn qq|$class\->$stmt\n| if $self->debug;
1256     $self->_raw_stmt($class, '__PACKAGE__->' . $stmt);
1257     return;
1258 }
1259
1260 # generates the accompanying pod for a DBIC class method statement,
1261 # storing it with $self->_pod
1262 sub _make_pod {
1263     my $self   = shift;
1264     my $class  = shift;
1265     my $method = shift;
1266
1267     if ( $method eq 'table' ) {
1268         my ($table) = @_;
1269         $self->_pod( $class, "=head1 NAME" );
1270         my $table_descr = $class;
1271         if ( $self->can('_table_comment') ) {
1272             my $comment = $self->_table_comment($table);
1273             $table_descr .= " - " . $comment if $comment;
1274         }
1275         $self->{_class2table}{ $class } = $table;
1276         $self->_pod( $class, $table_descr );
1277         $self->_pod_cut( $class );
1278     } elsif ( $method eq 'add_columns' ) {
1279         $self->_pod( $class, "=head1 ACCESSORS" );
1280         my $col_counter = 0;
1281         my @cols = @_;
1282         while( my ($name,$attrs) = splice @cols,0,2 ) {
1283             $col_counter++;
1284             $self->_pod( $class, '=head2 ' . $name  );
1285             $self->_pod( $class,
1286                          join "\n", map {
1287                              my $s = $attrs->{$_};
1288                              $s = !defined $s      ? 'undef'          :
1289                                   length($s) == 0  ? '(empty string)' :
1290                                                      $s;
1291
1292                              "  $_: $s"
1293                          } sort keys %$attrs,
1294                        );
1295
1296             if( $self->can('_column_comment')
1297                 and my $comment = $self->_column_comment( $self->{_class2table}{$class}, $col_counter)
1298               ) {
1299                 $self->_pod( $class, $comment );
1300             }
1301         }
1302         $self->_pod_cut( $class );
1303     } elsif ( $method =~ /^(belongs_to|has_many|might_have)$/ ) {
1304         $self->_pod( $class, "=head1 RELATIONS" ) unless $self->{_relations_started} { $class } ;
1305         my ( $accessor, $rel_class ) = @_;
1306         $self->_pod( $class, "=head2 $accessor" );
1307         $self->_pod( $class, 'Type: ' . $method );
1308         $self->_pod( $class, "Related object: L<$rel_class>" );
1309         $self->_pod_cut( $class );
1310         $self->{_relations_started} { $class } = 1;
1311     }
1312 }
1313
1314 # Stores a POD documentation
1315 sub _pod {
1316     my ($self, $class, $stmt) = @_;
1317     $self->_raw_stmt( $class, "\n" . $stmt  );
1318 }
1319
1320 sub _pod_cut {
1321     my ($self, $class ) = @_;
1322     $self->_raw_stmt( $class, "\n=cut\n" );
1323 }
1324
1325
1326 # Store a raw source line for a class (for dumping purposes)
1327 sub _raw_stmt {
1328     my ($self, $class, $stmt) = @_;
1329     push(@{$self->{_dump_storage}->{$class}}, $stmt);
1330 }
1331
1332 # Like above, but separately for the externally loaded stuff
1333 sub _ext_stmt {
1334     my ($self, $class, $stmt) = @_;
1335     push(@{$self->{_ext_storage}->{$class}}, $stmt);
1336 }
1337
1338 sub _quote_table_name {
1339     my ($self, $table) = @_;
1340
1341     my $qt = $self->schema->storage->sql_maker->quote_char;
1342
1343     return $table unless $qt;
1344
1345     if (ref $qt) {
1346         return $qt->[0] . $table . $qt->[1];
1347     }
1348
1349     return $qt . $table . $qt;
1350 }
1351
1352 sub _is_case_sensitive { 0 }
1353
1354 # remove the dump dir from @INC on destruction
1355 sub DESTROY {
1356     my $self = shift;
1357
1358     @INC = grep $_ ne $self->dump_directory, @INC;
1359 }
1360
1361 =head2 monikers
1362
1363 Returns a hashref of loaded table to moniker mappings.  There will
1364 be two entries for each table, the original name and the "normalized"
1365 name, in the case that the two are different (such as databases
1366 that like uppercase table names, or preserve your original mixed-case
1367 definitions, or what-have-you).
1368
1369 =head2 classes
1370
1371 Returns a hashref of table to class mappings.  In some cases it will
1372 contain multiple entries per table for the original and normalized table
1373 names, as above in L</monikers>.
1374
1375 =head1 SEE ALSO
1376
1377 L<DBIx::Class::Schema::Loader>
1378
1379 =head1 AUTHOR
1380
1381 See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
1382
1383 =head1 LICENSE
1384
1385 This library is free software; you can redistribute it and/or modify it under
1386 the same terms as Perl itself.
1387
1388 =cut
1389
1390 1;