lib/DBIx/Class/Schema/Loader.pm

   1 package DBIx::Class::Schema::Loader;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class::Schema Class::Accessor::Grouped/;
   6 use MRO::Compat;
   7 use mro 'c3';
   8 use Carp::Clan qw/^DBIx::Class/;
   9 use Scalar::Util 'weaken';
  10 use Sub::Name 'subname';
  11 use namespace::clean;
  12
  13 # Always remember to do all digits for the version even if they're 0
  14 # i.e. first release of 0.XX *must* be 0.XX000. This avoids fBSD ports
  15 # brain damage and presumably various other packaging systems too
  16 our $VERSION = '0.07011';
  17
  18 __PACKAGE__->mk_group_accessors('inherited', qw/
  19                                 _loader_args
  20                                 dump_to_dir
  21                                 _loader_invoked
  22                                 _loader
  23                                 loader_class
  24                                 naming
  25                                 use_namespaces
  26 /);
  27 __PACKAGE__->_loader_args({});
  28
  29 =head1 NAME
  30
  31 DBIx::Class::Schema::Loader - Create a DBIx::Class::Schema based on a database
  32
  33 =head1 SYNOPSIS
  34
  35   ### use this module to generate a set of class files
  36
  37   # in a script
  38   use DBIx::Class::Schema::Loader qw/ make_schema_at /;
  39   make_schema_at(
  40       'My::Schema',
  41       { debug => 1,
  42         dump_directory => './lib',
  43       },
  44       [ 'dbi:Pg:dbname="foo"', 'myuser', 'mypassword',
  45          { loader_class => 'MyLoader' } # optionally
  46       ],
  47   );
  48
  49   # from the command line or a shell script with dbicdump (distributed
  50   # with this module).  Do `perldoc dbicdump` for usage.
  51   dbicdump -o dump_directory=./lib \
  52            -o components='["InflateColumn::DateTime"]' \
  53            -o debug=1 \
  54            My::Schema \
  55            'dbi:Pg:dbname=foo' \
  56            myuser \
  57            mypassword
  58
  59   ### or generate and load classes at runtime
  60   # note: this technique is not recommended
  61   # for use in production code
  62
  63   package My::Schema;
  64   use base qw/DBIx::Class::Schema::Loader/;
  65
  66   __PACKAGE__->loader_options(
  67       constraint              => '^foo.*',
  68       # debug                 => 1,
  69   );
  70
  71   #### in application code elsewhere:
  72
  73   use My::Schema;
  74
  75   my $schema1 = My::Schema->connect( $dsn, $user, $password, $attrs);
  76   # -or-
  77   my $schema1 = "My::Schema"; $schema1->connection(as above);
  78
  79 =head1 DESCRIPTION
  80
  81 DBIx::Class::Schema::Loader automates the definition of a
  82 L<DBIx::Class::Schema> by scanning database table definitions and setting up
  83 the columns, primary keys, unique constraints and relationships.
  84
  85 See L<dbicdump> for the C<dbicdump> utility.
  86
  87 DBIx::Class::Schema::Loader currently supports only the DBI storage type. It
  88 has explicit support for L<DBD::Pg>, L<DBD::mysql>, L<DBD::DB2>,
  89 L<DBD::Firebird>, L<DBD::InterBase>, L<DBD::Informix>, L<DBD::SQLAnywhere>,
  90 L<DBD::SQLite>, L<DBD::Sybase> (for Sybase ASE and MSSSQL), L<DBD::ODBC> (for
  91 MSSQL, MSAccess, Firebird and SQL Anywhere) L<DBD::ADO> (for MSSQL and
  92 MSAccess) and L<DBD::Oracle>.  Other DBI drivers may function to a greater or
  93 lesser degree with this loader, depending on how much of the DBI spec they
  94 implement, and how standard their implementation is.
  95
  96 Patches to make other DBDs work correctly welcome.
  97
  98 See L<DBIx::Class::Schema::Loader::DBI::Writing> for notes on writing
  99 your own vendor-specific subclass for an unsupported DBD driver.
 100
 101 This module requires L<DBIx::Class> 0.08127 or later, and obsoletes the older
 102 L<DBIx::Class::Loader>.
 103
 104 See L<DBIx::Class::Schema::Loader::Base> for available options.
 105
 106 =head1 METHODS
 107
 108 =head2 loader
 109
 110 The loader object, as class data on your Schema. For methods available see
 111 L<DBIx::Class::Schema::Loader::Base> and L<DBIx::Class::Schema::Loader::DBI>.
 112
 113 =cut
 114
 115 sub loader {
 116     my $self = shift;
 117     $self->_loader(@_);
 118 }
 119
 120 =head2 loader_class
 121
 122 =over 4
 123
 124 =item Argument: $loader_class
 125
 126 =back
 127
 128 Set the loader class to be instantiated when L</connection> is called.
 129 If the classname starts with "::", "DBIx::Class::Schema::Loader" is
 130 prepended. Defaults to L<DBIx::Class::Schema/storage_type> (which must
 131 start with "::" when using L<DBIx::Class::Schema::Loader>).
 132
 133 This is mostly useful for subclassing existing loaders or in conjunction
 134 with L</dump_to_dir>.
 135
 136 =head2 loader_options
 137
 138 =over 4
 139
 140 =item Argument: \%loader_options
 141
 142 =back
 143
 144 Example in Synopsis above demonstrates a few common arguments.  For
 145 detailed information on all of the arguments, most of which are
 146 only useful in fairly complex scenarios, see the
 147 L<DBIx::Class::Schema::Loader::Base> documentation.
 148
 149 If you intend to use C<loader_options>, you must call
 150 C<loader_options> before any connection is made, or embed the
 151 C<loader_options> in the connection information itself as shown
 152 below.  Setting C<loader_options> after the connection has
 153 already been made is useless.
 154
 155 =cut
 156
 157 sub loader_options {
 158     my $self = shift;
 159
 160     my %args = (ref $_[0] eq 'HASH') ? %{$_[0]} : @_;
 161     $self->_loader_args(\%args);
 162
 163     $self;
 164 }
 165
 166 sub _invoke_loader {
 167     my $self = shift;
 168     my $class = ref $self || $self;
 169
 170     my $args = $self->_loader_args;
 171
 172     # set up the schema/schema_class arguments
 173     $args->{schema} = $self;
 174     $args->{schema_class} = $class;
 175     weaken($args->{schema}) if ref $self;
 176     $args->{dump_directory} ||= $self->dump_to_dir;
 177     $args->{naming} = $self->naming if $self->naming;
 178     $args->{use_namespaces} = $self->use_namespaces if defined $self->use_namespaces;
 179
 180     # XXX this only works for relative storage_type, like ::DBI ...
 181     my $loader_class = $self->loader_class;
 182     if ($loader_class) {
 183         $loader_class = "DBIx::Class::Schema::Loader${loader_class}" if $loader_class =~ /^::/;
 184         $args->{loader_class} = $loader_class;
 185     };
 186
 187     my $impl = $loader_class || "DBIx::Class::Schema::Loader" . $self->storage_type;
 188     eval { $self->ensure_class_loaded($impl) };
 189     croak qq/Could not load loader_class "$impl": "$@"/ if $@;
 190
 191     $self->loader($impl->new(%$args));
 192     $self->loader->load;
 193     $self->_loader_invoked(1);
 194
 195     $self;
 196 }
 197
 198 =head2 connection
 199
 200 =over 4
 201
 202 =item Arguments: @args
 203
 204 =item Return Value: $new_schema
 205
 206 =back
 207
 208 See L<DBIx::Class::Schema/connection> for basic usage.
 209
 210 If the final argument is a hashref, and it contains the keys C<loader_options>
 211 or C<loader_class>, those keys will be deleted, and their values value will be
 212 used for the loader options or class, respectively, just as if set via the
 213 L</loader_options> or L</loader_class> methods above.
 214
 215 The actual auto-loading operation (the heart of this module) will be invoked
 216 as soon as the connection information is defined.
 217
 218 =cut
 219
 220 sub connection {
 221     my $self  = shift;
 222     my $class = ref $self || $self;
 223
 224     if($_[-1] && ref $_[-1] eq 'HASH') {
 225         for my $option (qw/loader_class loader_options/) {
 226             if(my $value = delete $_[-1]->{$option}) {
 227                 $self->$option($value);
 228             }
 229         }
 230         pop @_ if !keys %{$_[-1]};
 231     }
 232
 233     # Make sure we inherit from schema_base_class and load schema_components
 234     # before connecting.
 235     require DBIx::Class::Schema::Loader::Base;
 236     my $temp_loader = DBIx::Class::Schema::Loader::Base->new(
 237         %{ $self->_loader_args },
 238         schema => $self,
 239         naming => 'current',
 240         use_namespaces => 1,
 241     );
 242
 243     if ($temp_loader->schema_base_class || $temp_loader->schema_components) {
 244         my @components = @{ $temp_loader->schema_components }
 245             if $temp_loader->schema_components;
 246
 247         push @components, ('+'.$temp_loader->schema_base_class)
 248             if $temp_loader->schema_base_class;
 249
 250         $class->load_components(@components);
 251
 252         # This hack is necessary because we changed @ISA of $self through
 253         # ->load_components and we are now in a different place in the mro.
 254         no warnings 'redefine';
 255
 256         local *connection = subname __PACKAGE__.'::connection' => sub {
 257             my $self = shift;
 258             $self->next::method(@_);
 259         };
 260
 261         my @linear_isa = @{ mro::get_linear_isa($class) };
 262
 263         my $next_method;
 264
 265         foreach my $i (1..$#linear_isa) {
 266             no strict 'refs';
 267             $next_method = *{$linear_isa[$i].'::connection'}{CODE};
 268             last if $next_method;
 269         }
 270
 271         $self = $self->$next_method(@_);
 272     }
 273     else {
 274         $self = $self->next::method(@_);
 275     }
 276
 277     if(!$class->_loader_invoked) {
 278         $self->_invoke_loader
 279     }
 280
 281     return $self;
 282 }
 283
 284 =head2 clone
 285
 286 See L<DBIx::Class::Schema/clone>.
 287
 288 =cut
 289
 290 sub clone {
 291     my $self = shift;
 292
 293     my $clone = $self->next::method(@_);
 294
 295     if($clone->_loader_args) {
 296         $clone->_loader_args->{schema} = $clone;
 297         weaken($clone->_loader_args->{schema});
 298     }
 299
 300     $clone;
 301 }
 302
 303 =head2 dump_to_dir
 304
 305 =over 4
 306
 307 =item Argument: $directory
 308
 309 =back
 310
 311 Calling this as a class method on either L<DBIx::Class::Schema::Loader>
 312 or any derived schema class will cause all schemas to dump
 313 manual versions of themselves to the named directory when they are
 314 loaded.  In order to be effective, this must be set before defining a
 315 connection on this schema class or any derived object (as the loading
 316 happens as soon as both a connection and loader_options are set, and
 317 only once per class).
 318
 319 See L<DBIx::Class::Schema::Loader::Base/dump_directory> for more
 320 details on the dumping mechanism.
 321
 322 This can also be set at module import time via the import option
 323 C<dump_to_dir:/foo/bar> to L<DBIx::Class::Schema::Loader>, where
 324 C</foo/bar> is the target directory.
 325
 326 Examples:
 327
 328     # My::Schema isa DBIx::Class::Schema::Loader, and has connection info
 329     #   hardcoded in the class itself:
 330     perl -MDBIx::Class::Schema::Loader=dump_to_dir:/foo/bar -MMy::Schema -e1
 331
 332     # Same, but no hard-coded connection, so we must provide one:
 333     perl -MDBIx::Class::Schema::Loader=dump_to_dir:/foo/bar -MMy::Schema -e 'My::Schema->connection("dbi:Pg:dbname=foo", ...)'
 334
 335     # Or as a class method, as long as you get it done *before* defining a
 336     #  connection on this schema class or any derived object:
 337     use My::Schema;
 338     My::Schema->dump_to_dir('/foo/bar');
 339     My::Schema->connection(........);
 340
 341     # Or as a class method on the DBIx::Class::Schema::Loader itself, which affects all
 342     #   derived schemas
 343     use My::Schema;
 344     use My::OtherSchema;
 345     DBIx::Class::Schema::Loader->dump_to_dir('/foo/bar');
 346     My::Schema->connection(.......);
 347     My::OtherSchema->connection(.......);
 348
 349     # Another alternative to the above:
 350     use DBIx::Class::Schema::Loader qw| dump_to_dir:/foo/bar |;
 351     use My::Schema;
 352     use My::OtherSchema;
 353     My::Schema->connection(.......);
 354     My::OtherSchema->connection(.......);
 355
 356 =cut
 357
 358 sub import {
 359     my $self = shift;
 360
 361     return if !@_;
 362
 363     my $cpkg = (caller)[0];
 364
 365     foreach my $opt (@_) {
 366         if($opt =~ m{^dump_to_dir:(.*)$}) {
 367             $self->dump_to_dir($1)
 368         }
 369         elsif($opt eq 'make_schema_at') {
 370             no strict 'refs';
 371             *{"${cpkg}::make_schema_at"} = \&make_schema_at;
 372         }
 373         elsif($opt eq 'naming') {
 374             no strict 'refs';
 375             *{"${cpkg}::naming"} = sub { $self->naming(@_) };
 376         }
 377         elsif($opt eq 'use_namespaces') {
 378             no strict 'refs';
 379             *{"${cpkg}::use_namespaces"} = sub { $self->use_namespaces(@_) };
 380         }
 381     }
 382 }
 383
 384 =head2 make_schema_at
 385
 386 =over 4
 387
 388 =item Arguments: $schema_class_name, \%loader_options, \@connect_info
 389
 390 =item Return Value: $schema_class_name
 391
 392 =back
 393
 394 This function creates a DBIx::Class schema from an existing RDBMS
 395 schema.  With the C<dump_directory> option, generates a set of
 396 DBIx::Class classes from an existing database schema read from the
 397 given dsn.  Without a C<dump_directory>, creates schema classes in
 398 memory at runtime without generating on-disk class files.
 399
 400 For a complete list of supported loader_options, see
 401 L<DBIx::Class::Schema::Loader::Base>
 402
 403 The last hashref in the C<\@connect_info> can specify the L</loader_class>.
 404
 405 This function can be imported in the usual way, as illustrated in
 406 these Examples:
 407
 408     # Simple example, creates as a new class 'New::Schema::Name' in
 409     #  memory in the running perl interpreter.
 410     use DBIx::Class::Schema::Loader qw/ make_schema_at /;
 411     make_schema_at(
 412         'New::Schema::Name',
 413         { debug => 1 },
 414         [ 'dbi:Pg:dbname="foo"','postgres','',
 415           { loader_class => 'MyLoader' } # optionally
 416         ],
 417     );
 418
 419     # Inside a script, specifying a dump directory in which to write
 420     # class files
 421     use DBIx::Class::Schema::Loader qw/ make_schema_at /;
 422     make_schema_at(
 423         'New::Schema::Name',
 424         { debug => 1, dump_directory => './lib' },
 425         [ 'dbi:Pg:dbname="foo"','postgres','',
 426           { loader_class => 'MyLoader' } # optionally
 427         ],
 428     );
 429
 430 The last hashref in the C<\@connect_info> is checked for loader arguments such
 431 as C<loader_options> and C<loader_class>, see L</connection> for more details.
 432
 433 =cut
 434
 435 sub make_schema_at {
 436     my ($target, $opts, $connect_info) = @_;
 437
 438     {
 439         no strict 'refs';
 440         @{$target . '::ISA'} = qw/DBIx::Class::Schema::Loader/;
 441     }
 442
 443     eval { $target->_loader_invoked(0) };
 444
 445     $target->loader_options($opts);
 446     $target->connection(@$connect_info);
 447 }
 448
 449 =head2 rescan
 450
 451 =over 4
 452
 453 =item Return Value: @new_monikers
 454
 455 =back
 456
 457 Re-scans the database for newly added tables since the initial
 458 load, and adds them to the schema at runtime, including relationships,
 459 etc.  Does not process drops or changes.
 460
 461 Returns a list of the new monikers added.
 462
 463 =cut
 464
 465 sub rescan { my $self = shift; $self->loader->rescan($self) }
 466
 467 =head2 naming
 468
 469 =over 4
 470
 471 =item Arguments: \%opts | $ver
 472
 473 =back
 474
 475 Controls the naming options for backward compatibility, see
 476 L<DBIx::Class::Schema::Loader::Base/naming> for details.
 477
 478 To upgrade a dynamic schema, use:
 479
 480     __PACKAGE__->naming('current');
 481
 482 Can be imported into your dump script and called as a function as well:
 483
 484     naming('v4');
 485
 486 =head2 use_namespaces
 487
 488 =over 4
 489
 490 =item Arguments: 1|0
 491
 492 =back
 493
 494 Controls the use_namespaces options for backward compatibility, see
 495 L<DBIx::Class::Schema::Loader::Base/use_namespaces> for details.
 496
 497 To upgrade a dynamic schema, use:
 498
 499     __PACKAGE__->use_namespaces(1);
 500
 501 Can be imported into your dump script and called as a function as well:
 502
 503     use_namespaces(1);
 504
 505 =head1 KNOWN ISSUES
 506
 507 =head2 Multiple Database Schemas
 508
 509 See L<DBIx::Class::Schema::Loader::Base/db_schema>.
 510
 511 =head1 ACKNOWLEDGEMENTS
 512
 513 Matt S Trout, all of the #dbix-class folks, and everyone who's ever sent
 514 in a bug report or suggestion.
 515
 516 Based on L<DBIx::Class::Loader> by Sebastian Riedel
 517
 518 Based upon the work of IKEBE Tomohiro
 519
 520 =head1 AUTHOR
 521
 522 blblack: Brandon Black <blblack@gmail.com>
 523
 524 =head1 CONTRIBUTORS
 525
 526 ilmari: Dagfinn Ilmari MannsE<aring>ker <ilmari@ilmari.org>
 527
 528 arcanez: Justin Hunter <justin.d.hunter@gmail.com>
 529
 530 ash: Ash Berlin <ash@cpan.org>
 531
 532 btilly: Ben Tilly <btilly@gmail.com>
 533
 534 Caelum: Rafael Kitover <rkitover@cpan.org>
 535
 536 TSUNODA Kazuya <drk@drk7.jp>
 537
 538 rbo: Robert Bohne <rbo@cpan.org>
 539
 540 ribasushi: Peter Rabbitson <ribasushi@cpan.org>
 541
 542 gugu: Andrey Kostenko <a.kostenko@rambler-co.ru>
 543
 544 jhannah: Jay Hannah <jay@jays.net>
 545
 546 rbuels: Robert Buels <rmb32@cornell.edu>
 547
 548 timbunce: Tim Bunce <timb@cpan.org>
 549
 550 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
 551
 552 mstratman: Mark A. Stratman <stratman@gmail.com>
 553
 554 kane: Jos Boumans <kane@cpan.org>
 555
 556 waawaamilk: Nigel McNie <nigel@mcnie.name>
 557
 558 acmoore: Andrew Moore <amoore@cpan.org>
 559
 560 bphillips: Brian Phillips <bphillips@cpan.org>
 561
 562 schwern: Michael G. Schwern <mschwern@cpan.org>
 563
 564 hobbs: Andrew Rodland <arodland@cpan.org>
 565
 566 domm: Thomas Klausner <domm@plix.at>
 567
 568 spb: Stephen Bennett <spb@exherbo.org>
 569
 570 Matias E. Fernandez <mfernandez@pisco.ch>
 571
 572 alnewkirk: Al Newkirk <awncorp@cpan.org>
 573
 574 ... and lots of other folks. If we forgot you, please write the current
 575 maintainer or RT.
 576
 577 =head1 COPYRIGHT & LICENSE
 578
 579 Copyright (c) 2006 - 2009 by the aforementioned
 580 L<DBIx::Class::Schema::Loader/AUTHOR> and
 581 L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
 582
 583 This library is free software; you can redistribute it and/or modify it under
 584 the same terms as Perl itself.
 585
 586 =head1 SEE ALSO
 587
 588 L<DBIx::Class>, L<DBIx::Class::Manual::ExampleSchema>
 589
 590 =cut
 591
 592 1;
 593 # vim:et sts=4 sw=4 tw=0: