lib/DBIx/Class/DeploymentHandler/DeployMethod/SQL/Translator.pm

   1 package DBIx::Class::DeploymentHandler::DeployMethod::SQL::Translator;
   2 use Moose;
   3 use Method::Signatures::Simple;
   4 use Try::Tiny;
   5 use SQL::Translator;
   6 require SQL::Translator::Diff;
   7 require DBIx::Class::Storage;   # loaded for type constraint
   8 use autodie;
   9 use File::Path;
  10
  11 with 'DBIx::Class::DeploymentHandler::HandlesDeploy';
  12
  13 use Carp 'carp';
  14
  15 has schema => (
  16   isa      => 'DBIx::Class::Schema',
  17   is       => 'ro',
  18   required => 1,
  19   handles => [qw( schema_version )],
  20 );
  21
  22 has storage => (
  23   isa        => 'DBIx::Class::Storage',
  24   is         => 'ro',
  25   lazy_build => 1,
  26 );
  27
  28 method _build_storage {
  29   my $s = $self->schema->storage;
  30   $s->_determine_driver;
  31   $s
  32 }
  33
  34 has sqltargs => (
  35   isa => 'HashRef',
  36   is  => 'ro',
  37   default => sub { {} },
  38 );
  39 has upgrade_directory => (
  40   isa      => 'Str',
  41   is       => 'ro',
  42   required => 1,
  43   default  => 'sql',
  44 );
  45
  46 has databases => (
  47   coerce  => 1,
  48   isa     => 'DBIx::Class::DeploymentHandler::Databases',
  49   is      => 'ro',
  50   default => sub { [qw( MySQL SQLite PostgreSQL )] },
  51 );
  52
  53 has _filedata => (
  54   isa => 'ArrayRef[Str]',
  55   is  => 'rw',
  56 );
  57
  58 method __ddl_consume_with_prefix($type, $versions, $prefix) {
  59   my $base_dir = $self->upgrade_directory;
  60
  61   my $main    = File::Spec->catfile( $base_dir, $type                         );
  62   my $generic = File::Spec->catfile( $base_dir, '_generic'                    );
  63   my $common =  File::Spec->catfile( $base_dir, '_common', $prefix, join q(-), @{$versions} );
  64
  65   my $dir;
  66   if (-d $main) {
  67     $dir = File::Spec->catfile($main, $prefix, join q(-), @{$versions})
  68   } elsif (-d $generic) {
  69     $dir = File::Spec->catfile($main, $prefix, join q(-), @{$versions})
  70   } else {
  71     die 'PREPARE TO SQL'
  72   }
  73
  74   opendir my($dh), $dir;
  75   my %files = map { $_ => "$dir/$_" } grep { /\.sql$/ && -f "$dir/$_" } readdir($dh);
  76   closedir $dh;
  77
  78   if (-d $common) {
  79     opendir my($dh), $common;
  80     for my $filename (grep { /\.sql$/ && -f "$common/$_" } readdir($dh)) {
  81       unless ($files{$filename}) {
  82         $files{$filename} = "$common/$_";
  83       }
  84     }
  85     closedir $dh;
  86   }
  87
  88   return [@files{sort keys %files}]
  89 }
  90
  91 method _ddl_schema_consume_filenames($type, $version) {
  92   $self->__ddl_consume_with_prefix($type, [ $version ], 'schema')
  93 }
  94
  95 method _ddl_schema_produce_filename($type, $version) {
  96   my $base_dir = $self->upgrade_directory;
  97   my $dirname = File::Spec->catfile(
  98     $base_dir, $type, 'schema', $version
  99   );
 100   File::Path::mkpath($dirname) unless -d $dirname;
 101
 102   return File::Spec->catfile(
 103     $dirname, '001-auto.sql'
 104   );
 105 }
 106
 107 method _ddl_schema_up_consume_filenames($type, $versions) {
 108   $self->__ddl_consume_with_prefix($type, $versions, 'up')
 109 }
 110
 111 method _ddl_schema_down_consume_filenames($type, $versions) {
 112   $self->__ddl_consume_with_prefix($type, $versions, 'down')
 113 }
 114
 115 method _ddl_schema_up_produce_filename($type, $versions) {
 116   my $dir = $self->upgrade_directory;
 117
 118   my $dirname = File::Spec->catfile(
 119     $dir, $type, 'up', join( q(-), @{$versions} )
 120   );
 121   File::Path::mkpath($dirname) unless -d $dirname;
 122
 123   return File::Spec->catfile(
 124     $dirname, '001-auto.sql'
 125   );
 126 }
 127
 128 method _ddl_schema_down_produce_filename($type, $versions, $dir) {
 129   my $dirname = File::Spec->catfile(
 130     $dir, $type, 'down', join( q(-), @{$versions} )
 131   );
 132   File::Path::mkpath($dirname) unless -d $dirname;
 133
 134   return File::Spec->catfile(
 135     $dirname, '001-auto.sql'
 136   );
 137 }
 138
 139 method _deployment_statements {
 140   my $dir      = $self->upgrade_directory;
 141   my $schema   = $self->schema;
 142   my $type     = $self->storage->sqlt_type;
 143   my $sqltargs = $self->sqltargs;
 144   my $version  = $self->schema_version;
 145
 146   my @filenames = @{$self->_ddl_schema_consume_filenames($type, $version)};
 147
 148   for my $filename (@filenames) {
 149     if(-f $filename) {
 150         my $file;
 151         open $file, q(<), $filename
 152           or carp "Can't open $filename ($!)";
 153         my @rows = <$file>;
 154         close $file;
 155         return join '', @rows;
 156     }
 157   }
 158
 159   # sources needs to be a parser arg, but for simplicty allow at top level
 160   # coming in
 161   $sqltargs->{parser_args}{sources} = delete $sqltargs->{sources}
 162       if exists $sqltargs->{sources};
 163
 164   my $tr = SQL::Translator->new(
 165     producer => "SQL::Translator::Producer::${type}",
 166     %$sqltargs,
 167     parser => 'SQL::Translator::Parser::DBIx::Class',
 168     data => $schema,
 169   );
 170
 171   my $ret = $tr->translate;
 172
 173   $schema->throw_exception( 'Unable to produce deployment statements: ' . $tr->error)
 174     unless defined $ret;
 175
 176   return $ret;
 177 }
 178
 179 sub _deploy {
 180   my $self = shift;
 181   my $storage  = $self->storage;
 182
 183   my $deploy = sub {
 184     my $line = shift;
 185 #< frew> k, also, we filter out comments and transaction stuff and blank lines
 186 #< frew> is that really necesary?
 187 #< frew> and what if I want to run my upgrade in a txn?  seems like something you'd
 188 #        always want to do really
 189 #< ribasushi> again - some stuff chokes
 190 #< frew> ok, so I see filtering out -- and \s*
 191 #< frew> but I think the txn filtering should be optional and default to NOT filter it
 192 #        out
 193 #< ribasushi> then you have a problem
 194 #< frew> tell me
 195 #< ribasushi> someone runs a deploy in txn_do
 196 #< ribasushi> the inner begin will blow up
 197 #< frew> because it's a nested TXN?
 198 #< ribasushi> (you an't begin twice on most dbs)
 199 #< ribasushi> right
 200 #< ribasushi> on sqlite - for sure
 201 #< frew> so...read the docs and set txn_filter to true?
 202 #< ribasushi> more like wrap deploy in a txn
 203 #< frew> I like that better
 204 #< ribasushi> and make sure the ddl has no literal txns in them
 205 #< frew> sure
 206 #< ribasushi> this way you have stuff under control
 207 #< frew> so we have txn_wrap default to true
 208 #< frew> and if people wanna do that by hand they can
 209
 210     return if(!$line || $line =~ /^--|^BEGIN TRANSACTION|^COMMIT|^\s+$/);
 211     $storage->_query_start($line);
 212     try {
 213       # do a dbh_do cycle here, as we need some error checking in
 214       # place (even though we will ignore errors)
 215       $storage->dbh_do (sub { $_[1]->do($line) });
 216     }
 217     catch {
 218       carp "$_ (running '${line}')"
 219     }
 220     $storage->_query_end($line);
 221   };
 222   my @statements = $self->_deployment_statements();
 223   if (@statements > 1) {
 224     foreach my $statement (@statements) {
 225       $deploy->( $statement );
 226     }
 227   }
 228   elsif (@statements == 1) {
 229     foreach my $line ( split(";\n", $statements[0])) {
 230       $deploy->( $line );
 231     }
 232   }
 233 }
 234
 235 sub prepare_install {
 236   my $self = shift;
 237   my $schema    = $self->schema;
 238   my $databases = $self->databases;
 239   my $dir       = $self->upgrade_directory;
 240   my $sqltargs  = $self->sqltargs;
 241   my $version = $schema->schema_version;
 242
 243   unless( -d $dir ) {
 244     carp "Upgrade directory $dir does not exist, using ./\n";
 245     $dir = './';
 246   }
 247
 248
 249   my $sqlt = SQL::Translator->new({
 250     add_drop_table          => 1,
 251     ignore_constraint_names => 1,
 252     ignore_index_names      => 1,
 253     parser                  => 'SQL::Translator::Parser::DBIx::Class',
 254     %{$sqltargs || {}}
 255   });
 256
 257   my $sqlt_schema = $sqlt->translate({ data => $schema })
 258     or $self->throw_exception ($sqlt->error);
 259
 260   foreach my $db (@$databases) {
 261     $sqlt->reset;
 262     $sqlt->{schema} = $sqlt_schema;
 263     $sqlt->producer($db);
 264
 265     my $filename = $self->_ddl_schema_produce_filename($db, $version, $dir);
 266     if (-e $filename ) {
 267       carp "Overwriting existing DDL file - $filename";
 268       unlink $filename;
 269     }
 270
 271     my $output = $sqlt->translate;
 272     if(!$output) {
 273       carp("Failed to translate to $db, skipping. (" . $sqlt->error . ")");
 274       next;
 275     }
 276     my $file;
 277     unless( open $file, q(>), $filename ) {
 278       $self->throw_exception("Can't open $filename for writing ($!)");
 279       next;
 280     }
 281     print {$file} $output;
 282     close $file;
 283   }
 284 }
 285
 286 sub prepare_upgrade {
 287   my ($self, $from_version, $to_version, $version_set) = @_;
 288
 289   $from_version ||= $self->db_version;
 290   $to_version   ||= $self->schema_version;
 291
 292   # for updates prepared automatically (rob's stuff)
 293   # one would want to explicitly set $version_set to
 294   # [$to_version]
 295   $version_set  ||= [$from_version, $to_version];
 296
 297   $self->_prepare_changegrade($from_version, $to_version, $version_set, 'up');
 298 }
 299
 300 sub prepare_downgrade {
 301   my ($self, $from_version, $to_version, $version_set) = @_;
 302
 303   $from_version ||= $self->db_version;
 304   $to_version   ||= $self->schema_version;
 305
 306   # for updates prepared automatically (rob's stuff)
 307   # one would want to explicitly set $version_set to
 308   # [$to_version]
 309   $version_set  ||= [$from_version, $to_version];
 310
 311   $self->_prepare_changegrade($from_version, $to_version, $version_set, 'down');
 312 }
 313
 314 method _prepare_changegrade($from_version, $to_version, $version_set, $direction) {
 315   my $schema    = $self->schema;
 316   my $databases = $self->databases;
 317   my $dir       = $self->upgrade_directory;
 318   my $sqltargs  = $self->sqltargs;
 319
 320   my $schema_version = $schema->schema_version;
 321
 322   $sqltargs = {
 323     add_drop_table => 1,
 324     ignore_constraint_names => 1,
 325     ignore_index_names => 1,
 326     %{$sqltargs}
 327   };
 328
 329   my $sqlt = SQL::Translator->new( $sqltargs );
 330
 331   $sqlt->parser('SQL::Translator::Parser::DBIx::Class');
 332   my $sqlt_schema = $sqlt->translate({ data => $schema })
 333     or $self->throw_exception ($sqlt->error);
 334
 335   foreach my $db (@$databases) {
 336     $sqlt->reset;
 337     $sqlt->{schema} = $sqlt_schema;
 338     $sqlt->producer($db);
 339
 340     my $prefilename = $self->_ddl_schema_produce_filename($db, $from_version, $dir);
 341     unless(-e $prefilename) {
 342       carp("No previous schema file found ($prefilename)");
 343       next;
 344     }
 345     my $diff_file_method = "_ddl_schema_${direction}_produce_filename";
 346     my $diff_file = $self->$diff_file_method($db, $version_set, $dir );
 347     if(-e $diff_file) {
 348       carp("Overwriting existing $direction-diff file - $diff_file");
 349       unlink $diff_file;
 350     }
 351
 352     my $source_schema;
 353     {
 354       my $t = SQL::Translator->new({
 355          %{$sqltargs},
 356          debug => 0,
 357          trace => 0,
 358       });
 359
 360       $t->parser( $db ) # could this really throw an exception?
 361         or $self->throw_exception ($t->error);
 362
 363       my $out = $t->translate( $prefilename )
 364         or $self->throw_exception ($t->error);
 365
 366       $source_schema = $t->schema;
 367
 368       $source_schema->name( $prefilename )
 369         unless  $source_schema->name;
 370     }
 371
 372     # The "new" style of producers have sane normalization and can support
 373     # diffing a SQL file against a DBIC->SQLT schema. Old style ones don't
 374     # And we have to diff parsed SQL against parsed SQL.
 375     my $dest_schema = $sqlt_schema;
 376
 377     unless ( "SQL::Translator::Producer::$db"->can('preprocess_schema') ) {
 378       my $t = SQL::Translator->new({
 379          %{$sqltargs},
 380          debug => 0,
 381          trace => 0,
 382       });
 383
 384       $t->parser( $db ) # could this really throw an exception?
 385         or $self->throw_exception ($t->error);
 386
 387       my $filename = $self->_ddl_schema_produce_filename($db, $to_version, $dir);
 388       my $out = $t->translate( $filename )
 389         or $self->throw_exception ($t->error);
 390
 391       $dest_schema = $t->schema;
 392
 393       $dest_schema->name( $filename )
 394         unless $dest_schema->name;
 395     }
 396
 397     my $diff = SQL::Translator::Diff::schema_diff(
 398        $source_schema, $db,
 399        $dest_schema,   $db,
 400        $sqltargs
 401     );
 402     my $file;
 403     unless(open $file, q(>), $diff_file) {
 404       $self->throw_exception("Can't write to $diff_file ($!)");
 405       next;
 406     }
 407     print {$file} $diff;
 408     close $file;
 409   }
 410 }
 411
 412 method _read_sql_file($file) {
 413   return unless $file;
 414
 415   open my $fh, '<', $file or carp("Can't open upgrade file, $file ($!)");
 416   my @data = split /\n/, join '', <$fh>;
 417   close $fh;
 418
 419   @data = grep {
 420     $_ &&
 421     !/^--/ &&
 422     !/^(BEGIN|BEGIN TRANSACTION|COMMIT)/m
 423   } split /;/,
 424     join '', @data;
 425
 426   return \@data;
 427 }
 428
 429 # these are exactly the same for now
 430 sub _downgrade_single_step {
 431   my $self = shift;
 432   my @version_set = @{ shift @_ };
 433   my @upgrade_files = @{$self->_ddl_schema_up_consume_filenames(
 434     $self->storage->sqlt_type,
 435     \@version_set,
 436   )};
 437
 438   for my $upgrade_file (@upgrade_files) {
 439     unless (-f $upgrade_file) {
 440       # croak?
 441       carp "Upgrade not possible, no upgrade file found ($upgrade_file), please create one\n";
 442       return;
 443     }
 444
 445     $self->_filedata($self->_read_sql_file($upgrade_file)); # I don't like this --fREW 2010-02-22
 446     $self->schema->txn_do(sub { $self->_do_upgrade });
 447   }
 448 }
 449
 450 sub _upgrade_single_step {
 451   my $self = shift;
 452   my @version_set = @{ shift @_ };
 453   my @upgrade_files = @{$self->_ddl_schema_up_consume_filenames(
 454     $self->storage->sqlt_type,
 455     \@version_set,
 456   )};
 457
 458   for my $upgrade_file (@upgrade_files) {
 459     unless (-f $upgrade_file) {
 460       # croak?
 461       carp "Upgrade not possible, no upgrade file found ($upgrade_file), please create one\n";
 462       return;
 463     }
 464
 465     $self->_filedata($self->_read_sql_file($upgrade_file)); # I don't like this --fREW 2010-02-22
 466     $self->schema->txn_do(sub { $self->_do_upgrade });
 467   }
 468 }
 469
 470 method _do_upgrade { $self->_run_upgrade(qr/.*?/) }
 471
 472 method _run_upgrade($stm) {
 473   return unless $self->_filedata;
 474   my @statements = grep { $_ =~ $stm } @{$self->_filedata};
 475
 476   for (@statements) {
 477     $self->storage->debugobj->query_start($_) if $self->storage->debug;
 478     $self->_apply_statement($_);
 479     $self->storage->debugobj->query_end($_) if $self->storage->debug;
 480   }
 481 }
 482
 483 method _apply_statement($statement) {
 484   # croak?
 485   $self->storage->dbh->do($_) or carp "SQL was: $_"
 486 }
 487
 488 1;
 489
 490 __END__
 491
 492 vim: ts=2 sw=2 expandtab