lib/DBIx/Class/Schema/Journal.pm

   1 package DBIx::Class::Schema::Journal;
   2
   3 use base qw/DBIx::Class/;
   4
   5 use Scalar::Util 'blessed';
   6 use DBIx::Class::Schema::Journal::DB;
   7 use Class::C3::Componentised ();
   8
   9 __PACKAGE__->mk_classdata('journal_storage_type');
  10 __PACKAGE__->mk_classdata('journal_connection');
  11 __PACKAGE__->mk_classdata('journal_deploy_on_connect');
  12 __PACKAGE__->mk_classdata('journal_sources'); ## [ source names ]
  13 __PACKAGE__->mk_classdata('journal_user'); ## [ class, field for user id ]
  14 __PACKAGE__->mk_classdata('journal_copy_sources');
  15 __PACKAGE__->mk_classdata('__journal_schema_prototype');
  16 __PACKAGE__->mk_classdata('_journal_schema'); ## schema object for journal
  17 __PACKAGE__->mk_classdata('journal_component');
  18 __PACKAGE__->mk_classdata('journal_components');
  19 __PACKAGE__->mk_classdata('journal_nested_changesets');
  20 __PACKAGE__->mk_classdata('journal_prefix');
  21
  22 use strict;
  23 use warnings;
  24
  25
  26 sub _journal_schema_prototype {
  27     my $self = shift;
  28     if (my $proto = $self->__journal_schema_prototype) {
  29           return $proto;
  30     }
  31     my $c = blessed($self)||$self;
  32     my $journal_schema_class = "${c}::_JOURNAL";
  33     Class::C3::Componentised->inject_base($journal_schema_class, 'DBIx::Class::Schema::Journal::DB');
  34     $journal_schema_class->load_components($self->journal_components)
  35         if $self->journal_components;
  36     my $proto = $self->__journal_schema_prototype (
  37         $journal_schema_class->compose_namespace( $c.'::Journal')
  38     );
  39
  40
  41     my $comp = $self->journal_component || "Journal";
  42
  43     my $prefix = $self->journal_prefix || '';
  44     foreach my $audit (qw(ChangeSet ChangeLog)) {
  45         my $class = blessed($proto) . "::$audit";
  46
  47         Class::C3::Componentised->inject_base($class, "DBIx::Class::Schema::Journal::DB::$audit");
  48
  49         $class->journal_define_table(blessed($proto), $prefix);
  50
  51         $proto->register_class($audit, $class);
  52
  53         $self->register_class($audit, $class)
  54             if $self->journal_copy_sources;
  55     }
  56
  57     ## Create auditlog+history per table
  58     my %j_sources = map { $_ => 1 } $self->journal_sources
  59        ? @{$self->journal_sources}
  60        : $self->sources;
  61
  62     foreach my $s_name ($self->sources) {
  63         next unless($j_sources{$s_name});
  64         $self->create_journal_for($s_name => $proto);
  65         $self->class($s_name)->load_components($comp);
  66     }
  67     return $proto;
  68 }
  69
  70 sub connection {
  71     my $self = shift;
  72     my $schema = $self->next::method(@_);
  73
  74     my $journal_schema = (ref $self||$self)->_journal_schema_prototype->clone;
  75
  76     if($self->journal_connection) {
  77         $journal_schema->storage_type($self->journal_storage_type)
  78             if $self->journal_storage_type;
  79         $journal_schema->connection(@{ $self->journal_connection });
  80     } else {
  81         $journal_schema->storage( $schema->storage );
  82     }
  83
  84     $self->_journal_schema($journal_schema);
  85
  86
  87     if ( $self->journal_nested_changesets ) {
  88         $self->_journal_schema->nested_changesets(1);
  89         die 'FIXME nested changeset schema not yet supported... add parent_id to ChangeSet here';
  90     }
  91
  92     $self->journal_schema_deploy()
  93         if $self->journal_deploy_on_connect;
  94
  95     ## Set up relationship between changeset->user_id and this schema's user
  96     if(!@{$self->journal_user || []}) {
  97         #warn "No Journal User set!"; # no need to warn, user_id is useful even without a rel
  98         return $schema;
  99     }
 100
 101     $self->_journal_schema->class('ChangeSet')->belongs_to('user', @{$self->journal_user});
 102     $self->_journal_schema->storage->disconnect();
 103
 104     return $schema;
 105 }
 106
 107 sub journal_schema_deploy {
 108     my $self = shift;
 109
 110     $self->_journal_schema->deploy(@_);
 111 }
 112
 113 sub create_journal_for {
 114     my ($self, $s_name, $journal_schema) = @_;
 115
 116     my $source = $self->source($s_name);
 117
 118     foreach my $audit (qw(AuditLog AuditHistory)) {
 119         my $audit_source = $s_name.$audit;
 120         my $class = blessed($journal_schema) . "::$audit_source";
 121
 122         Class::C3::Componentised->inject_base($class, "DBIx::Class::Schema::Journal::DB::$audit");
 123
 124         $class->journal_define_table($source, blessed($journal_schema));
 125
 126         $journal_schema->register_class($audit_source, $class);
 127
 128         $self->register_class($audit_source, $class)
 129             if $self->journal_copy_sources;
 130     }
 131 }
 132
 133 # XXX FIXME deploy is not idempotent :-(
 134 sub bootstrap_journal {
 135     my $self = shift;
 136     $self->journal_schema_deploy;
 137     $self->prepopulate_journal;
 138 }
 139
 140 # copy data from original schema sources into the journal as inserts in one
 141 # changeset, so that later deletes will not fail to be journalled.
 142 sub prepopulate_journal {
 143     my $self = shift;
 144     my $schema = $self;
 145
 146     # woah, looks like prepopulate has already run?
 147     return if $schema->_journal_schema->resultset('ChangeSet')->count != 0;
 148
 149     # using our own overridden txn_do (see below) will create a changeset
 150     $schema->txn_do( sub {
 151         my %j_sources = map { $_ => 1 } $self->journal_sources
 152         ? @{$self->journal_sources}
 153         : $self->sources;
 154
 155         my $j_schema = $self->_journal_schema;
 156         my $changelog_rs = $j_schema->resultset('ChangeLog');
 157         my $chs_id = $j_schema->current_changeset;
 158
 159         foreach my $s_name ($self->sources) {
 160             next unless $j_sources{$s_name};
 161
 162             my $from_rs = $schema->resultset($s_name);
 163             my @pks = $from_rs->result_source->primary_columns;
 164             $from_rs->result_class('DBIx::Class::ResultClass::HashRefInflator');
 165
 166             my $to_rs  = $j_schema->resultset("${s_name}AuditHistory");
 167             my $log_rs = $j_schema->resultset("${s_name}AuditLog");
 168
 169             my $page = 1;
 170             while (
 171                 my @x = $from_rs->search(undef, {
 172                     rows => 1_000,
 173                     page => $page++,
 174                 })
 175             ) {
 176                 # get some number of change log IDs to be generated for this page
 177                 my @log_ids = map $_->id,
 178                    $changelog_rs->populate([
 179                        map +{ changeset_id => $chs_id }, (0 .. $#x)
 180                    ]);
 181
 182
 183                 my @datas;
 184                 for my $idx (0 .. $#x ) {
 185                    push @datas, {
 186                        create_id => $log_ids[$idx],
 187                        map { $_ => $x[$idx]->{$_} } @pks,
 188                    }
 189                 }
 190                 # create the audit log entries for the rows in this page
 191                 $log_rs->populate([@datas]);
 192
 193                 # now populate the audit history
 194                 $to_rs->populate([
 195                     map +{
 196                         %{$x[$_]},
 197                         audit_change_id => $log_ids[$_],
 198                     }, (0 .. $#x)
 199                 ]);
 200             }
 201         }
 202     });
 203 }
 204
 205 sub txn_do {
 206     my ($self, $user_code, @args) = @_;
 207
 208     my $jschema = $self->_journal_schema;
 209
 210     my $code = $user_code;
 211
 212     my $current_changeset = $jschema->_current_changeset;
 213     if ( !$current_changeset || $self->journal_nested_changesets ) {
 214         my $current_changeset_ref = $jschema->_current_changeset_container;
 215
 216         unless ( $current_changeset_ref ) {
 217             # this is a hash because scalar refs can't be localized
 218             $current_changeset_ref = { };
 219             $jschema->_current_changeset_container($current_changeset_ref);
 220         }
 221
 222         # wrap the thunk with a new changeset creation
 223         $code = sub {
 224             my $changeset = $jschema->journal_create_changeset( parent_id => $current_changeset );
 225             local $current_changeset_ref->{changeset} = $changeset->id;
 226             $user_code->(@_);
 227         };
 228
 229     }
 230
 231     if ( $jschema->storage != $self->storage ) {
 232         my $inner_code = $code;
 233         $code = sub { $jschema->txn_do($inner_code, @_) };
 234     }
 235
 236     return $self->next::method($code, @args);
 237 }
 238
 239 sub changeset_user {
 240     my ($self, $userid) = @_;
 241
 242     return $self->_journal_schema->current_user()
 243        if @_ == 1;
 244
 245     $self->_journal_schema->current_user($userid);
 246 }
 247
 248 sub changeset_session {
 249     my ($self, $sessionid) = @_;
 250
 251     return $self->_journal_schema->current_session()
 252        if @_ == 1;
 253
 254     $self->_journal_schema->current_session($sessionid);
 255 }
 256
 257 1;