1 package DBIx::Class::Schema::Loader::Base;
5 use base qw/Class::Accessor::Grouped Class::C3::Componentised/;
7 use Carp::Clan qw/^DBIx::Class/;
8 use DBIx::Class::Schema::Loader::RelBuilder;
9 use Data::Dump qw/ dump /;
14 use Lingua::EN::Inflect::Number qw//;
17 use Class::Inspector ();
20 our $VERSION = '0.05002';
22 __PACKAGE__->mk_group_ro_accessors('simple', qw/
29 additional_base_classes
44 default_resultset_class
47 overwrite_modifications
61 __PACKAGE__->mk_group_accessors('simple', qw/
63 schema_version_to_dump
65 _upgrading_from_load_classes
66 _downgrading_to_load_classes
67 _rewriting_result_namespace
72 pod_comment_spillover_length
77 DBIx::Class::Schema::Loader::Base - Base DBIx::Class::Schema::Loader Implementation.
81 See L<DBIx::Class::Schema::Loader>
85 This is the base class for the storage-specific C<DBIx::Class::Schema::*>
86 classes, and implements the common functionality between them.
88 =head1 CONSTRUCTOR OPTIONS
90 These constructor options are the base options for
91 L<DBIx::Class::Schema::Loader/loader_options>. Available constructor options are:
93 =head2 skip_relationships
95 Skip setting up relationships. The default is to attempt the loading
98 =head2 skip_load_external
100 Skip loading of other classes in @INC. The default is to merge all other classes
101 with the same name found in @INC into the schema file we are creating.
105 Static schemas (ones dumped to disk) will, by default, use the new-style 0.05XXX
106 relationship names and singularized Results, unless you're overwriting an
107 existing dump made by a 0.04XXX version of L<DBIx::Class::Schema::Loader>, in
108 which case the backward compatible RelBuilder will be activated, and
109 singularization will be turned off.
115 will disable the backward-compatible RelBuilder and use
116 the new-style relationship names along with singularized Results, even when
117 overwriting a dump made with an earlier version.
119 The option also takes a hashref:
121 naming => { relationships => 'v5', monikers => 'v4' }
129 How to name relationship accessors.
133 How to name Result classes.
143 Latest default style, whatever that happens to be.
147 Version 0.05XXX style.
151 Version 0.04XXX style.
155 Dynamic schemas will always default to the 0.04XXX relationship names and won't
156 singularize Results for backward compatibility, to activate the new RelBuilder
157 and singularization put this in your C<Schema.pm> file:
159 __PACKAGE__->naming('current');
161 Or if you prefer to use 0.05XXX features but insure that nothing breaks in the
162 next major version upgrade:
164 __PACKAGE__->naming('v5');
168 By default POD will be generated for columns and relationships, using database
169 metadata for the text if available and supported.
171 Reading database metadata (e.g. C<COMMENT ON TABLE some_table ...>) is only
172 supported for Postgres right now.
174 Set this to C<0> to turn off all POD generation.
176 =head2 pod_comment_mode
178 Controls where table comments appear in the generated POD. Smaller table
179 comments are appended to the C<NAME> section of the documentation, and larger
180 ones are inserted into C<DESCRIPTION> instead. You can force a C<DESCRIPTION>
181 section to be generated with the comment always, only use C<NAME>, or choose
182 the length threshold at which the comment is forced into the description.
188 Use C<NAME> section only.
192 Force C<DESCRIPTION> always.
196 Use C<DESCRIPTION> if length > L</pod_comment_spillover_length>, this is the
201 =head2 pod_comment_spillover_length
203 When pod_comment_mode is set to C<auto>, this is the length of the comment at
204 which it will be forced into a separate description section.
208 =head2 relationship_attrs
210 Hashref of attributes to pass to each generated relationship, listed
211 by type. Also supports relationship type 'all', containing options to
212 pass to all generated relationships. Attributes set for more specific
213 relationship types override those set in 'all'.
217 relationship_attrs => {
218 all => { cascade_delete => 0 },
219 has_many => { cascade_delete => 1 },
222 will set the C<cascade_delete> option to 0 for all generated relationships,
223 except for C<has_many>, which will have cascade_delete as 1.
225 NOTE: this option is not supported if v4 backward-compatible naming is
226 set either globally (naming => 'v4') or just for relationships.
230 If set to true, each constructive L<DBIx::Class> statement the loader
231 decides to execute will be C<warn>-ed before execution.
235 Set the name of the schema to load (schema in the sense that your database
236 vendor means it). Does not currently support loading more than one schema
241 Only load tables matching regex. Best specified as a qr// regex.
245 Exclude tables matching regex. Best specified as a qr// regex.
249 Overrides the default table name to moniker translation. Can be either
250 a hashref of table keys and moniker values, or a coderef for a translator
251 function taking a single scalar table name argument and returning
252 a scalar moniker. If the hash entry does not exist, or the function
253 returns a false value, the code falls back to default behavior
256 The default behavior is to singularize the table name, and: C<join '', map
257 ucfirst, split /[\W_]+/, lc $table>, which is to say: lowercase everything,
258 split up the table name into chunks anywhere a non-alpha-numeric character
259 occurs, change the case of first letter of each chunk to upper case, and put
260 the chunks back together. Examples:
262 Table Name | Moniker Name
263 ---------------------------
265 luser_group | LuserGroup
266 luser-opts | LuserOpt
268 =head2 inflect_plural
270 Just like L</moniker_map> above (can be hash/code-ref, falls back to default
271 if hash key does not exist or coderef returns false), but acts as a map
272 for pluralizing relationship names. The default behavior is to utilize
273 L<Lingua::EN::Inflect::Number/to_PL>.
275 =head2 inflect_singular
277 As L</inflect_plural> above, but for singularizing relationship names.
278 Default behavior is to utilize L<Lingua::EN::Inflect::Number/to_S>.
280 =head2 schema_base_class
282 Base class for your schema classes. Defaults to 'DBIx::Class::Schema'.
284 =head2 result_base_class
286 Base class for your table classes (aka result classes). Defaults to
289 =head2 additional_base_classes
291 List of additional base classes all of your table classes will use.
293 =head2 left_base_classes
295 List of additional base classes all of your table classes will use
296 that need to be leftmost.
298 =head2 additional_classes
300 List of additional classes which all of your table classes will use.
304 List of additional components to be loaded into all of your table
305 classes. A good example would be C<ResultSetManager>.
307 =head2 resultset_components
309 List of additional ResultSet components to be loaded into your table
310 classes. A good example would be C<AlwaysRS>. Component
311 C<ResultSetManager> will be automatically added to the above
312 C<components> list if this option is set.
314 =head2 use_namespaces
316 This is now the default, to go back to L<DBIx::Class::Schema/load_classes> pass
319 Generate result class names suitable for
320 L<DBIx::Class::Schema/load_namespaces> and call that instead of
321 L<DBIx::Class::Schema/load_classes>. When using this option you can also
322 specify any of the options for C<load_namespaces> (i.e. C<result_namespace>,
323 C<resultset_namespace>, C<default_resultset_class>), and they will be added
324 to the call (and the generated result class names adjusted appropriately).
326 =head2 dump_directory
328 This option is designed to be a tool to help you transition from this
329 loader to a manually-defined schema when you decide it's time to do so.
331 The value of this option is a perl libdir pathname. Within
332 that directory this module will create a baseline manual
333 L<DBIx::Class::Schema> module set, based on what it creates at runtime
336 The created schema class will have the same classname as the one on
337 which you are setting this option (and the ResultSource classes will be
338 based on this name as well).
340 Normally you wouldn't hard-code this setting in your schema class, as it
341 is meant for one-time manual usage.
343 See L<DBIx::Class::Schema::Loader/dump_to_dir> for examples of the
344 recommended way to access this functionality.
346 =head2 dump_overwrite
348 Deprecated. See L</really_erase_my_files> below, which does *not* mean
349 the same thing as the old C<dump_overwrite> setting from previous releases.
351 =head2 really_erase_my_files
353 Default false. If true, Loader will unconditionally delete any existing
354 files before creating the new ones from scratch when dumping a schema to disk.
356 The default behavior is instead to only replace the top portion of the
357 file, up to and including the final stanza which contains
358 C<# DO NOT MODIFY THIS OR ANYTHING ABOVE!>
359 leaving any customizations you placed after that as they were.
361 When C<really_erase_my_files> is not set, if the output file already exists,
362 but the aforementioned final stanza is not found, or the checksum
363 contained there does not match the generated contents, Loader will
364 croak and not touch the file.
366 You should really be using version control on your schema classes (and all
367 of the rest of your code for that matter). Don't blame me if a bug in this
368 code wipes something out when it shouldn't have, you've been warned.
370 =head2 overwrite_modifications
372 Default false. If false, when updating existing files, Loader will
373 refuse to modify any Loader-generated code that has been modified
374 since its last run (as determined by the checksum Loader put in its
377 If true, Loader will discard any manual modifications that have been
378 made to Loader-generated code.
380 Again, you should be using version control on your schema classes. Be
381 careful with this option.
383 =head2 custom_column_info
385 Must be a coderef, returing a hashref with the custom column informations.
389 custom_column_info => sub {
391 # Example from $info hashref:
393 # 'DECIMAL_DIGITS' => undef,
394 # 'COLUMN_DEF' => undef,
395 # 'TABLE_CAT' => undef,
396 # 'NUM_PREC_RADIX' => undef,
397 # 'TABLE_SCHEM' => 'TESTS',
398 # 'BUFFER_LENGTH' => '8',
399 # 'CHAR_OCTET_LENGTH' => undef,
400 # 'IS_NULLABLE' => 'NO',
401 # 'REMARKS' => undef,
402 # 'COLUMN_SIZE' => '8',
403 # 'ORDINAL_POSITION' => '1',
404 # 'COLUMN_NAME' => 'LOADER_TEST9',
405 # 'TYPE_NAME' => 'VARCHAR2',
407 # 'DATA_TYPE' => '12',
408 # 'TABLE_NAME' => 'LOADER_TEST9',
409 # 'SQL_DATA_TYPE' => '12',
410 # 'SQL_DATETIME_SUB' => undef
413 if ( $info->{TYPE_NAME} eq 'DATE' ){
414 return { timezone => "Europe/Berlin" };
419 Add to all columns with type DATE the attribute timezone => "Europe/Berlin".
423 None of these methods are intended for direct invocation by regular
424 users of L<DBIx::Class::Schema::Loader>. Anything you can find here
425 can also be found via standard L<DBIx::Class::Schema> methods somehow.
429 use constant CURRENT_V => 'v5';
431 use constant CLASS_ARGS => qw(
432 schema_base_class result_base_class additional_base_classes
433 left_base_classes additional_classes components resultset_components
436 # ensure that a peice of object data is a valid arrayref, creating
437 # an empty one or encapsulating whatever's there.
438 sub _ensure_arrayref {
443 $self->{$_} = [ $self->{$_} ]
444 unless ref $self->{$_} eq 'ARRAY';
450 Constructor for L<DBIx::Class::Schema::Loader::Base>, used internally
451 by L<DBIx::Class::Schema::Loader>.
456 my ( $class, %args ) = @_;
458 my $self = { %args };
460 bless $self => $class;
462 $self->_ensure_arrayref(qw/additional_classes
463 additional_base_classes
469 $self->_validate_class_args;
471 push(@{$self->{components}}, 'ResultSetManager')
472 if @{$self->{resultset_components}};
474 $self->{monikers} = {};
475 $self->{classes} = {};
476 $self->{_upgrading_classes} = {};
478 $self->{schema_class} ||= ( ref $self->{schema} || $self->{schema} );
479 $self->{schema} ||= $self->{schema_class};
481 croak "dump_overwrite is deprecated. Please read the"
482 . " DBIx::Class::Schema::Loader::Base documentation"
483 if $self->{dump_overwrite};
485 $self->{dynamic} = ! $self->{dump_directory};
486 $self->{temp_directory} ||= File::Temp::tempdir( 'dbicXXXX',
491 $self->{dump_directory} ||= $self->{temp_directory};
493 $self->version_to_dump($DBIx::Class::Schema::Loader::VERSION);
494 $self->schema_version_to_dump($DBIx::Class::Schema::Loader::VERSION);
496 if ((not ref $self->naming) && defined $self->naming) {
497 my $naming_ver = $self->naming;
499 relationships => $naming_ver,
500 monikers => $naming_ver,
505 for (values %{ $self->naming }) {
506 $_ = CURRENT_V if $_ eq 'current';
509 $self->{naming} ||= {};
511 $self->_check_back_compat;
513 $self->use_namespaces(1) unless defined $self->use_namespaces;
514 $self->generate_pod(1) unless defined $self->generate_pod;
515 $self->pod_comment_mode('auto') unless defined $self->pod_comment_mode;
516 $self->pod_comment_spillover_length(60) unless defined $self->pod_comment_spillover_length;
521 sub _check_back_compat {
524 # dynamic schemas will always be in 0.04006 mode, unless overridden
525 if ($self->dynamic) {
526 # just in case, though no one is likely to dump a dynamic schema
527 $self->schema_version_to_dump('0.04006');
529 if (not %{ $self->naming }) {
530 warn <<EOF unless $ENV{SCHEMA_LOADER_BACKCOMPAT};
532 Dynamic schema detected, will run in 0.04006 mode.
534 Set the 'naming' attribute or the SCHEMA_LOADER_BACKCOMPAT environment variable
535 to disable this warning.
537 Also consider setting 'use_namespaces => 1' if/when upgrading.
539 See perldoc DBIx::Class::Schema::Loader::Manual::UpgradingFromV4 for more
544 $self->_upgrading_from('v4');
547 $self->naming->{relationships} ||= 'v4';
548 $self->naming->{monikers} ||= 'v4';
550 if ($self->use_namespaces) {
551 $self->_upgrading_from_load_classes(1);
554 $self->use_namespaces(0);
560 # otherwise check if we need backcompat mode for a static schema
561 my $filename = $self->_get_dump_filename($self->schema_class);
562 return unless -e $filename;
564 open(my $fh, '<', $filename)
565 or croak "Cannot open '$filename' for reading: $!";
567 my $load_classes = 0;
568 my $result_namespace = '';
571 if (/^__PACKAGE__->load_classes;/) {
573 } elsif (/result_namespace => '([^']+)'/) {
574 $result_namespace = $1;
575 } elsif (my ($real_ver) =
576 /^# Created by DBIx::Class::Schema::Loader v(\d+\.\d+)/) {
578 if ($load_classes && (not defined $self->use_namespaces)) {
579 warn <<"EOF" unless $ENV{SCHEMA_LOADER_BACKCOMPAT};
581 'load_classes;' static schema detected, turning off 'use_namespaces'.
583 Set the 'use_namespaces' attribute or the SCHEMA_LOADER_BACKCOMPAT environment
584 variable to disable this warning.
586 See perldoc DBIx::Class::Schema::Loader::Manual::UpgradingFromV4 for more
589 $self->use_namespaces(0);
591 elsif ($load_classes && $self->use_namespaces) {
592 $self->_upgrading_from_load_classes(1);
594 elsif ((not $load_classes) && defined $self->use_namespaces
595 && (not $self->use_namespaces)) {
596 $self->_downgrading_to_load_classes(
597 $result_namespace || 'Result'
600 elsif ((not defined $self->use_namespaces)
601 || $self->use_namespaces) {
602 if (not $self->result_namespace) {
603 $self->result_namespace($result_namespace || 'Result');
605 elsif ($result_namespace ne $self->result_namespace) {
606 $self->_rewriting_result_namespace(
607 $result_namespace || 'Result'
612 # XXX when we go past .0 this will need fixing
613 my ($v) = $real_ver =~ /([1-9])/;
616 last if $v eq CURRENT_V || $real_ver =~ /^0\.\d\d999/;
618 if (not %{ $self->naming }) {
619 warn <<"EOF" unless $ENV{SCHEMA_LOADER_BACKCOMPAT};
621 Version $real_ver static schema detected, turning on backcompat mode.
623 Set the 'naming' attribute or the SCHEMA_LOADER_BACKCOMPAT environment variable
624 to disable this warning.
626 See perldoc DBIx::Class::Schema::Loader::Manual::UpgradingFromV4 for more
631 $self->_upgrading_from($v);
635 $self->naming->{relationships} ||= $v;
636 $self->naming->{monikers} ||= $v;
638 $self->schema_version_to_dump($real_ver);
646 sub _validate_class_args {
650 foreach my $k (CLASS_ARGS) {
651 next unless $self->$k;
653 my @classes = ref $self->$k eq 'ARRAY' ? @{ $self->$k } : $self->$k;
654 foreach my $c (@classes) {
655 # components default to being under the DBIx::Class namespace unless they
656 # are preceeded with a '+'
657 if ( $k =~ m/components$/ && $c !~ s/^\+// ) {
658 $c = 'DBIx::Class::' . $c;
661 # 1 == installed, 0 == not installed, undef == invalid classname
662 my $installed = Class::Inspector->installed($c);
663 if ( defined($installed) ) {
664 if ( $installed == 0 ) {
665 croak qq/$c, as specified in the loader option "$k", is not installed/;
668 croak qq/$c, as specified in the loader option "$k", is an invalid class name/;
674 sub _find_file_in_inc {
675 my ($self, $file) = @_;
677 foreach my $prefix (@INC) {
678 my $fullpath = File::Spec->catfile($prefix, $file);
679 return $fullpath if -f $fullpath
680 # abs_path throws on Windows for nonexistant files
681 and eval { Cwd::abs_path($fullpath) } ne
682 (eval { Cwd::abs_path(File::Spec->catfile($self->dump_directory, $file)) } || '');
689 my ($self, $class) = @_;
691 my $class_path = $class;
692 $class_path =~ s{::}{/}g;
693 $class_path .= '.pm';
698 sub _find_class_in_inc {
699 my ($self, $class) = @_;
701 return $self->_find_file_in_inc($self->_class_path($class));
707 return $self->_upgrading_from
708 || $self->_upgrading_from_load_classes
709 || $self->_downgrading_to_load_classes
710 || $self->_rewriting_result_namespace
714 sub _rewrite_old_classnames {
715 my ($self, $code) = @_;
717 return $code unless $self->_rewriting;
719 my %old_classes = reverse %{ $self->_upgrading_classes };
721 my $re = join '|', keys %old_classes;
724 $code =~ s/$re/$old_classes{$1} || $1/eg;
730 my ($self, $class) = @_;
732 return if $self->{skip_load_external};
734 # so that we don't load our own classes, under any circumstances
735 local *INC = [ grep $_ ne $self->dump_directory, @INC ];
737 my $real_inc_path = $self->_find_class_in_inc($class);
739 my $old_class = $self->_upgrading_classes->{$class}
740 if $self->_rewriting;
742 my $old_real_inc_path = $self->_find_class_in_inc($old_class)
743 if $old_class && $old_class ne $class;
745 return unless $real_inc_path || $old_real_inc_path;
747 if ($real_inc_path) {
748 # If we make it to here, we loaded an external definition
749 warn qq/# Loaded external class definition for '$class'\n/
752 open(my $fh, '<', $real_inc_path)
753 or croak "Failed to open '$real_inc_path' for reading: $!";
754 my $code = do { local $/; <$fh> };
756 or croak "Failed to close $real_inc_path: $!";
757 $code = $self->_rewrite_old_classnames($code);
759 if ($self->dynamic) { # load the class too
760 # kill redefined warnings
761 my $warn_handler = $SIG{__WARN__} || sub { warn @_ };
762 local $SIG{__WARN__} = sub {
764 unless $_[0] =~ /^Subroutine \S+ redefined/;
770 $self->_ext_stmt($class,
771 qq|# These lines were loaded from '$real_inc_path' found in \@INC.\n|
772 .qq|# They are now part of the custom portion of this file\n|
773 .qq|# for you to hand-edit. If you do not either delete\n|
774 .qq|# this section or remove that file from \@INC, this section\n|
775 .qq|# will be repeated redundantly when you re-create this\n|
776 .qq|# file again via Loader! See skip_load_external to disable\n|
777 .qq|# this feature.\n|
780 $self->_ext_stmt($class, $code);
781 $self->_ext_stmt($class,
782 qq|# End of lines loaded from '$real_inc_path' |
786 if ($old_real_inc_path) {
787 open(my $fh, '<', $old_real_inc_path)
788 or croak "Failed to open '$old_real_inc_path' for reading: $!";
789 $self->_ext_stmt($class, <<"EOF");
791 # These lines were loaded from '$old_real_inc_path',
792 # based on the Result class name that would have been created by an 0.04006
793 # version of the Loader. For a static schema, this happens only once during
794 # upgrade. See skip_load_external to disable this feature.
798 local ($/, @ARGV) = (undef, $old_real_inc_path); <>
800 $code = $self->_rewrite_old_classnames($code);
802 if ($self->dynamic) {
805 Detected external content in '$old_real_inc_path', a class name that would have
806 been used by an 0.04006 version of the Loader.
808 * PLEASE RENAME THIS CLASS: from '$old_class' to '$class', as that is the
809 new name of the Result.
811 # kill redefined warnings
812 my $warn_handler = $SIG{__WARN__} || sub { warn @_ };
813 local $SIG{__WARN__} = sub {
815 unless $_[0] =~ /^Subroutine \S+ redefined/;
822 $self->_ext_stmt($class, $code);
823 $self->_ext_stmt($class,
824 qq|# End of lines loaded from '$old_real_inc_path' |
831 Does the actual schema-construction work.
838 $self->_load_tables($self->_tables_list);
845 Rescan the database for newly added tables. Does
846 not process drops or changes. Returns a list of
847 the newly added table monikers.
849 The schema argument should be the schema class
850 or object to be affected. It should probably
851 be derived from the original schema_class used
857 my ($self, $schema) = @_;
859 $self->{schema} = $schema;
860 $self->_relbuilder->{schema} = $schema;
863 my @current = $self->_tables_list;
864 foreach my $table ($self->_tables_list) {
865 if(!exists $self->{_tables}->{$table}) {
866 push(@created, $table);
870 my $loaded = $self->_load_tables(@created);
872 return map { $self->monikers->{$_} } @$loaded;
876 no warnings 'uninitialized';
879 return if $self->{skip_relationships};
881 if ($self->naming->{relationships} eq 'v4') {
882 require DBIx::Class::Schema::Loader::RelBuilder::Compat::v0_040;
883 return $self->{relbuilder} ||=
884 DBIx::Class::Schema::Loader::RelBuilder::Compat::v0_040->new(
885 $self->schema, $self->inflect_plural, $self->inflect_singular
889 $self->{relbuilder} ||= DBIx::Class::Schema::Loader::RelBuilder->new (
891 $self->inflect_plural,
892 $self->inflect_singular,
893 $self->relationship_attrs,
898 my ($self, @tables) = @_;
900 # First, use _tables_list with constraint and exclude
901 # to get a list of tables to operate on
903 my $constraint = $self->constraint;
904 my $exclude = $self->exclude;
906 @tables = grep { /$constraint/ } @tables if $constraint;
907 @tables = grep { ! /$exclude/ } @tables if $exclude;
909 # Save the new tables to the tables list
911 $self->{_tables}->{$_} = 1;
914 $self->_make_src_class($_) for @tables;
915 $self->_setup_src_meta($_) for @tables;
917 if(!$self->skip_relationships) {
918 # The relationship loader needs a working schema
920 local $self->{dump_directory} = $self->{temp_directory};
921 $self->_reload_classes(\@tables);
922 $self->_load_relationships($_) for @tables;
925 # Remove that temp dir from INC so it doesn't get reloaded
926 @INC = grep $_ ne $self->dump_directory, @INC;
929 $self->_load_external($_)
930 for map { $self->classes->{$_} } @tables;
932 # Reload without unloading first to preserve any symbols from external
934 $self->_reload_classes(\@tables, 0);
936 # Drop temporary cache
937 delete $self->{_cache};
942 sub _reload_classes {
943 my ($self, $tables, $unload) = @_;
945 my @tables = @$tables;
946 $unload = 1 unless defined $unload;
948 # so that we don't repeat custom sections
949 @INC = grep $_ ne $self->dump_directory, @INC;
951 $self->_dump_to_dir(map { $self->classes->{$_} } @tables);
953 unshift @INC, $self->dump_directory;
956 my %have_source = map { $_ => $self->schema->source($_) }
957 $self->schema->sources;
959 for my $table (@tables) {
960 my $moniker = $self->monikers->{$table};
961 my $class = $self->classes->{$table};
964 no warnings 'redefine';
965 local *Class::C3::reinitialize = sub {};
968 Class::Unload->unload($class) if $unload;
969 my ($source, $resultset_class);
971 ($source = $have_source{$moniker})
972 && ($resultset_class = $source->resultset_class)
973 && ($resultset_class ne 'DBIx::Class::ResultSet')
975 my $has_file = Class::Inspector->loaded_filename($resultset_class);
976 Class::Unload->unload($resultset_class) if $unload;
977 $self->_reload_class($resultset_class) if $has_file;
979 $self->_reload_class($class);
981 push @to_register, [$moniker, $class];
984 Class::C3->reinitialize;
986 $self->schema->register_class(@$_);
990 # We use this instead of ensure_class_loaded when there are package symbols we
993 my ($self, $class) = @_;
995 my $class_path = $self->_class_path($class);
996 delete $INC{ $class_path };
998 # kill redefined warnings
999 my $warn_handler = $SIG{__WARN__} || sub { warn @_ };
1000 local $SIG{__WARN__} = sub {
1002 unless $_[0] =~ /^Subroutine \S+ redefined/;
1004 eval "require $class;";
1007 sub _get_dump_filename {
1008 my ($self, $class) = (@_);
1010 $class =~ s{::}{/}g;
1011 return $self->dump_directory . q{/} . $class . q{.pm};
1014 sub _ensure_dump_subdirs {
1015 my ($self, $class) = (@_);
1017 my @name_parts = split(/::/, $class);
1018 pop @name_parts; # we don't care about the very last element,
1019 # which is a filename
1021 my $dir = $self->dump_directory;
1024 mkdir($dir) or croak "mkdir('$dir') failed: $!";
1026 last if !@name_parts;
1027 $dir = File::Spec->catdir($dir, shift @name_parts);
1032 my ($self, @classes) = @_;
1034 my $schema_class = $self->schema_class;
1035 my $schema_base_class = $self->schema_base_class || 'DBIx::Class::Schema';
1037 my $target_dir = $self->dump_directory;
1038 warn "Dumping manual schema for $schema_class to directory $target_dir ...\n"
1039 unless $self->{dynamic} or $self->{quiet};
1042 qq|package $schema_class;\n\n|
1043 . qq|# Created by DBIx::Class::Schema::Loader\n|
1044 . qq|# DO NOT MODIFY THE FIRST PART OF THIS FILE\n\n|
1045 . qq|use strict;\nuse warnings;\n\n|
1046 . qq|use base '$schema_base_class';\n\n|;
1048 if ($self->use_namespaces) {
1049 $schema_text .= qq|__PACKAGE__->load_namespaces|;
1050 my $namespace_options;
1051 for my $attr (qw(result_namespace
1053 default_resultset_class)) {
1055 $namespace_options .= qq| $attr => '| . $self->$attr . qq|',\n|
1058 $schema_text .= qq|(\n$namespace_options)| if $namespace_options;
1059 $schema_text .= qq|;\n|;
1062 $schema_text .= qq|__PACKAGE__->load_classes;\n|;
1066 local $self->{version_to_dump} = $self->schema_version_to_dump;
1067 $self->_write_classfile($schema_class, $schema_text, 1);
1070 my $result_base_class = $self->result_base_class || 'DBIx::Class::Core';
1072 foreach my $src_class (@classes) {
1074 qq|package $src_class;\n\n|
1075 . qq|# Created by DBIx::Class::Schema::Loader\n|
1076 . qq|# DO NOT MODIFY THE FIRST PART OF THIS FILE\n\n|
1077 . qq|use strict;\nuse warnings;\n\n|
1078 . qq|use base '$result_base_class';\n\n|;
1080 $self->_write_classfile($src_class, $src_text);
1083 # remove Result dir if downgrading from use_namespaces, and there are no
1085 if (my $result_ns = $self->_downgrading_to_load_classes
1086 || $self->_rewriting_result_namespace) {
1087 my $result_namespace = $self->_result_namespace(
1092 (my $result_dir = $result_namespace) =~ s{::}{/}g;
1093 $result_dir = $self->dump_directory . '/' . $result_dir;
1095 unless (my @files = glob "$result_dir/*") {
1100 warn "Schema dump completed.\n" unless $self->{dynamic} or $self->{quiet};
1105 my ($self, $version, $ts) = @_;
1106 return qq|\n\n# Created by DBIx::Class::Schema::Loader|
1109 . qq|\n# DO NOT MODIFY THIS OR ANYTHING ABOVE! md5sum:|;
1112 sub _write_classfile {
1113 my ($self, $class, $text, $is_schema) = @_;
1115 my $filename = $self->_get_dump_filename($class);
1116 $self->_ensure_dump_subdirs($class);
1118 if (-f $filename && $self->really_erase_my_files) {
1119 warn "Deleting existing file '$filename' due to "
1120 . "'really_erase_my_files' setting\n" unless $self->{quiet};
1124 my ($custom_content, $old_md5, $old_ver, $old_ts) = $self->_get_custom_content($class, $filename);
1126 if (my $old_class = $self->_upgrading_classes->{$class}) {
1127 my $old_filename = $self->_get_dump_filename($old_class);
1129 my ($old_custom_content) = $self->_get_custom_content(
1130 $old_class, $old_filename, 0 # do not add default comment
1133 $old_custom_content =~ s/\n\n# You can replace.*\n1;\n//;
1135 if ($old_custom_content) {
1137 "\n" . $old_custom_content . "\n" . $custom_content;
1140 unlink $old_filename;
1143 $custom_content = $self->_rewrite_old_classnames($custom_content);
1146 for @{$self->{_dump_storage}->{$class} || []};
1148 # Check and see if the dump is infact differnt
1152 $compare_to = $text . $self->_sig_comment($old_ver, $old_ts);
1155 if (Digest::MD5::md5_base64($compare_to) eq $old_md5) {
1156 return unless $self->_upgrading_from && $is_schema;
1160 $text .= $self->_sig_comment(
1161 $self->version_to_dump,
1162 POSIX::strftime('%Y-%m-%d %H:%M:%S', localtime)
1165 open(my $fh, '>', $filename)
1166 or croak "Cannot open '$filename' for writing: $!";
1168 # Write the top half and its MD5 sum
1169 print $fh $text . Digest::MD5::md5_base64($text) . "\n";
1171 # Write out anything loaded via external partial class file in @INC
1173 for @{$self->{_ext_storage}->{$class} || []};
1175 # Write out any custom content the user has added
1176 print $fh $custom_content;
1179 or croak "Error closing '$filename': $!";
1182 sub _default_custom_content {
1183 return qq|\n\n# You can replace this text with custom|
1184 . qq| content, and it will be preserved on regeneration|
1188 sub _get_custom_content {
1189 my ($self, $class, $filename, $add_default) = @_;
1191 $add_default = 1 unless defined $add_default;
1193 return ($self->_default_custom_content) if ! -f $filename;
1195 open(my $fh, '<', $filename)
1196 or croak "Cannot open '$filename' for reading: $!";
1199 qr{^(# DO NOT MODIFY THIS OR ANYTHING ABOVE! md5sum:)([A-Za-z0-9/+]{22})\n};
1202 my ($md5, $ts, $ver);
1204 if(!$md5 && /$mark_re/) {
1208 # Pull out the previous version and timestamp
1209 ($ver, $ts) = $buffer =~ m/# Created by DBIx::Class::Schema::Loader v(.*?) @ (.*?)$/s;
1212 croak "Checksum mismatch in '$filename', the auto-generated part of the file has been modified outside of this loader. Aborting.\nIf you want to overwrite these modifications, set the 'overwrite_modifications' loader option.\n"
1213 if !$self->overwrite_modifications && Digest::MD5::md5_base64($buffer) ne $md5;
1222 croak "Cannot not overwrite '$filename' without 'really_erase_my_files',"
1223 . " it does not appear to have been generated by Loader"
1226 # Default custom content:
1227 $buffer ||= $self->_default_custom_content if $add_default;
1229 return ($buffer, $md5, $ver, $ts);
1237 warn "$target: use $_;" if $self->debug;
1238 $self->_raw_stmt($target, "use $_;");
1245 my $schema_class = $self->schema_class;
1247 my $blist = join(q{ }, @_);
1248 warn "$target: use base qw/ $blist /;" if $self->debug && @_;
1249 $self->_raw_stmt($target, "use base qw/ $blist /;") if @_;
1252 sub _result_namespace {
1253 my ($self, $schema_class, $ns) = @_;
1254 my @result_namespace;
1256 if ($ns =~ /^\+(.*)/) {
1257 # Fully qualified namespace
1258 @result_namespace = ($1)
1261 # Relative namespace
1262 @result_namespace = ($schema_class, $ns);
1265 return wantarray ? @result_namespace : join '::', @result_namespace;
1268 # Create class with applicable bases, setup monikers, etc
1269 sub _make_src_class {
1270 my ($self, $table) = @_;
1272 my $schema = $self->schema;
1273 my $schema_class = $self->schema_class;
1275 my $table_moniker = $self->_table2moniker($table);
1276 my @result_namespace = ($schema_class);
1277 if ($self->use_namespaces) {
1278 my $result_namespace = $self->result_namespace || 'Result';
1279 @result_namespace = $self->_result_namespace(
1284 my $table_class = join(q{::}, @result_namespace, $table_moniker);
1286 if ((my $upgrading_v = $self->_upgrading_from)
1287 || $self->_rewriting) {
1288 local $self->naming->{monikers} = $upgrading_v
1291 my @result_namespace = @result_namespace;
1292 if ($self->_upgrading_from_load_classes) {
1293 @result_namespace = ($schema_class);
1295 elsif (my $ns = $self->_downgrading_to_load_classes) {
1296 @result_namespace = $self->_result_namespace(
1301 elsif ($ns = $self->_rewriting_result_namespace) {
1302 @result_namespace = $self->_result_namespace(
1308 my $old_class = join(q{::}, @result_namespace,
1309 $self->_table2moniker($table));
1311 $self->_upgrading_classes->{$table_class} = $old_class
1312 unless $table_class eq $old_class;
1315 my $table_normalized = lc $table;
1316 $self->classes->{$table} = $table_class;
1317 $self->classes->{$table_normalized} = $table_class;
1318 $self->monikers->{$table} = $table_moniker;
1319 $self->monikers->{$table_normalized} = $table_moniker;
1321 $self->_use ($table_class, @{$self->additional_classes});
1322 $self->_inject($table_class, @{$self->left_base_classes});
1324 if (my @components = @{ $self->components }) {
1325 $self->_dbic_stmt($table_class, 'load_components', @components);
1328 $self->_dbic_stmt($table_class, 'load_resultset_components', @{$self->resultset_components})
1329 if @{$self->resultset_components};
1330 $self->_inject($table_class, @{$self->additional_base_classes});
1333 # Set up metadata (cols, pks, etc)
1334 sub _setup_src_meta {
1335 my ($self, $table) = @_;
1337 my $schema = $self->schema;
1338 my $schema_class = $self->schema_class;
1340 my $table_class = $self->classes->{$table};
1341 my $table_moniker = $self->monikers->{$table};
1343 my $table_name = $table;
1344 my $name_sep = $self->schema->storage->sql_maker->name_sep;
1346 if ($name_sep && $table_name =~ /\Q$name_sep\E/) {
1347 $table_name = \ $self->_quote_table_name($table_name);
1350 $self->_dbic_stmt($table_class,'table',$table_name);
1352 my $cols = $self->_table_columns($table);
1354 eval { $col_info = $self->_columns_info_for($table) };
1356 $self->_dbic_stmt($table_class,'add_columns',@$cols);
1359 if ($self->_is_case_sensitive) {
1360 for my $col (keys %$col_info) {
1361 $col_info->{$col}{accessor} = lc $col
1362 if $col ne lc($col);
1365 $col_info = { map { lc($_), $col_info->{$_} } keys %$col_info };
1368 my $fks = $self->_table_fk_info($table);
1370 for my $fkdef (@$fks) {
1371 for my $col (@{ $fkdef->{local_columns} }) {
1372 $col_info->{$col}{is_foreign_key} = 1;
1378 map { $_, ($col_info->{$_}||{}) } @$cols
1382 my %uniq_tag; # used to eliminate duplicate uniqs
1384 my $pks = $self->_table_pk_info($table) || [];
1385 @$pks ? $self->_dbic_stmt($table_class,'set_primary_key',@$pks)
1386 : carp("$table has no primary key");
1387 $uniq_tag{ join("\0", @$pks) }++ if @$pks; # pk is a uniq
1389 my $uniqs = $self->_table_uniq_info($table) || [];
1391 my ($name, $cols) = @$_;
1392 next if $uniq_tag{ join("\0", @$cols) }++; # skip duplicates
1393 $self->_dbic_stmt($table_class,'add_unique_constraint', $name, $cols);
1400 Returns a sorted list of loaded tables, using the original database table
1408 return keys %{$self->_tables};
1411 # Make a moniker from a table
1412 sub _default_table2moniker {
1413 no warnings 'uninitialized';
1414 my ($self, $table) = @_;
1416 if ($self->naming->{monikers} eq 'v4') {
1417 return join '', map ucfirst, split /[\W_]+/, lc $table;
1420 return join '', map ucfirst, split /[\W_]+/,
1421 Lingua::EN::Inflect::Number::to_S(lc $table);
1424 sub _table2moniker {
1425 my ( $self, $table ) = @_;
1429 if( ref $self->moniker_map eq 'HASH' ) {
1430 $moniker = $self->moniker_map->{$table};
1432 elsif( ref $self->moniker_map eq 'CODE' ) {
1433 $moniker = $self->moniker_map->($table);
1436 $moniker ||= $self->_default_table2moniker($table);
1441 sub _load_relationships {
1442 my ($self, $table) = @_;
1444 my $tbl_fk_info = $self->_table_fk_info($table);
1445 foreach my $fkdef (@$tbl_fk_info) {
1446 $fkdef->{remote_source} =
1447 $self->monikers->{delete $fkdef->{remote_table}};
1449 my $tbl_uniq_info = $self->_table_uniq_info($table);
1451 my $local_moniker = $self->monikers->{$table};
1452 my $rel_stmts = $self->_relbuilder->generate_code($local_moniker, $tbl_fk_info, $tbl_uniq_info);
1454 foreach my $src_class (sort keys %$rel_stmts) {
1455 my $src_stmts = $rel_stmts->{$src_class};
1456 foreach my $stmt (@$src_stmts) {
1457 $self->_dbic_stmt($src_class,$stmt->{method},@{$stmt->{args}});
1462 # Overload these in driver class:
1464 # Returns an arrayref of column names
1465 sub _table_columns { croak "ABSTRACT METHOD" }
1467 # Returns arrayref of pk col names
1468 sub _table_pk_info { croak "ABSTRACT METHOD" }
1470 # Returns an arrayref of uniqs [ [ foo => [ col1, col2 ] ], [ bar => [ ... ] ] ]
1471 sub _table_uniq_info { croak "ABSTRACT METHOD" }
1473 # Returns an arrayref of foreign key constraints, each
1474 # being a hashref with 3 keys:
1475 # local_columns (arrayref), remote_columns (arrayref), remote_table
1476 sub _table_fk_info { croak "ABSTRACT METHOD" }
1478 # Returns an array of lower case table names
1479 sub _tables_list { croak "ABSTRACT METHOD" }
1481 # Execute a constructive DBIC class method, with debug/dump_to_dir hooks.
1487 # generate the pod for this statement, storing it with $self->_pod
1488 $self->_make_pod( $class, $method, @_ ) if $self->generate_pod;
1490 my $args = dump(@_);
1491 $args = '(' . $args . ')' if @_ < 2;
1492 my $stmt = $method . $args . q{;};
1494 warn qq|$class\->$stmt\n| if $self->debug;
1495 $self->_raw_stmt($class, '__PACKAGE__->' . $stmt);
1499 # generates the accompanying pod for a DBIC class method statement,
1500 # storing it with $self->_pod
1506 if ( $method eq 'table' ) {
1508 my $pcm = $self->pod_comment_mode;
1509 my ($comment, $comment_overflows, $comment_in_name, $comment_in_desc);
1510 if ( $self->can('_table_comment') ) {
1511 $comment = $self->_table_comment($table);
1512 $comment_overflows = ($comment and length $comment > $self->pod_comment_spillover_length);
1513 $comment_in_name = ($pcm eq 'name' or ($pcm eq 'auto' and !$comment_overflows));
1514 $comment_in_desc = ($pcm eq 'description' or ($pcm eq 'auto' and $comment_overflows));
1516 $self->_pod( $class, "=head1 NAME" );
1517 my $table_descr = $class;
1518 $table_descr .= " - " . $comment if $comment and $comment_in_name;
1519 $self->{_class2table}{ $class } = $table;
1520 $self->_pod( $class, $table_descr );
1521 if ($comment and $comment_in_desc) {
1522 $self->_pod( $class, "=head1 DESCRIPTION" );
1523 $self->_pod( $class, $comment );
1525 $self->_pod_cut( $class );
1526 } elsif ( $method eq 'add_columns' ) {
1527 $self->_pod( $class, "=head1 ACCESSORS" );
1528 my $col_counter = 0;
1530 while( my ($name,$attrs) = splice @cols,0,2 ) {
1532 $self->_pod( $class, '=head2 ' . $name );
1533 $self->_pod( $class,
1535 my $s = $attrs->{$_};
1536 $s = !defined $s ? 'undef' :
1537 length($s) == 0 ? '(empty string)' :
1541 } sort keys %$attrs,
1544 if( $self->can('_column_comment')
1545 and my $comment = $self->_column_comment( $self->{_class2table}{$class}, $col_counter)
1547 $self->_pod( $class, $comment );
1550 $self->_pod_cut( $class );
1551 } elsif ( $method =~ /^(belongs_to|has_many|might_have)$/ ) {
1552 $self->_pod( $class, "=head1 RELATIONS" ) unless $self->{_relations_started} { $class } ;
1553 my ( $accessor, $rel_class ) = @_;
1554 $self->_pod( $class, "=head2 $accessor" );
1555 $self->_pod( $class, 'Type: ' . $method );
1556 $self->_pod( $class, "Related object: L<$rel_class>" );
1557 $self->_pod_cut( $class );
1558 $self->{_relations_started} { $class } = 1;
1562 # Stores a POD documentation
1564 my ($self, $class, $stmt) = @_;
1565 $self->_raw_stmt( $class, "\n" . $stmt );
1569 my ($self, $class ) = @_;
1570 $self->_raw_stmt( $class, "\n=cut\n" );
1573 # Store a raw source line for a class (for dumping purposes)
1575 my ($self, $class, $stmt) = @_;
1576 push(@{$self->{_dump_storage}->{$class}}, $stmt);
1579 # Like above, but separately for the externally loaded stuff
1581 my ($self, $class, $stmt) = @_;
1582 push(@{$self->{_ext_storage}->{$class}}, $stmt);
1585 sub _quote_table_name {
1586 my ($self, $table) = @_;
1588 my $qt = $self->schema->storage->sql_maker->quote_char;
1590 return $table unless $qt;
1593 return $qt->[0] . $table . $qt->[1];
1596 return $qt . $table . $qt;
1599 sub _is_case_sensitive { 0 }
1601 sub _custom_column_info {
1602 my ( $self, $info ) = @_;
1604 if( ref $self->custom_column_info eq 'CODE' ) {
1605 return $self->custom_column_info->($info);
1610 # remove the dump dir from @INC on destruction
1614 @INC = grep $_ ne $self->dump_directory, @INC;
1619 Returns a hashref of loaded table to moniker mappings. There will
1620 be two entries for each table, the original name and the "normalized"
1621 name, in the case that the two are different (such as databases
1622 that like uppercase table names, or preserve your original mixed-case
1623 definitions, or what-have-you).
1627 Returns a hashref of table to class mappings. In some cases it will
1628 contain multiple entries per table for the original and normalized table
1629 names, as above in L</monikers>.
1633 L<DBIx::Class::Schema::Loader>
1637 See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
1641 This library is free software; you can redistribute it and/or modify it under
1642 the same terms as Perl itself.