override storage to access sth details

[dbsrgits/DBIx-Class-RowCountStatistics.git] / t / basic.t

use strict;
use warnings;

use Test::More;
use FindBin;

BEGIN {
    push @INC, "$FindBin::Bin/lib";
}

use TestSchema;
use CtrlO::DBIC::Cursor::RowCountStatistics;

our @_COMPLETE;

do {
    package TestStats;
    use parent 'DBIx::Class::Storage::Statistics';
    sub new {
        bless {}, shift;
    }
    sub query_start { }
    sub query_end { }
    sub query_complete {
        my ($self, @args) = @_;
        push @_COMPLETE, \@args;
    }
};

my $schema = TestSchema->connect(
    'dbi:SQLite:dbname=:memory:',
    undef, undef,
    {},
    {
        cursor_class => 'CtrlO::DBIC::Cursor::RowCountStatistics',
    }
);
$schema->deploy();
$schema->storage->debugobj(TestStats->new);
$schema->storage->debug(1);

ok $schema, 'schema created';
is $schema->storage->cursor_class,
    'CtrlO::DBIC::Cursor::RowCountStatistics',
    'cursor_class set';

my $rs = $schema->resultset('Test');

subtest 'count with ->next' => sub {
    local @_COMPLETE;
    $rs->create({ id => $_ }) for 1..10;
    do {
        my $rows = $rs->search_rs;
        is ref($rows->cursor), 'CtrlO::DBIC::Cursor::RowCountStatistics',
            'resultset cursor';
        1 while $rows->next;
    };
    is scalar(@_COMPLETE), 1, 'single complete call';
    is $_COMPLETE[0][0], 10, 'full count';
    ok length($_COMPLETE[0][1]), 'SQL was passed';
    like $_COMPLETE[0][1], qr{SELECT}i, 'SQL contains SELECT';
    $rs->delete;
};

subtest 'count with ->all' => sub {
    local @_COMPLETE;
    $rs->create({ id => $_ }) for 1..10;
    do {
        my $rows = $rs->search_rs;
        is ref($rows->cursor), 'CtrlO::DBIC::Cursor::RowCountStatistics',
            'resultset cursor';
        my @all = $rows->all;
    };
    is scalar(@_COMPLETE), 1, 'single complete call';
    is $_COMPLETE[0][0], 10, 'full count';
    $rs->delete;
};

subtest 'empty' => sub {
    local @_COMPLETE;
    do {
        my $rows = $rs->search_rs;
        1 while $rows->next;
    };
    is scalar(@_COMPLETE), 1, 'single complete call';
    is $_COMPLETE[0][0], 0, 'full count';
};

subtest 'no fetch' => sub {
    local @_COMPLETE;
    $rs->create({ id => $_ }) for 1..10;
    do {
        my $rows = $rs->search_rs;
    };
    is scalar(@_COMPLETE), 0, 'no complete calls';
    $rs->delete;
};

done_testing;