[dbsrgits/DBIx-Class-Schema-Loader.git] / lib / DBIx / Class / Schema / Loader / DBI / Pg.pm

package DBIx::Class::Schema::Loader::DBI::Pg;

use strict;
use warnings;
use base 'DBIx::Class::Schema::Loader::DBI::Component::QuotedDefault';
use mro 'c3';

our $VERSION = '0.07048_01';

=head1 NAME

DBIx::Class::Schema::Loader::DBI::Pg - DBIx::Class::Schema::Loader::DBI
PostgreSQL Implementation.

=head1 DESCRIPTION

See L<DBIx::Class::Schema::Loader> and L<DBIx::Class::Schema::Loader::Base>.

=cut

sub _setup {
    my $self = shift;

    $self->next::method(@_);

    $self->{db_schema} ||= ['public'];

    if (not defined $self->preserve_case) {
        $self->preserve_case(0);
    }
    elsif ($self->preserve_case) {
        $self->schema->storage->sql_maker->quote_char('"');
        $self->schema->storage->sql_maker->name_sep('.');
    }
}

sub _system_schemas {
    my $self = shift;

    return ($self->next::method(@_), 'pg_catalog');
}

my %pg_rules = (
    a => 'NO ACTION',
    r => 'RESTRICT',
    c => 'CASCADE',
    n => 'SET NULL',
    d => 'SET DEFAULT',
);

sub _table_fk_info {
    my ($self, $table) = @_;

    my $sth = $self->dbh->prepare_cached(<<"EOF");
      select constr.conname, to_ns.nspname, to_class.relname, from_col.attname, to_col.attname,
             constr.confdeltype, constr.confupdtype, constr.condeferrable
      from pg_catalog.pg_constraint constr
      join pg_catalog.pg_namespace from_ns on constr.connamespace = from_ns.oid
      join pg_catalog.pg_class from_class on constr.conrelid = from_class.oid and from_class.relnamespace = from_ns.oid
      join pg_catalog.pg_class to_class on constr.confrelid = to_class.oid
      join pg_catalog.pg_namespace to_ns on to_class.relnamespace = to_ns.oid
      -- can't do unnest() until 8.4, so join against a series table instead
      join pg_catalog.generate_series(1, pg_catalog.current_setting('max_index_keys')::integer) colnum(i)
           on colnum.i <= pg_catalog.array_upper(constr.conkey,1)
      join pg_catalog.pg_attribute to_col
           on to_col.attrelid = constr.confrelid
           and to_col.attnum = constr.confkey[colnum.i]
      join pg_catalog.pg_attribute from_col
           on from_col.attrelid = constr.conrelid
           and from_col.attnum = constr.conkey[colnum.i]
      where from_ns.nspname = ?
        and from_class.relname = ?
        and from_class.relkind = 'r'
        and constr.contype = 'f'
      order by constr.conname, colnum.i
EOF

    $sth->execute($table->schema, $table->name);

    my %rels;

    while (my ($fk, $remote_schema, $remote_table, $col, $remote_col,
               $delete_rule, $update_rule, $is_deferrable) = $sth->fetchrow_array) {
        push @{ $rels{$fk}{local_columns}  }, $self->_lc($col);
        push @{ $rels{$fk}{remote_columns} }, $self->_lc($remote_col);

        $rels{$fk}{remote_table} = DBIx::Class::Schema::Loader::Table->new(
            loader   => $self,
            name     => $remote_table,
            schema   => $remote_schema,
        ) unless exists $rels{$fk}{remote_table};

        $rels{$fk}{attrs} ||= {
            on_delete     => $pg_rules{$delete_rule},
            on_update     => $pg_rules{$update_rule},
            is_deferrable => $is_deferrable,
        };
    }

    return [ map { $rels{$_} } sort keys %rels ];
}


