[dbsrgits/DBIx-Class-Schema-Loader.git] / lib / DBIx / Class / Schema / Loader / DBI / Oracle.pm

package DBIx::Class::Schema::Loader::DBI::Oracle;

use strict;
use warnings;
use base qw/
    DBIx::Class::Schema::Loader::DBI::Component::QuotedDefault
    DBIx::Class::Schema::Loader::DBI
/;
use Carp::Clan qw/^DBIx::Class/;
use Class::C3;

our $VERSION = '0.07000';

=head1 NAME

DBIx::Class::Schema::Loader::DBI::Oracle - DBIx::Class::Schema::Loader::DBI 
Oracle Implementation.

=head1 DESCRIPTION

See L<DBIx::Class::Schema::Loader::Base>.

=cut

sub _setup {
    my $self = shift;

    $self->next::method(@_);

    my $dbh = $self->schema->storage->dbh;

    my ($current_schema) = $dbh->selectrow_array('SELECT USER FROM DUAL', {});

    $self->{db_schema} ||= $current_schema;

    if (lc($self->db_schema) ne lc($current_schema)) {
        $dbh->do('ALTER SESSION SET current_schema=' . $self->db_schema);
    }

    if (not defined $self->preserve_case) {
        $self->preserve_case(0);
    }
    elsif ($self->preserve_case) {
        $self->schema->storage->sql_maker->quote_char('"');
        $self->schema->storage->sql_maker->name_sep('.');
    }
}

sub _table_as_sql {
    my ($self, $table) = @_;

    return $self->_quote_table_name($table);
}

sub _tables_list { 
    my ($self, $opts) = @_;

    my $dbh = $self->schema->storage->dbh;

    my @tables;
    for my $table ( $dbh->tables(undef, $self->db_schema, '%', 'TABLE,VIEW') ) { #catalog, schema, table, type
        my $quoter = $dbh->get_info(29);
        $table =~ s/$quoter//g;

        # remove "user." (schema) prefixes
        $table =~ s/\w+\.//;

        next if $table eq 'PLAN_TABLE';
        $table = $self->_lc($table);
        push @tables, $1
          if $table =~ /\A(\w+)\z/;
    }

    return $self->_filter_tables(\@tables, $opts);
}

sub _table_columns {
    my ($self, $table) = @_;

    my $dbh = $self->schema->storage->dbh;

    my $sth = $dbh->column_info(undef, $self->db_schema, $self->_uc($table), '%');

    return [ map $self->_lc($_->{COLUMN_NAME}), @{ $sth->fetchall_arrayref({ COLUMN_NAME => 1 }) || [] } ];
}

sub _table_uniq_info {
    my ($self, $table) = @_;

    my $dbh = $self->schema->storage->dbh;

    my $sth = $dbh->prepare_cached(
        q{
            SELECT constraint_name, acc.column_name
            FROM all_constraints JOIN all_cons_columns acc USING (constraint_name)
            WHERE acc.table_name=? and acc.owner = ? AND constraint_type='U'
            ORDER BY acc.position
        },
        {}, 1);

    $sth->execute($self->_uc($table),$self->{db_schema} );
    my %constr_names;
    while(my $constr = $sth->fetchrow_arrayref) {
        my $constr_name = $self->_lc($constr->[0]);
        my $constr_col  = $self->_lc($constr->[1]);
        $constr_name =~ s/\Q$self->{_quoter}\E//;
        $constr_col  =~ s/\Q$self->{_quoter}\E//;
        push @{$constr_names{$constr_name}}, $constr_col;
    }
    
    my @uniqs = map { [ $_ => $constr_names{$_} ] } keys %constr_names;
    return \@uniqs;
}

sub _table_pk_info {
    my ($self, $table) = (shift, shift);

    return $self->next::method($self->_uc($table), @_);
}

sub _table_fk_info {
    my ($self, $table) = (shift, shift);

    my $rels = $self->next::method($self->_uc($table), @_);

    foreach my $rel (@$rels) {
        $rel->{remote_table} = $self->_lc($rel->{remote_table});
    }

    return $rels;
}

