lib/DBIx/Class/Schema/Loader.pm

   1 package DBIx::Class::Schema::Loader;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class::Schema Class::Accessor::Grouped/;
   6 use MRO::Compat;
   7 use mro 'c3';
   8 use Carp::Clan qw/^DBIx::Class/;
   9 use Scalar::Util 'weaken';
  10 use Sub::Name 'subname';
  11 use namespace::clean;
  12
  13 # Always remember to do all digits for the version even if they're 0
  14 # i.e. first release of 0.XX *must* be 0.XX000. This avoids fBSD ports
  15 # brain damage and presumably various other packaging systems too
  16 our $VERSION = '0.07010';
  17
  18 __PACKAGE__->mk_group_accessors('inherited', qw/
  19                                 _loader_args
  20                                 dump_to_dir
  21                                 _loader_invoked
  22                                 _loader
  23                                 loader_class
  24                                 naming
  25                                 use_namespaces
  26 /);
  27 __PACKAGE__->_loader_args({});
  28
  29 =head1 NAME
  30
  31 DBIx::Class::Schema::Loader - Create a DBIx::Class::Schema based on a database
  32
  33 =head1 SYNOPSIS
  34
  35   ### use this module to generate a set of class files
  36
  37   # in a script
  38   use DBIx::Class::Schema::Loader qw/ make_schema_at /;
  39   make_schema_at(
  40       'My::Schema',
  41       { debug => 1,
  42         dump_directory => './lib',
  43       },
  44       [ 'dbi:Pg:dbname="foo"', 'myuser', 'mypassword',
  45          { loader_class => 'MyLoader' } # optionally
  46       ],
  47   );
  48
  49   # from the command line or a shell script with dbicdump (distributed
  50   # with this module).  Do `perldoc dbicdump` for usage.
  51   dbicdump -o dump_directory=./lib \
  52            -o components='["InflateColumn::DateTime"]' \
  53            -o debug=1 \
  54            My::Schema \
  55            'dbi:Pg:dbname=foo' \
  56            myuser \
  57            mypassword
  58
  59   ### or generate and load classes at runtime
  60   # note: this technique is not recommended
  61   # for use in production code
  62
  63   package My::Schema;
  64   use base qw/DBIx::Class::Schema::Loader/;
  65
  66   __PACKAGE__->loader_options(
  67       constraint              => '^foo.*',
  68       # debug                 => 1,
  69   );
  70
  71   #### in application code elsewhere:
  72
  73   use My::Schema;
  74
  75   my $schema1 = My::Schema->connect( $dsn, $user, $password, $attrs);
  76   # -or-
  77   my $schema1 = "My::Schema"; $schema1->connection(as above);
  78
  79 =head1 DESCRIPTION
  80
  81 DBIx::Class::Schema::Loader automates the definition of a
  82 L<DBIx::Class::Schema> by scanning database table definitions and setting up
  83 the columns, primary keys, unique constraints and relationships.
  84
  85 See L<dbicdump> for the C<dbicdump> utility.
  86
  87 DBIx::Class::Schema::Loader currently supports only the DBI storage type. It
  88 has explicit support for L<DBD::Pg>, L<DBD::mysql>, L<DBD::DB2>,
  89 L<DBD::Firebird>, L<DBD::InterBase>, L<DBD::Informix>, L<DBD::SQLAnywhere>,
  90 L<DBD::SQLite>, L<DBD::Sybase> (for Sybase ASE and MSSSQL), L<DBD::ODBC> (for
  91 MSSQL, MSAccess, Firebird and SQL Anywhere) L<DBD::ADO> (for MSSQL and
  92 MSAccess) and L<DBD::Oracle>.  Other DBI drivers may function to a greater or
  93 lesser degree with this loader, depending on how much of the DBI spec they
  94 implement, and how standard their implementation is.
  95
  96 Patches to make other DBDs work correctly welcome.
  97
  98 See L<DBIx::Class::Schema::Loader::DBI::Writing> for notes on writing
  99 your own vendor-specific subclass for an unsupported DBD driver.
 100
 101 This module requires L<DBIx::Class> 0.08127 or later, and obsoletes the older
 102 L<DBIx::Class::Loader>.
 103
 104 See L<DBIx::Class::Schema::Loader::Base> for available options.
 105
 106 =head1 METHODS
 107
 108 =head2 loader
 109
 110 The loader object, as class data on your Schema. For methods available see
 111 L<DBIx::Class::Schema::Loader::Base> and L<DBIx::Class::Schema::Loader::DBI>.
 112
 113 =cut
 114
 115 sub loader {
 116     my $self = shift;
 117     $self->_loader(@_);
 118 }
 119
 120 =head2 loader_class
 121
 122 =over 4
 123
 124 =item Argument: $loader_class
 125
 126 =back
 127
 128 Set the loader class to be instantiated when L</connection> is called.
 129 If the classname starts with "::", "DBIx::Class::Schema::Loader" is
 130 prepended. Defaults to L<DBIx::Class::Schema/storage_type> (which must
 131 start with "::" when using L<DBIx::Class::Schema::Loader>).
 132
 133 This is mostly useful for subclassing existing loaders or in conjunction
 134 with L</dump_to_dir>.
 135
 136 =head2 loader_options
 137
 138 =over 4
 139
 140 =item Argument: \%loader_options
 141
 142 =back
 143
 144 Example in Synopsis above demonstrates a few common arguments.  For
 145 detailed information on all of the arguments, most of which are
 146 only useful in fairly complex scenarios, see the
 147 L<DBIx::Class::Schema::Loader::Base> documentation.
 148
 149 If you intend to use C<loader_options>, you must call
 150 C<loader_options> before any connection is made, or embed the
 151 C<loader_options> in the connection information itself as shown
 152 below.  Setting C<loader_options> after the connection has
 153 already been made is useless.
 154
 155 =cut
 156
 157 sub loader_options {
 158     my $self = shift;
 159
 160     my %args = (ref $_[0] eq 'HASH') ? %{$_[0]} : @_;
 161     $self->_loader_args(\%args);
 162
 163     $self;
 164 }
 165
 166 sub _invoke_loader {
 167     my $self = shift;
 168     my $class = ref $self || $self;
 169
 170     my $args = $self->_loader_args;
 171
 172     # set up the schema/schema_class arguments
 173     $args->{schema} = $self;
 174     $args->{schema_class} = $class;
 175     weaken($args->{schema}) if ref $self;
 176     $args->{dump_directory} ||= $self->dump_to_dir;
 177     $args->{naming} = $self->naming if $self->naming;
 178     $args->{use_namespaces} = $self->use_namespaces if defined $self->use_namespaces;
 179
 180     # XXX this only works for relative storage_type, like ::DBI ...
 181     my $loader_class = $self->loader_class;
 182     if ($loader_class) {
 183         $loader_class = "DBIx::Class::Schema::Loader${loader_class}" if $loader_class =~ /^::/;
 184         $args->{loader_class} = $loader_class;
 185     };
 186
 187     my $impl = $loader_class || "DBIx::Class::Schema::Loader" . $self->storage_type;
 188     eval { $self->ensure_class_loaded($impl) };
 189     croak qq/Could not load loader_class "$impl": "$@"/ if $@;
 190
 191     $self->loader($impl->new(%$args));
 192     $self->loader->load;
 193     $self->_loader_invoked(1);
 194
 195     $self;
 196 }
 197
 198 =head2 connection
 199
 200 =over 4
 201
 202 =item Arguments: @args
 203
 204 =item Return Value: $new_schema
 205
 206 =back
 207
 208 See L<DBIx::Class::Schema/connection> for basic usage.
 209
 210 If the final argument is a hashref, and it contains the keys C<loader_options>
 211 or C<loader_class>, those keys will be deleted, and their values value will be
 212 used for the loader options or class, respectively, just as if set via the
 213 L</loader_options> or L</loader_class> methods above.
 214
 215 The actual auto-loading operation (the heart of this module) will be invoked
 216 as soon as the connection information is defined.
 217
 218 =cut
 219
 220 sub connection {
 221     my $self  = shift;
 222     my $class = ref $self || $self;
 223
 224     if($_[-1] && ref $_[-1] eq 'HASH') {
 225         for my $option (qw/loader_class loader_options/) {
 226             if(my $value = delete $_[-1]->{$option}) {
 227                 $self->$option($value);
 228             }
 229         }
 230         pop @_ if !keys %{$_[-1]};
 231     }
 232
 233     # Make sure we inherit from schema_base_class and load schema_components
 234     # before connecting.
 235     require DBIx::Class::Schema::Loader::Base;
 236     my $temp_loader = DBIx::Class::Schema::Loader::Base->new(
 237         %{ $self->_loader_args }
 238     );
 239
 240     if ($temp_loader->schema_base_class || $temp_loader->schema_components) {
 241         my @components = @{ $temp_loader->schema_components }
 242             if $temp_loader->schema_components;
 243
 244         push @components, ('+'.$temp_loader->schema_base_class)
 245             if $temp_loader->schema_base_class;
 246
 247         $class->load_components(@components);
 248
 249         # This hack is necessary because we changed @ISA of $self through
 250         # ->load_components and we are now in a different place in the mro.
 251         no warnings 'redefine';
 252
 253         local *connection = subname __PACKAGE__.'::connection' => sub {
 254             my $self = shift;
 255             $self->next::method(@_);
 256         };
 257
 258         my @linear_isa = @{ mro::get_linear_isa($class) };
 259
 260         my $next_method;
 261
 262         foreach my $i (1..$#linear_isa) {
 263             no strict 'refs';
 264             $next_method = *{$linear_isa[$i].'::connection'}{CODE};
 265             last if $next_method;
 266         }
 267
 268         $self = $self->$next_method(@_);
 269     }
 270     else {
 271         $self = $self->next::method(@_);
 272     }
 273
 274     if(!$class->_loader_invoked) {
 275         $self->_invoke_loader
 276     }
 277
 278     return $self;
 279 }
 280
 281 =head2 clone
 282
 283 See L<DBIx::Class::Schema/clone>.
 284
 285 =cut
 286
 287 sub clone {
 288     my $self = shift;
 289
 290     my $clone = $self->next::method(@_);
 291
 292     if($clone->_loader_args) {
 293         $clone->_loader_args->{schema} = $clone;
 294         weaken($clone->_loader_args->{schema});
 295     }
 296
 297     $clone;
 298 }
 299
 300 =head2 dump_to_dir
 301
 302 =over 4
 303
 304 =item Argument: $directory
 305
 306 =back
 307
 308 Calling this as a class method on either L<DBIx::Class::Schema::Loader>
 309 or any derived schema class will cause all schemas to dump
 310 manual versions of themselves to the named directory when they are
 311 loaded.  In order to be effective, this must be set before defining a
 312 connection on this schema class or any derived object (as the loading
 313 happens as soon as both a connection and loader_options are set, and
 314 only once per class).
 315
 316 See L<DBIx::Class::Schema::Loader::Base/dump_directory> for more
 317 details on the dumping mechanism.
 318
 319 This can also be set at module import time via the import option
 320 C<dump_to_dir:/foo/bar> to L<DBIx::Class::Schema::Loader>, where
 321 C</foo/bar> is the target directory.
 322
 323 Examples:
 324
 325     # My::Schema isa DBIx::Class::Schema::Loader, and has connection info
 326     #   hardcoded in the class itself:
 327     perl -MDBIx::Class::Schema::Loader=dump_to_dir:/foo/bar -MMy::Schema -e1
 328
 329     # Same, but no hard-coded connection, so we must provide one:
 330     perl -MDBIx::Class::Schema::Loader=dump_to_dir:/foo/bar -MMy::Schema -e 'My::Schema->connection("dbi:Pg:dbname=foo", ...)'
 331
 332     # Or as a class method, as long as you get it done *before* defining a
 333     #  connection on this schema class or any derived object:
 334     use My::Schema;
 335     My::Schema->dump_to_dir('/foo/bar');
 336     My::Schema->connection(........);
 337
 338     # Or as a class method on the DBIx::Class::Schema::Loader itself, which affects all
 339     #   derived schemas
 340     use My::Schema;
 341     use My::OtherSchema;
 342     DBIx::Class::Schema::Loader->dump_to_dir('/foo/bar');
 343     My::Schema->connection(.......);
 344     My::OtherSchema->connection(.......);
 345
 346     # Another alternative to the above:
 347     use DBIx::Class::Schema::Loader qw| dump_to_dir:/foo/bar |;
 348     use My::Schema;
 349     use My::OtherSchema;
 350     My::Schema->connection(.......);
 351     My::OtherSchema->connection(.......);
 352
 353 =cut
 354
 355 sub import {
 356     my $self = shift;
 357
 358     return if !@_;
 359
 360     my $cpkg = (caller)[0];
 361
 362     foreach my $opt (@_) {
 363         if($opt =~ m{^dump_to_dir:(.*)$}) {
 364             $self->dump_to_dir($1)
 365         }
 366         elsif($opt eq 'make_schema_at') {
 367             no strict 'refs';
 368             *{"${cpkg}::make_schema_at"} = \&make_schema_at;
 369         }
 370         elsif($opt eq 'naming') {
 371             no strict 'refs';
 372             *{"${cpkg}::naming"} = sub { $self->naming(@_) };
 373         }
 374         elsif($opt eq 'use_namespaces') {
 375             no strict 'refs';
 376             *{"${cpkg}::use_namespaces"} = sub { $self->use_namespaces(@_) };
 377         }
 378     }
 379 }
 380
 381 =head2 make_schema_at
 382
 383 =over 4
 384
 385 =item Arguments: $schema_class_name, \%loader_options, \@connect_info
 386
 387 =item Return Value: $schema_class_name
 388
 389 =back
 390
 391 This function creates a DBIx::Class schema from an existing RDBMS
 392 schema.  With the C<dump_directory> option, generates a set of
 393 DBIx::Class classes from an existing database schema read from the
 394 given dsn.  Without a C<dump_directory>, creates schema classes in
 395 memory at runtime without generating on-disk class files.
 396
 397 For a complete list of supported loader_options, see
 398 L<DBIx::Class::Schema::Loader::Base>
 399
 400 The last hashref in the C<\@connect_info> can specify the L</loader_class>.
 401
 402 This function can be imported in the usual way, as illustrated in
 403 these Examples:
 404
 405     # Simple example, creates as a new class 'New::Schema::Name' in
 406     #  memory in the running perl interpreter.
 407     use DBIx::Class::Schema::Loader qw/ make_schema_at /;
 408     make_schema_at(
 409         'New::Schema::Name',
 410         { debug => 1 },
 411         [ 'dbi:Pg:dbname="foo"','postgres','',
 412           { loader_class => 'MyLoader' } # optionally
 413         ],
 414     );
 415
 416     # Inside a script, specifying a dump directory in which to write
 417     # class files
 418     use DBIx::Class::Schema::Loader qw/ make_schema_at /;
 419     make_schema_at(
 420         'New::Schema::Name',
 421         { debug => 1, dump_directory => './lib' },
 422         [ 'dbi:Pg:dbname="foo"','postgres','',
 423           { loader_class => 'MyLoader' } # optionally
 424         ],
 425     );
 426
 427 The last hashref in the C<\@connect_info> is checked for loader arguments such
 428 as C<loader_options> and C<loader_class>, see L</connection> for more details.
 429
 430 =cut
 431
 432 sub make_schema_at {
 433     my ($target, $opts, $connect_info) = @_;
 434
 435     {
 436         no strict 'refs';
 437         @{$target . '::ISA'} = qw/DBIx::Class::Schema::Loader/;
 438     }
 439
 440     eval { $target->_loader_invoked(0) };
 441
 442     $target->loader_options($opts);
 443     $target->connection(@$connect_info);
 444 }
 445
 446 =head2 rescan
 447
 448 =over 4
 449
 450 =item Return Value: @new_monikers
 451
 452 =back
 453
 454 Re-scans the database for newly added tables since the initial
 455 load, and adds them to the schema at runtime, including relationships,
 456 etc.  Does not process drops or changes.
 457
 458 Returns a list of the new monikers added.
 459
 460 =cut
 461
 462 sub rescan { my $self = shift; $self->loader->rescan($self) }
 463
 464 =head2 naming
 465
 466 =over 4
 467
 468 =item Arguments: \%opts | $ver
 469
 470 =back
 471
 472 Controls the naming options for backward compatibility, see
 473 L<DBIx::Class::Schema::Loader::Base/naming> for details.
 474
 475 To upgrade a dynamic schema, use:
 476
 477     __PACKAGE__->naming('current');
 478
 479 Can be imported into your dump script and called as a function as well:
 480
 481     naming('v4');
 482
 483 =head2 use_namespaces
 484
 485 =over 4
 486
 487 =item Arguments: 1|0
 488
 489 =back
 490
 491 Controls the use_namespaces options for backward compatibility, see
 492 L<DBIx::Class::Schema::Loader::Base/use_namespaces> for details.
 493
 494 To upgrade a dynamic schema, use:
 495
 496     __PACKAGE__->use_namespaces(1);
 497
 498 Can be imported into your dump script and called as a function as well:
 499
 500     use_namespaces(1);
 501
 502 =head1 KNOWN ISSUES
 503
 504 =head2 Multiple Database Schemas
 505
 506 See L<DBIx::Class::Schema::Loader::Base/db_schema>.
 507
 508 =head1 ACKNOWLEDGEMENTS
 509
 510 Matt S Trout, all of the #dbix-class folks, and everyone who's ever sent
 511 in a bug report or suggestion.
 512
 513 Based on L<DBIx::Class::Loader> by Sebastian Riedel
 514
 515 Based upon the work of IKEBE Tomohiro
 516
 517 =head1 AUTHOR
 518
 519 blblack: Brandon Black <blblack@gmail.com>
 520
 521 =head1 CONTRIBUTORS
 522
 523 ilmari: Dagfinn Ilmari MannsE<aring>ker <ilmari@ilmari.org>
 524
 525 arcanez: Justin Hunter <justin.d.hunter@gmail.com>
 526
 527 ash: Ash Berlin <ash@cpan.org>
 528
 529 btilly: Ben Tilly <btilly@gmail.com>
 530
 531 Caelum: Rafael Kitover <rkitover@cpan.org>
 532
 533 TSUNODA Kazuya <drk@drk7.jp>
 534
 535 rbo: Robert Bohne <rbo@cpan.org>
 536
 537 ribasushi: Peter Rabbitson <ribasushi@cpan.org>
 538
 539 gugu: Andrey Kostenko <a.kostenko@rambler-co.ru>
 540
 541 jhannah: Jay Hannah <jay@jays.net>
 542
 543 rbuels: Robert Buels <rmb32@cornell.edu>
 544
 545 timbunce: Tim Bunce <timb@cpan.org>
 546
 547 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
 548
 549 mstratman: Mark A. Stratman <stratman@gmail.com>
 550
 551 kane: Jos Boumans <kane@cpan.org>
 552
 553 waawaamilk: Nigel McNie <nigel@mcnie.name>
 554
 555 acmoore: Andrew Moore <amoore@cpan.org>
 556
 557 bphillips: Brian Phillips <bphillips@cpan.org>
 558
 559 schwern: Michael G. Schwern <mschwern@cpan.org>
 560
 561 hobbs: Andrew Rodland <arodland@cpan.org>
 562
 563 domm: Thomas Klausner <domm@plix.at>
 564
 565 spb: Stephen Bennett <spb@exherbo.org>
 566
 567 Matias E. Fernandez <mfernandez@pisco.ch>
 568
 569 Al Newkirk <awncorp@cpan.org>
 570
 571 ... and lots of other folks. If we forgot you, please write the current
 572 maintainer or RT.
 573
 574 =head1 COPYRIGHT & LICENSE
 575
 576 Copyright (c) 2006 - 2009 by the aforementioned
 577 L<DBIx::Class::Schema::Loader/AUTHOR> and
 578 L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
 579
 580 This library is free software; you can redistribute it and/or modify it under
 581 the same terms as Perl itself.
 582
 583 =head1 SEE ALSO
 584
 585 L<DBIx::Class>, L<DBIx::Class::Manual::ExampleSchema>
 586
 587 =cut
 588
 589 1;
 590 # vim:et sts=4 sw=4 tw=0: