lib/DBIx/Class/DeploymentHandler/Dad.pm

   1 package DBIx::Class::DeploymentHandler::Dad;
   2
   3 use Moose;
   4 use Method::Signatures::Simple;
   5 require DBIx::Class::Schema;    # loaded for type constraint
   6 use Carp::Clan '^DBIx::Class::DeploymentHandler';
   7
   8 has schema => (
   9   isa      => 'DBIx::Class::Schema',
  10   is       => 'ro',
  11   required => 1,
  12   handles => ['schema_version'],
  13 );
  14
  15 has backup_directory => (
  16   isa => 'Str',
  17   is  => 'ro',
  18   predicate  => 'has_backup_directory',
  19 );
  20
  21 has to_version => (
  22   is         => 'ro',
  23   lazy_build => 1,
  24 );
  25
  26 sub _build_to_version { $_[0]->schema->schema_version }
  27
  28 method install {
  29   croak 'Install not possible as versions table already exists in database'
  30     if $self->version_storage_is_installed;
  31
  32   my $ddl = $self->deploy;
  33
  34   $self->add_database_version({
  35     version     => $self->to_version,
  36     ddl         => $ddl,
  37   });
  38 }
  39
  40 sub upgrade {
  41   my $self = shift;
  42   while ( my $version_list = $self->next_version_set ) {
  43     my ($ddl, $upgrade_sql) = @{$self->upgrade_single_step($version_list)||[]};
  44
  45     $self->add_database_version({
  46       version     => $version_list->[-1],
  47       ddl         => $ddl,
  48       upgrade_sql => $upgrade_sql,
  49     });
  50   }
  51 }
  52
  53 sub downgrade {
  54   my $self = shift;
  55   while ( my $version_list = $self->previous_version_set ) {
  56     $self->downgrade_single_step($version_list);
  57
  58     # do we just delete a row here?  I think so but not sure
  59     $self->delete_database_version({ version => $version_list->[-1] });
  60   }
  61 }
  62
  63 method backup { $self->storage->backup($self->backup_directory) }
  64
  65 __PACKAGE__->meta->make_immutable;
  66
  67 1;
  68
  69 # vim: ts=2 sw=2 expandtab
  70
  71 __END__
  72
  73 =pod
  74
  75 =attr schema
  76
  77 The L<DBIx::Class::Schema> (B<required>) that is used to talk to the database
  78 and generate the DDL.
  79
  80 =attr backup_directory
  81
  82 The directory that backups are stored in
  83
  84 =attr to_version
  85
  86 The version (defaults to schema's version) to migrate the database to
  87
  88 =method install
  89
  90  $dh->install
  91
  92 Deploys the current schema into the database.  Populates C<version_storage> with
  93 C<version> and C<ddl>.
  94
  95 B<Note>: you typically need to call C<< $dh->prepare_install >> before you call
  96 this method.
  97
  98 B<Note>: you cannot install on top of an already installed database
  99
 100 =method upgrade
 101
 102  $dh->upgrade
 103
 104 Upgrades the database one step at a time till L</next_version_set>
 105 returns C<undef>.  Each upgrade step will add a C<version>, C<ddl>, and
 106 C<upgrade_sql> to the version storage (if C<ddl> and/or C<upgrade_sql> are
 107 returned from L</upgrade_single_step>.
 108
 109 =method downgrade
 110
 111  $dh->downgrade
 112
 113 Downgrades the database one step at a time till L</previous_version_set>
 114 returns C<undef>.  Each downgrade step will delete a C<version> from the
 115 version storage.
 116
 117 =method backup
 118
 119  $dh->backup
 120
 121 Simply calls backup on the C<< $schema->storage >>, passing in
 122 C<< $self->backup_directory >> as an argument.  Please test yourself before
 123 assuming it will work.
 124
 125 =head1 METHODS THAT ARE REQUIRED IN SUBCLASSES
 126
 127 =head2 deploy
 128
 129 See L<DBIx::Class::DeploymentHandler::HandlesDeploy/deploy>.
 130
 131 =head2 version_storage_is_installed
 132
 133 See L<DBIx::Class::DeploymentHandler::HandlesVersionStorage/version_storage_is_installed>.
 134
 135 =head2 add_database_version
 136
 137 See L<DBIx::Class::DeploymentHandler::HandlesVersionStorage/add_database_version>.
 138
 139 =head2 delete_database_version
 140
 141 See L<DBIx::Class::DeploymentHandler::HandlesVersionStorage/delete_database_version>.
 142
 143 =head2 next_version_set
 144
 145 See L<DBIx::Class::DeploymentHandler::HandlesVersioning/next_version_set>.
 146
 147 =head2 previous_version_set
 148
 149 See L<DBIx::Class::DeploymentHandler::HandlesVersioning/previous_version_set>.
 150
 151 =head2 upgrade_single_step
 152
 153 See L<DBIx::Class::DeploymentHandler::HandlesDeploy/upgrade_single_step>.
 154
 155 =head2 downgrade_single_step
 156
 157 See L<DBIx::Class::DeploymentHandler::HandlesDeploy/downgrade_single_step>.
 158
 159 =head1 ORTHODOX METHODS
 160
 161 These methods are not actually B<required> as things will probably still work
 162 if you don't implement them, but if you want your subclass to get along with
 163 other subclasses (or more likely, tools made to use another subclass), you
 164 should probably implement these too, even if they are no-ops.
 165
 166 =head2 database_version
 167
 168 see L<DBIx::Class::DeploymentHandler::HandlesVersionStorage/database_version>
 169
 170 =head2 prepare_install
 171
 172 see L<DBIx::Class::DeploymentHandler::HandlesDeploy/prepare_install>
 173
 174 =head2 prepare_resultsource_install
 175
 176 see L<DBIx::Class::DeploymentHandler::HandlesDeploy/prepare_resultsource_install>
 177
 178 =head2 install_resultsource
 179
 180 see L<DBIx::Class::DeploymentHandler::HandlesDeploy/install_resultsource>
 181
 182 =head2 prepare_upgrade
 183
 184 see L<DBIx::Class::DeploymentHandler::HandlesDeploy/prepare_upgrade>
 185
 186 =head2 prepare_downgrade
 187
 188 see L<DBIx::Class::DeploymentHandler::HandlesDeploy/prepare_downgrade>
 189
 190 =back
 191
 192 =head2 SUBCLASSING
 193
 194 All of the methods mentioned in L</METHODS THAT ARE REQUIRED IN SUBCLASSES> and
 195 L</ORTHODOX METHODS> can be implemented in any fashion you choose.  In the
 196 spirit of code reuse I have used roles to implement them in my two subclasses,
 197 L<DBIx::Class::DeploymentHandler> and
 198 L<DBIx::Class::DeploymentHandler::Deprecated>, but you are free to implement
 199 them entirely in a subclass if you so choose to.
 200
 201 For in-depth documentation on how methods are supposed to work, see the roles
 202 L<DBIx::Class::DeploymentHandler::HandlesDeploy>,
 203 L<DBIx::Class::DeploymentHandler::HandlesVersioning>, and
 204 L<DBIx::Class::DeploymentHandler::HandlesVersionStorage>.
 205