[dbsrgits/DBIx-Class-Schema-Loader.git] / lib / DBIx / Class / Schema / Loader / DBI / Pg.pm

package DBIx::Class::Schema::Loader::DBI::Pg;

use strict;
use warnings;
use base 'DBIx::Class::Schema::Loader::DBI::Component::QuotedDefault';
use mro 'c3';

our $VERSION = '0.07039';

=head1 NAME

DBIx::Class::Schema::Loader::DBI::Pg - DBIx::Class::Schema::Loader::DBI
PostgreSQL Implementation.

=head1 DESCRIPTION

See L<DBIx::Class::Schema::Loader> and L<DBIx::Class::Schema::Loader::Base>.

=cut

sub _setup {
    my $self = shift;

    $self->next::method(@_);

    $self->{db_schema} ||= ['public'];

    if (not defined $self->preserve_case) {
        $self->preserve_case(0);
    }
    elsif ($self->preserve_case) {
        $self->schema->storage->sql_maker->quote_char('"');
        $self->schema->storage->sql_maker->name_sep('.');
    }
}

sub _system_schemas {
    my $self = shift;

    return ($self->next::method(@_), 'pg_catalog');
}

my %pg_rules = (
    a => 'NO ACTION',
    r => 'RESTRICT',
    c => 'CASCADE',
    n => 'SET NULL',
    d => 'SET DEFAULT',
);

sub _table_fk_info {
    my ($self, $table) = @_;

    my $sth = $self->dbh->prepare_cached(<<"EOF");
      select constr.conname, to_ns.nspname, to_class.relname, from_col.attname, to_col.attname,
             constr.confdeltype, constr.confupdtype, constr.condeferrable
      from pg_catalog.pg_constraint constr
      join pg_catalog.pg_namespace from_ns on constr.connamespace = from_ns.oid
      join pg_catalog.pg_class from_class on constr.conrelid = from_class.oid and from_class.relnamespace = from_ns.oid
      join pg_catalog.pg_class to_class on constr.confrelid = to_class.oid
      join pg_catalog.pg_namespace to_ns on to_class.relnamespace = to_ns.oid
      -- can't do unnest() until 8.4, so join against a series table instead
      join pg_catalog.generate_series(1, pg_catalog.current_setting('max_index_keys')::integer) colnum(i)
           on colnum.i <= pg_catalog.array_upper(constr.conkey,1)
      join pg_catalog.pg_attribute to_col
           on to_col.attrelid = constr.confrelid
           and to_col.attnum = constr.confkey[colnum.i]
      join pg_catalog.pg_attribute from_col
           on from_col.attrelid = constr.conrelid
           and from_col.attnum = constr.conkey[colnum.i]
      where from_ns.nspname = ?
        and from_class.relname = ?
        and from_class.relkind = 'r'
        and constr.contype = 'f'
      order by constr.conname, colnum.i
EOF

    $sth->execute($table->schema, $table->name);

    my %rels;

    while (my ($fk, $remote_schema, $remote_table, $col, $remote_col,
               $delete_rule, $update_rule, $is_deferrable) = $sth->fetchrow_array) {
        push @{ $rels{$fk}{local_columns}  }, $self->_lc($col);
        push @{ $rels{$fk}{remote_columns} }, $self->_lc($remote_col);

        $rels{$fk}{remote_table} = DBIx::Class::Schema::Loader::Table->new(
            loader   => $self,
            name     => $remote_table,
            schema   => $remote_schema,
        ) unless exists $rels{$fk}{remote_table};

        $rels{$fk}{attrs} ||= {
            on_delete     => $pg_rules{$delete_rule},
            on_update     => $pg_rules{$update_rule},
            is_deferrable => $is_deferrable,
        };
    }

    return [ map { $rels{$_} } sort keys %rels ];
}


sub _table_uniq_info {
    my ($self, $table) = @_;

    # Use the default support if available
    return $self->next::method($table)
        if $DBD::Pg::VERSION >= 1.50;

    my @uniqs;

    # Most of the SQL here is mostly based on
    #   Rose::DB::Object::Metadata::Auto::Pg, after some prodding from
    #   John Siracusa to use his superior SQL code :)

    my $attr_sth = $self->{_cache}->{pg_attr_sth} ||= $self->dbh->prepare(
        q{SELECT attname FROM pg_catalog.pg_attribute
        WHERE attrelid = ? AND attnum = ?}
    );

    my $uniq_sth = $self->{_cache}->{pg_uniq_sth} ||= $self->dbh->prepare(
        q{SELECT x.indrelid, i.relname, x.indkey
        FROM
          pg_catalog.pg_index x
          JOIN pg_catalog.pg_class c ON c.oid = x.indrelid
          JOIN pg_catalog.pg_class i ON i.oid = x.indexrelid
          JOIN pg_catalog.pg_namespace n ON n.oid = c.relnamespace
        WHERE
          x.indisunique = 't' AND
          x.indpred     IS NULL AND
          c.relkind     = 'r' AND
          i.relkind     = 'i' AND
          n.nspname     = ? AND
          c.relname     = ?}
    );

    $uniq_sth->execute($table->schema, $table->name);
    while(my $row = $uniq_sth->fetchrow_arrayref) {
        my ($tableid, $indexname, $col_nums) = @$row;
        $col_nums =~ s/^\s+//;
        my @col_nums = split(/\s+/, $col_nums);
        my @col_names;

        foreach (@col_nums) {
            $attr_sth->execute($tableid, $_);
            my $name_aref = $attr_sth->fetchrow_arrayref;
            push(@col_names, $self->_lc($name_aref->[0])) if $name_aref;
        }

        # skip indexes with missing column names (e.g. expression indexes)
        if(@col_names == @col_nums) {
            push(@uniqs, [ $indexname => \@col_names ]);
        }
    }

    return \@uniqs;
}

sub _table_comment {
    my $self = shift;
    my ($table) = @_;

    my $table_comment = $self->next::method(@_);

    return $table_comment if $table_comment;

    ($table_comment) = $self->dbh->selectrow_array(<<'EOF', {}, $table->name, $table->schema);
SELECT pg_catalog.obj_description(oid)
FROM pg_catalog.pg_class
WHERE relname=? AND relnamespace=(SELECT oid FROM pg_catalog.pg_namespace WHERE nspname=?)
EOF

    return $table_comment
}


sub _column_comment {
    my $self = shift;
    my ($table, $column_number, $column_name) = @_;

    my $column_comment = $self->next::method(@_);

    return $column_comment if $column_comment;

    my ($table_oid) = $self->dbh->selectrow_array(<<'EOF', {}, $table->name, $table->schema);
SELECT oid
FROM pg_catalog.pg_class
WHERE relname=? AND relnamespace=(SELECT oid FROM pg_catalog.pg_namespace WHERE nspname=?)
EOF

    return $self->dbh->selectrow_array('SELECT pg_catalog.col_description(?,?)', {}, $table_oid, $column_number);
}

# Make sure data_type's that don't need it don't have a 'size' column_info, and
# set the correct precision for datetime and varbit types.
sub _columns_info_for {
    my $self = shift;
    my ($table) = @_;

    my $result = $self->next::method(@_);

    while (my ($col, $info) = each %$result) {
        my $data_type = $info->{data_type};

        # these types are fixed size
        # XXX should this be a negative match?
        if ($data_type =~
/^(?:bigint|int8|bigserial|serial8|bool(?:ean)?|box|bytea|cidr|circle|date|double precision|float8|inet|integer|int|int4|line|lseg|macaddr|money|path|point|polygon|real|float4|smallint|int2|serial|serial4|text)\z/i) {
            delete $info->{size};
        }
# for datetime types, check if it has a precision or not
        elsif ($data_type =~ /^(?:interval|time|timestamp)\b/i) {
            if (lc($data_type) eq 'timestamp without time zone') {
                $info->{data_type} = 'timestamp';
            }
            elsif (lc($data_type) eq 'time without time zone') {
                $info->{data_type} = 'time';
            }

            my ($precision) = $self->schema->storage->dbh
                ->selectrow_array(<<EOF, {}, $table->name, $col);
SELECT datetime_precision
FROM information_schema.columns
WHERE table_name = ? and column_name = ?
EOF

            if ($data_type =~ /^time\b/i) {
                if ((not $precision) || $precision !~ /^\d/) {
                    delete $info->{size};
                }
                else {
                    my ($integer_datetimes) = $self->dbh
                        ->selectrow_array('show integer_datetimes');

                    my $max_precision =
                        $integer_datetimes =~ /^on\z/i ? 6 : 10;

                    if ($precision == $max_precision) {
                        delete $info->{size};
                    }
                    else {
                        $info->{size} = $precision;
                    }
                }
            }
            elsif ((not $precision) || $precision !~ /^\d/ || $precision == 6) {
                delete $info->{size};
            }
            else {
                $info->{size} = $precision;
            }
        }
        elsif ($data_type =~ /^(?:bit(?: varying)?|varbit)\z/i) {
            $info->{data_type} = 'varbit' if $data_type =~ /var/i;

            my ($precision) = $self->dbh->selectrow_array(<<EOF, {}, $table->name, $col);
SELECT character_maximum_length
FROM information_schema.columns
WHERE table_name = ? and column_name = ?
EOF

            $info->{size} = $precision if $precision;

            $info->{size} = 1 if (not $precision) && lc($data_type) eq 'bit';
        }
        elsif ($data_type =~ /^(?:numeric|decimal)\z/i && (my $size = $info->{size})) {
            $size =~ s/\s*//g;

            my ($scale, $precision) = split /,/, $size;

            $info->{size} = [ $precision, $scale ];
        }
        elsif (lc($data_type) eq 'character varying') {
            $info->{data_type} = 'varchar';

            if (not $info->{size}) {
                $info->{data_type}           = 'text';
                $info->{original}{data_type} = 'varchar';
            }
        }
        elsif (lc($data_type) eq 'character') {
            $info->{data_type} = 'char';
        }
        else {
            my ($typetype) = $self->schema->storage->dbh
                ->selectrow_array(<<EOF, {}, $data_type);
SELECT typtype
FROM pg_catalog.pg_type
WHERE typname = ?
EOF
            if ($typetype && $typetype eq 'e') {
                # The following will extract a list of allowed values for the
                # enum.
                my $order_column = $self->dbh->{pg_server_version} >= 90100 ? 'enumsortorder' : 'oid';
                my $typevalues = $self->dbh
                    ->selectall_arrayref(<<EOF, {}, $info->{data_type});
SELECT e.enumlabel
FROM pg_catalog.pg_enum e
JOIN pg_catalog.pg_type t ON t.oid = e.enumtypid
WHERE t.typname = ?
ORDER BY e.$order_column
EOF

                $info->{extra}{list} = [ map { $_->[0] } @$typevalues ];

                # Store its original name in extra for SQLT to pick up.
                $info->{extra}{custom_type_name} = $info->{data_type};

                $info->{data_type} = 'enum';

                delete $info->{size};
            }
        }

# process SERIAL columns
        if (ref($info->{default_value}) eq 'SCALAR'
                && ${ $info->{default_value} } =~ /\bnextval\('([^:]+)'/i) {
            $info->{is_auto_increment} = 1;
            $info->{sequence}          = $1;
            delete $info->{default_value};
        }

# alias now() to current_timestamp for deploying to other DBs
        if ((eval { lc ${ $info->{default_value} } }||'') eq 'now()') {
            # do not use a ref to a constant, that breaks Data::Dump output
            ${$info->{default_value}} = 'current_timestamp';

            my $now = 'now()';
            $info->{original}{default_value} = \$now;
        }

# detect 0/1 for booleans and rewrite
        if ($data_type =~ /^bool/i && exists $info->{default_value}) {
            if ($info->{default_value} eq '0') {
                my $false = 'false';
                $info->{default_value} = \$false;
            }
            elsif ($info->{default_value} eq '1') {
                my $true = 'true';
                $info->{default_value} = \$true;
            }
        }
    }

    return $result;
}

=head1 SEE ALSO

L<DBIx::Class::Schema::Loader>, L<DBIx::Class::Schema::Loader::Base>,
L<DBIx::Class::Schema::Loader::DBI>

=head1 AUTHOR

See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.

=head1 LICENSE

This library is free software; you can redistribute it and/or modify it under
the same terms as Perl itself.

=cut

1;
Commit	Line	Data
996be9ee	1	package DBIx::Class::Schema::Loader::DBI::Pg;
	2
	3	use strict;
	4	use warnings;
383bd2a8	5	use base 'DBIx::Class::Schema::Loader::DBI::Component::QuotedDefault';
942bd5e0	6	use mro 'c3';
996be9ee	7
a6900c91	8	our $VERSION = '0.07039';
32f784fc	9
996be9ee	10	=head1 NAME
996be9ee	11
8f9d7ce5	12	DBIx::Class::Schema::Loader::DBI::Pg - DBIx::Class::Schema::Loader::DBI
8f9d7ce5	13	PostgreSQL Implementation.
996be9ee	14
996be9ee	15	=head1 DESCRIPTION
996be9ee	16
c4a69b87	17	See L<DBIx::Class::Schema::Loader> and L<DBIx::Class::Schema::Loader::Base>.
996be9ee	18
	19	=cut
	20
	21	sub _setup {
	22	my $self = shift;
	23
	24	$self->next::method(@_);
bc1cb85e	25
c4a69b87	26	$self->{db_schema} \|\|= ['public'];
996be9ee	27
bc1cb85e	28	if (not defined $self->preserve_case) {
	29	$self->preserve_case(0);
	30	}
c930f78b	31	elsif ($self->preserve_case) {
	32	$self->schema->storage->sql_maker->quote_char('"');
	33	$self->schema->storage->sql_maker->name_sep('.');
	34	}
bc1cb85e	35	}
fbcfebdd	36
c4a69b87	37	sub _system_schemas {
c4a69b87	38	my $self = shift;
12b86f07	39
c4a69b87	40	return ($self->next::method(@_), 'pg_catalog');
12b86f07	41	}
12b86f07	42
f839d33b	43	my %pg_rules = (
	44	a => 'NO ACTION',
	45	r => 'RESTRICT',
2e86a3e6	46	c => 'CASCADE',
f839d33b	47	n => 'SET NULL',
	48	d => 'SET DEFAULT',
	49	);
	50
958d5fcf	51	sub _table_fk_info {
	52	my ($self, $table) = @_;
	53
	54	my $sth = $self->dbh->prepare_cached(<<"EOF");
b5f68cbe	55	select constr.conname, to_ns.nspname, to_class.relname, from_col.attname, to_col.attname,
b5f68cbe	56	constr.confdeltype, constr.confupdtype, constr.condeferrable
764b262a	57	from pg_catalog.pg_constraint constr
	58	join pg_catalog.pg_namespace from_ns on constr.connamespace = from_ns.oid
	59	join pg_catalog.pg_class from_class on constr.conrelid = from_class.oid and from_class.relnamespace = from_ns.oid
	60	join pg_catalog.pg_class to_class on constr.confrelid = to_class.oid
	61	join pg_catalog.pg_namespace to_ns on to_class.relnamespace = to_ns.oid
b5f68cbe	62	-- can't do unnest() until 8.4, so join against a series table instead
764b262a	63	join pg_catalog.generate_series(1, pg_catalog.current_setting('max_index_keys')::integer) colnum(i)
764b262a	64	on colnum.i <= pg_catalog.array_upper(constr.conkey,1)
b5f68cbe	65	join pg_catalog.pg_attribute to_col
	66	on to_col.attrelid = constr.confrelid
	67	and to_col.attnum = constr.confkey[colnum.i]
	68	join pg_catalog.pg_attribute from_col
	69	on from_col.attrelid = constr.conrelid
	70	and from_col.attnum = constr.conkey[colnum.i]
f839d33b	71	where from_ns.nspname = ?
	72	and from_class.relname = ?
	73	and from_class.relkind = 'r'
	74	and constr.contype = 'f'
b5f68cbe	75	order by constr.conname, colnum.i
958d5fcf	76	EOF
958d5fcf	77
f839d33b	78	$sth->execute($table->schema, $table->name);
958d5fcf	79
	80	my %rels;
	81
	82	while (my ($fk, $remote_schema, $remote_table, $col, $remote_col,
	83	$delete_rule, $update_rule, $is_deferrable) = $sth->fetchrow_array) {
	84	push @{ $rels{$fk}{local_columns} }, $self->_lc($col);
	85	push @{ $rels{$fk}{remote_columns} }, $self->_lc($remote_col);
	86
	87	$rels{$fk}{remote_table} = DBIx::Class::Schema::Loader::Table->new(
	88	loader => $self,
	89	name => $remote_table,
	90	schema => $remote_schema,
	91	) unless exists $rels{$fk}{remote_table};
	92
b9762446	93	$rels{$fk}{attrs} \|\|= {
f839d33b	94	on_delete => $pg_rules{$delete_rule},
	95	on_update => $pg_rules{$update_rule},
	96	is_deferrable => $is_deferrable,
b9762446	97	};
958d5fcf	98	}
958d5fcf	99
9fc706c1	100	return [ map { $rels{$_} } sort keys %rels ];
958d5fcf	101	}
	102
	103
996be9ee	104	sub _table_uniq_info {
	105	my ($self, $table) = @_;
	106
fd589700	107	# Use the default support if available
fd589700	108	return $self->next::method($table)
79fe0081	109	if $DBD::Pg::VERSION >= 1.50;
fd589700	110
996be9ee	111	my @uniqs;
996be9ee	112
5223f24a	113	# Most of the SQL here is mostly based on
	114	# Rose::DB::Object::Metadata::Auto::Pg, after some prodding from
	115	# John Siracusa to use his superior SQL code :)
	116
c4a69b87	117	my $attr_sth = $self->{_cache}->{pg_attr_sth} \|\|= $self->dbh->prepare(
5223f24a	118	q{SELECT attname FROM pg_catalog.pg_attribute
	119	WHERE attrelid = ? AND attnum = ?}
	120	);
	121
c4a69b87	122	my $uniq_sth = $self->{_cache}->{pg_uniq_sth} \|\|= $self->dbh->prepare(
5223f24a	123	q{SELECT x.indrelid, i.relname, x.indkey
	124	FROM
	125	pg_catalog.pg_index x
	126	JOIN pg_catalog.pg_class c ON c.oid = x.indrelid
	127	JOIN pg_catalog.pg_class i ON i.oid = x.indexrelid
a01ac8ee	128	JOIN pg_catalog.pg_namespace n ON n.oid = c.relnamespace
5223f24a	129	WHERE
5223f24a	130	x.indisunique = 't' AND
a01ac8ee	131	x.indpred IS NULL AND
5223f24a	132	c.relkind = 'r' AND
5223f24a	133	i.relkind = 'i' AND
5223f24a	134	n.nspname = ? AND
	135	c.relname = ?}
	136	);
	137
116431d6	138	$uniq_sth->execute($table->schema, $table->name);
5223f24a	139	while(my $row = $uniq_sth->fetchrow_arrayref) {
	140	my ($tableid, $indexname, $col_nums) = @$row;
	141	$col_nums =~ s/^\s+//;
	142	my @col_nums = split(/\s+/, $col_nums);
	143	my @col_names;
	144
	145	foreach (@col_nums) {
	146	$attr_sth->execute($tableid, $_);
	147	my $name_aref = $attr_sth->fetchrow_arrayref;
116431d6	148	push(@col_names, $self->_lc($name_aref->[0])) if $name_aref;
996be9ee	149	}
5223f24a	150
a01ac8ee	151	# skip indexes with missing column names (e.g. expression indexes)
a01ac8ee	152	if(@col_names == @col_nums) {
5223f24a	153	push(@uniqs, [ $indexname => \@col_names ]);
996be9ee	154	}
	155	}
	156
	157	return \@uniqs;
	158	}
	159
fbcfebdd	160	sub _table_comment {
c4a69b87	161	my $self = shift;
	162	my ($table) = @_;
	163
	164	my $table_comment = $self->next::method(@_);
	165
	166	return $table_comment if $table_comment;
	167
	168	($table_comment) = $self->dbh->selectrow_array(<<'EOF', {}, $table->name, $table->schema);
764b262a	169	SELECT pg_catalog.obj_description(oid)
	170	FROM pg_catalog.pg_class
	171	WHERE relname=? AND relnamespace=(SELECT oid FROM pg_catalog.pg_namespace WHERE nspname=?)
c4a69b87	172	EOF
c4a69b87	173
fbcfebdd	174	return $table_comment
	175	}
	176
	177
	178	sub _column_comment {
c4a69b87	179	my $self = shift;
	180	my ($table, $column_number, $column_name) = @_;
	181
	182	my $column_comment = $self->next::method(@_);
	183
	184	return $column_comment if $column_comment;
	185
	186	my ($table_oid) = $self->dbh->selectrow_array(<<'EOF', {}, $table->name, $table->schema);
	187	SELECT oid
764b262a	188	FROM pg_catalog.pg_class
764b262a	189	WHERE relname=? AND relnamespace=(SELECT oid FROM pg_catalog.pg_namespace WHERE nspname=?)
c4a69b87	190	EOF
c4a69b87	191
764b262a	192	return $self->dbh->selectrow_array('SELECT pg_catalog.col_description(?,?)', {}, $table_oid, $column_number);
fbcfebdd	193	}
fbcfebdd	194
baff904e	195	# Make sure data_type's that don't need it don't have a 'size' column_info, and
afb4c5bc	196	# set the correct precision for datetime and varbit types.
baff904e	197	sub _columns_info_for {
	198	my $self = shift;
	199	my ($table) = @_;
	200
	201	my $result = $self->next::method(@_);
	202
f80b0ea7	203	while (my ($col, $info) = each %$result) {
f80b0ea7	204	my $data_type = $info->{data_type};
baff904e	205
baff904e	206	# these types are fixed size
7640ef4b	207	# XXX should this be a negative match?
baff904e	208	if ($data_type =~
96336646	209	/^(?:bigint\|int8\|bigserial\|serial8\|bool(?:ean)?\|box\|bytea\|cidr\|circle\|date\|double precision\|float8\|inet\|integer\|int\|int4\|line\|lseg\|macaddr\|money\|path\|point\|polygon\|real\|float4\|smallint\|int2\|serial\|serial4\|text)\z/i) {
f80b0ea7	210	delete $info->{size};
baff904e	211	}
afb4c5bc	212	# for datetime types, check if it has a precision or not
43b982ea	213	elsif ($data_type =~ /^(?:interval\|time\|timestamp)\b/i) {
f80b0ea7	214	if (lc($data_type) eq 'timestamp without time zone') {
	215	$info->{data_type} = 'timestamp';
	216	}
8e030521	217	elsif (lc($data_type) eq 'time without time zone') {
	218	$info->{data_type} = 'time';
	219	}
f80b0ea7	220
baff904e	221	my ($precision) = $self->schema->storage->dbh
116431d6	222	->selectrow_array(<<EOF, {}, $table->name, $col);
baff904e	223	SELECT datetime_precision
	224	FROM information_schema.columns
	225	WHERE table_name = ? and column_name = ?
	226	EOF
	227
5f85388e	228	if ($data_type =~ /^time\b/i) {
5f85388e	229	if ((not $precision) \|\| $precision !~ /^\d/) {
f80b0ea7	230	delete $info->{size};
5f85388e	231	}
5f85388e	232	else {
c4a69b87	233	my ($integer_datetimes) = $self->dbh
5f85388e	234	->selectrow_array('show integer_datetimes');
	235
	236	my $max_precision =
	237	$integer_datetimes =~ /^on\z/i ? 6 : 10;
	238
	239	if ($precision == $max_precision) {
f80b0ea7	240	delete $info->{size};
5f85388e	241	}
5f85388e	242	else {
f80b0ea7	243	$info->{size} = $precision;
5f85388e	244	}
	245	}
	246	}
	247	elsif ((not $precision) \|\| $precision !~ /^\d/ \|\| $precision == 6) {
f80b0ea7	248	delete $info->{size};
baff904e	249	}
baff904e	250	else {
f80b0ea7	251	$info->{size} = $precision;
baff904e	252	}
baff904e	253	}
f80b0ea7	254	elsif ($data_type =~ /^(?:bit(?: varying)?\|varbit)\z/i) {
	255	$info->{data_type} = 'varbit' if $data_type =~ /var/i;
	256
116431d6	257	my ($precision) = $self->dbh->selectrow_array(<<EOF, {}, $table->name, $col);
afb4c5bc	258	SELECT character_maximum_length
	259	FROM information_schema.columns
	260	WHERE table_name = ? and column_name = ?
	261	EOF
	262
f80b0ea7	263	$info->{size} = $precision if $precision;
	264
	265	$info->{size} = 1 if (not $precision) && lc($data_type) eq 'bit';
afb4c5bc	266	}
f80b0ea7	267	elsif ($data_type =~ /^(?:numeric\|decimal)\z/i && (my $size = $info->{size})) {
d4d1a665	268	$size =~ s/\s*//g;
	269
	270	my ($scale, $precision) = split /,/, $size;
	271
f80b0ea7	272	$info->{size} = [ $precision, $scale ];
	273	}
	274	elsif (lc($data_type) eq 'character varying') {
	275	$info->{data_type} = 'varchar';
	276
8e030521	277	if (not $info->{size}) {
	278	$info->{data_type} = 'text';
	279	$info->{original}{data_type} = 'varchar';
	280	}
f80b0ea7	281	}
	282	elsif (lc($data_type) eq 'character') {
	283	$info->{data_type} = 'char';
d4d1a665	284	}
12333562	285	else {
	286	my ($typetype) = $self->schema->storage->dbh
	287	->selectrow_array(<<EOF, {}, $data_type);
	288	SELECT typtype
	289	FROM pg_catalog.pg_type
	290	WHERE typname = ?
	291	EOF
c4a69b87	292	if ($typetype && $typetype eq 'e') {
463c86fb	293	# The following will extract a list of allowed values for the
463c86fb	294	# enum.
9fc706c1	295	my $order_column = $self->dbh->{pg_server_version} >= 90100 ? 'enumsortorder' : 'oid';
c4a69b87	296	my $typevalues = $self->dbh
463c86fb	297	->selectall_arrayref(<<EOF, {}, $info->{data_type});
	298	SELECT e.enumlabel
	299	FROM pg_catalog.pg_enum e
	300	JOIN pg_catalog.pg_type t ON t.oid = e.enumtypid
	301	WHERE t.typname = ?
9fc706c1	302	ORDER BY e.$order_column
463c86fb	303	EOF
	304
	305	$info->{extra}{list} = [ map { $_->[0] } @$typevalues ];
	306
	307	# Store its original name in extra for SQLT to pick up.
	308	$info->{extra}{custom_type_name} = $info->{data_type};
	309
12333562	310	$info->{data_type} = 'enum';
958d5fcf	311
463c86fb	312	delete $info->{size};
12333562	313	}
	314	}
	315
df956aad	316	# process SERIAL columns
12b86f07	317	if (ref($info->{default_value}) eq 'SCALAR'
12b86f07	318	&& ${ $info->{default_value} } =~ /\bnextval\('([^:]+)'/i) {
f80b0ea7	319	$info->{is_auto_increment} = 1;
	320	$info->{sequence} = $1;
	321	delete $info->{default_value};
df956aad	322	}
8e64075f	323
6e566cc4	324	# alias now() to current_timestamp for deploying to other DBs
45321eda	325	if ((eval { lc ${ $info->{default_value} } }\|\|'') eq 'now()') {
8a64178e	326	# do not use a ref to a constant, that breaks Data::Dump output
f80b0ea7	327	${$info->{default_value}} = 'current_timestamp';
701cd3e3	328
	329	my $now = 'now()';
	330	$info->{original}{default_value} = \$now;
8e64075f	331	}
96336646	332
	333	# detect 0/1 for booleans and rewrite
	334	if ($data_type =~ /^bool/i && exists $info->{default_value}) {
	335	if ($info->{default_value} eq '0') {
	336	my $false = 'false';
	337	$info->{default_value} = \$false;
	338	}
	339	elsif ($info->{default_value} eq '1') {
	340	my $true = 'true';
	341	$info->{default_value} = \$true;
	342	}
	343	}
a8df0345	344	}
a8df0345	345
df956aad	346	return $result;
78b7ccaa	347	}
78b7ccaa	348
996be9ee	349	=head1 SEE ALSO
	350
	351	L<DBIx::Class::Schema::Loader>, L<DBIx::Class::Schema::Loader::Base>,
	352	L<DBIx::Class::Schema::Loader::DBI>
	353
be80bba7	354	=head1 AUTHOR
be80bba7	355
9cc8e7e1	356	See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
be80bba7	357
	358	=head1 LICENSE
	359
	360	This library is free software; you can redistribute it and/or modify it under
	361	the same terms as Perl itself.
	362
996be9ee	363	=cut
	364
	365	1;