sub _table_uniq_info {
    my ($self, $table) = @_;

    # Use the default support if available
    return $self->next::method($table)
        if $DBD::Pg::VERSION >= 1.50;

    my @uniqs;

    # Most of the SQL here is mostly based on
    #   Rose::DB::Object::Metadata::Auto::Pg, after some prodding from
    #   John Siracusa to use his superior SQL code :)

    my $attr_sth = $self->{_cache}->{pg_attr_sth} ||= $self->dbh->prepare(
        q{SELECT attname FROM pg_catalog.pg_attribute
        WHERE attrelid = ? AND attnum = ?}
    );

    my $uniq_sth = $self->{_cache}->{pg_uniq_sth} ||= $self->dbh->prepare(
        q{SELECT x.indrelid, i.relname, x.indkey
        FROM
          pg_catalog.pg_index x
          JOIN pg_catalog.pg_class c ON c.oid = x.indrelid
          JOIN pg_catalog.pg_class i ON i.oid = x.indexrelid
          JOIN pg_catalog.pg_namespace n ON n.oid = c.relnamespace
        WHERE
          x.indisunique = 't' AND
          x.indpred     IS NULL AND
          c.relkind     = 'r' AND
          i.relkind     = 'i' AND
          n.nspname     = ? AND
          c.relname     = ?
        ORDER BY i.relname}
    );

    $uniq_sth->execute($table->schema, $table->name);
    while(my $row = $uniq_sth->fetchrow_arrayref) {
        my ($tableid, $indexname, $col_nums) = @$row;
        $col_nums =~ s/^\s+//;
        my @col_nums = split(/\s+/, $col_nums);
        my @col_names;

        foreach (@col_nums) {
            $attr_sth->execute($tableid, $_);
            my $name_aref = $attr_sth->fetchrow_arrayref;
            push(@col_names, $self->_lc($name_aref->[0])) if $name_aref;
        }

        # skip indexes with missing column names (e.g. expression indexes)
        if(@col_names == @col_nums) {
            push(@uniqs, [ $indexname => \@col_names ]);
        }
    }

    return \@uniqs;
}

sub _table_comment {
    my $self = shift;
    my ($table) = @_;

    my $table_comment = $self->next::method(@_);

    return $table_comment if $table_comment;

    ($table_comment) = $self->dbh->selectrow_array(<<'EOF', {}, $table->name, $table->schema);
SELECT pg_catalog.obj_description(oid)
FROM pg_catalog.pg_class
WHERE relname=? AND relnamespace=(SELECT oid FROM pg_catalog.pg_namespace WHERE nspname=?)
EOF

    return $table_comment
}


sub _column_comment {
    my $self = shift;
    my ($table, $column_number, $column_name) = @_;

    my $column_comment = $self->next::method(@_);

    return $column_comment if $column_comment;

    return $self->dbh->selectrow_array(<<'EOF', {}, $column_number, $table->name, $table->schema);
SELECT pg_catalog.col_description(oid, ?)
FROM pg_catalog.pg_class
WHERE relname=? AND relnamespace=(SELECT oid FROM pg_catalog.pg_namespace WHERE nspname=?)
EOF
}

# Make sure data_type's that don't need it don't have a 'size' column_info, and
# set the correct precision for datetime and varbit types.
sub _columns_info_for {
    my $self = shift;
    my ($table) = @_;

    my ($result, $raw) = $self->next::method(@_);

    while (my ($col, $info) = each %$result) {
        my $data_type = $info->{data_type};

        # these types are fixed size
        # XXX should this be a negative match?
        if ($data_type =~
/^(?:bigint|int8|bigserial|serial8|bool(?:ean)?|box|bytea|cidr|circle|date|double precision|float8|inet|integer|int|int4|line|lseg|macaddr|money|path|point|polygon|real|float4|smallint|int2|serial|serial4|text)\z/i) {
            delete $info->{size};
        }
# for datetime types, check if it has a precision or not
        elsif ($data_type =~ /^(?:interval|time|timestamp)\b/i) {
            if (lc($data_type) eq 'timestamp without time zone') {
                $info->{data_type} = 'timestamp';
            }
            elsif (lc($data_type) eq 'time without time zone') {
                $info->{data_type} = 'time';
            }

            my ($precision) = $self->schema->storage->dbh
                ->selectrow_array(<<EOF, {}, $table->name, $col);
SELECT datetime_precision
FROM information_schema.columns
WHERE table_name = ? and column_name = ?
EOF

            if ($data_type =~ /^time\b/i) {
                if ((not defined $precision) || $precision !~ /^\d/) {
                    delete $info->{size};
                }
                else {
                    my ($integer_datetimes) = $self->dbh
                        ->selectrow_array('show integer_datetimes');

                    my $max_precision =
                        $integer_datetimes =~ /^on\z/i ? 6 : 10;

                    if ($precision == $max_precision) {
                        delete $info->{size};
                    }
                    else {
                        $info->{size} = $precision;
                    }
                }
            }
            elsif ((not defined $precision) || $precision !~ /^\d/ || $precision == 6) {
                delete $info->{size};
            }
            else {
                $info->{size} = $precision;
            }
        }
        elsif ($data_type =~ /^(?:bit(?: varying)?|varbit)\z/i) {
            $info->{data_type} = 'varbit' if $data_type =~ /var/i;

            my ($precision) = $self->dbh->selectrow_array(<<EOF, {}, $table->name, $col);
SELECT character_maximum_length
FROM information_schema.columns
WHERE table_name = ? and column_name = ?
EOF

            $info->{size} = $precision if $precision;

            $info->{size} = 1 if (not $precision) && lc($data_type) eq 'bit';
        }
        elsif ($data_type =~ /^(?:numeric|decimal)\z/i && (my $size = $info->{size})) {
            $size =~ s/\s*//g;

            my ($scale, $precision) = split /,/, $size;

            $info->{size} = [ $precision, $scale ];
        }
        elsif (lc($data_type) eq 'character varying') {
            $info->{data_type} = 'varchar';

            if (not $info->{size}) {
                $info->{data_type}           = 'text';
                $info->{original}{data_type} = 'varchar';
            }
        }
        elsif (lc($data_type) eq 'character') {
            $info->{data_type} = 'char';
        }
        # DBD::Pg < 3.5.2 can get the order wrong on Pg >= 9.1.0
        elsif (
            ($DBD::Pg::VERSION >= 3.005002 or $self->dbh->{pg_server_version} < 90100)
                and
            my $values = $raw->{$col}->{pg_enum_values}
        ) {
            $info->{extra}{list} = $values;

            # Store its original name in extra for SQLT to pick up.
            $info->{extra}{custom_type_name} = $info->{data_type};

            $info->{data_type} = 'enum';

            delete $info->{size};
        }
        else  {
            my ($typetype) = $self->schema->storage->dbh
                ->selectrow_array(<<EOF, {}, $data_type);
SELECT typtype
FROM pg_catalog.pg_type
WHERE oid = ?::regtype
EOF
            if ($typetype && $typetype eq 'e') {
                # The following will extract a list of allowed values for the enum.
                my $order_column = $self->dbh->{pg_server_version} >= 90100 ? 'enumsortorder' : 'oid';
                $info->{extra}{list} = $self->dbh
                    ->selectcol_arrayref(<<EOF, {}, $data_type);
SELECT e.enumlabel
FROM pg_catalog.pg_enum e
WHERE e.enumtypid = ?::regtype
ORDER BY e.$order_column
EOF

                # Store its original name in extra for SQLT to pick up.
                $info->{extra}{custom_type_name} = $data_type;

                $info->{data_type} = 'enum';

                delete $info->{size};
            }
        }

        if (ref($info->{default_value}) eq 'SCALAR') {
            # process SERIAL columns
            if (${ $info->{default_value} } =~ /\bnextval\('([^:]+)'/i) {
                $info->{is_auto_increment} = 1;
                $info->{sequence}          = $1;
                delete $info->{default_value};
            }
            # alias now() to current_timestamp for deploying to other DBs
            elsif (lc ${ $info->{default_value} } eq 'now()') {
                # do not use a ref to a constant, that breaks Data::Dump output
                ${$info->{default_value}} = 'current_timestamp';

                my $now = 'now()';
                $info->{original}{default_value} = \$now;
            }
            elsif (${ $info->{default_value} } =~ /\bCURRENT_TIMESTAMP\b/) {
                # PostgreSQL v10 upcases current_timestamp in default values
                ${ $info->{default_value} } =~ s/\b(CURRENT_TIMESTAMP)\b/lc $1/ge;
            }
        }

        # detect 0/1 for booleans and rewrite
        if ($data_type =~ /^bool/i && exists $info->{default_value}) {
            if ($info->{default_value} eq '0') {
                my $false = 'false';
                $info->{default_value} = \$false;
            }
            elsif ($info->{default_value} eq '1') {
                my $true = 'true';
                $info->{default_value} = \$true;
            }
        }
    }

    return $result;
}

sub _view_definition {
    my ($self, $view) = @_;

    my $def =  $self->schema->storage->dbh->selectrow_array(<<'EOF', {}, $view->schema, $view->name);
SELECT pg_catalog.pg_get_viewdef(oid)
FROM pg_catalog.pg_class
WHERE relnamespace = (SELECT OID FROM pg_catalog.pg_namespace WHERE nspname = ?)
AND relname = ?
EOF
    # The definition is returned as a complete statement including the
    # trailing semicolon, but that's not allowed in CREATE VIEW, so
    # strip it out
    $def =~ s/\s*;\s*\z//;
    return $def;
}

=head1 SEE ALSO

L<DBIx::Class::Schema::Loader>, L<DBIx::Class::Schema::Loader::Base>,
L<DBIx::Class::Schema::Loader::DBI>

=head1 AUTHORS

See L<DBIx::Class::Schema::Loader/AUTHORS>.

=head1 LICENSE

This library is free software; you can redistribute it and/or modify it under
the same terms as Perl itself.

=cut

1;
Commit	Line	Data
996be9ee	1	package DBIx::Class::Schema::Loader::DBI::Pg;
	2
	3	use strict;
	4	use warnings;
383bd2a8	5	use base 'DBIx::Class::Schema::Loader::DBI::Component::QuotedDefault';
942bd5e0	6	use mro 'c3';
996be9ee	7
46564a42	8	our $VERSION = '0.07048_01';
32f784fc	9
996be9ee	10	=head1 NAME
996be9ee	11
8f9d7ce5	12	DBIx::Class::Schema::Loader::DBI::Pg - DBIx::Class::Schema::Loader::DBI
8f9d7ce5	13	PostgreSQL Implementation.
996be9ee	14
996be9ee	15	=head1 DESCRIPTION
996be9ee	16
c4a69b87	17	See L<DBIx::Class::Schema::Loader> and L<DBIx::Class::Schema::Loader::Base>.
996be9ee	18
	19	=cut
	20
	21	sub _setup {
	22	my $self = shift;
	23
	24	$self->next::method(@_);
bc1cb85e	25
c4a69b87	26	$self->{db_schema} \|\|= ['public'];
996be9ee	27
bc1cb85e	28	if (not defined $self->preserve_case) {
	29	$self->preserve_case(0);
	30	}
c930f78b	31	elsif ($self->preserve_case) {
	32	$self->schema->storage->sql_maker->quote_char('"');
	33	$self->schema->storage->sql_maker->name_sep('.');
	34	}
bc1cb85e	35	}
fbcfebdd	36
c4a69b87	37	sub _system_schemas {
c4a69b87	38	my $self = shift;
12b86f07	39
c4a69b87	40	return ($self->next::method(@_), 'pg_catalog');
12b86f07	41	}
12b86f07	42
f839d33b	43	my %pg_rules = (
	44	a => 'NO ACTION',
	45	r => 'RESTRICT',
2e86a3e6	46	c => 'CASCADE',
f839d33b	47	n => 'SET NULL',
	48	d => 'SET DEFAULT',
	49	);
	50
958d5fcf	51	sub _table_fk_info {
	52	my ($self, $table) = @_;
	53
	54	my $sth = $self->dbh->prepare_cached(<<"EOF");
b5f68cbe	55	select constr.conname, to_ns.nspname, to_class.relname, from_col.attname, to_col.attname,
b5f68cbe	56	constr.confdeltype, constr.confupdtype, constr.condeferrable
764b262a	57	from pg_catalog.pg_constraint constr
	58	join pg_catalog.pg_namespace from_ns on constr.connamespace = from_ns.oid
	59	join pg_catalog.pg_class from_class on constr.conrelid = from_class.oid and from_class.relnamespace = from_ns.oid
	60	join pg_catalog.pg_class to_class on constr.confrelid = to_class.oid
	61	join pg_catalog.pg_namespace to_ns on to_class.relnamespace = to_ns.oid
b5f68cbe	62	-- can't do unnest() until 8.4, so join against a series table instead
764b262a	63	join pg_catalog.generate_series(1, pg_catalog.current_setting('max_index_keys')::integer) colnum(i)
764b262a	64	on colnum.i <= pg_catalog.array_upper(constr.conkey,1)
b5f68cbe	65	join pg_catalog.pg_attribute to_col
	66	on to_col.attrelid = constr.confrelid
	67	and to_col.attnum = constr.confkey[colnum.i]
	68	join pg_catalog.pg_attribute from_col
	69	on from_col.attrelid = constr.conrelid
	70	and from_col.attnum = constr.conkey[colnum.i]
f839d33b	71	where from_ns.nspname = ?
	72	and from_class.relname = ?
	73	and from_class.relkind = 'r'
	74	and constr.contype = 'f'
b5f68cbe	75	order by constr.conname, colnum.i
958d5fcf	76	EOF
958d5fcf	77
f839d33b	78	$sth->execute($table->schema, $table->name);
958d5fcf	79
	80	my %rels;
	81
	82	while (my ($fk, $remote_schema, $remote_table, $col, $remote_col,
	83	$delete_rule, $update_rule, $is_deferrable) = $sth->fetchrow_array) {
	84	push @{ $rels{$fk}{local_columns} }, $self->_lc($col);
	85	push @{ $rels{$fk}{remote_columns} }, $self->_lc($remote_col);
	86
	87	$rels{$fk}{remote_table} = DBIx::Class::Schema::Loader::Table->new(
	88	loader => $self,
	89	name => $remote_table,
	90	schema => $remote_schema,
	91	) unless exists $rels{$fk}{remote_table};
	92
b9762446	93	$rels{$fk}{attrs} \|\|= {
f839d33b	94	on_delete => $pg_rules{$delete_rule},
	95	on_update => $pg_rules{$update_rule},
	96	is_deferrable => $is_deferrable,
b9762446	97	};
958d5fcf	98	}
958d5fcf	99
9fc706c1	100	return [ map { $rels{$_} } sort keys %rels ];
958d5fcf	101	}
	102
	103
996be9ee	104	sub _table_uniq_info {
	105	my ($self, $table) = @_;
	106
fd589700	107	# Use the default support if available
fd589700	108	return $self->next::method($table)
79fe0081	109	if $DBD::Pg::VERSION >= 1.50;
fd589700	110
996be9ee	111	my @uniqs;
996be9ee	112
5223f24a	113	# Most of the SQL here is mostly based on
	114	# Rose::DB::Object::Metadata::Auto::Pg, after some prodding from
	115	# John Siracusa to use his superior SQL code :)
	116
c4a69b87	117	my $attr_sth = $self->{_cache}->{pg_attr_sth} \|\|= $self->dbh->prepare(
5223f24a	118	q{SELECT attname FROM pg_catalog.pg_attribute
	119	WHERE attrelid = ? AND attnum = ?}
	120	);
	121
c4a69b87	122	my $uniq_sth = $self->{_cache}->{pg_uniq_sth} \|\|= $self->dbh->prepare(
5223f24a	123	q{SELECT x.indrelid, i.relname, x.indkey
	124	FROM
	125	pg_catalog.pg_index x
	126	JOIN pg_catalog.pg_class c ON c.oid = x.indrelid
	127	JOIN pg_catalog.pg_class i ON i.oid = x.indexrelid
a01ac8ee	128	JOIN pg_catalog.pg_namespace n ON n.oid = c.relnamespace
5223f24a	129	WHERE
5223f24a	130	x.indisunique = 't' AND
a01ac8ee	131	x.indpred IS NULL AND
5223f24a	132	c.relkind = 'r' AND
5223f24a	133	i.relkind = 'i' AND
5223f24a	134	n.nspname = ? AND
6c4f5a4a	135	c.relname = ?
6c4f5a4a	136	ORDER BY i.relname}
5223f24a	137	);
5223f24a	138
116431d6	139	$uniq_sth->execute($table->schema, $table->name);
5223f24a	140	while(my $row = $uniq_sth->fetchrow_arrayref) {
	141	my ($tableid, $indexname, $col_nums) = @$row;
	142	$col_nums =~ s/^\s+//;
	143	my @col_nums = split(/\s+/, $col_nums);
	144	my @col_names;
	145
	146	foreach (@col_nums) {
	147	$attr_sth->execute($tableid, $_);
	148	my $name_aref = $attr_sth->fetchrow_arrayref;
116431d6	149	push(@col_names, $self->_lc($name_aref->[0])) if $name_aref;
996be9ee	150	}
5223f24a	151
a01ac8ee	152	# skip indexes with missing column names (e.g. expression indexes)
a01ac8ee	153	if(@col_names == @col_nums) {
5223f24a	154	push(@uniqs, [ $indexname => \@col_names ]);
996be9ee	155	}
	156	}
	157
	158	return \@uniqs;
	159	}
	160
fbcfebdd	161	sub _table_comment {
c4a69b87	162	my $self = shift;
	163	my ($table) = @_;
	164
	165	my $table_comment = $self->next::method(@_);
	166
	167	return $table_comment if $table_comment;
	168
	169	($table_comment) = $self->dbh->selectrow_array(<<'EOF', {}, $table->name, $table->schema);
764b262a	170	SELECT pg_catalog.obj_description(oid)
	171	FROM pg_catalog.pg_class
	172	WHERE relname=? AND relnamespace=(SELECT oid FROM pg_catalog.pg_namespace WHERE nspname=?)
c4a69b87	173	EOF
c4a69b87	174
fbcfebdd	175	return $table_comment
	176	}
	177
	178
	179	sub _column_comment {
c4a69b87	180	my $self = shift;
	181	my ($table, $column_number, $column_name) = @_;
	182
	183	my $column_comment = $self->next::method(@_);
	184
	185	return $column_comment if $column_comment;
	186
f8791d9f	187	return $self->dbh->selectrow_array(<<'EOF', {}, $column_number, $table->name, $table->schema);
f8791d9f	188	SELECT pg_catalog.col_description(oid, ?)
764b262a	189	FROM pg_catalog.pg_class
764b262a	190	WHERE relname=? AND relnamespace=(SELECT oid FROM pg_catalog.pg_namespace WHERE nspname=?)
c4a69b87	191	EOF
fbcfebdd	192	}
fbcfebdd	193
baff904e	194	# Make sure data_type's that don't need it don't have a 'size' column_info, and
afb4c5bc	195	# set the correct precision for datetime and varbit types.
baff904e	196	sub _columns_info_for {
	197	my $self = shift;
	198	my ($table) = @_;
	199
afa71a98	200	my ($result, $raw) = $self->next::method(@_);
baff904e	201
f80b0ea7	202	while (my ($col, $info) = each %$result) {
f80b0ea7	203	my $data_type = $info->{data_type};
baff904e	204
baff904e	205	# these types are fixed size
7640ef4b	206	# XXX should this be a negative match?
baff904e	207	if ($data_type =~
96336646	208	/^(?:bigint\|int8\|bigserial\|serial8\|bool(?:ean)?\|box\|bytea\|cidr\|circle\|date\|double precision\|float8\|inet\|integer\|int\|int4\|line\|lseg\|macaddr\|money\|path\|point\|polygon\|real\|float4\|smallint\|int2\|serial\|serial4\|text)\z/i) {
f80b0ea7	209	delete $info->{size};
baff904e	210	}
afb4c5bc	211	# for datetime types, check if it has a precision or not
43b982ea	212	elsif ($data_type =~ /^(?:interval\|time\|timestamp)\b/i) {
f80b0ea7	213	if (lc($data_type) eq 'timestamp without time zone') {
	214	$info->{data_type} = 'timestamp';
	215	}
8e030521	216	elsif (lc($data_type) eq 'time without time zone') {
	217	$info->{data_type} = 'time';
	218	}
f80b0ea7	219
baff904e	220	my ($precision) = $self->schema->storage->dbh
116431d6	221	->selectrow_array(<<EOF, {}, $table->name, $col);
baff904e	222	SELECT datetime_precision
	223	FROM information_schema.columns
	224	WHERE table_name = ? and column_name = ?
	225	EOF
	226
5f85388e	227	if ($data_type =~ /^time\b/i) {
a6fd0a48	228	if ((not defined $precision) \|\| $precision !~ /^\d/) {
f80b0ea7	229	delete $info->{size};
5f85388e	230	}
5f85388e	231	else {
c4a69b87	232	my ($integer_datetimes) = $self->dbh
5f85388e	233	->selectrow_array('show integer_datetimes');
	234
	235	my $max_precision =
	236	$integer_datetimes =~ /^on\z/i ? 6 : 10;
	237
	238	if ($precision == $max_precision) {
f80b0ea7	239	delete $info->{size};
5f85388e	240	}
5f85388e	241	else {
f80b0ea7	242	$info->{size} = $precision;
5f85388e	243	}
	244	}
	245	}
a6fd0a48	246	elsif ((not defined $precision) \|\| $precision !~ /^\d/ \|\| $precision == 6) {
f80b0ea7	247	delete $info->{size};
baff904e	248	}
baff904e	249	else {
f80b0ea7	250	$info->{size} = $precision;
baff904e	251	}
baff904e	252	}
f80b0ea7	253	elsif ($data_type =~ /^(?:bit(?: varying)?\|varbit)\z/i) {
	254	$info->{data_type} = 'varbit' if $data_type =~ /var/i;
	255
116431d6	256	my ($precision) = $self->dbh->selectrow_array(<<EOF, {}, $table->name, $col);
afb4c5bc	257	SELECT character_maximum_length
	258	FROM information_schema.columns
	259	WHERE table_name = ? and column_name = ?
	260	EOF
	261
f80b0ea7	262	$info->{size} = $precision if $precision;
	263
	264	$info->{size} = 1 if (not $precision) && lc($data_type) eq 'bit';
afb4c5bc	265	}
f80b0ea7	266	elsif ($data_type =~ /^(?:numeric\|decimal)\z/i && (my $size = $info->{size})) {
d4d1a665	267	$size =~ s/\s*//g;
	268
	269	my ($scale, $precision) = split /,/, $size;
	270
f80b0ea7	271	$info->{size} = [ $precision, $scale ];
	272	}
	273	elsif (lc($data_type) eq 'character varying') {
	274	$info->{data_type} = 'varchar';
	275
8e030521	276	if (not $info->{size}) {
	277	$info->{data_type} = 'text';
	278	$info->{original}{data_type} = 'varchar';
	279	}
f80b0ea7	280	}
	281	elsif (lc($data_type) eq 'character') {
	282	$info->{data_type} = 'char';
d4d1a665	283	}
afa71a98	284	# DBD::Pg < 3.5.2 can get the order wrong on Pg >= 9.1.0
	285	elsif (
	286	($DBD::Pg::VERSION >= 3.005002 or $self->dbh->{pg_server_version} < 90100)
	287	and
	288	my $values = $raw->{$col}->{pg_enum_values}
	289	) {
	290	$info->{extra}{list} = $values;
	291
	292	# Store its original name in extra for SQLT to pick up.
	293	$info->{extra}{custom_type_name} = $info->{data_type};
	294
	295	$info->{data_type} = 'enum';
	296
	297	delete $info->{size};
	298	}
	299	else {
12333562	300	my ($typetype) = $self->schema->storage->dbh
	301	->selectrow_array(<<EOF, {}, $data_type);
	302	SELECT typtype
	303	FROM pg_catalog.pg_type
a07eab0a	304	WHERE oid = ?::regtype
12333562	305	EOF
c4a69b87	306	if ($typetype && $typetype eq 'e') {
a47f63fb	307	# The following will extract a list of allowed values for the enum.
9fc706c1	308	my $order_column = $self->dbh->{pg_server_version} >= 90100 ? 'enumsortorder' : 'oid';
a47f63fb	309	$info->{extra}{list} = $self->dbh
a07eab0a	310	->selectcol_arrayref(<<EOF, {}, $data_type);
463c86fb	311	SELECT e.enumlabel
463c86fb	312	FROM pg_catalog.pg_enum e
a07eab0a	313	WHERE e.enumtypid = ?::regtype
9fc706c1	314	ORDER BY e.$order_column
463c86fb	315	EOF
463c86fb	316
463c86fb	317	# Store its original name in extra for SQLT to pick up.
a07eab0a	318	$info->{extra}{custom_type_name} = $data_type;
463c86fb	319
12333562	320	$info->{data_type} = 'enum';
958d5fcf	321
463c86fb	322	delete $info->{size};
12333562	323	}
	324	}
	325
a64b98ad	326	if (ref($info->{default_value}) eq 'SCALAR') {
	327	# process SERIAL columns
	328	if (${ $info->{default_value} } =~ /\bnextval\('([^:]+)'/i) {
	329	$info->{is_auto_increment} = 1;
	330	$info->{sequence} = $1;
	331	delete $info->{default_value};
	332	}
	333	# alias now() to current_timestamp for deploying to other DBs
	334	elsif (lc ${ $info->{default_value} } eq 'now()') {
	335	# do not use a ref to a constant, that breaks Data::Dump output
	336	${$info->{default_value}} = 'current_timestamp';
701cd3e3	337
a64b98ad	338	my $now = 'now()';
	339	$info->{original}{default_value} = \$now;
	340	}
ed566bb0	341	elsif (${ $info->{default_value} } =~ /\bCURRENT_TIMESTAMP\b/) {
	342	# PostgreSQL v10 upcases current_timestamp in default values
	343	${ $info->{default_value} } =~ s/\b(CURRENT_TIMESTAMP)\b/lc $1/ge;
	344	}
8e64075f	345	}
96336646	346
a64b98ad	347	# detect 0/1 for booleans and rewrite
96336646	348	if ($data_type =~ /^bool/i && exists $info->{default_value}) {
	349	if ($info->{default_value} eq '0') {
	350	my $false = 'false';
	351	$info->{default_value} = \$false;
	352	}
	353	elsif ($info->{default_value} eq '1') {
	354	my $true = 'true';
	355	$info->{default_value} = \$true;
	356	}
	357	}
a8df0345	358	}
a8df0345	359
df956aad	360	return $result;
78b7ccaa	361	}
78b7ccaa	362
d7e0e0e8	363	sub _view_definition {
	364	my ($self, $view) = @_;
	365
	366	my $def = $self->schema->storage->dbh->selectrow_array(<<'EOF', {}, $view->schema, $view->name);
	367	SELECT pg_catalog.pg_get_viewdef(oid)
	368	FROM pg_catalog.pg_class
	369	WHERE relnamespace = (SELECT OID FROM pg_catalog.pg_namespace WHERE nspname = ?)
	370	AND relname = ?
	371	EOF
	372	# The definition is returned as a complete statement including the
	373	# trailing semicolon, but that's not allowed in CREATE VIEW, so
	374	# strip it out
	375	$def =~ s/\s;\s\z//;
	376	return $def;
	377	}
	378
996be9ee	379	=head1 SEE ALSO
	380
	381	L<DBIx::Class::Schema::Loader>, L<DBIx::Class::Schema::Loader::Base>,
	382	L<DBIx::Class::Schema::Loader::DBI>
	383
b87ab391	384	=head1 AUTHORS
be80bba7	385
b87ab391	386	See L<DBIx::Class::Schema::Loader/AUTHORS>.
be80bba7	387
	388	=head1 LICENSE
	389
	390	This library is free software; you can redistribute it and/or modify it under
	391	the same terms as Perl itself.
	392
996be9ee	393	=cut
	394
	395	1;