lib/DBIx/Class/DeploymentHandler/Dad.pm

   1 package DBIx::Class::DeploymentHandler::Dad;
   2
   3 # ABSTRACT: Parent class for DeploymentHandlers
   4
   5 use Moose;
   6 use Method::Signatures::Simple;
   7 require DBIx::Class::Schema;    # loaded for type constraint
   8 use Carp::Clan '^DBIx::Class::DeploymentHandler';
   9 use DBIx::Class::DeploymentHandler::Logger;
  10 use Log::Contextual ':log', -default_logger =>
  11   DBIx::Class::DeploymentHandler::Logger->new({
  12     env_prefix => 'DBICDH'
  13   });
  14
  15 has schema => (
  16   isa      => 'DBIx::Class::Schema',
  17   is       => 'ro',
  18   required => 1,
  19 );
  20
  21 has backup_directory => (
  22   isa => 'Str',
  23   is  => 'ro',
  24   predicate  => 'has_backup_directory',
  25 );
  26
  27 has to_version => (
  28   is         => 'ro',
  29   isa        => 'Str',
  30   lazy_build => 1,
  31 );
  32
  33 sub _build_to_version { $_[0]->schema_version }
  34
  35 has schema_version => (
  36   is         => 'ro',
  37   isa        => 'Str',
  38   lazy_build => 1,
  39 );
  40
  41 sub _build_schema_version { $_[0]->schema->schema_version }
  42
  43 method install {
  44   log_info { 'installing version ' . $self->to_version };
  45   croak 'Install not possible as versions table already exists in database'
  46     if $self->version_storage_is_installed;
  47
  48   my $ddl = $self->deploy;
  49
  50   $self->add_database_version({
  51     version     => $self->to_version,
  52     ddl         => $ddl,
  53   });
  54 }
  55
  56 sub upgrade {
  57   log_info { 'upgrading' };
  58   my $self = shift;
  59   my $ran_once = 0;
  60   while ( my $version_list = $self->next_version_set ) {
  61     $ran_once = 1;
  62     my ($ddl, $upgrade_sql) = @{
  63       $self->upgrade_single_step({ version_set => $version_list })
  64     ||[]};
  65
  66     $self->add_database_version({
  67       version     => $version_list->[-1],
  68       ddl         => $ddl,
  69       upgrade_sql => $upgrade_sql,
  70     });
  71   }
  72
  73   log_warn { 'no need to run upgrade' } unless $ran_once;
  74 }
  75
  76 sub downgrade {
  77   log_info { 'upgrading' };
  78   my $self = shift;
  79   my $ran_once = 0;
  80   while ( my $version_list = $self->previous_version_set ) {
  81     $ran_once = 1;
  82     $self->downgrade_single_step({ version_set => $version_list });
  83
  84     # do we just delete a row here?  I think so but not sure
  85     $self->delete_database_version({ version => $version_list->[-1] });
  86   }
  87   log_warn { 'no version to run downgrade' } unless $ran_once;
  88 }
  89
  90 method backup {
  91   log_info { 'backing up' };
  92   $self->storage->backup($self->backup_directory)
  93 }
  94
  95 __PACKAGE__->meta->make_immutable;
  96
  97 1;
  98
  99 # vim: ts=2 sw=2 expandtab
 100
 101 __END__
 102
 103 =pod
 104
 105 =attr schema
 106
 107 The L<DBIx::Class::Schema> (B<required>) that is used to talk to the database
 108 and generate the DDL.
 109
 110 =attr schema_version
 111
 112 The version that the schema is currently at.  Defaults to
 113 C<< $self->schema->schema_version >>.
 114
 115 =attr backup_directory
 116
 117 The directory where backups are stored
 118
 119 =attr to_version
 120
 121 The version (defaults to schema's version) to migrate the database to
 122
 123 =method install
 124
 125  $dh->install
 126
 127 Deploys the current schema into the database.  Populates C<version_storage> with
 128 C<version> and C<ddl>.
 129
 130 B<Note>: you typically need to call C<< $dh->prepare_deploy >> before you call
 131 this method.
 132
 133 B<Note>: you cannot install on top of an already installed database
 134
 135 =method upgrade
 136
 137  $dh->upgrade
 138
 139 Upgrades the database one step at a time till L</next_version_set>
 140 returns C<undef>.  Each upgrade step will add a C<version>, C<ddl>, and
 141 C<upgrade_sql> to the version storage (if C<ddl> and/or C<upgrade_sql> are
 142 returned from L</upgrade_single_step>.
 143
 144 =method downgrade
 145
 146  $dh->downgrade
 147
 148 Downgrades the database one step at a time till L</previous_version_set>
 149 returns C<undef>.  Each downgrade step will delete a C<version> from the
 150 version storage.
 151
 152 =method backup
 153
 154  $dh->backup
 155
 156 Simply calls backup on the C<< $schema->storage >>, passing in
 157 C<< $self->backup_directory >> as an argument.  Please test yourself before
 158 assuming it will work.
 159
 160 =head1 METHODS THAT ARE REQUIRED IN SUBCLASSES
 161
 162 =head2 deploy
 163
 164 See L<DBIx::Class::DeploymentHandler::HandlesDeploy/deploy>.
 165
 166 =head2 version_storage_is_installed
 167
 168 See L<DBIx::Class::DeploymentHandler::HandlesVersionStorage/version_storage_is_installed>.
 169
 170 =head2 add_database_version
 171
 172 See L<DBIx::Class::DeploymentHandler::HandlesVersionStorage/add_database_version>.
 173
 174 =head2 delete_database_version
 175
 176 See L<DBIx::Class::DeploymentHandler::HandlesVersionStorage/delete_database_version>.
 177
 178 =head2 next_version_set
 179
 180 See L<DBIx::Class::DeploymentHandler::HandlesVersioning/next_version_set>.
 181
 182 =head2 previous_version_set
 183
 184 See L<DBIx::Class::DeploymentHandler::HandlesVersioning/previous_version_set>.
 185
 186 =head2 upgrade_single_step
 187
 188 See L<DBIx::Class::DeploymentHandler::HandlesDeploy/upgrade_single_step>.
 189
 190 =head2 downgrade_single_step
 191
 192 See L<DBIx::Class::DeploymentHandler::HandlesDeploy/downgrade_single_step>.
 193
 194 =head1 ORTHODOX METHODS
 195
 196 These methods are not actually B<required> as things will probably still work
 197 if you don't implement them, but if you want your subclass to get along with
 198 other subclasses (or more likely, tools made to use another subclass), you
 199 should probably implement these too, even if they are no-ops.
 200
 201 =head2 database_version
 202
 203 see L<DBIx::Class::DeploymentHandler::HandlesVersionStorage/database_version>
 204
 205 =head2 prepare_deploy
 206
 207 see L<DBIx::Class::DeploymentHandler::HandlesDeploy/prepare_deploy>
 208
 209 =head2 prepare_resultsource_install
 210
 211 see L<DBIx::Class::DeploymentHandler::HandlesDeploy/prepare_resultsource_install>
 212
 213 =head2 install_resultsource
 214
 215 see L<DBIx::Class::DeploymentHandler::HandlesDeploy/install_resultsource>
 216
 217 =head2 prepare_upgrade
 218
 219 see L<DBIx::Class::DeploymentHandler::HandlesDeploy/prepare_upgrade>
 220
 221 =head2 prepare_downgrade
 222
 223 see L<DBIx::Class::DeploymentHandler::HandlesDeploy/prepare_downgrade>
 224
 225 =head2 SUBCLASSING
 226
 227 All of the methods mentioned in L</METHODS THAT ARE REQUIRED IN SUBCLASSES> and
 228 L</ORTHODOX METHODS> can be implemented in any fashion you choose.  In the
 229 spirit of code reuse I have used roles to implement them in my two subclasses,
 230 L<DBIx::Class::DeploymentHandler> and
 231 L<DBIx::Class::DeploymentHandler::Deprecated>, but you are free to implement
 232 them entirely in a subclass if you so choose to.
 233
 234 For in-depth documentation on how methods are supposed to work, see the roles
 235 L<DBIx::Class::DeploymentHandler::HandlesDeploy>,
 236 L<DBIx::Class::DeploymentHandler::HandlesVersioning>, and
 237 L<DBIx::Class::DeploymentHandler::HandlesVersionStorage>.
 238