lib/DBIx/Class/DeploymentHandler/DeployMethod/SQL/Translator.pm

   1 package DBIx::Class::DeploymentHandler::DeployMethod::SQL::Translator;
   2 use Moose;
   3 use Method::Signatures::Simple;
   4 use Try::Tiny;
   5 use SQL::Translator;
   6 require SQL::Translator::Diff;
   7 require DBIx::Class::Storage;   # loaded for type constraint
   8 use autodie;
   9 use File::Path;
  10
  11 with 'DBIx::Class::DeploymentHandler::HandlesDeploy';
  12
  13 use Carp 'carp';
  14
  15 has schema => (
  16   isa      => 'DBIx::Class::Schema',
  17   is       => 'ro',
  18   required => 1,
  19   handles => [qw( schema_version )],
  20 );
  21
  22 has storage => (
  23   isa        => 'DBIx::Class::Storage',
  24   is         => 'ro',
  25   lazy_build => 1,
  26 );
  27
  28 method _build_storage {
  29   my $s = $self->schema->storage;
  30   $s->_determine_driver;
  31   $s
  32 }
  33
  34 has sqltargs => (
  35   isa => 'HashRef',
  36   is  => 'ro',
  37   default => sub { {} },
  38 );
  39 has upgrade_directory => (
  40   isa      => 'Str',
  41   is       => 'ro',
  42   required => 1,
  43   default  => 'sql',
  44 );
  45
  46 has databases => (
  47   coerce  => 1,
  48   isa     => 'DBIx::Class::DeploymentHandler::Databases',
  49   is      => 'ro',
  50   default => sub { [qw( MySQL SQLite PostgreSQL )] },
  51 );
  52
  53 has _filedata => (
  54   isa => 'ArrayRef[Str]',
  55   is  => 'rw',
  56 );
  57
  58 has txn_wrap => (
  59   is => 'ro',
  60   isa => 'Bool',
  61   default => 1,
  62 );
  63
  64 method __ddl_consume_with_prefix($type, $versions, $prefix) {
  65   my $base_dir = $self->upgrade_directory;
  66
  67   my $main    = File::Spec->catfile( $base_dir, $type                         );
  68   my $generic = File::Spec->catfile( $base_dir, '_generic'                    );
  69   my $common =  File::Spec->catfile( $base_dir, '_common', $prefix, join q(-), @{$versions} );
  70
  71   my $dir;
  72   if (-d $main) {
  73     $dir = File::Spec->catfile($main, $prefix, join q(-), @{$versions})
  74   } elsif (-d $generic) {
  75     $dir = File::Spec->catfile($main, $prefix, join q(-), @{$versions})
  76   } else {
  77     die 'PREPARE TO SQL'
  78   }
  79
  80   opendir my($dh), $dir;
  81   my %files = map { $_ => "$dir/$_" } grep { /\.sql$/ && -f "$dir/$_" } readdir($dh);
  82   closedir $dh;
  83
  84   if (-d $common) {
  85     opendir my($dh), $common;
  86     for my $filename (grep { /\.sql$/ && -f "$common/$_" } readdir($dh)) {
  87       unless ($files{$filename}) {
  88         $files{$filename} = "$common/$_";
  89       }
  90     }
  91     closedir $dh;
  92   }
  93
  94   return [@files{sort keys %files}]
  95 }
  96
  97 method _ddl_schema_consume_filenames($type, $version) {
  98   $self->__ddl_consume_with_prefix($type, [ $version ], 'schema')
  99 }
 100
 101 method _ddl_schema_produce_filename($type, $version) {
 102   my $base_dir = $self->upgrade_directory;
 103   my $dirname = File::Spec->catfile(
 104     $base_dir, $type, 'schema', $version
 105   );
 106   File::Path::mkpath($dirname) unless -d $dirname;
 107
 108   return File::Spec->catfile(
 109     $dirname, '001-auto.sql'
 110   );
 111 }
 112
 113 method _ddl_schema_up_consume_filenames($type, $versions) {
 114   $self->__ddl_consume_with_prefix($type, $versions, 'up')
 115 }
 116
 117 method _ddl_schema_down_consume_filenames($type, $versions) {
 118   $self->__ddl_consume_with_prefix($type, $versions, 'down')
 119 }
 120
 121 method _ddl_schema_up_produce_filename($type, $versions) {
 122   my $dir = $self->upgrade_directory;
 123
 124   my $dirname = File::Spec->catfile(
 125     $dir, $type, 'up', join( q(-), @{$versions} )
 126   );
 127   File::Path::mkpath($dirname) unless -d $dirname;
 128
 129   return File::Spec->catfile(
 130     $dirname, '001-auto.sql'
 131   );
 132 }
 133
 134 method _ddl_schema_down_produce_filename($type, $versions, $dir) {
 135   my $dirname = File::Spec->catfile(
 136     $dir, $type, 'down', join( q(-), @{$versions} )
 137   );
 138   File::Path::mkpath($dirname) unless -d $dirname;
 139
 140   return File::Spec->catfile(
 141     $dirname, '001-auto.sql'
 142   );
 143 }
 144
 145 method _deployment_statements {
 146   my $type     = $self->storage->sqlt_type;
 147   my $version  = $self->schema_version;
 148
 149   for my $filename (@{$self->_ddl_schema_consume_filenames($type, $version)}) {
 150       open my $file, q(<), $filename
 151         or carp "Can't open $filename ($!)";
 152       my @rows = <$file>;
 153       close $file;
 154       return join '', @rows;
 155   }
 156 }
 157
 158 sub _deploy {
 159   my $self = shift;
 160   my $storage  = $self->storage;
 161
 162   my $guard = $self->schema->txn_scope_guard if $self->txn_wrap;
 163
 164   foreach my $line ( split /;\n/, $self->_deployment_statements ) {
 165     $line = join '', grep { !/^--/ } split /\n/, $line;
 166     next if !$line || $line =~ /^BEGIN TRANSACTION|^COMMIT|^\s+$/;
 167     $storage->_query_start($line);
 168     try {
 169       # do a dbh_do cycle here, as we need some error checking in
 170       # place (even though we will ignore errors)
 171       $storage->dbh_do (sub { $_[1]->do($line) });
 172     }
 173     catch {
 174       carp "$_ (running '${line}')"
 175     }
 176     $storage->_query_end($line);
 177   }
 178
 179   $guard->commit if $self->txn_wrap;
 180 }
 181
 182 sub prepare_install {
 183   my $self = shift;
 184   my $schema    = $self->schema;
 185   my $databases = $self->databases;
 186   my $dir       = $self->upgrade_directory;
 187   my $sqltargs  = $self->sqltargs;
 188   my $version = $schema->schema_version;
 189
 190   my $sqlt = SQL::Translator->new({
 191     add_drop_table          => 1,
 192     ignore_constraint_names => 1,
 193     ignore_index_names      => 1,
 194     parser                  => 'SQL::Translator::Parser::DBIx::Class',
 195     %{$sqltargs}
 196   });
 197
 198   my $sqlt_schema = $sqlt->translate({ data => $schema })
 199     or $self->throw_exception($sqlt->error);
 200
 201   foreach my $db (@$databases) {
 202     $sqlt->reset;
 203     $sqlt->{schema} = $sqlt_schema;
 204     $sqlt->producer($db);
 205
 206     my $filename = $self->_ddl_schema_produce_filename($db, $version, $dir);
 207     if (-e $filename ) {
 208       carp "Overwriting existing DDL file - $filename";
 209       unlink $filename;
 210     }
 211
 212     my $output = $sqlt->translate;
 213     if(!$output) {
 214       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
 215       next;
 216     }
 217     my $file;
 218     unless( open $file, q(>), $filename ) {
 219       $self->throw_exception("Can't open $filename for writing ($!)");
 220       next;
 221     }
 222     print {$file} $output;
 223     close $file;
 224   }
 225 }
 226
 227 sub prepare_upgrade {
 228   my ($self, $from_version, $to_version, $version_set) = @_;
 229
 230   $from_version ||= $self->db_version;
 231   $to_version   ||= $self->schema_version;
 232
 233   # for updates prepared automatically (rob's stuff)
 234   # one would want to explicitly set $version_set to
 235   # [$to_version]
 236   $version_set  ||= [$from_version, $to_version];
 237
 238   $self->_prepare_changegrade($from_version, $to_version, $version_set, 'up');
 239 }
 240
 241 sub prepare_downgrade {
 242   my ($self, $from_version, $to_version, $version_set) = @_;
 243
 244   $from_version ||= $self->db_version;
 245   $to_version   ||= $self->schema_version;
 246
 247   # for updates prepared automatically (rob's stuff)
 248   # one would want to explicitly set $version_set to
 249   # [$to_version]
 250   $version_set  ||= [$from_version, $to_version];
 251
 252   $self->_prepare_changegrade($from_version, $to_version, $version_set, 'down');
 253 }
 254
 255 method _prepare_changegrade($from_version, $to_version, $version_set, $direction) {
 256   my $schema    = $self->schema;
 257   my $databases = $self->databases;
 258   my $dir       = $self->upgrade_directory;
 259   my $sqltargs  = $self->sqltargs;
 260
 261   my $schema_version = $schema->schema_version;
 262
 263   $sqltargs = {
 264     add_drop_table => 1,
 265     ignore_constraint_names => 1,
 266     ignore_index_names => 1,
 267     %{$sqltargs}
 268   };
 269
 270   my $sqlt = SQL::Translator->new( $sqltargs );
 271
 272   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
 273   my $sqlt_schema = $sqlt->translate({ data => $schema })
 274     or $self->throw_exception ($sqlt->error);
 275
 276   foreach my $db (@$databases) {
 277     $sqlt->reset;
 278     $sqlt->{schema} = $sqlt_schema;
 279     $sqlt->producer($db);
 280
 281     my $prefilename = $self->_ddl_schema_produce_filename($db, $from_version, $dir);
 282     unless(-e $prefilename) {
 283       carp("No previous schema file found ($prefilename)");
 284       next;
 285     }
 286     my $diff_file_method = "_ddl_schema_${direction}_produce_filename";
 287     my $diff_file = $self->$diff_file_method($db, $version_set, $dir );
 288     if(-e $diff_file) {
 289       carp("Overwriting existing $direction-diff file - $diff_file");
 290       unlink $diff_file;
 291     }
 292
 293     my $source_schema;
 294     {
 295       my $t = SQL::Translator->new({
 296          %{$sqltargs},
 297          debug => 0,
 298          trace => 0,
 299       });
 300
 301       $t->parser( $db ) # could this really throw an exception?
 302         or $self->throw_exception ($t->error);
 303
 304       my $out = $t->translate( $prefilename )
 305         or $self->throw_exception ($t->error);
 306
 307       $source_schema = $t->schema;
 308
 309       $source_schema->name( $prefilename )
 310         unless  $source_schema->name;
 311     }
 312
 313     # The "new" style of producers have sane normalization and can support
 314     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
 315     # And we have to diff parsed SQL against parsed SQL.
 316     my $dest_schema = $sqlt_schema;
 317
 318     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
 319       my $t = SQL::Translator->new({
 320          %{$sqltargs},
 321          debug => 0,
 322          trace => 0,
 323       });
 324
 325       $t->parser( $db ) # could this really throw an exception?
 326         or $self->throw_exception ($t->error);
 327
 328       my $filename = $self->_ddl_schema_produce_filename($db, $to_version, $dir);
 329       my $out = $t->translate( $filename )
 330         or $self->throw_exception ($t->error);
 331
 332       $dest_schema = $t->schema;
 333
 334       $dest_schema->name( $filename )
 335         unless $dest_schema->name;
 336     }
 337
 338     my $diff = SQL::Translator::Diff::schema_diff(
 339        $source_schema, $db,
 340        $dest_schema,   $db,
 341        $sqltargs
 342     );
 343     my $file;
 344     unless(open $file, q(>), $diff_file) {
 345       $self->throw_exception("Can't write to $diff_file ($!)");
 346       next;
 347     }
 348     print {$file} $diff;
 349     close $file;
 350   }
 351 }
 352
 353 method _read_sql_file($file) {
 354   return unless $file;
 355
 356   open my $fh, '<', $file or carp("Can't open upgrade file, $file ($!)");
 357   my @data = split /\n/, join '', <$fh>;
 358   close $fh;
 359
 360   @data = grep {
 361     $_ &&
 362     !/^--/ &&
 363     !/^(BEGIN|BEGIN TRANSACTION|COMMIT)/m
 364   } split /;/,
 365     join '', @data;
 366
 367   return \@data;
 368 }
 369
 370 # these are exactly the same for now
 371 sub _downgrade_single_step {
 372   my $self = shift;
 373   my @version_set = @{ shift @_ };
 374   my @upgrade_files = @{$self->_ddl_schema_up_consume_filenames(
 375     $self->storage->sqlt_type,
 376     \@version_set,
 377   )};
 378
 379   for my $upgrade_file (@upgrade_files) {
 380     unless (-f $upgrade_file) {
 381       # croak?
 382       carp "Upgrade not possible, no upgrade file found ($upgrade_file), please create one\n";
 383       return;
 384     }
 385
 386     $self->_filedata($self->_read_sql_file($upgrade_file)); # I don't like this --fREW 2010-02-22
 387
 388     my $guard = $self->schema->txn_scope_guard if $self->txn_wrap;
 389     $self->_do_upgrade;
 390     $guard->commit if $self->txn_wrap;
 391   }
 392 }
 393
 394 sub _upgrade_single_step {
 395   my $self = shift;
 396   my @version_set = @{ shift @_ };
 397   my @upgrade_files = @{$self->_ddl_schema_up_consume_filenames(
 398     $self->storage->sqlt_type,
 399     \@version_set,
 400   )};
 401
 402   for my $upgrade_file (@upgrade_files) {
 403     unless (-f $upgrade_file) {
 404       # croak?
 405       carp "Upgrade not possible, no upgrade file found ($upgrade_file), please create one\n";
 406       return;
 407     }
 408
 409     $self->_filedata($self->_read_sql_file($upgrade_file)); # I don't like this --fREW 2010-02-22
 410     my $guard = $self->schema->txn_scope_guard if $self->txn_wrap;
 411     $self->_do_upgrade;
 412     $guard->commit if $self->txn_wrap;
 413   }
 414 }
 415
 416 method _do_upgrade { $self->_run_upgrade(qr/.*?/) }
 417
 418 method _run_upgrade($stm) {
 419   return unless $self->_filedata;
 420   my @statements = grep { $_ =~ $stm } @{$self->_filedata};
 421
 422   for (@statements) {
 423     $self->storage->debugobj->query_start($_) if $self->storage->debug;
 424     $self->_apply_statement($_);
 425     $self->storage->debugobj->query_end($_) if $self->storage->debug;
 426   }
 427 }
 428
 429 method _apply_statement($statement) {
 430   # croak?
 431   $self->storage->dbh->do($_) or carp "SQL was: $_"
 432 }
 433
 434 1;
 435
 436 __END__
 437
 438 vim: ts=2 sw=2 expandtab