lib/XML/Feed/Entry.pm

   1 # $Id$
   2
   3 package XML::Feed::Entry;
   4 use strict;
   5 use base qw( Class::ErrorHandler );
   6
   7 use Scalar::Util qw( blessed );
   8
   9 use Carp;
  10
  11 sub wrap {
  12     my $class = shift;
  13     my($item) = @_;
  14     bless { entry => $item }, $class;
  15 }
  16
  17 sub unwrap { $_[0]->{entry} }
  18
  19 sub new {
  20     my $class = shift;
  21     my($format) = @_;
  22     $format ||= 'Atom';
  23     my $format_class = 'XML::Feed::Format::' . $format;
  24     eval "use $format_class";
  25     Carp::croak("Unsupported format $format: $@") if $@;
  26     my $entry = bless {}, join('::', __PACKAGE__, "Format", $format);
  27     $entry->init_empty or return $class->error($entry->errstr);
  28     $entry;
  29 }
  30
  31 sub init_empty { 1 }
  32
  33 sub convert {
  34     my $entry = shift;
  35     my($format) = @_;
  36     my $new = __PACKAGE__->new($format);
  37     for my $field (qw( title link content summary category author id issued modified lat long )) {
  38         my $val = $entry->$field();
  39         next unless defined $val;
  40         next if blessed $val && $val->isa('XML::Feed::Content') && ! defined $val->body;
  41         $new->$field($val);
  42     }
  43     $new;
  44 }
  45
  46 sub title;
  47 sub link;
  48 sub content;
  49 sub summary;
  50 sub category;
  51 sub author;
  52 sub id;
  53 sub issued;
  54 sub modified;
  55 sub lat;
  56 sub long;
  57 sub format;
  58 sub tags { shift->category(@_) }
  59
  60 1;
  61 __END__
  62
  63 =head1 NAME
  64
  65 XML::Feed::Entry - Entry/item in a syndication feed
  66
  67 =head1 SYNOPSIS
  68
  69     ## $feed is an XML::Feed object.
  70     for my $entry ($feed->entries) {
  71         print $entry->title, "\n", $entry->summary, "\n\n";
  72     }
  73
  74 =head1 DESCRIPTION
  75
  76 I<XML::Feed::Entry> represents an entry/item in an I<XML::Feed> syndication
  77 feed.
  78
  79 =head1 USAGE
  80
  81 =head2 XML::Feed::Entry->new($format)
  82
  83 Creates a new I<XML::Feed::Entry> object in the format I<$format>, which
  84 should be either I<RSS> or I<Atom>.
  85
  86 =head2 $entry->convert($format)
  87
  88 Converts the I<XML::Feed::Entry> object into the I<$format> format, and
  89 returns the new object.
  90
  91 =head2 $entry->title([ $title ])
  92
  93 The title of the entry.
  94
  95 =head2 $entry->base([ $base ])
  96
  97 The url base of the entry.
  98
  99 =head2 $entry->link([ $uri ])
 100
 101 The permalink of the entry, in most cases, except in cases where it points
 102 instead to an offsite URI referenced in the entry.
 103
 104 =head2 $entry->content([ $content ])
 105
 106 Bn I<XML::Feed::Content> object representing the full entry body, or as
 107 much as is available in the feed.
 108
 109 In RSS feeds, this method will look first for
 110 I<http://purl.org/rss/1.0/modules/content/#encoded> and
 111 I<http://www.w3.org/1999/xhtml#body> elements, then fall back to a
 112 I<E<lt>descriptionE<gt>> element.
 113
 114 =head2 $entry->summary([ $summary ])
 115
 116 An I<XML::Feed::Content> object representing a short summary of the entry.
 117 Possibly.
 118
 119 Since RSS feeds do not have the idea of a summary separate from the entry
 120 body, this may not always be what you want. If the entry contains both a
 121 I<E<lt>descriptionE<gt>> element B<and> another element typically used for
 122 the full content of the entry--either I<http://www.w3.org/1999/xhtml/body>
 123 or I<http://purl.org/rss/1.0/modules/content/#encoded>--we treat that as
 124 the summary. Otherwise, we assume that there isn't a summary, and return
 125 an I<XML::Feed::Content> object with an empty string in the I<body>.
 126
 127 =head2 $entry->category([ $category ])
 128
 129 The category in which the entry was posted.
 130
 131 Returns a list of categories if called in array context or the first
 132 category if called in scalar context.
 133
 134 =head2 $entry->tags([ $tag ])
 135
 136 A synonym for I<category>;
 137
 138 =head2 $entry->author([ $author ])
 139
 140 The name or email address of the person who posted the entry.
 141
 142 =head2 $entry->id([ $id ])
 143
 144 The unique ID of the entry.
 145
 146 =head2 $entry->issued([ $issued ])
 147
 148 A I<DateTime> object representing the date and time at which the entry
 149 was posted.
 150
 151 If present, I<$issued> should be a I<DateTime> object.
 152
 153 =head2 $entry->modified([ $modified ])
 154
 155 A I<DateTime> object representing the last-modified date of the entry.
 156
 157 If present, I<$modified> should be a I<DateTime> object.
 158
 159 =head2 $entry->wrap
 160
 161 Take an entry in its native format and turn it into an I<XML::Feed::Entry> object.
 162
 163 =head2 $entry->unwrap
 164
 165 Take an I<XML::Feed::Entry> object and turn it into its native format.
 166
 167 =head1 AUTHOR & COPYRIGHT
 168
 169 Please see the I<XML::Feed> manpage for author, copyright, and license
 170 information.
 171
 172 =cut