[catagits/XML-Feed.git] / lib / XML / Feed / Format / Atom.pm

# $Id$

package XML::Feed::Format::Atom;
use strict;

use base qw( XML::Feed );
use XML::Atom::Feed;
use XML::Atom::Util qw( iso2dt );
use List::Util qw( first );
use DateTime::Format::W3CDTF;
use HTML::Entities;

use XML::Atom::Entry;
XML::Atom::Entry->mk_elem_accessors(qw( lat long ), ['http://www.w3.org/2003/01/geo/wgs84_pos#']);

use XML::Atom::Content;

sub identify {
    my $class   = shift;
    my $xml     = shift;
    my $tag     = $class->_get_first_tag($xml);
    return ($tag eq 'feed');
}


sub init_empty {
    my ($feed, %args) = @_;
    $args{'Version'} ||= '1.0';
    
    $feed->{atom} = XML::Atom::Feed->new(%args);
    $feed;
}

sub init_string {
    my $feed = shift;
    my($str) = @_;
    if ($str) {
        $feed->{atom} = XML::Atom::Feed->new(Stream => $str)
            or return $feed->error(XML::Atom::Feed->errstr);
    }
    $feed;
}

sub format { 'Atom' }

sub title { shift->{atom}->title(@_) }
sub link {
    my $feed = shift;
    if (@_) {
        $feed->{atom}->add_link({ rel => 'alternate', href => $_[0],
                                  type => 'text/html', });
    } else {
        my $l = first { !defined $_->rel || $_->rel eq 'alternate' } $feed->{atom}->link;
        $l ? $l->href : undef;
    }
}

sub self_link {
    my $feed = shift;
    if (@_) {
        my $uri = shift;
        $feed->{atom}->add_link({type => "application/atom+xml", rel => "self", href => $uri});
        return $uri;
    } 
    else
    {
        my $l =
            first
            { !defined $_->rel || $_->rel eq 'self' }
            $feed->{atom}->link;
            ;

        return $l ? $l->href : undef;
    }
}

sub description { shift->{atom}->tagline(@_) }
sub copyright   { shift->{atom}->copyright(@_) }
sub language    { shift->{atom}->language(@_) }
sub generator   { shift->{atom}->generator(@_) }
sub id          { shift->{atom}->id(@_) }
sub updated     { shift->{atom}->updated(@_) }
sub add_link    { shift->{atom}->add_link(@_) }
sub base        { shift->{atom}->base(@_) }

sub author {
    my $feed = shift;
    if (@_ && $_[0]) {
        my $person = XML::Atom::Person->new(Version => 1.0);
        $person->name($_[0]);
        $feed->{atom}->author($person);
    } else {
        $feed->{atom}->author ? $feed->{atom}->author->name : undef;
    }
}


sub modified {
    my $feed = shift;
    if (@_) {
        $feed->{atom}->modified(DateTime::Format::W3CDTF->format_datetime($_[0]));
    } else {
        return iso2dt($feed->{atom}->modified) if $feed->{atom}->modified;
        return iso2dt($feed->{atom}->updated)  if $feed->{atom}->updated;
        return undef;
    }
}

sub entries {
    my @entries;
    for my $entry ($_[0]->{atom}->entries) {
        push @entries, XML::Feed::Entry::Format::Atom->wrap($entry);
    }

    @entries;
}

sub add_entry {
    my $feed  = shift;
    my $entry = shift || return;
    $entry    = $feed->_convert_entry($entry);
    $feed->{atom}->add_entry($entry->unwrap);
}

sub as_xml { $_[0]->{atom}->as_xml }

package XML::Feed::Entry::Format::Atom;
use strict;

use base qw( XML::Feed::Entry );
use XML::Atom::Util qw( iso2dt );
use XML::Feed::Content;
use XML::Atom::Entry;
use List::Util qw( first );

sub init_empty {
    my $entry = shift;
    $entry->{entry} = XML::Atom::Entry->new(Version => 1.0);
    1;
}

sub format { 'Atom' }

sub title { shift->{entry}->title(@_) }
sub source { shift->{entry}->source(@_) }
sub updated { shift->{entry}->updated(@_) }
sub base { shift->{entry}->base(@_) }

sub link {
    my $entry = shift;
    if (@_) {
        $entry->{entry}->add_link({ rel => 'alternate', href => $_[0],
                                    type => 'text/html', });
    } else {
        my $l = first { !defined $_->rel || $_->rel eq 'alternate' } $entry->{entry}->link;
        $l ? $l->href : undef;
    }
}

sub summary {
    my $entry = shift;
    if (@_) {
		my %param;
		if (ref($_[0]) eq 'XML::Feed::Content') {
			%param = (Body => $_[0]->body);
		} else {
			 %param = (Body => $_[0]);
		}
		$entry->{entry}->summary(XML::Atom::Content->new(%param, Version => 1.0));
    } else {
		my $s = $entry->{entry}->summary;
        # map Atom types to MIME types
        my $type = ($s && ref($s) eq 'XML::Feed::Content') ? $s->type : undef;
        if ($type) {
            $type = 'text/html'  if $type eq 'xhtml' || $type eq 'html';
            $type = 'text/plain' if $type eq 'text';
        }
		my $body = $s;	
		if (defined $s && ref($s) eq 'XML::Feed::Content') {
			$body = $s->body;
		}
        XML::Feed::Content->wrap({ type => $type,
                                   body => $body });
    }
}

my %types = (
	'text/xhtml' => 'xhtml',
	'text/html'  => 'html',
	'text/plain' => 'text',
);

sub content {
    my $entry = shift;
    if (@_) {
        my %param;
        my $base;
        my $orig_body;
        if (ref($_[0]) eq 'XML::Feed::Content') {
            $orig_body = $_[0]->body;
			if (defined $_[0]->type && defined $types{$_[0]->type}) {
	            %param = (Body => $_[0]->body, Type => $types{$_[0]->type});

                if ($param{'Type'} eq "html") {
                    $param{'Body'} = HTML::Entities::encode_entities($param{'Body'});
                }
			} else {
				%param = (Body => $_[0]->body);
			}
            $base = $_[0]->base if defined $_[0]->base;
        } else {
			$orig_body = $_[0];
            %param = (Body => $_[0]);
        }
        $entry->{entry}->content(XML::Atom::Content->new(%param, Version => 1.0));
        $entry->{entry}->content->base($base) if defined $base;
    } else {
        my $c = $entry->{entry}->content;

        # map Atom types to MIME types
        my $type = $c ? $c->type : undef;
        if ($type) {
            $type = 'text/html'  if $type eq 'xhtml' || $type eq 'html';
            $type = 'text/plain' if $type eq 'text';
        }

        XML::Feed::Content->wrap({ type => $type,
                                   base => $c ? $c->base : undef, 
                                   body => $c ? $c->body : undef });
    }
}

sub category {
    my $entry = shift;
    my $ns = XML::Atom::Namespace->new(dc => 'http://purl.org/dc/elements/1.1/');
    if (@_) {
        $entry->{entry}->add_category({ term => $_ }) for @_;
        return 1
    } else {


        my @category = ($entry->{entry}->can('categories')) ? $entry->{entry}->categories : $entry->{entry}->category;
        my @return = @category
            ? (map { $_->label || $_->term } @category)
            : $entry->{entry}->getlist($ns, 'subject');

        return wantarray? @return : $return[0];
    }
}

sub author {
    my $entry = shift;
    if (@_ && $_[0]) {
        my $person = XML::Atom::Person->new(Version => 1.0);
        $person->name($_[0]);
        $entry->{entry}->author($person);
    } else {
        $entry->{entry}->author ? $entry->{entry}->author->name : undef;
    }
}

sub id { shift->{entry}->id(@_) }

sub issued {
    my $entry = shift;
    if (@_) {
        $entry->{entry}->issued(DateTime::Format::W3CDTF->format_datetime($_[0])) if $_[0];
    } else {
        $entry->{entry}->issued ? iso2dt($entry->{entry}->issued) : undef;
    }
}

sub modified {
    my $entry = shift;
    if (@_) {
        $entry->{entry}->modified(DateTime::Format::W3CDTF->format_datetime($_[0])) if $_[0];
    } else {
        return iso2dt($entry->{entry}->modified) if $entry->{entry}->modified;
        return iso2dt($entry->{entry}->updated)  if $entry->{entry}->updated;
        return undef;
    }
}

sub lat {
    my $entry = shift;
    if (@_) {
   $entry->{entry}->lat($_[0]) if $_[0];
    } else {
   $entry->{entry}->lat;
    }
}

sub long {
    my $entry = shift;
    if (@_) {
   $entry->{entry}->long($_[0]) if $_[0];
    } else {
   $entry->{entry}->long;
    }
}


sub enclosure {
    my $entry = shift;

    if (@_) {
        my $enclosure = shift;
        my $method    = ($XML::Feed::MULTIPLE_ENCLOSURES)? 'add_link' : 'link';
        $entry->{entry}->$method({ rel => 'enclosure', href => $enclosure->{url},
                                length => $enclosure->{length},
                                type   => $enclosure->{type} });
        return 1;
    } else {
        my @links = grep { defined $_->rel && $_->rel eq 'enclosure' } $entry->{entry}->link;
        return undef unless @links;
        my @encs = map { XML::Feed::Enclosure->new({ url => $_->href, length => $_->length, type => $_->type }) } @links ;
        return ($XML::Feed::MULTIPLE_ENCLOSURES)? @encs : $encs[-1];
    }
}


1;
Commit	Line	Data
3353d70c	1	# $Id$
0d5e38d1	2
729cd7a8	3	package XML::Feed::Format::Atom;
0d5e38d1	4	use strict;
	5
	6	use base qw( XML::Feed );
	7	use XML::Atom::Feed;
	8	use XML::Atom::Util qw( iso2dt );
	9	use List::Util qw( first );
ecac864a	10	use DateTime::Format::W3CDTF;
b7c406f5	11	use HTML::Entities;
0d5e38d1	12
9a36f82c	13	use XML::Atom::Entry;
	14	XML::Atom::Entry->mk_elem_accessors(qw( lat long ), ['http://www.w3.org/2003/01/geo/wgs84_pos#']);
	15
5383a560	16	use XML::Atom::Content;
5383a560	17
9b6bc912	18	sub identify {
	19	my $class = shift;
	20	my $xml = shift;
	21	my $tag = $class->_get_first_tag($xml);
	22	return ($tag eq 'feed');
	23	}
	24
	25
973e1f9e	26	sub init_empty {
4e9c4625	27	my ($feed, %args) = @_;
	28	$args{'Version'} \|\|= '1.0';
	29
	30	$feed->{atom} = XML::Atom::Feed->new(%args);
973e1f9e	31	$feed;
	32	}
	33
0d5e38d1	34	sub init_string {
	35	my $feed = shift;
	36	my($str) = @_;
fe71566d	37	if ($str) {
	38	$feed->{atom} = XML::Atom::Feed->new(Stream => $str)
	39	or return $feed->error(XML::Atom::Feed->errstr);
	40	}
0d5e38d1	41	$feed;
	42	}
	43
	44	sub format { 'Atom' }
	45
973e1f9e	46	sub title { shift->{atom}->title(@_) }
0d5e38d1	47	sub link {
973e1f9e	48	my $feed = shift;
	49	if (@_) {
	50	$feed->{atom}->add_link({ rel => 'alternate', href => $_[0],
	51	type => 'text/html', });
	52	} else {
4679cf3f	53	my $l = first { !defined $_->rel \|\| $_->rel eq 'alternate' } $feed->{atom}->link;
973e1f9e	54	$l ? $l->href : undef;
	55	}
	56	}
9a36f82c	57
	58	sub self_link {
	59	my $feed = shift;
	60	if (@_) {
	61	my $uri = shift;
	62	$feed->{atom}->add_link({type => "application/atom+xml", rel => "self", href => $uri});
	63	return $uri;
	64	}
	65	else
	66	{
	67	my $l =
	68	first
	69	{ !defined $_->rel \|\| $_->rel eq 'self' }
	70	$feed->{atom}->link;
	71	;
	72
	73	return $l ? $l->href : undef;
	74	}
	75	}
	76
973e1f9e	77	sub description { shift->{atom}->tagline(@_) }
	78	sub copyright { shift->{atom}->copyright(@_) }
	79	sub language { shift->{atom}->language(@_) }
	80	sub generator { shift->{atom}->generator(@_) }
e8fcbc5b	81	sub id { shift->{atom}->id(@_) }
	82	sub updated { shift->{atom}->updated(@_) }
	83	sub add_link { shift->{atom}->add_link(@_) }
5383a560	84	sub base { shift->{atom}->base(@_) }
973e1f9e	85
	86	sub author {
	87	my $feed = shift;
	88	if (@_ && $_[0]) {
c4d4c98e	89	my $person = XML::Atom::Person->new(Version => 1.0);
973e1f9e	90	$person->name($_[0]);
	91	$feed->{atom}->author($person);
	92	} else {
	93	$feed->{atom}->author ? $feed->{atom}->author->name : undef;
	94	}
	95	}
	96
5383a560	97
	98
	99
973e1f9e	100	sub modified {
	101	my $feed = shift;
	102	if (@_) {
ecac864a	103	$feed->{atom}->modified(DateTime::Format::W3CDTF->format_datetime($_[0]));
973e1f9e	104	} else {
1ee56ab5	105	return iso2dt($feed->{atom}->modified) if $feed->{atom}->modified;
	106	return iso2dt($feed->{atom}->updated) if $feed->{atom}->updated;
	107	return undef;
973e1f9e	108	}
0d5e38d1	109	}
0d5e38d1	110
c4d4c98e	111	sub entries {
0d5e38d1	112	my @entries;
0d5e38d1	113	for my $entry ($_[0]->{atom}->entries) {
729cd7a8	114	push @entries, XML::Feed::Entry::Format::Atom->wrap($entry);
0d5e38d1	115	}
c4d4c98e	116
0d5e38d1	117	@entries;
	118	}
	119
973e1f9e	120	sub add_entry {
33d4cb3f	121	my $feed = shift;
	122	my $entry = shift \|\| return;
	123	$entry = $feed->_convert_entry($entry);
973e1f9e	124	$feed->{atom}->add_entry($entry->unwrap);
	125	}
	126
	127	sub as_xml { $_[0]->{atom}->as_xml }
	128
729cd7a8	129	package XML::Feed::Entry::Format::Atom;
0d5e38d1	130	use strict;
	131
	132	use base qw( XML::Feed::Entry );
	133	use XML::Atom::Util qw( iso2dt );
a749d9b9	134	use XML::Feed::Content;
973e1f9e	135	use XML::Atom::Entry;
0d5e38d1	136	use List::Util qw( first );
0d5e38d1	137
973e1f9e	138	sub init_empty {
973e1f9e	139	my $entry = shift;
c4d4c98e	140	$entry->{entry} = XML::Atom::Entry->new(Version => 1.0);
973e1f9e	141	1;
	142	}
	143
3bdbab6f	144	sub format { 'Atom' }
3bdbab6f	145
973e1f9e	146	sub title { shift->{entry}->title(@_) }
e8fcbc5b	147	sub source { shift->{entry}->source(@_) }
e8fcbc5b	148	sub updated { shift->{entry}->updated(@_) }
5383a560	149	sub base { shift->{entry}->base(@_) }
e8fcbc5b	150
0d5e38d1	151	sub link {
973e1f9e	152	my $entry = shift;
	153	if (@_) {
	154	$entry->{entry}->add_link({ rel => 'alternate', href => $_[0],
	155	type => 'text/html', });
	156	} else {
4679cf3f	157	my $l = first { !defined $_->rel \|\| $_->rel eq 'alternate' } $entry->{entry}->link;
973e1f9e	158	$l ? $l->href : undef;
973e1f9e	159	}
0d5e38d1	160	}
a749d9b9	161
a749d9b9	162	sub summary {
973e1f9e	163	my $entry = shift;
973e1f9e	164	if (@_) {
ac9492d2	165	my %param;
	166	if (ref($_[0]) eq 'XML::Feed::Content') {
	167	%param = (Body => $_[0]->body);
	168	} else {
	169	%param = (Body => $_[0]);
	170	}
	171	$entry->{entry}->summary(XML::Atom::Content->new(%param, Version => 1.0));
973e1f9e	172	} else {
ac9492d2	173	my $s = $entry->{entry}->summary;
	174	# map Atom types to MIME types
	175	my $type = ($s && ref($s) eq 'XML::Feed::Content') ? $s->type : undef;
	176	if ($type) {
	177	$type = 'text/html' if $type eq 'xhtml' \|\| $type eq 'html';
	178	$type = 'text/plain' if $type eq 'text';
	179	}
	180	my $body = $s;
	181	if (defined $s && ref($s) eq 'XML::Feed::Content') {
	182	$body = $s->body;
	183	}
	184	XML::Feed::Content->wrap({ type => $type,
	185	body => $body });
973e1f9e	186	}
a749d9b9	187	}
a749d9b9	188
4f413435	189	my %types = (
	190	'text/xhtml' => 'xhtml',
	191	'text/html' => 'html',
	192	'text/plain' => 'text',
	193	);
	194
