lib/DBIx/Class/DeploymentHandler/DeployMethod/SQL/Translator.pm

   1 package DBIx::Class::DeploymentHandler::DeployMethod::SQL::Translator;
   2 use Moose;
   3 use Method::Signatures::Simple;
   4 use Try::Tiny;
   5 use SQL::Translator;
   6 require SQL::Translator::Diff;
   7 require DBIx::Class::Storage;   # loaded for type constraint
   8
   9 with 'DBIx::Class::DeploymentHandler::HandlesDeploy';
  10 use Carp 'carp';
  11
  12 has storage => (
  13   isa        => 'DBIx::Class::Storage',
  14   is         => 'ro',
  15   lazy_build => 1,
  16 );
  17
  18 method _build_storage {
  19   my $s = $self->schema->storage;
  20   $s->_determine_driver;
  21   $s
  22 }
  23
  24 has sqltargs => (
  25   isa => 'HashRef',
  26   is  => 'ro',
  27   default => sub { {} },
  28 );
  29 has upgrade_directory => (
  30   isa      => 'Str',
  31   is       => 'ro',
  32   required => 1,
  33   default  => 'sql',
  34 );
  35
  36 has databases => (
  37   coerce  => 1,
  38   isa     => 'DBIx::Class::DeploymentHandler::Databases',
  39   is      => 'ro',
  40   default => sub { [qw( MySQL SQLite PostgreSQL )] },
  41 );
  42
  43 has schema => (
  44   isa      => 'DBIx::Class::Schema',
  45   is       => 'ro',
  46   required => 1,
  47   handles => [qw( schema_version )],
  48 );
  49
  50 has _filedata => (
  51   isa => 'ArrayRef[Str]',
  52   is  => 'rw',
  53 );
  54
  55 method _ddl_filename($type, $versions, $dir) {
  56   my $filename = ref $self->schema;
  57   $filename =~ s/::/-/g;
  58
  59   $filename = File::Spec->catfile(
  60     $dir, "$filename-" . join( q(-), @{$versions} ) . "-$type.sql"
  61   );
  62
  63   return $filename;
  64 }
  65
  66 method _deployment_statements {
  67   my $dir      = $self->upgrade_directory;
  68   my $schema   = $self->schema;
  69   my $type     = $self->storage->sqlt_type;
  70   my $sqltargs = $self->sqltargs;
  71   my $version  = $self->schema_version || '1.x';
  72
  73   my $filename = $self->_ddl_filename($type, [ $version ], $dir);
  74   if(-f $filename) {
  75       my $file;
  76       open $file, q(<), $filename
  77         or carp "Can't open $filename ($!)";
  78       my @rows = <$file>;
  79       close $file;
  80       return join '', @rows;
  81   }
  82
  83   # sources needs to be a parser arg, but for simplicty allow at top level
  84   # coming in
  85   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
  86       if exists $sqltargs->{sources};
  87
  88   my $tr = SQL::Translator->new(
  89     producer => "SQL::Translator::Producer::${type}",
  90     %$sqltargs,
  91     parser => 'SQL::Translator::Parser::DBIx::Class',
  92     data => $schema,
  93   );
  94
  95   my @ret;
  96   my $wa = wantarray;
  97   if ($wa) {
  98     @ret = $tr->translate;
  99   }
 100   else {
 101     $ret[0] = $tr->translate;
 102   }
 103
 104   $schema->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
 105     unless (@ret && defined $ret[0]);
 106
 107   return $wa ? @ret : $ret[0];
 108 }
 109
 110 sub _deploy {
 111   my $self = shift;
 112   my $storage  = $self->storage;
 113
 114   my $deploy = sub {
 115     my $line = shift;
 116     return if(!$line || $line =~ /^--|^BEGIN TRANSACTION|^COMMIT|^\s+$/);
 117     $storage->_query_start($line);
 118     try {
 119       # do a dbh_do cycle here, as we need some error checking in
 120       # place (even though we will ignore errors)
 121       $storage->dbh_do (sub { $_[1]->do($line) });
 122     }
 123     catch {
 124       carp "$_ (running '${line}')"
 125     }
 126     $storage->_query_end($line);
 127   };
 128   my @statements = $self->_deployment_statements();
 129   if (@statements > 1) {
 130     foreach my $statement (@statements) {
 131       $deploy->( $statement );
 132     }
 133   }
 134   elsif (@statements == 1) {
 135     foreach my $line ( split(";\n", $statements[0])) {
 136       $deploy->( $line );
 137     }
 138   }
 139 }
 140
 141 sub prepare_install {
 142   my $self = shift;
 143   my $schema    = $self->schema;
 144   my $databases = $self->databases;
 145   my $dir       = $self->upgrade_directory;
 146   my $sqltargs  = $self->sqltargs;
 147   unless( -d $dir ) {
 148     carp "Upgrade directory $dir does not exist, using ./\n";
 149     $dir = "./";
 150   }
 151
 152   my $version = $schema->schema_version || '1.x';
 153   my $schema_version = $schema->schema_version || '1.x';
 154   $version ||= $schema_version;
 155
 156   $sqltargs = {
 157     add_drop_table => 1,
 158     ignore_constraint_names => 1,
 159     ignore_index_names => 1,
 160     %{$sqltargs || {}}
 161   };
 162
 163   my $sqlt = SQL::Translator->new( $sqltargs );
 164
 165   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
 166   my $sqlt_schema = $sqlt->translate({ data => $schema })
 167     or $self->throw_exception ($sqlt->error);
 168
 169   foreach my $db (@$databases) {
 170     $sqlt->reset;
 171     $sqlt->{schema} = $sqlt_schema;
 172     $sqlt->producer($db);
 173
 174     my $filename = $self->_ddl_filename($db, [ $version ], $dir);
 175     if (-e $filename && ($version eq $schema_version )) {
 176       # if we are dumping the current version, overwrite the DDL
 177       carp "Overwriting existing DDL file - $filename";
 178       unlink $filename;
 179     }
 180
 181     my $output = $sqlt->translate;
 182     if(!$output) {
 183       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
 184       next;
 185     }
 186     my $file;
 187     unless( open $file, q(>), $filename ) {
 188       $self->throw_exception("Can't open $filename for writing ($!)");
 189       next;
 190     }
 191     print {$file} $output;
 192     close $file;
 193   }
 194 }
 195
 196 sub prepare_update {
 197   my ($self, $version, $preversion) = @_;
 198   my $schema    = $self->schema;
 199   my $databases = $self->databases;
 200   my $dir       = $self->upgrade_directory;
 201   my $sqltargs  = $self->sqltargs;
 202
 203   unless( -d $dir ) {
 204     carp "Upgrade directory $dir does not exist, using ./\n";
 205     $dir = "./";
 206   }
 207
 208   my $schema_version = $schema->schema_version || '1.x';
 209   $version ||= $schema_version;
 210
 211   $sqltargs = {
 212     add_drop_table => 1,
 213     ignore_constraint_names => 1,
 214     ignore_index_names => 1,
 215     %{$sqltargs}
 216   };
 217
 218   my $sqlt = SQL::Translator->new( $sqltargs );
 219
 220   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
 221   my $sqlt_schema = $sqlt->translate({ data => $schema })
 222     or $self->throw_exception ($sqlt->error);
 223
 224   foreach my $db (@$databases) {
 225     $sqlt->reset;
 226     $sqlt->{schema} = $sqlt_schema;
 227     $sqlt->producer($db);
 228
 229     my $prefilename = $self->_ddl_filename($db, [ $preversion ], $dir);
 230     unless(-e $prefilename) {
 231       carp("No previous schema file found ($prefilename)");
 232       next;
 233     }
 234
 235     my $diff_file = $self->_ddl_filename($db, [ $preversion, $version ], $dir );
 236     if(-e $diff_file) {
 237       carp("Overwriting existing diff file - $diff_file");
 238       unlink $diff_file;
 239     }
 240
 241     my $source_schema;
 242     {
 243       my $t = SQL::Translator->new({
 244          %{$sqltargs},
 245          debug => 0,
 246          trace => 0,
 247       });
 248
 249       $t->parser( $db ) # could this really throw an exception?
 250         or $self->throw_exception ($t->error);
 251
 252       my $out = $t->translate( $prefilename )
 253         or $self->throw_exception ($t->error);
 254
 255       $source_schema = $t->schema;
 256
 257       $source_schema->name( $prefilename )
 258         unless  $source_schema->name;
 259     }
 260
 261     # The "new" style of producers have sane normalization and can support
 262     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
 263     # And we have to diff parsed SQL against parsed SQL.
 264     my $dest_schema = $sqlt_schema;
 265
 266     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
 267       my $t = SQL::Translator->new({
 268          %{$sqltargs},
 269          debug => 0,
 270          trace => 0,
 271       });
 272
 273       $t->parser( $db ) # could this really throw an exception?
 274         or $self->throw_exception ($t->error);
 275
 276       my $filename = $self->_ddl_filename($db, [ $version ], $dir);
 277       my $out = $t->translate( $filename )
 278         or $self->throw_exception ($t->error);
 279
 280       $dest_schema = $t->schema;
 281
 282       $dest_schema->name( $filename )
 283         unless $dest_schema->name;
 284     }
 285
 286     my $diff = SQL::Translator::Diff::schema_diff(
 287        $source_schema, $db,
 288        $dest_schema,   $db,
 289        $sqltargs
 290     );
 291     my $file;
 292     unless(open $file, q(>), $diff_file) {
 293       $self->throw_exception("Can't write to $diff_file ($!)");
 294       next;
 295     }
 296     print {$file} $diff;
 297     close $file;
 298   }
 299 }
 300
 301 method _read_sql_file($file) {
 302   return unless $file;
 303
 304   open my $fh, '<', $file or carp("Can't open upgrade file, $file ($!)");
 305   my @data = split /\n/, join '', <$fh>;
 306   close $fh;
 307
 308   @data = grep {
 309     $_ &&
 310     !/^--/ &&
 311     !/^(BEGIN|BEGIN TRANSACTION|COMMIT)/m
 312   } split /;/,
 313     join '', @data;
 314
 315   return \@data;
 316 }
 317
 318 sub _upgrade_single_step {
 319   my $self = shift;
 320   my @version_set = @{ shift @_ };
 321   my $upgrade_file = $self->_ddl_filename(
 322     $self->storage->sqlt_type,
 323     \@version_set,
 324     $self->upgrade_directory,
 325   );
 326
 327   unless (-f $upgrade_file) {
 328     # croak?
 329     carp "Upgrade not possible, no upgrade file found ($upgrade_file), please create one\n";
 330     return;
 331   }
 332
 333   $self->_filedata($self->_read_sql_file($upgrade_file)); # I don't like this --fREW 2010-02-22
 334   $self->schema->txn_do(sub { $self->_do_upgrade });
 335 }
 336
 337 method _do_upgrade { $self->_run_upgrade(qr/.*?/) }
 338
 339 method _run_upgrade($stm) {
 340   return unless $self->_filedata;
 341   my @statements = grep { $_ =~ $stm } @{$self->_filedata};
 342
 343   for (@statements) {
 344     $self->storage->debugobj->query_start($_) if $self->storage->debug;
 345     $self->_apply_statement($_);
 346     $self->storage->debugobj->query_end($_) if $self->storage->debug;
 347   }
 348 }
 349
 350 method _apply_statement($statement) {
 351   # croak?
 352   $self->storage->dbh->do($_) or carp "SQL was: $_"
 353 }
 354
 355 __PACKAGE__->meta->make_immutable;
 356
 357 1;
 358
 359 __END__
 360
 361 vim: ts=2 sw=2 expandtab