sub _columns_info_for {
    my ($self, $table) = (shift, shift);

    my $result = $self->next::method($self->_uc($table), @_);

    my $dbh = $self->schema->storage->dbh;

    local $dbh->{LongReadLen} = 100000;
    local $dbh->{LongTruncOk} = 1;

    my $sth = $dbh->prepare_cached(q{
SELECT atc.column_name, ut.trigger_body
FROM all_triggers ut
JOIN all_trigger_cols atc USING (trigger_name)
WHERE atc.table_name = ?
AND lower(column_usage) LIKE '%new%' AND lower(column_usage) LIKE '%out%'
AND upper(trigger_type) LIKE '%BEFORE EACH ROW%' AND lower(triggering_event) LIKE '%insert%'
    }, {}, 1);

    $sth->execute($self->_uc($table));

    while (my ($col_name, $trigger_body) = $sth->fetchrow_array) {
        $col_name = $self->_lc($col_name);

        $result->{$col_name}{is_auto_increment} = 1;

        if (my ($seq_schema, $seq_name) = $trigger_body =~ /(?:\."?(\w+)"?)?"?(\w+)"?\.nextval/i) {
            $seq_schema = $self->_lc($seq_schema) || $self->db_schema;
            $seq_name   = $self->_lc($seq_name);

            $result->{$col_name}{sequence} = ($self->qualify_objects ? ($seq_schema . '.') : '') . $seq_name;
        }
    }

    while (my ($col, $info) = each %$result) {
        no warnings 'uninitialized';

        if ($info->{data_type} =~ /^(?:n?[cb]lob|long(?: raw)?|bfile|date|binary_(?:float|double)|rowid)\z/i) {
            delete $info->{size};
        }

        if ($info->{data_type} =~ /^n(?:var)?char2?\z/i) {
            $info->{size} = $info->{size} / 2;
        }
        elsif (lc($info->{data_type}) eq 'number') {
            $info->{original}{data_type} = 'number';
            $info->{data_type}           = 'numeric';

            if (eval { $info->{size}[0] == 38 && $info->{size}[1] == 0 }) {
                $info->{original}{size} = $info->{size};

                $info->{data_type} = 'integer';
                delete $info->{size};
            }
        }
        elsif (my ($precision) = $info->{data_type} =~ /^timestamp\((\d+)\)(?: with (?:local )?time zone)?\z/i) {
            $info->{data_type} = join ' ', $info->{data_type} =~ /[a-z]+/ig;

            if ($precision == 6) {
                delete $info->{size};
            }
            else {
                $info->{size} = $precision;
            }
        }
        elsif (($precision) = $info->{data_type} =~ /^interval year\((\d+)\) to month\z/i) {
            $info->{data_type} = join ' ', $info->{data_type} =~ /[a-z]+/ig;

            if ($precision == 2) {
                delete $info->{size};
            }
            else {
                $info->{size} = $precision;
            }
        }
        elsif (my ($day_precision, $second_precision) = $info->{data_type} =~ /^interval day\((\d+)\) to second\((\d+)\)\z/i) {
            $info->{data_type} = join ' ', $info->{data_type} =~ /[a-z]+/ig;

            if ($day_precision == 2 && $second_precision == 6) {
                delete $info->{size};
            }
            else {
                $info->{size} = [ $day_precision, $second_precision ];
            }
        }
        elsif (lc($info->{data_type}) eq 'float') {
            $info->{original}{data_type} = 'float';
            $info->{original}{size}      = $info->{size};

            if ($info->{size} <= 63) {
                $info->{data_type} = 'real';
            }
            else {
                $info->{data_type} = 'double precision';
            }
            delete $info->{size};
        }
        elsif (lc($info->{data_type}) eq 'urowid' && $info->{size} == 4000) {
            delete $info->{size};
        }
        elsif (lc($info->{data_type}) eq 'date') {
            $info->{data_type}           = 'datetime';
            $info->{original}{data_type} = 'date';
        }
        elsif (lc($info->{data_type}) eq 'binary_float') {
            $info->{data_type}           = 'real';
            $info->{original}{data_type} = 'binary_float';
        } 
        elsif (lc($info->{data_type}) eq 'binary_double') {
            $info->{data_type}           = 'double precision';
            $info->{original}{data_type} = 'binary_double';
        } 

        if ((eval { lc(${ $info->{default_value} }) }||'') eq 'sysdate') {
            my $current_timestamp  = 'current_timestamp';
            $info->{default_value} = \$current_timestamp;

            my $sysdate = 'sysdate';
            $info->{original}{default_value} = \$sysdate;
        }
    }

    return $result;
}

=head1 SEE ALSO

L<DBIx::Class::Schema::Loader>, L<DBIx::Class::Schema::Loader::Base>,
L<DBIx::Class::Schema::Loader::DBI>

=head1 AUTHOR

See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.

=head1 LICENSE

This library is free software; you can redistribute it and/or modify it under
the same terms as Perl itself.

=cut

1;
# vim:et sts=4 sw=4 tw=0:
Commit	Line	Data
d87d939a	1	package DBIx::Class::Schema::Loader::DBI::Oracle;
e7262300	2
	3	use strict;
	4	use warnings;
6b0e47fc	5	use base qw/
	6	DBIx::Class::Schema::Loader::DBI::Component::QuotedDefault
	7	DBIx::Class::Schema::Loader::DBI
	8	/;
e7262300	9	use Carp::Clan qw/^DBIx::Class/;
	10	use Class::C3;
	11
9990e58f	12	our $VERSION = '0.07000';
e7262300	13
	14	=head1 NAME
	15
	16	DBIx::Class::Schema::Loader::DBI::Oracle - DBIx::Class::Schema::Loader::DBI
	17	Oracle Implementation.
	18
e7262300	19	=head1 DESCRIPTION
	20
	21	See L<DBIx::Class::Schema::Loader::Base>.
	22
e7262300	23	=cut
e7262300	24
d0e184e9	25	sub _setup {
	26	my $self = shift;
	27
	28	$self->next::method(@_);
	29
	30	my $dbh = $self->schema->storage->dbh;
46065bcb	31
	32	my ($current_schema) = $dbh->selectrow_array('SELECT USER FROM DUAL', {});
	33
	34	$self->{db_schema} \|\|= $current_schema;
	35
	36	if (lc($self->db_schema) ne lc($current_schema)) {
	37	$dbh->do('ALTER SESSION SET current_schema=' . $self->db_schema);
	38	}
bc1cb85e	39
	40	if (not defined $self->preserve_case) {
	41	$self->preserve_case(0);
	42	}
3785bc2e	43	elsif ($self->preserve_case) {
c930f78b	44	$self->schema->storage->sql_maker->quote_char('"');
c930f78b	45	$self->schema->storage->sql_maker->name_sep('.');
3785bc2e	46	}
d0e184e9	47	}
d0e184e9	48
075aff97	49	sub _table_as_sql {
e7262300	50	my ($self, $table) = @_;
e7262300	51
075aff97	52	return $self->_quote_table_name($table);
e7262300	53	}
	54
	55	sub _tables_list {
bfb43060	56	my ($self, $opts) = @_;
e7262300	57
	58	my $dbh = $self->schema->storage->dbh;
	59
	60	my @tables;
	61	for my $table ( $dbh->tables(undef, $self->db_schema, '%', 'TABLE,VIEW') ) { #catalog, schema, table, type
	62	my $quoter = $dbh->get_info(29);
	63	$table =~ s/$quoter//g;
	64
	65	# remove "user." (schema) prefixes
	66	$table =~ s/\w+\.//;
	67
	68	next if $table eq 'PLAN_TABLE';
3785bc2e	69	$table = $self->_lc($table);
e7262300	70	push @tables, $1
	71	if $table =~ /\A(\w+)\z/;
	72	}
ffb03c96	73
bfb43060	74	return $self->_filter_tables(\@tables, $opts);
e7262300	75	}
e7262300	76
4337bddf	77	sub _table_columns {
	78	my ($self, $table) = @_;
	79
	80	my $dbh = $self->schema->storage->dbh;
	81
3785bc2e	82	my $sth = $dbh->column_info(undef, $self->db_schema, $self->_uc($table), '%');
3785bc2e	83
b511f36e	84	return [ map $self->_lc($_->{COLUMN_NAME}), @{ $sth->fetchall_arrayref({ COLUMN_NAME => 1 }) \|\| [] } ];
4337bddf	85	}
4337bddf	86
e7262300	87	sub _table_uniq_info {
	88	my ($self, $table) = @_;
	89
e7262300	90	my $dbh = $self->schema->storage->dbh;
	91
	92	my $sth = $dbh->prepare_cached(
65ab592d	93	q{
c7bf4194	94	SELECT constraint_name, acc.column_name
c7bf4194	95	FROM all_constraints JOIN all_cons_columns acc USING (constraint_name)
8803e4ed	96	WHERE acc.table_name=? and acc.owner = ? AND constraint_type='U'
c7bf4194	97	ORDER BY acc.position
65ab592d	98	},
65ab592d	99	{}, 1);
e7262300	100
3785bc2e	101	$sth->execute($self->_uc($table),$self->{db_schema} );
e7262300	102	my %constr_names;
e7262300	103	while(my $constr = $sth->fetchrow_arrayref) {
f28e7eae	104	my $constr_name = $self->_lc($constr->[0]);
3785bc2e	105	my $constr_col = $self->_lc($constr->[1]);
e7262300	106	$constr_name =~ s/\Q$self->{_quoter}\E//;
3785bc2e	107	$constr_col =~ s/\Q$self->{_quoter}\E//;
3785bc2e	108	push @{$constr_names{$constr_name}}, $constr_col;
e7262300	109	}
65ab592d	110
65ab592d	111	my @uniqs = map { [ $_ => $constr_names{$_} ] } keys %constr_names;
e7262300	112	return \@uniqs;
	113	}
	114
	115	sub _table_pk_info {
3785bc2e	116	my ($self, $table) = (shift, shift);
	117
	118	return $self->next::method($self->_uc($table), @_);
e7262300	119	}
	120
	121	sub _table_fk_info {
3785bc2e	122	my ($self, $table) = (shift, shift);
e7262300	123
3785bc2e	124	my $rels = $self->next::method($self->_uc($table), @_);
e7262300	125
65ab592d	126	foreach my $rel (@$rels) {
3785bc2e	127	$rel->{remote_table} = $self->_lc($rel->{remote_table});
e7262300	128	}
e7262300	129
65ab592d	130	return $rels;
	131	}
	132
	133	sub _columns_info_for {
760fd65c	134	my ($self, $table) = (shift, shift);
e7262300	135
3785bc2e	136	my $result = $self->next::method($self->_uc($table), @_);
fb328d1a	137
fb328d1a	138	my $dbh = $self->schema->storage->dbh;
fb328d1a	139
5cd600fa	140	local $dbh->{LongReadLen} = 100000;
	141	local $dbh->{LongTruncOk} = 1;
	142
760fd65c	143	my $sth = $dbh->prepare_cached(q{
5cd600fa	144	SELECT atc.column_name, ut.trigger_body
760fd65c	145	FROM all_triggers ut
	146	JOIN all_trigger_cols atc USING (trigger_name)
	147	WHERE atc.table_name = ?
	148	AND lower(column_usage) LIKE '%new%' AND lower(column_usage) LIKE '%out%'
	149	AND upper(trigger_type) LIKE '%BEFORE EACH ROW%' AND lower(triggering_event) LIKE '%insert%'
	150	}, {}, 1);
	151
3785bc2e	152	$sth->execute($self->_uc($table));
760fd65c	153
5cd600fa	154	while (my ($col_name, $trigger_body) = $sth->fetchrow_array) {
	155	$col_name = $self->_lc($col_name);
	156
	157	$result->{$col_name}{is_auto_increment} = 1;
	158
69219349	159	if (my ($seq_schema, $seq_name) = $trigger_body =~ /(?:\."?(\w+)"?)?"?(\w+)"?\.nextval/i) {
	160	$seq_schema = $self->_lc($seq_schema) \|\| $self->db_schema;
	161	$seq_name = $self->_lc($seq_name);
5cd600fa	162
69219349	163	$result->{$col_name}{sequence} = ($self->qualify_objects ? ($seq_schema . '.') : '') . $seq_name;
5cd600fa	164	}
760fd65c	165	}
	166
	167	while (my ($col, $info) = each %$result) {
	168	no warnings 'uninitialized';
	169
	170	if ($info->{data_type} =~ /^(?:n?[cb]lob\|long(?: raw)?\|bfile\|date\|binary_(?:float\|double)\|rowid)\z/i) {
	171	delete $info->{size};
	172	}
	173
	174	if ($info->{data_type} =~ /^n(?:var)?char2?\z/i) {
	175	$info->{size} = $info->{size} / 2;
	176	}
	177	elsif (lc($info->{data_type}) eq 'number') {
4ea15dfe	178	$info->{original}{data_type} = 'number';
4ea15dfe	179	$info->{data_type} = 'numeric';
760fd65c	180
760fd65c	181	if (eval { $info->{size}[0] == 38 && $info->{size}[1] == 0 }) {
4ea15dfe	182	$info->{original}{size} = $info->{size};
4ea15dfe	183
760fd65c	184	$info->{data_type} = 'integer';
	185	delete $info->{size};
	186	}
	187	}
	188	elsif (my ($precision) = $info->{data_type} =~ /^timestamp\((\d+)\)(?: with (?:local )?time zone)?\z/i) {
	189	$info->{data_type} = join ' ', $info->{data_type} =~ /[a-z]+/ig;
	190
	191	if ($precision == 6) {
	192	delete $info->{size};
	193	}
	194	else {
	195	$info->{size} = $precision;
	196	}
	197	}
	198	elsif (($precision) = $info->{data_type} =~ /^interval year\((\d+)\) to month\z/i) {
	199	$info->{data_type} = join ' ', $info->{data_type} =~ /[a-z]+/ig;
	200
	201	if ($precision == 2) {
	202	delete $info->{size};
	203	}
	204	else {
	205	$info->{size} = $precision;
	206	}
	207	}
	208	elsif (my ($day_precision, $second_precision) = $info->{data_type} =~ /^interval day\((\d+)\) to second\((\d+)\)\z/i) {
	209	$info->{data_type} = join ' ', $info->{data_type} =~ /[a-z]+/ig;
	210
	211	if ($day_precision == 2 && $second_precision == 6) {
	212	delete $info->{size};
	213	}
	214	else {
	215	$info->{size} = [ $day_precision, $second_precision ];
	216	}
	217	}
1c22571b	218	elsif (lc($info->{data_type}) eq 'float') {
	219	$info->{original}{data_type} = 'float';
	220	$info->{original}{size} = $info->{size};
	221
	222	if ($info->{size} <= 63) {
	223	$info->{data_type} = 'real';
	224	}
	225	else {
	226	$info->{data_type} = 'double precision';
	227	}
	228	delete $info->{size};
	229	}
760fd65c	230	elsif (lc($info->{data_type}) eq 'urowid' && $info->{size} == 4000) {
	231	delete $info->{size};
	232	}
3785bc2e	233	elsif (lc($info->{data_type}) eq 'date') {
	234	$info->{data_type} = 'datetime';
	235	$info->{original}{data_type} = 'date';
	236	}
1c22571b	237	elsif (lc($info->{data_type}) eq 'binary_float') {
	238	$info->{data_type} = 'real';
	239	$info->{original}{data_type} = 'binary_float';
	240	}
	241	elsif (lc($info->{data_type}) eq 'binary_double') {
	242	$info->{data_type} = 'double precision';
	243	$info->{original}{data_type} = 'binary_double';
	244	}
760fd65c	245
268cc246	246	if ((eval { lc(${ $info->{default_value} }) }\|\|'') eq 'sysdate') {
3785bc2e	247	my $current_timestamp = 'current_timestamp';
3785bc2e	248	$info->{default_value} = \$current_timestamp;
701cd3e3	249
	250	my $sysdate = 'sysdate';
	251	$info->{original}{default_value} = \$sysdate;
760fd65c	252	}
fb328d1a	253	}
fb328d1a	254
760fd65c	255	return $result;
fb328d1a	256	}
fb328d1a	257
e7262300	258	=head1 SEE ALSO
	259
	260	L<DBIx::Class::Schema::Loader>, L<DBIx::Class::Schema::Loader::Base>,
	261	L<DBIx::Class::Schema::Loader::DBI>
	262
	263	=head1 AUTHOR
	264
9cc8e7e1	265	See L<DBIx::Class::Schema::Loader/AUTHOR> and L<DBIx::Class::Schema::Loader/CONTRIBUTORS>.
e7262300	266
be80bba7	267	=head1 LICENSE
	268
	269	This library is free software; you can redistribute it and/or modify it under
	270	the same terms as Perl itself.
fb328d1a	271
e7262300	272	=cut
	273
	274	1;
760fd65c	275	# vim:et sts=4 sw=4 tw=0: