lib/DBIx/Class/Schema/Loader.pm

   1 package DBIx::Class::Schema::Loader;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class::Schema Class::Accessor::Grouped/;
   6 use MRO::Compat;
   7 use mro 'c3';
   8 use Carp::Clan qw/^DBIx::Class/;
   9 use Scalar::Util 'weaken';
  10 use Sub::Name 'subname';
  11 use namespace::clean;
  12
  13 # Always remember to do all digits for the version even if they're 0
  14 # i.e. first release of 0.XX *must* be 0.XX000. This avoids fBSD ports
  15 # brain damage and presumably various other packaging systems too
  16 our $VERSION = '0.07010';
  17
  18 __PACKAGE__->mk_group_accessors('inherited', qw/
  19                                 _loader_args
  20                                 dump_to_dir
  21                                 _loader_invoked
  22                                 _loader
  23                                 loader_class
  24                                 naming
  25                                 use_namespaces
  26 /);
  27 __PACKAGE__->_loader_args({});
  28
  29 =head1 NAME
  30
  31 DBIx::Class::Schema::Loader - Create a DBIx::Class::Schema based on a database
  32
  33 =head1 SYNOPSIS
  34
  35   ### use this module to generate a set of class files
  36
  37   # in a script
  38   use DBIx::Class::Schema::Loader qw/ make_schema_at /;
  39   make_schema_at(
  40       'My::Schema',
  41       { debug => 1,
  42         dump_directory => './lib',
  43       },
  44       [ 'dbi:Pg:dbname="foo"', 'myuser', 'mypassword',
  45          { loader_class => 'MyLoader' } # optionally
  46       ],
  47   );
  48
  49   # from the command line or a shell script with dbicdump (distributed
  50   # with this module).  Do `perldoc dbicdump` for usage.
  51   dbicdump -o dump_directory=./lib \
  52            -o components='["InflateColumn::DateTime"]' \
  53            -o debug=1 \
  54            My::Schema \
  55            'dbi:Pg:dbname=foo' \
  56            myuser \
  57            mypassword
  58
  59   ### or generate and load classes at runtime
  60   # note: this technique is not recommended
  61   # for use in production code
  62
  63   package My::Schema;
  64   use base qw/DBIx::Class::Schema::Loader/;
  65
  66   __PACKAGE__->loader_options(
  67       constraint              => '^foo.*',
  68       # debug                 => 1,
  69   );
  70
  71   #### in application code elsewhere:
  72
  73   use My::Schema;
  74
  75   my $schema1 = My::Schema->connect( $dsn, $user, $password, $attrs);
  76   # -or-
  77   my $schema1 = "My::Schema"; $schema1->connection(as above);
  78
  79 =head1 DESCRIPTION
  80
  81 DBIx::Class::Schema::Loader automates the definition of a
  82 L<DBIx::Class::Schema> by scanning database table definitions and setting up
  83 the columns, primary keys, unique constraints and relationships.
  84
  85 See L<dbicdump> for the C<dbicdump> utility.
  86
  87 DBIx::Class::Schema::Loader currently supports only the DBI storage type. It
  88 has explicit support for L<DBD::Pg>, L<DBD::mysql>, L<DBD::DB2>,
  89 L<DBD::Firebird>, L<DBD::InterBase>, L<DBD::Informix>, L<DBD::SQLAnywhere>,
  90 L<DBD::SQLite>, L<DBD::Sybase> (for Sybase ASE and MSSSQL), L<DBD::ODBC> (for
  91 MSSQL, MSAccess, Firebird and SQL Anywhere) L<DBD::ADO> (for MSSQL and
  92 MSAccess) and L<DBD::Oracle>.  Other DBI drivers may function to a greater or
  93 lesser degree with this loader, depending on how much of the DBI spec they
  94 implement, and how standard their implementation is.
  95
  96 Patches to make other DBDs work correctly welcome.
  97
  98 See L<DBIx::Class::Schema::Loader::DBI::Writing> for notes on writing
  99 your own vendor-specific subclass for an unsupported DBD driver.
 100
 101 This module requires L<DBIx::Class> 0.08127 or later, and obsoletes the older
 102 L<DBIx::Class::Loader>.
 103
 104 See L<DBIx::Class::Schema::Loader::Base> for available options.
 105
 106 =head1 METHODS
 107
 108 =head2 loader
 109
 110 The loader object, as class data on your Schema. For methods available see
 111 L<DBIx::Class::Schema::Loader::Base> and L<DBIx::Class::Schema::Loader::DBI>.
 112
 113 =cut
 114
 115 sub loader {
 116     my $self = shift;
 117     $self->_loader(@_);
 118 }
 119
 120 =head2 loader_class
 121
 122 =over 4
 123
 124 =item Argument: $loader_class
 125
 126 =back
 127
 128 Set the loader class to be instantiated when L</connection> is called.
 129 If the classname starts with "::", "DBIx::Class::Schema::Loader" is
 130 prepended. Defaults to L<DBIx::Class::Schema/storage_type> (which must
 131 start with "::" when using L<DBIx::Class::Schema::Loader>).
 132
 133 This is mostly useful for subclassing existing loaders or in conjunction
 134 with L</dump_to_dir>.
 135
 136 =head2 loader_options
 137
 138 =over 4
 139
 140 =item Argument: \%loader_options
 141
 142 =back
 143
 144 Example in Synopsis above demonstrates a few common arguments.  For
 145 detailed information on all of the arguments, most of which are
 146 only useful in fairly complex scenarios, see the
 147 L<DBIx::Class::Schema::Loader::Base> documentation.
 148
 149 If you intend to use C<loader_options>, you must call
 150 C<loader_options> before any connection is made, or embed the
 151 C<loader_options> in the connection information itself as shown
 152 below.  Setting C<loader_options> after the connection has
 153 already been made is useless.
 154
 155 =cut
 156
 157 sub loader_options {
 158     my $self = shift;
 159
 160     my %args = (ref $_[0] eq 'HASH') ? %{$_[0]} : @_;
 161     $self->_loader_args(\%args);
 162
 163     $self;
 164 }
 165
 166 sub _invoke_loader {
 167     my $self = shift;
 168     my $class = ref $self || $self;
 169
 170     my $args = $self->_loader_args;
 171
 172     # set up the schema/schema_class arguments
 173     $args->{schema} = $self;
 174     $args->{schema_class} = $class;
 175     weaken($args->{schema}) if ref $self;
 176     $args->{dump_directory} ||= $self->dump_to_dir;
 177     $args->{naming} = $self->naming if $self->naming;
 178     $args->{use_namespaces} = $self->use_namespaces if defined $self->use_namespaces;
 179
 180     # XXX this only works for relative storage_type, like ::DBI ...
 181     my $loader_class = $self->loader_class;
 182     if ($loader_class) {
 183         $loader_class = "DBIx::Class::Schema::Loader${loader_class}" if $loader_class =~ /^::/;
 184         $args->{loader_class} = $loader_class;
 185     };
 186
 187     my $impl = $loader_class || "DBIx::Class::Schema::Loader" . $self->storage_type;
 188     eval { $self->ensure_class_loaded($impl) };
 189     croak qq/Could not load loader_class "$impl": "$@"/ if $@;
 190
 191     $self->loader($impl->new(%$args));
 192     $self->loader->load;
 193     $self->_loader_invoked(1);
 194
 195     $self;
 196 }
 197
 198 =head2 connection
 199
 200 =over 4
 201
 202 =item Arguments: @args
 203
 204 =item Return Value: $new_schema
 205
 206 =back
 207
 208 See L<DBIx::Class::Schema/connection> for basic usage.
 209
 210 If the final argument is a hashref, and it contains the keys C<loader_options>
 211 or C<loader_class>, those keys will be deleted, and their values value will be
 212 used for the loader options or class, respectively, just as if set via the
 213 L</loader_options> or L</loader_class> methods above.
 214
 215 The actual auto-loading operation (the heart of this module) will be invoked
 216 as soon as the connection information is defined.
 217
 218 =cut
 219
 220 sub connection {
 221     my $self  = shift;
 222     my $class = ref $self || $self;
 223
 224     if($_[-1] && ref $_[-1] eq 'HASH') {
 225         for my $option (qw/loader_class loader_options/) {
 226             if(my $value = delete $_[-1]->{$option}) {
 227                 $self->$option($value);
 228             }
 229         }
 230         pop @_ if !keys %{$_[-1]};
 231     }
 232
 233     # Make sure we inherit from schema_base_class and load schema_components
 234     # before connecting.
 235     require DBIx::Class::Schema::Loader::Base;
 236     my $temp_loader = DBIx::Class::Schema::Loader::Base->new(
 237         %{ $self->_loader_args },
 238         schema => $self,
 239     );
 240
 241     if ($temp_loader->schema_base_class || $temp_loader->schema_components) {
 242         my @components = @{ $temp_loader->schema_components }
 243             if $temp_loader->schema_components;
 244
 245         push @components, ('+'.$temp_loader->schema_base_class)
 246             if $temp_loader->schema_base_class;
 247
 248         $class->load_components(@components);
 249
 250         # This hack is necessary because we changed @ISA of $self through
 251         # ->load_components and we are now in a different place in the mro.
 252         no warnings 'redefine';
 253
 254         local *connection = subname __PACKAGE__.'::connection' => sub {
 255             my $self = shift;
 256             $self->next::method(@_);
 257         };
 258
 259         my @linear_isa = @{ mro::get_linear_isa($class) };
 260
 261         my $next_method;
 262
 263         foreach my $i (1..$#linear_isa) {
 264             no strict 'refs';
 265             $next_method = *{$linear_isa[$i].'::connection'}{CODE};
 266             last if $next_method;
 267         }
 268
 269         $self = $self->$next_method(@_);
 270     }
 271     else {
 272         $self = $self->next::method(@_);
 273     }
 274
 275     if(!$class->_loader_invoked) {
 276         $self->_invoke_loader
 277     }
 278
 279     return $self;
 280 }
 281
 282 =head2 clone
 283
 284 See L<DBIx::Class::Schema/clone>.
 285
 286 =cut
 287
 288 sub clone {
 289     my $self = shift;
 290
 291     my $clone = $self->next::method(@_);
 292
 293     if($clone->_loader_args) {
 294         $clone->_loader_args->{schema} = $clone;
 295         weaken($clone->_loader_args->{schema});
 296     }
 297
 298     $clone;
 299 }
 300
 301 =head2 dump_to_dir
 302
 303 =over 4
 304
 305 =item Argument: $directory
 306
 307 =back
 308
 309 Calling this as a class method on either L<DBIx::Class::Schema::Loader>
 310 or any derived schema class will cause all schemas to dump
 311 manual versions of themselves to the named directory when they are
 312 loaded.  In order to be effective, this must be set before defining a
 313 connection on this schema class or any derived object (as the loading
 314 happens as soon as both a connection and loader_options are set, and
 315 only once per class).
 316
 317 See L<DBIx::Class::Schema::Loader::Base/dump_directory> for more
 318 details on the dumping mechanism.
 319
 320 This can also be set at module import time via the import option
 321 C<dump_to_dir:/foo/bar> to L<DBIx::Class::Schema::Loader>, where
 322 C</foo/bar> is the target directory.
 323
 324 Examples:
 325
 326     # My::Schema isa DBIx::Class::Schema::Loader, and has connection info
 327     #   hardcoded in the class itself:
 328     perl -MDBIx::Class::Schema::Loader=dump_to_dir:/foo/bar -MMy::Schema -e1
 329
 330     # Same, but no hard-coded connection, so we must provide one:
 331     perl -MDBIx::Class::Schema::Loader=dump_to_dir:/foo/bar -MMy::Schema -e 'My::Schema->connection("dbi:Pg:dbname=foo", ...)'
 332
 333     # Or as a class method, as long as you get it done *before* defining a
 334     #  connection on this schema class or any derived object:
 335     use My::Schema;
 336     My::Schema->dump_to_dir('/foo/bar');
 337     My::Schema->connection(........);
 338
 339     # Or as a class method on the DBIx::Class::Schema::Loader itself, which affects all
 340     #   derived schemas
 341     use My::Schema;
 342     use My::OtherSchema;
 343     DBIx::Class::Schema::Loader->dump_to_dir('/foo/bar');
 344     My::Schema->connection(.......);
 345     My::OtherSchema->connection(.......);
 346
 347     # Another alternative to the above:
 348     use DBIx::Class::Schema::Loader qw| dump_to_dir:/foo/bar |;
 349     use My::Schema;
 350     use My::OtherSchema;
 351     My::Schema->connection(.......);
 352     My::OtherSchema->connection(.......);
 353
 354 =cut
 355
 356 sub import {
 357     my $self = shift;
 358
 359     return if !@_;
 360
 361     my $cpkg = (caller)[0];
 362
 363     foreach my $opt (@_) {
 364         if($opt =~ m{^dump_to_dir:(.*)$}) {
 365             $self->dump_to_dir($1)
 366         }
 367         elsif($opt eq 'make_schema_at') {
 368             no strict 'refs';
 369             *{"${cpkg}::make_schema_at"} = \&make_schema_at;
 370         }
 371         elsif($opt eq 'naming') {
 372             no strict 'refs';
 373             *{"${cpkg}::naming"} = sub { $self->naming(@_) };
 374         }
 375         elsif($opt eq 'use_namespaces') {
 376             no strict 'refs';
 377             *{"${cpkg}::use_namespaces"} = sub { $self->use_namespaces(@_) };
 378         }
 379     }
 380 }
 381
 382 =head2 make_schema_at
 383
 384 =over 4
 385
 386 =item Arguments: $schema_class_name, \%loader_options, \@connect_info
 387
 388 =item Return Value: $schema_class_name
 389
 390 =back
 391
 392 This function creates a DBIx::Class schema from an existing RDBMS
 393 schema.  With the C<dump_directory> option, generates a set of
 394 DBIx::Class classes from an existing database schema read from the
 395 given dsn.  Without a C<dump_directory>, creates schema classes in
 396 memory at runtime without generating on-disk class files.
 397
 398 For a complete list of supported loader_options, see
 399 L<DBIx::Class::Schema::Loader::Base>
 400
 401 The last hashref in the C<\@connect_info> can specify the L</loader_class>.
 402
 403 This function can be imported in the usual way, as illustrated in
 404 these Examples:
 405
 406     # Simple example, creates as a new class 'New::Schema::Name' in
 407     #  memory in the running perl interpreter.
 408     use DBIx::Class::Schema::Loader qw/ make_schema_at /;
 409     make_schema_at(
 410         'New::Schema::Name',
 411         { debug => 1 },
 412         [ 'dbi:Pg:dbname="foo"','postgres','',
 413           { loader_class => 'MyLoader' } # optionally
 414         ],
 415     );
 416
 417     # Inside a script, specifying a dump directory in which to write
 418     # class files
 419     use DBIx::Class::Schema::Loader qw/ make_schema_at /;
 420     make_schema_at(
 421         'New::Schema::Name',
 422         { debug => 1, dump_directory => './lib' },
 423         [ 'dbi:Pg:dbname="foo"','postgres','',
 424           { loader_class => 'MyLoader' } # optionally
 425         ],
 426     );
 427
 428 The last hashref in the C<\@connect_info> is checked for loader arguments such
 429 as C<loader_options> and C<loader_class>, see L</connection> for more details.
 430
 431 =cut
 432
 433 sub make_schema_at {
 434     my ($target, $opts, $connect_info) = @_;
 435
 436     {
 437         no strict 'refs';
 438         @{$target . '::ISA'} = qw/DBIx::Class::Schema::Loader/;
 439     }
 440
 441     eval { $target->_loader_invoked(0) };
 442
 443     $target->loader_options($opts);
 444     $target->connection(@$connect_info);
 445 }
 446
 447 =head2 rescan
 448
 449 =over 4
 450
 451 =item Return Value: @new_monikers
 452
 453 =back
 454
 455 Re-scans the database for newly added tables since the initial
 456 load, and adds them to the schema at runtime, including relationships,
 457 etc.  Does not process drops or changes.
 458
 459 Returns a list of the new monikers added.
 460
 461 =cut
 462
 463 sub rescan { my $self = shift; $self->loader->rescan($self) }
 464
 465 =head2 naming
 466
 467 =over 4
 468
 469 =item Arguments: \%opts | $ver
 470
 471 =back
 472
 473 Controls the naming options for backward compatibility, see
 474 L<DBIx::Class::Schema::Loader::Base/naming> for details.
 475
 476 To upgrade a dynamic schema, use:
 477
 478     __PACKAGE__->naming('current');
 479
 480 Can be imported into your dump script and called as a function as well:
 481
 482     naming('v4');
 483
 484 =head2 use_namespaces
 485
 486 =over 4
 487
 488 =item Arguments: 1|0
 489
 490 =back
 491
 492 Controls the use_namespaces options for backward compatibility, see
 493 L<DBIx::Class::Schema::Loader::Base/use_namespaces> for details.
 494
 495 To upgrade a dynamic schema, use:
 496
 497     __PACKAGE__->use_namespaces(1);
 498
 499 Can be imported into your dump script and called as a function as well:
 500
 501     use_namespaces(1);
 502
 503 =head1 KNOWN ISSUES
 504
 505 =head2 Multiple Database Schemas
 506
 507 See L<DBIx::Class::Schema::Loader::Base/db_schema>.
 508
 509 =head1 ACKNOWLEDGEMENTS
 510
 511 Matt S Trout, all of the #dbix-class folks, and everyone who's ever sent
 512 in a bug report or suggestion.
 513
 514 Based on L<DBIx::Class::Loader> by Sebastian Riedel
 515
 516 Based upon the work of IKEBE Tomohiro
 517
 518 =head1 AUTHOR
 519
 520 blblack: Brandon Black <blblack@gmail.com>
 521
 522 =head1 CONTRIBUTORS
 523
 524 ilmari: Dagfinn Ilmari MannsE<aring>ker <ilmari@ilmari.org>
 525
 526 arcanez: Justin Hunter <justin.d.hunter@gmail.com>
 527
 528 ash: Ash Berlin <ash@cpan.org>
 529
 530 btilly: Ben Tilly <btilly@gmail.com>
 531
 532 Caelum: Rafael Kitover <rkitover@cpan.org>
 533
 534 TSUNODA Kazuya <drk@drk7.jp>
 535
 536 rbo: Robert Bohne <rbo@cpan.org>
 537
 538 ribasushi: Peter Rabbitson <ribasushi@cpan.org>
 539
 540 gugu: Andrey Kostenko <a.kostenko@rambler-co.ru>
 541
 542 jhannah: Jay Hannah <jay@jays.net>
 543
 544 rbuels: Robert Buels <rmb32@cornell.edu>
 545
 546 timbunce: Tim Bunce <timb@cpan.org>
 547
 548 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
 549
 550 mstratman: Mark A. Stratman <stratman@gmail.com>
 551
 552 kane: Jos Boumans <kane@cpan.org>
 553
 554 waawaamilk: Nigel McNie <nigel@mcnie.name>
 555
 556 acmoore: Andrew Moore <amoore@cpan.org>
 557
 558 bphillips: Brian Phillips <bphillips@cpan.org>
 559
 560 schwern: Michael G. Schwern <mschwern@cpan.org>
 561
 562 hobbs: Andrew Rodland <arodland@cpan.org>
 563
 564 domm: Thomas Klausner <domm@plix.at>
 565
 566 spb: Stephen Bennett <spb@exherbo.org>
 567
 568 Matias E. Fernandez <mfernandez@pisco.ch>
 569
 570 Al Newkirk <awncorp@cpan.org>
 571
 572 ... and lots of other folks. If we forgot you, please write the current
 573 maintainer or RT.
 574
 575 =head1 COPYRIGHT & LICENSE
 576
 577 Copyright (c) 2006 - 2009 by the aforementioned
 578 L<DBIx::Class::Schema::Loader/AUTHOR> and
 579 L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
 580
 581 This library is free software; you can redistribute it and/or modify it under
 582 the same terms as Perl itself.
 583
 584 =head1 SEE ALSO
 585
 586 L<DBIx::Class>, L<DBIx::Class::Manual::ExampleSchema>
 587
 588 =cut
 589
 590 1;
 591 # vim:et sts=4 sw=4 tw=0: