lib/DBIx/Class/DeploymentHandler/DeployMethod/SQL/Translator.pm

   1 package DBIx::Class::DeploymentHandler::DeployMethod::SQL::Translator;
   2 use Moose;
   3
   4 use autodie;
   5 use Carp qw( carp croak );
   6
   7 use Method::Signatures::Simple;
   8 use Try::Tiny;
   9
  10 use SQL::Translator;
  11 require SQL::Translator::Diff;
  12
  13 require DBIx::Class::Storage;   # loaded for type constraint
  14 use DBIx::Class::DeploymentHandler::Types;
  15
  16 use File::Path 'mkpath';
  17 use File::Spec::Functions;
  18
  19 with 'DBIx::Class::DeploymentHandler::HandlesDeploy';
  20
  21 has schema => (
  22   isa      => 'DBIx::Class::Schema',
  23   is       => 'ro',
  24   required => 1,
  25   handles => [qw( schema_version )],
  26 );
  27
  28 has storage => (
  29   isa        => 'DBIx::Class::Storage',
  30   is         => 'ro',
  31   lazy_build => 1,
  32 );
  33
  34 method _build_storage {
  35   my $s = $self->schema->storage;
  36   $s->_determine_driver;
  37   $s
  38 }
  39
  40 has sqltargs => (
  41   isa => 'HashRef',
  42   is  => 'ro',
  43   default => sub { {} },
  44 );
  45 has upgrade_directory => (
  46   isa      => 'Str',
  47   is       => 'ro',
  48   required => 1,
  49   default  => 'sql',
  50 );
  51
  52 has databases => (
  53   coerce  => 1,
  54   isa     => 'DBIx::Class::DeploymentHandler::Databases',
  55   is      => 'ro',
  56   default => sub { [qw( MySQL SQLite PostgreSQL )] },
  57 );
  58
  59 has _filedata => (
  60   isa => 'ArrayRef[Str]',
  61   is  => 'rw',
  62   default => sub { [] },
  63 );
  64
  65 has txn_wrap => (
  66   is => 'ro',
  67   isa => 'Bool',
  68   default => 1,
  69 );
  70
  71 method __ddl_consume_with_prefix($type, $versions, $prefix) {
  72   my $base_dir = $self->upgrade_directory;
  73
  74   my $main    = catfile( $base_dir, $type      );
  75   my $generic = catfile( $base_dir, '_generic' );
  76   my $common  =
  77     catfile( $base_dir, '_common', $prefix, join q(-), @{$versions} );
  78
  79   my $dir;
  80   if (-d $main) {
  81     $dir = catfile($main, $prefix, join q(-), @{$versions})
  82   } elsif (-d $generic) {
  83     $dir = catfile($generic, $prefix, join q(-), @{$versions});
  84   } else {
  85     croak "neither $main or $generic exist; please write/generate some SQL";
  86   }
  87
  88   opendir my($dh), $dir;
  89   my %files = map { $_ => "$dir/$_" } grep { /\.(?:sql|pl)$/ && -f "$dir/$_" } readdir $dh;
  90   closedir $dh;
  91
  92   if (-d $common) {
  93     opendir my($dh), $common;
  94     for my $filename (grep { /\.(?:sql|pl)$/ && -f catfile($common,$_) } readdir $dh) {
  95       unless ($files{$filename}) {
  96         $files{$filename} = catfile($common,$filename);
  97       }
  98     }
  99     closedir $dh;
 100   }
 101
 102   return [@files{sort keys %files}]
 103 }
 104
 105 method _ddl_schema_consume_filenames($type, $version) {
 106   $self->__ddl_consume_with_prefix($type, [ $version ], 'schema')
 107 }
 108
 109 method _ddl_schema_produce_filename($type, $version) {
 110   my $dirname = catfile( $self->upgrade_directory, $type, 'schema', $version );
 111   mkpath($dirname) unless -d $dirname;
 112
 113   return catfile( $dirname, '001-auto.sql' );
 114 }
 115
 116 method _ddl_schema_up_consume_filenames($type, $versions) {
 117   $self->__ddl_consume_with_prefix($type, $versions, 'up')
 118 }
 119
 120 method _ddl_schema_down_consume_filenames($type, $versions) {
 121   $self->__ddl_consume_with_prefix($type, $versions, 'down')
 122 }
 123
 124 method _ddl_schema_up_produce_filename($type, $versions) {
 125   my $dir = $self->upgrade_directory;
 126
 127   my $dirname = catfile( $dir, $type, 'up', join q(-), @{$versions});
 128   mkpath($dirname) unless -d $dirname;
 129
 130   return catfile( $dirname, '001-auto.sql'
 131   );
 132 }
 133
 134 method _ddl_schema_down_produce_filename($type, $versions, $dir) {
 135   my $dirname = catfile( $dir, $type, 'down', join q(-), @{$versions} );
 136   mkpath($dirname) unless -d $dirname;
 137
 138   return catfile( $dirname, '001-auto.sql');
 139 }
 140
 141 method _run_sql_and_perl($filenames) {
 142   my @files = @{$filenames};
 143   my $storage = $self->storage;
 144
 145   my $guard = $self->schema->txn_scope_guard if $self->txn_wrap;
 146
 147   my $sql;
 148   for my $filename (@files) {
 149     if ($filename =~ /\.sql$/) {
 150       my @sql = @{$self->_read_sql_file($filename)};
 151       $sql .= join "\n", @sql;
 152
 153       foreach my $line (@sql) {
 154         $storage->_query_start($line);
 155         try {
 156           # do a dbh_do cycle here, as we need some error checking in
 157           # place (even though we will ignore errors)
 158           $storage->dbh_do (sub { $_[1]->do($line) });
 159         }
 160         catch {
 161           carp "$_ (running '${line}')"
 162         }
 163         $storage->_query_end($line);
 164       }
 165     } elsif ( $filename =~ /\.pl$/ ) {
 166       qx( $^X $filename );
 167     } else {
 168       croak "A file got to deploy that wasn't sql or perl!";
 169     }
 170   }
 171
 172   $guard->commit if $self->txn_wrap;
 173
 174   return $sql;
 175 }
 176
 177 sub deploy {
 178   my $self = shift;
 179
 180   return $self->_run_sql_and_perl($self->_ddl_schema_consume_filenames(
 181     $self->storage->sqlt_type,
 182     $self->schema_version
 183   ));
 184 }
 185
 186 sub prepare_install {
 187   my $self = shift;
 188   my $schema    = $self->schema;
 189   my $databases = $self->databases;
 190   my $dir       = $self->upgrade_directory;
 191   my $sqltargs  = $self->sqltargs;
 192   my $version = $schema->schema_version;
 193
 194   my $sqlt = SQL::Translator->new({
 195     add_drop_table          => 1,
 196     ignore_constraint_names => 1,
 197     ignore_index_names      => 1,
 198     parser                  => 'SQL::Translator::Parser::DBIx::Class',
 199     %{$sqltargs}
 200   });
 201
 202   my $sqlt_schema = $sqlt->translate( data => $schema )
 203     or croak($sqlt->error);
 204
 205   foreach my $db (@$databases) {
 206     $sqlt->reset;
 207     $sqlt->{schema} = $sqlt_schema;
 208     $sqlt->producer($db);
 209
 210     my $filename = $self->_ddl_schema_produce_filename($db, $version, $dir);
 211     if (-e $filename ) {
 212       carp "Overwriting existing DDL file - $filename";
 213       unlink $filename;
 214     }
 215
 216     my $output = $sqlt->translate;
 217     if(!$output) {
 218       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
 219       next;
 220     }
 221     open my $file, q(>), $filename;
 222     print {$file} $output;
 223     close $file;
 224   }
 225 }
 226
 227 sub prepare_upgrade {
 228   my ($self, $from_version, $to_version, $version_set) = @_;
 229   # for updates prepared automatically (rob's stuff)
 230   # one would want to explicitly set $version_set to
 231   # [$to_version]
 232   $self->_prepare_changegrade($from_version, $to_version, $version_set, 'up');
 233 }
 234
 235 sub prepare_downgrade {
 236   my ($self, $from_version, $to_version, $version_set) = @_;
 237
 238   # for updates prepared automatically (rob's stuff)
 239   # one would want to explicitly set $version_set to
 240   # [$to_version]
 241   $self->_prepare_changegrade($from_version, $to_version, $version_set, 'down');
 242 }
 243
 244 method _prepare_changegrade($from_version, $to_version, $version_set, $direction) {
 245   my $schema    = $self->schema;
 246   my $databases = $self->databases;
 247   my $dir       = $self->upgrade_directory;
 248   my $sqltargs  = $self->sqltargs;
 249
 250   my $schema_version = $schema->schema_version;
 251
 252   $sqltargs = {
 253     add_drop_table => 1,
 254     ignore_constraint_names => 1,
 255     ignore_index_names => 1,
 256     %{$sqltargs}
 257   };
 258
 259   my $sqlt = SQL::Translator->new( $sqltargs );
 260
 261   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
 262   my $sqlt_schema = $sqlt->translate( data => $schema )
 263     or croak($sqlt->error);
 264
 265   foreach my $db (@$databases) {
 266     $sqlt->reset;
 267     $sqlt->{schema} = $sqlt_schema;
 268     $sqlt->producer($db);
 269
 270     my $prefilename = $self->_ddl_schema_produce_filename($db, $from_version, $dir);
 271     unless(-e $prefilename) {
 272       carp("No previous schema file found ($prefilename)");
 273       next;
 274     }
 275     my $diff_file_method = "_ddl_schema_${direction}_produce_filename";
 276     my $diff_file = $self->$diff_file_method($db, $version_set, $dir );
 277     if(-e $diff_file) {
 278       carp("Overwriting existing $direction-diff file - $diff_file");
 279       unlink $diff_file;
 280     }
 281
 282     my $source_schema;
 283     {
 284       my $t = SQL::Translator->new({
 285          %{$sqltargs},
 286          debug => 0,
 287          trace => 0,
 288       });
 289
 290       $t->parser( $db ) # could this really throw an exception?
 291         or croak($t->error);
 292
 293       my $out = $t->translate( $prefilename )
 294         or croak($t->error);
 295
 296       $source_schema = $t->schema;
 297
 298       $source_schema->name( $prefilename )
 299         unless  $source_schema->name;
 300     }
 301
 302     # The "new" style of producers have sane normalization and can support
 303     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
 304     # And we have to diff parsed SQL against parsed SQL.
 305     my $dest_schema = $sqlt_schema;
 306
 307     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
 308       my $t = SQL::Translator->new({
 309          %{$sqltargs},
 310          debug => 0,
 311          trace => 0,
 312       });
 313
 314       $t->parser( $db ) # could this really throw an exception?
 315         or croak($t->error);
 316
 317       my $filename = $self->_ddl_schema_produce_filename($db, $to_version, $dir);
 318       my $out = $t->translate( $filename )
 319         or croak($t->error);
 320
 321       $dest_schema = $t->schema;
 322
 323       $dest_schema->name( $filename )
 324         unless $dest_schema->name;
 325     }
 326
 327     my $diff = SQL::Translator::Diff::schema_diff(
 328        $source_schema, $db,
 329        $dest_schema,   $db,
 330        $sqltargs
 331     );
 332     open my $file, q(>), $diff_file;
 333     print {$file} $diff;
 334     close $file;
 335   }
 336 }
 337
 338 method _read_sql_file($file) {
 339   return unless $file;
 340
 341   open my $fh, '<', $file;
 342   my @data = split /;\n/, join '', <$fh>;
 343   close $fh;
 344
 345   @data = grep {
 346     $_ && # remove blank lines
 347     !/^(BEGIN|BEGIN TRANSACTION|COMMIT)/ # strip txn's
 348   } map {
 349     s/^\s+//; s/\s+$//; # trim whitespace
 350     join '', grep { !/^--/ } split /\n/ # remove comments
 351   } @data;
 352
 353   return \@data;
 354 }
 355
 356 sub downgrade_single_step {
 357   my $self = shift;
 358   my @version_set = @{ shift @_ };
 359
 360   my $sql = $self->_run_sql_and_perl($self->_ddl_schema_down_consume_filenames(
 361     $self->storage->sqlt_type,
 362     \@version_set,
 363   ));
 364
 365   return ['', $sql];
 366 }
 367
 368 sub upgrade_single_step {
 369   my $self = shift;
 370   my @version_set = @{ shift @_ };
 371
 372   my $sql = $self->_run_sql_and_perl($self->_ddl_schema_up_consume_filenames(
 373     $self->storage->sqlt_type,
 374     \@version_set,
 375   ));
 376   return ['', $sql];
 377 }
 378
 379 __PACKAGE__->meta->make_immutable;
 380
 381 1;
 382
 383 __END__
 384
 385 vim: ts=2 sw=2 expandtab