lib/DBIx/Class/Schema/Loader.pm

   1 package DBIx::Class::Schema::Loader;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class::Schema Class::Accessor::Grouped/;
   6 use MRO::Compat;
   7 use mro 'c3';
   8 use Carp::Clan qw/^DBIx::Class/;
   9 use Scalar::Util 'weaken';
  10 use Sub::Name 'subname';
  11 use namespace::clean;
  12
  13 # Always remember to do all digits for the version even if they're 0
  14 # i.e. first release of 0.XX *must* be 0.XX000. This avoids fBSD ports
  15 # brain damage and presumably various other packaging systems too
  16 our $VERSION = '0.07010';
  17
  18 __PACKAGE__->mk_group_accessors('inherited', qw/
  19                                 _loader_args
  20                                 dump_to_dir
  21                                 _loader_invoked
  22                                 _loader
  23                                 loader_class
  24                                 naming
  25                                 use_namespaces
  26 /);
  27 __PACKAGE__->_loader_args({});
  28
  29 =head1 NAME
  30
  31 DBIx::Class::Schema::Loader - Create a DBIx::Class::Schema based on a database
  32
  33 =head1 SYNOPSIS
  34
  35   ### use this module to generate a set of class files
  36
  37   # in a script
  38   use DBIx::Class::Schema::Loader qw/ make_schema_at /;
  39   make_schema_at(
  40       'My::Schema',
  41       { debug => 1,
  42         dump_directory => './lib',
  43       },
  44       [ 'dbi:Pg:dbname="foo"', 'myuser', 'mypassword',
  45          { loader_class => 'MyLoader' } # optionally
  46       ],
  47   );
  48
  49   # from the command line or a shell script with dbicdump (distributed
  50   # with this module).  Do `perldoc dbicdump` for usage.
  51   dbicdump -o dump_directory=./lib \
  52            -o components='["InflateColumn::DateTime"]' \
  53            -o debug=1 \
  54            My::Schema \
  55            'dbi:Pg:dbname=foo' \
  56            myuser \
  57            mypassword
  58
  59   ### or generate and load classes at runtime
  60   # note: this technique is not recommended
  61   # for use in production code
  62
  63   package My::Schema;
  64   use base qw/DBIx::Class::Schema::Loader/;
  65
  66   __PACKAGE__->loader_options(
  67       constraint              => '^foo.*',
  68       # debug                 => 1,
  69   );
  70
  71   #### in application code elsewhere:
  72
  73   use My::Schema;
  74
  75   my $schema1 = My::Schema->connect( $dsn, $user, $password, $attrs);
  76   # -or-
  77   my $schema1 = "My::Schema"; $schema1->connection(as above);
  78
  79 =head1 DESCRIPTION
  80
  81 DBIx::Class::Schema::Loader automates the definition of a
  82 L<DBIx::Class::Schema> by scanning database table definitions and setting up
  83 the columns, primary keys, unique constraints and relationships.
  84
  85 See L<dbicdump> for the C<dbicdump> utility.
  86
  87 DBIx::Class::Schema::Loader currently supports only the DBI storage type. It
  88 has explicit support for L<DBD::Pg>, L<DBD::mysql>, L<DBD::DB2>,
  89 L<DBD::Firebird>, L<DBD::InterBase>, L<DBD::Informix>, L<DBD::SQLAnywhere>,
  90 L<DBD::SQLite>, L<DBD::Sybase> (for Sybase ASE and MSSSQL), L<DBD::ODBC> (for
  91 MSSQL, MSAccess, Firebird and SQL Anywhere) L<DBD::ADO> (for MSSQL and
  92 MSAccess) and L<DBD::Oracle>.  Other DBI drivers may function to a greater or
  93 lesser degree with this loader, depending on how much of the DBI spec they
  94 implement, and how standard their implementation is.
  95
  96 Patches to make other DBDs work correctly welcome.
  97
  98 See L<DBIx::Class::Schema::Loader::DBI::Writing> for notes on writing
  99 your own vendor-specific subclass for an unsupported DBD driver.
 100
 101 This module requires L<DBIx::Class> 0.08127 or later, and obsoletes the older
 102 L<DBIx::Class::Loader>.
 103
 104 See L<DBIx::Class::Schema::Loader::Base> for available options.
 105
 106 =head1 METHODS
 107
 108 =head2 loader
 109
 110 The loader object, as class data on your Schema. For methods available see
 111 L<DBIx::Class::Schema::Loader::Base> and L<DBIx::Class::Schema::Loader::DBI>.
 112
 113 =cut
 114
 115 sub loader {
 116     my $self = shift;
 117     $self->_loader(@_);
 118 }
 119
 120 =head2 loader_class
 121
 122 =over 4
 123
 124 =item Argument: $loader_class
 125
 126 =back
 127
 128 Set the loader class to be instantiated when L</connection> is called.
 129 If the classname starts with "::", "DBIx::Class::Schema::Loader" is
 130 prepended. Defaults to L<DBIx::Class::Schema/storage_type> (which must
 131 start with "::" when using L<DBIx::Class::Schema::Loader>).
 132
 133 This is mostly useful for subclassing existing loaders or in conjunction
 134 with L</dump_to_dir>.
 135
 136 =head2 loader_options
 137
 138 =over 4
 139
 140 =item Argument: \%loader_options
 141
 142 =back
 143
 144 Example in Synopsis above demonstrates a few common arguments.  For
 145 detailed information on all of the arguments, most of which are
 146 only useful in fairly complex scenarios, see the
 147 L<DBIx::Class::Schema::Loader::Base> documentation.
 148
 149 If you intend to use C<loader_options>, you must call
 150 C<loader_options> before any connection is made, or embed the
 151 C<loader_options> in the connection information itself as shown
 152 below.  Setting C<loader_options> after the connection has
 153 already been made is useless.
 154
 155 =cut
 156
 157 sub loader_options {
 158     my $self = shift;
 159
 160     my %args = (ref $_[0] eq 'HASH') ? %{$_[0]} : @_;
 161     $self->_loader_args(\%args);
 162
 163     $self;
 164 }
 165
 166 sub _invoke_loader {
 167     my $self = shift;
 168     my $class = ref $self || $self;
 169
 170     my $args = $self->_loader_args;
 171
 172     # set up the schema/schema_class arguments
 173     $args->{schema} = $self;
 174     $args->{schema_class} = $class;
 175     weaken($args->{schema}) if ref $self;
 176     $args->{dump_directory} ||= $self->dump_to_dir;
 177     $args->{naming} = $self->naming if $self->naming;
 178     $args->{use_namespaces} = $self->use_namespaces if defined $self->use_namespaces;
 179
 180     # XXX this only works for relative storage_type, like ::DBI ...
 181     my $loader_class = $self->loader_class;
 182     if ($loader_class) {
 183         $loader_class = "DBIx::Class::Schema::Loader${loader_class}" if $loader_class =~ /^::/;
 184         $args->{loader_class} = $loader_class;
 185     };
 186
 187     my $impl = $loader_class || "DBIx::Class::Schema::Loader" . $self->storage_type;
 188     eval { $self->ensure_class_loaded($impl) };
 189     croak qq/Could not load loader_class "$impl": "$@"/ if $@;
 190
 191     $self->loader($impl->new(%$args));
 192     $self->loader->load;
 193     $self->_loader_invoked(1);
 194
 195     $self;
 196 }
 197
 198 =head2 connection
 199
 200 =over 4
 201
 202 =item Arguments: @args
 203
 204 =item Return Value: $new_schema
 205
 206 =back
 207
 208 See L<DBIx::Class::Schema/connection> for basic usage.
 209
 210 If the final argument is a hashref, and it contains the keys C<loader_options>
 211 or C<loader_class>, those keys will be deleted, and their values value will be
 212 used for the loader options or class, respectively, just as if set via the
 213 L</loader_options> or L</loader_class> methods above.
 214
 215 The actual auto-loading operation (the heart of this module) will be invoked
 216 as soon as the connection information is defined.
 217
 218 =cut
 219
 220 sub connection {
 221     my $self = shift;
 222
 223     if($_[-1] && ref $_[-1] eq 'HASH') {
 224         for my $option (qw/loader_class loader_options/) {
 225             if(my $value = delete $_[-1]->{$option}) {
 226                 $self->$option($value);
 227             }
 228         }
 229         pop @_ if !keys %{$_[-1]};
 230     }
 231
 232     # Make sure we inherit from schema_base_class and load schema_components
 233     # before connecting.
 234     require DBIx::Class::Schema::Loader::Base;
 235     my $temp_loader = DBIx::Class::Schema::Loader::Base->new(
 236         %{ $self->_loader_args }
 237     );
 238
 239     if ($temp_loader->schema_base_class || $temp_loader->schema_components) {
 240         my @components = @{ $temp_loader->schema_components }
 241             if $temp_loader->schema_components;
 242
 243         push @components, ('+'.$temp_loader->schema_base_class)
 244             if $temp_loader->schema_base_class;
 245
 246         $self->load_components(@components);
 247     }
 248
 249     # This hack is necessary if we changed @ISA of $self through ->load_components.
 250     {
 251         no warnings 'redefine';
 252
 253         local *connection = subname __PACKAGE__.'::connection' => sub {
 254             my $self = shift;
 255             $self->next::method(@_);
 256         };
 257
 258         $self = $self->connection(@_);
 259     }
 260
 261     my $class = ref $self || $self;
 262     if(!$class->_loader_invoked) {
 263         $self->_invoke_loader
 264     }
 265
 266     return $self;
 267 }
 268
 269 =head2 clone
 270
 271 See L<DBIx::Class::Schema/clone>.
 272
 273 =cut
 274
 275 sub clone {
 276     my $self = shift;
 277
 278     my $clone = $self->next::method(@_);
 279
 280     if($clone->_loader_args) {
 281         $clone->_loader_args->{schema} = $clone;
 282         weaken($clone->_loader_args->{schema});
 283     }
 284
 285     $clone;
 286 }
 287
 288 =head2 dump_to_dir
 289
 290 =over 4
 291
 292 =item Argument: $directory
 293
 294 =back
 295
 296 Calling this as a class method on either L<DBIx::Class::Schema::Loader>
 297 or any derived schema class will cause all schemas to dump
 298 manual versions of themselves to the named directory when they are
 299 loaded.  In order to be effective, this must be set before defining a
 300 connection on this schema class or any derived object (as the loading
 301 happens as soon as both a connection and loader_options are set, and
 302 only once per class).
 303
 304 See L<DBIx::Class::Schema::Loader::Base/dump_directory> for more
 305 details on the dumping mechanism.
 306
 307 This can also be set at module import time via the import option
 308 C<dump_to_dir:/foo/bar> to L<DBIx::Class::Schema::Loader>, where
 309 C</foo/bar> is the target directory.
 310
 311 Examples:
 312
 313     # My::Schema isa DBIx::Class::Schema::Loader, and has connection info
 314     #   hardcoded in the class itself:
 315     perl -MDBIx::Class::Schema::Loader=dump_to_dir:/foo/bar -MMy::Schema -e1
 316
 317     # Same, but no hard-coded connection, so we must provide one:
 318     perl -MDBIx::Class::Schema::Loader=dump_to_dir:/foo/bar -MMy::Schema -e 'My::Schema->connection("dbi:Pg:dbname=foo", ...)'
 319
 320     # Or as a class method, as long as you get it done *before* defining a
 321     #  connection on this schema class or any derived object:
 322     use My::Schema;
 323     My::Schema->dump_to_dir('/foo/bar');
 324     My::Schema->connection(........);
 325
 326     # Or as a class method on the DBIx::Class::Schema::Loader itself, which affects all
 327     #   derived schemas
 328     use My::Schema;
 329     use My::OtherSchema;
 330     DBIx::Class::Schema::Loader->dump_to_dir('/foo/bar');
 331     My::Schema->connection(.......);
 332     My::OtherSchema->connection(.......);
 333
 334     # Another alternative to the above:
 335     use DBIx::Class::Schema::Loader qw| dump_to_dir:/foo/bar |;
 336     use My::Schema;
 337     use My::OtherSchema;
 338     My::Schema->connection(.......);
 339     My::OtherSchema->connection(.......);
 340
 341 =cut
 342
 343 sub import {
 344     my $self = shift;
 345
 346     return if !@_;
 347
 348     my $cpkg = (caller)[0];
 349
 350     foreach my $opt (@_) {
 351         if($opt =~ m{^dump_to_dir:(.*)$}) {
 352             $self->dump_to_dir($1)
 353         }
 354         elsif($opt eq 'make_schema_at') {
 355             no strict 'refs';
 356             *{"${cpkg}::make_schema_at"} = \&make_schema_at;
 357         }
 358         elsif($opt eq 'naming') {
 359             no strict 'refs';
 360             *{"${cpkg}::naming"} = sub { $self->naming(@_) };
 361         }
 362         elsif($opt eq 'use_namespaces') {
 363             no strict 'refs';
 364             *{"${cpkg}::use_namespaces"} = sub { $self->use_namespaces(@_) };
 365         }
 366     }
 367 }
 368
 369 =head2 make_schema_at
 370
 371 =over 4
 372
 373 =item Arguments: $schema_class_name, \%loader_options, \@connect_info
 374
 375 =item Return Value: $schema_class_name
 376
 377 =back
 378
 379 This function creates a DBIx::Class schema from an existing RDBMS
 380 schema.  With the C<dump_directory> option, generates a set of
 381 DBIx::Class classes from an existing database schema read from the
 382 given dsn.  Without a C<dump_directory>, creates schema classes in
 383 memory at runtime without generating on-disk class files.
 384
 385 For a complete list of supported loader_options, see
 386 L<DBIx::Class::Schema::Loader::Base>
 387
 388 The last hashref in the C<\@connect_info> can specify the L</loader_class>.
 389
 390 This function can be imported in the usual way, as illustrated in
 391 these Examples:
 392
 393     # Simple example, creates as a new class 'New::Schema::Name' in
 394     #  memory in the running perl interpreter.
 395     use DBIx::Class::Schema::Loader qw/ make_schema_at /;
 396     make_schema_at(
 397         'New::Schema::Name',
 398         { debug => 1 },
 399         [ 'dbi:Pg:dbname="foo"','postgres','',
 400           { loader_class => 'MyLoader' } # optionally
 401         ],
 402     );
 403
 404     # Inside a script, specifying a dump directory in which to write
 405     # class files
 406     use DBIx::Class::Schema::Loader qw/ make_schema_at /;
 407     make_schema_at(
 408         'New::Schema::Name',
 409         { debug => 1, dump_directory => './lib' },
 410         [ 'dbi:Pg:dbname="foo"','postgres','',
 411           { loader_class => 'MyLoader' } # optionally
 412         ],
 413     );
 414
 415 The last hashref in the C<\@connect_info> is checked for loader arguments such
 416 as C<loader_options> and C<loader_class>, see L</connection> for more details.
 417
 418 =cut
 419
 420 sub make_schema_at {
 421     my ($target, $opts, $connect_info) = @_;
 422
 423     {
 424         no strict 'refs';
 425         @{$target . '::ISA'} = qw/DBIx::Class::Schema::Loader/;
 426     }
 427
 428     eval { $target->_loader_invoked(0) };
 429
 430     $target->loader_options($opts);
 431     $target->connection(@$connect_info);
 432 }
 433
 434 =head2 rescan
 435
 436 =over 4
 437
 438 =item Return Value: @new_monikers
 439
 440 =back
 441
 442 Re-scans the database for newly added tables since the initial
 443 load, and adds them to the schema at runtime, including relationships,
 444 etc.  Does not process drops or changes.
 445
 446 Returns a list of the new monikers added.
 447
 448 =cut
 449
 450 sub rescan { my $self = shift; $self->loader->rescan($self) }
 451
 452 =head2 naming
 453
 454 =over 4
 455
 456 =item Arguments: \%opts | $ver
 457
 458 =back
 459
 460 Controls the naming options for backward compatibility, see
 461 L<DBIx::Class::Schema::Loader::Base/naming> for details.
 462
 463 To upgrade a dynamic schema, use:
 464
 465     __PACKAGE__->naming('current');
 466
 467 Can be imported into your dump script and called as a function as well:
 468
 469     naming('v4');
 470
 471 =head2 use_namespaces
 472
 473 =over 4
 474
 475 =item Arguments: 1|0
 476
 477 =back
 478
 479 Controls the use_namespaces options for backward compatibility, see
 480 L<DBIx::Class::Schema::Loader::Base/use_namespaces> for details.
 481
 482 To upgrade a dynamic schema, use:
 483
 484     __PACKAGE__->use_namespaces(1);
 485
 486 Can be imported into your dump script and called as a function as well:
 487
 488     use_namespaces(1);
 489
 490 =head1 KNOWN ISSUES
 491
 492 =head2 Multiple Database Schemas
 493
 494 See L<DBIx::Class::Schema::Loader::Base/db_schema>.
 495
 496 =head1 ACKNOWLEDGEMENTS
 497
 498 Matt S Trout, all of the #dbix-class folks, and everyone who's ever sent
 499 in a bug report or suggestion.
 500
 501 Based on L<DBIx::Class::Loader> by Sebastian Riedel
 502
 503 Based upon the work of IKEBE Tomohiro
 504
 505 =head1 AUTHOR
 506
 507 blblack: Brandon Black <blblack@gmail.com>
 508
 509 =head1 CONTRIBUTORS
 510
 511 ilmari: Dagfinn Ilmari MannsE<aring>ker <ilmari@ilmari.org>
 512
 513 arcanez: Justin Hunter <justin.d.hunter@gmail.com>
 514
 515 ash: Ash Berlin <ash@cpan.org>
 516
 517 btilly: Ben Tilly <btilly@gmail.com>
 518
 519 Caelum: Rafael Kitover <rkitover@cpan.org>
 520
 521 TSUNODA Kazuya <drk@drk7.jp>
 522
 523 rbo: Robert Bohne <rbo@cpan.org>
 524
 525 ribasushi: Peter Rabbitson <ribasushi@cpan.org>
 526
 527 gugu: Andrey Kostenko <a.kostenko@rambler-co.ru>
 528
 529 jhannah: Jay Hannah <jay@jays.net>
 530
 531 rbuels: Robert Buels <rmb32@cornell.edu>
 532
 533 timbunce: Tim Bunce <timb@cpan.org>
 534
 535 mst: Matt S. Trout <mst@shadowcatsystems.co.uk>
 536
 537 mstratman: Mark A. Stratman <stratman@gmail.com>
 538
 539 kane: Jos Boumans <kane@cpan.org>
 540
 541 waawaamilk: Nigel McNie <nigel@mcnie.name>
 542
 543 acmoore: Andrew Moore <amoore@cpan.org>
 544
 545 bphillips: Brian Phillips <bphillips@cpan.org>
 546
 547 schwern: Michael G. Schwern <mschwern@cpan.org>
 548
 549 hobbs: Andrew Rodland <arodland@cpan.org>
 550
 551 domm: Thomas Klausner <domm@plix.at>
 552
 553 spb: Stephen Bennett <spb@exherbo.org>
 554
 555 Matias E. Fernandez <mfernandez@pisco.ch>
 556
 557 Al Newkirk <awncorp@cpan.org>
 558
 559 ... and lots of other folks. If we forgot you, please write the current
 560 maintainer or RT.
 561
 562 =head1 COPYRIGHT & LICENSE
 563
 564 Copyright (c) 2006 - 2009 by the aforementioned
 565 L<DBIx::Class::Schema::Loader/AUTHOR> and
 566 L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
 567
 568 This library is free software; you can redistribute it and/or modify it under
 569 the same terms as Perl itself.
 570
 571 =head1 SEE ALSO
 572
 573 L<DBIx::Class>, L<DBIx::Class::Manual::ExampleSchema>
 574
 575 =cut
 576
 577 1;
 578 # vim:et sts=4 sw=4 tw=0: