lib/DBIx/Class/DeploymentHandler/DeployMethod/SQL/Translator.pm

   1 package DBIx::Class::DeploymentHandler::DeployMethod::SQL::Translator;
   2 use Moose;
   3
   4 use autodie;
   5 use Carp qw( carp croak );
   6
   7 use Method::Signatures::Simple;
   8 use Try::Tiny;
   9
  10 use SQL::Translator;
  11 require SQL::Translator::Diff;
  12
  13 require DBIx::Class::Storage;   # loaded for type constraint
  14 use DBIx::Class::DeploymentHandler::Types;
  15
  16 use File::Path 'mkpath';
  17 use File::Spec::Functions;
  18
  19 with 'DBIx::Class::DeploymentHandler::HandlesDeploy';
  20
  21 has schema => (
  22   isa      => 'DBIx::Class::Schema',
  23   is       => 'ro',
  24   required => 1,
  25   handles => [qw( schema_version )],
  26 );
  27
  28 has storage => (
  29   isa        => 'DBIx::Class::Storage',
  30   is         => 'ro',
  31   lazy_build => 1,
  32 );
  33
  34 method _build_storage {
  35   my $s = $self->schema->storage;
  36   $s->_determine_driver;
  37   $s
  38 }
  39
  40 has sqltargs => (
  41   isa => 'HashRef',
  42   is  => 'ro',
  43   default => sub { {} },
  44 );
  45 has upgrade_directory => (
  46   isa      => 'Str',
  47   is       => 'ro',
  48   required => 1,
  49   default  => 'sql',
  50 );
  51
  52 has databases => (
  53   coerce  => 1,
  54   isa     => 'DBIx::Class::DeploymentHandler::Databases',
  55   is      => 'ro',
  56   default => sub { [qw( MySQL SQLite PostgreSQL )] },
  57 );
  58
  59 has _filedata => (
  60   isa => 'ArrayRef[Str]',
  61   is  => 'rw',
  62   default => sub { [] },
  63 );
  64
  65 has txn_wrap => (
  66   is => 'ro',
  67   isa => 'Bool',
  68   default => 1,
  69 );
  70
  71 method __ddl_consume_with_prefix($type, $versions, $prefix) {
  72   my $base_dir = $self->upgrade_directory;
  73
  74   my $main    = catfile( $base_dir, $type      );
  75   my $generic = catfile( $base_dir, '_generic' );
  76   my $common  =
  77     catfile( $base_dir, '_common', $prefix, join q(-), @{$versions} );
  78
  79   my $dir;
  80   if (-d $main) {
  81     $dir = catfile($main, $prefix, join q(-), @{$versions})
  82   } elsif (-d $generic) {
  83     $dir = catfile($generic, $prefix, join q(-), @{$versions});
  84   } else {
  85     croak "neither $main or $generic exist; please write/generate some SQL";
  86   }
  87
  88   opendir my($dh), $dir;
  89   my %files = map { $_ => "$dir/$_" } grep { /\.(?:sql|pl)$/ && -f "$dir/$_" } readdir $dh;
  90   closedir $dh;
  91
  92   if (-d $common) {
  93     opendir my($dh), $common;
  94     for my $filename (grep { /\.(?:sql|pl)$/ && -f catfile($common,$_) } readdir $dh) {
  95       unless ($files{$filename}) {
  96         $files{$filename} = catfile($common,$filename);
  97       }
  98     }
  99     closedir $dh;
 100   }
 101
 102   return [@files{sort keys %files}]
 103 }
 104
 105 method _ddl_schema_consume_filenames($type, $version) {
 106   $self->__ddl_consume_with_prefix($type, [ $version ], 'schema')
 107 }
 108
 109 method _ddl_schema_produce_filename($type, $version) {
 110   my $dirname = catfile( $self->upgrade_directory, $type, 'schema', $version );
 111   mkpath($dirname) unless -d $dirname;
 112
 113   return catfile( $dirname, '001-auto.sql' );
 114 }
 115
 116 method _ddl_schema_up_consume_filenames($type, $versions) {
 117   $self->__ddl_consume_with_prefix($type, $versions, 'up')
 118 }
 119
 120 method _ddl_schema_down_consume_filenames($type, $versions) {
 121   $self->__ddl_consume_with_prefix($type, $versions, 'down')
 122 }
 123
 124 method _ddl_schema_up_produce_filename($type, $versions) {
 125   my $dir = $self->upgrade_directory;
 126
 127   my $dirname = catfile( $dir, $type, 'up', join q(-), @{$versions});
 128   mkpath($dirname) unless -d $dirname;
 129
 130   return catfile( $dirname, '001-auto.sql'
 131   );
 132 }
 133
 134 method _ddl_schema_down_produce_filename($type, $versions, $dir) {
 135   my $dirname = catfile( $dir, $type, 'down', join q(-), @{$versions} );
 136   mkpath($dirname) unless -d $dirname;
 137
 138   return catfile( $dirname, '001-auto.sql');
 139 }
 140
 141 method _run_sql_and_perl($filenames) {
 142   my @files = @{$filenames};
 143   my $storage = $self->storage;
 144
 145   my $guard = $self->schema->txn_scope_guard if $self->txn_wrap;
 146
 147   my $sql;
 148   for my $filename (@files) {
 149     if ($filename =~ /\.sql$/) {
 150       my @sql = @{$self->_read_sql_file($filename)};
 151       $sql .= join "\n", @sql;
 152
 153       foreach my $line (@sql) {
 154         $storage->_query_start($line);
 155         try {
 156           # do a dbh_do cycle here, as we need some error checking in
 157           # place (even though we will ignore errors)
 158           $storage->dbh_do (sub { $_[1]->do($line) });
 159         }
 160         catch {
 161           carp "$_ (running '${line}')"
 162         }
 163         $storage->_query_end($line);
 164       }
 165     } elsif ( $filename =~ /^(.+)\.pl$/ ) {
 166       my $package = $1;
 167       my $filedata = do { local( @ARGV, $/ ) = $filename; <> };
 168       # make the package name more palateable to perl
 169       $package =~ s/\W/_/g;
 170
 171       no warnings 'redefine';
 172       eval "package $package;\n\n$filedata";
 173       use warnings;
 174
 175       if (my $fn = $package->can('run')) {
 176         $fn->($self->schema);
 177       } else {
 178         carp "$filename should define a run method that takes a schema but it didn't!";
 179       }
 180     } else {
 181       croak "A file got to deploy that wasn't sql or perl!";
 182     }
 183   }
 184
 185   $guard->commit if $self->txn_wrap;
 186
 187   return $sql;
 188 }
 189
 190 sub deploy {
 191   my $self = shift;
 192
 193   return $self->_run_sql_and_perl($self->_ddl_schema_consume_filenames(
 194     $self->storage->sqlt_type,
 195     $self->schema_version
 196   ));
 197 }
 198
 199 sub prepare_install {
 200   my $self = shift;
 201   my $schema    = $self->schema;
 202   my $databases = $self->databases;
 203   my $dir       = $self->upgrade_directory;
 204   my $sqltargs  = $self->sqltargs;
 205   my $version = $schema->schema_version;
 206
 207   my $sqlt = SQL::Translator->new({
 208     add_drop_table          => 1,
 209     ignore_constraint_names => 1,
 210     ignore_index_names      => 1,
 211     parser                  => 'SQL::Translator::Parser::DBIx::Class',
 212     %{$sqltargs}
 213   });
 214
 215   my $sqlt_schema = $sqlt->translate( data => $schema )
 216     or croak($sqlt->error);
 217
 218   foreach my $db (@$databases) {
 219     $sqlt->reset;
 220     $sqlt->{schema} = $sqlt_schema;
 221     $sqlt->producer($db);
 222
 223     my $filename = $self->_ddl_schema_produce_filename($db, $version, $dir);
 224     if (-e $filename ) {
 225       carp "Overwriting existing DDL file - $filename";
 226       unlink $filename;
 227     }
 228
 229     my $output = $sqlt->translate;
 230     if(!$output) {
 231       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
 232       next;
 233     }
 234     open my $file, q(>), $filename;
 235     print {$file} $output;
 236     close $file;
 237   }
 238 }
 239
 240 sub prepare_upgrade {
 241   my ($self, $from_version, $to_version, $version_set) = @_;
 242   # for updates prepared automatically (rob's stuff)
 243   # one would want to explicitly set $version_set to
 244   # [$to_version]
 245   $self->_prepare_changegrade($from_version, $to_version, $version_set, 'up');
 246 }
 247
 248 sub prepare_downgrade {
 249   my ($self, $from_version, $to_version, $version_set) = @_;
 250
 251   # for updates prepared automatically (rob's stuff)
 252   # one would want to explicitly set $version_set to
 253   # [$to_version]
 254   $self->_prepare_changegrade($from_version, $to_version, $version_set, 'down');
 255 }
 256
 257 method _prepare_changegrade($from_version, $to_version, $version_set, $direction) {
 258   my $schema    = $self->schema;
 259   my $databases = $self->databases;
 260   my $dir       = $self->upgrade_directory;
 261   my $sqltargs  = $self->sqltargs;
 262
 263   my $schema_version = $schema->schema_version;
 264
 265   $sqltargs = {
 266     add_drop_table => 1,
 267     ignore_constraint_names => 1,
 268     ignore_index_names => 1,
 269     %{$sqltargs}
 270   };
 271
 272   my $sqlt = SQL::Translator->new( $sqltargs );
 273
 274   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
 275   my $sqlt_schema = $sqlt->translate( data => $schema )
 276     or croak($sqlt->error);
 277
 278   foreach my $db (@$databases) {
 279     $sqlt->reset;
 280     $sqlt->{schema} = $sqlt_schema;
 281     $sqlt->producer($db);
 282
 283     my $prefilename = $self->_ddl_schema_produce_filename($db, $from_version, $dir);
 284     unless(-e $prefilename) {
 285       carp("No previous schema file found ($prefilename)");
 286       next;
 287     }
 288     my $diff_file_method = "_ddl_schema_${direction}_produce_filename";
 289     my $diff_file = $self->$diff_file_method($db, $version_set, $dir );
 290     if(-e $diff_file) {
 291       carp("Overwriting existing $direction-diff file - $diff_file");
 292       unlink $diff_file;
 293     }
 294
 295     my $source_schema;
 296     {
 297       my $t = SQL::Translator->new({
 298          %{$sqltargs},
 299          debug => 0,
 300          trace => 0,
 301       });
 302
 303       $t->parser( $db ) # could this really throw an exception?
 304         or croak($t->error);
 305
 306       my $out = $t->translate( $prefilename )
 307         or croak($t->error);
 308
 309       $source_schema = $t->schema;
 310
 311       $source_schema->name( $prefilename )
 312         unless  $source_schema->name;
 313     }
 314
 315     # The "new" style of producers have sane normalization and can support
 316     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
 317     # And we have to diff parsed SQL against parsed SQL.
 318     my $dest_schema = $sqlt_schema;
 319
 320     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
 321       my $t = SQL::Translator->new({
 322          %{$sqltargs},
 323          debug => 0,
 324          trace => 0,
 325       });
 326
 327       $t->parser( $db ) # could this really throw an exception?
 328         or croak($t->error);
 329
 330       my $filename = $self->_ddl_schema_produce_filename($db, $to_version, $dir);
 331       my $out = $t->translate( $filename )
 332         or croak($t->error);
 333
 334       $dest_schema = $t->schema;
 335
 336       $dest_schema->name( $filename )
 337         unless $dest_schema->name;
 338     }
 339
 340     my $diff = SQL::Translator::Diff::schema_diff(
 341        $source_schema, $db,
 342        $dest_schema,   $db,
 343        $sqltargs
 344     );
 345     open my $file, q(>), $diff_file;
 346     print {$file} $diff;
 347     close $file;
 348   }
 349 }
 350
 351 method _read_sql_file($file) {
 352   return unless $file;
 353
 354   open my $fh, '<', $file;
 355   my @data = split /;\n/, join '', <$fh>;
 356   close $fh;
 357
 358   @data = grep {
 359     $_ && # remove blank lines
 360     !/^(BEGIN|BEGIN TRANSACTION|COMMIT)/ # strip txn's
 361   } map {
 362     s/^\s+//; s/\s+$//; # trim whitespace
 363     join '', grep { !/^--/ } split /\n/ # remove comments
 364   } @data;
 365
 366   return \@data;
 367 }
 368
 369 sub downgrade_single_step {
 370   my $self = shift;
 371   my @version_set = @{ shift @_ };
 372
 373   my $sql = $self->_run_sql_and_perl($self->_ddl_schema_down_consume_filenames(
 374     $self->storage->sqlt_type,
 375     \@version_set,
 376   ));
 377
 378   return ['', $sql];
 379 }
 380
 381 sub upgrade_single_step {
 382   my $self = shift;
 383   my @version_set = @{ shift @_ };
 384
 385   my $sql = $self->_run_sql_and_perl($self->_ddl_schema_up_consume_filenames(
 386     $self->storage->sqlt_type,
 387     \@version_set,
 388   ));
 389   return ['', $sql];
 390 }
 391
 392 __PACKAGE__->meta->make_immutable;
 393
 394 1;
 395
 396 __END__
 397
 398 vim: ts=2 sw=2 expandtab