a749d9b9	195	sub content {
973e1f9e	196	my $entry = shift;
	197	if (@_) {
	198	my %param;
5383a560	199	my $base;
b7c406f5	200	my $orig_body;
973e1f9e	201	if (ref($_[0]) eq 'XML::Feed::Content') {
b7c406f5	202	$orig_body = $_[0]->body;
4f413435	203	if (defined $_[0]->type && defined $types{$_[0]->type}) {
4f413435	204	%param = (Body => $_[0]->body, Type => $types{$_[0]->type});
b7c406f5	205
	206	if ($param{'Type'} eq "html") {
	207	$param{'Body'} = HTML::Entities::encode_entities($param{'Body'});
	208	}
4f413435	209	} else {
b7c406f5	210	%param = (Body => $_[0]->body);
4f413435	211	}
5383a560	212	$base = $_[0]->base if defined $_[0]->base;
973e1f9e	213	} else {
b7c406f5	214	$orig_body = $_[0];
c4d4c98e	215	%param = (Body => $_[0]);
973e1f9e	216	}
c4d4c98e	217	$entry->{entry}->content(XML::Atom::Content->new(%param, Version => 1.0));
5383a560	218	$entry->{entry}->content->base($base) if defined $base;
973e1f9e	219	} else {
973e1f9e	220	my $c = $entry->{entry}->content;
c4d4c98e	221
	222	# map Atom types to MIME types
	223	my $type = $c ? $c->type : undef;
	224	if ($type) {
	225	$type = 'text/html' if $type eq 'xhtml' \|\| $type eq 'html';
	226	$type = 'text/plain' if $type eq 'text';
	227	}
	228
	229	XML::Feed::Content->wrap({ type => $type,
5383a560	230	base => $c ? $c->base : undef,
973e1f9e	231	body => $c ? $c->body : undef });
973e1f9e	232	}
a749d9b9	233	}
0d5e38d1	234
0d5e38d1	235	sub category {
973e1f9e	236	my $entry = shift;
0d5e38d1	237	my $ns = XML::Atom::Namespace->new(dc => 'http://purl.org/dc/elements/1.1/');
973e1f9e	238	if (@_) {
a0cca2a4	239	$entry->{entry}->add_category({ term => $_ }) for @_;
a0cca2a4	240	return 1
973e1f9e	241	} else {
a0cca2a4	242
	243
	244	my @category = ($entry->{entry}->can('categories')) ? $entry->{entry}->categories : $entry->{entry}->category;
	245	my @return = @category
	246	? (map { $_->label \|\| $_->term } @category)
	247	: $entry->{entry}->getlist($ns, 'subject');
	248
bf34c07e	249	return wantarray? @return : $return[0];
973e1f9e	250	}
	251	}
	252
	253	sub author {
	254	my $entry = shift;
	255	if (@_ && $_[0]) {
c4d4c98e	256	my $person = XML::Atom::Person->new(Version => 1.0);
973e1f9e	257	$person->name($_[0]);
	258	$entry->{entry}->author($person);
	259	} else {
	260	$entry->{entry}->author ? $entry->{entry}->author->name : undef;
	261	}
	262	}
	263
	264	sub id { shift->{entry}->id(@_) }
	265
	266	sub issued {
	267	my $entry = shift;
	268	if (@_) {
ecac864a	269	$entry->{entry}->issued(DateTime::Format::W3CDTF->format_datetime($_[0])) if $_[0];
973e1f9e	270	} else {
	271	$entry->{entry}->issued ? iso2dt($entry->{entry}->issued) : undef;
	272	}
0d5e38d1	273	}
0d5e38d1	274
973e1f9e	275	sub modified {
	276	my $entry = shift;
	277	if (@_) {
ecac864a	278	$entry->{entry}->modified(DateTime::Format::W3CDTF->format_datetime($_[0])) if $_[0];
973e1f9e	279	} else {
1ee56ab5	280	return iso2dt($entry->{entry}->modified) if $entry->{entry}->modified;
	281	return iso2dt($entry->{entry}->updated) if $entry->{entry}->updated;
	282	return undef;
973e1f9e	283	}
973e1f9e	284	}
0d5e38d1	285
9a36f82c	286	sub lat {
	287	my $entry = shift;
	288	if (@_) {
	289	$entry->{entry}->lat($_[0]) if $_[0];
	290	} else {
	291	$entry->{entry}->lat;
	292	}
	293	}
	294
	295	sub long {
	296	my $entry = shift;
	297	if (@_) {
	298	$entry->{entry}->long($_[0]) if $_[0];
	299	} else {
	300	$entry->{entry}->long;
	301	}
	302	}
	303
af6b00a4	304
12a4079f	305	sub enclosure {
	306	my $entry = shift;
	307
	308	if (@_) {
	309	my $enclosure = shift;
b1aa7a62	310	my $method = ($XML::Feed::MULTIPLE_ENCLOSURES)? 'add_link' : 'link';
b1aa7a62	311	$entry->{entry}->$method({ rel => 'enclosure', href => $enclosure->{url},
12a4079f	312	length => $enclosure->{length},
	313	type => $enclosure->{type} });
	314	return 1;
	315	} else {
b1aa7a62	316	my @links = grep { defined $_->rel && $_->rel eq 'enclosure' } $entry->{entry}->link;
	317	return undef unless @links;
	318	my @encs = map { XML::Feed::Enclosure->new({ url => $_->href, length => $_->length, type => $_->type }) } @links ;
	319	return ($XML::Feed::MULTIPLE_ENCLOSURES)? @encs : $encs[-1];
12a4079f	320	}
12a4079f	321	}
af6b00a4	322
af6b00a4	323
0d5e38d1	324	1;