[catagits/XML-Feed.git] / lib / XML / Feed.pm

# $Id$

package XML::Feed;
use strict;

use base qw( Class::ErrorHandler );
use Feed::Find;
use URI::Fetch;
use LWP::UserAgent;
use Carp;
use Module::Pluggable search_path => "XML::Feed::Format",
                      require     => 1,
                      sub_name    => 'formatters';

our $VERSION = '0.41';
our @formatters;
BEGIN {
	@formatters = __PACKAGE__->formatters;
}

sub new {
    my $class = shift;
    my $format = shift || 'Atom';
    my $format_class = 'XML::Feed::Format::' . $format;
    eval "use $format_class";
    Carp::croak("Unsupported format $format: $@") if $@;
    my $feed = bless {}, join('::', __PACKAGE__, "Format", $format);
    $feed->init_empty(@_) or return $class->error($feed->errstr);
    $feed;
}

sub init_empty { 1 }

sub parse {
    my $class = shift;
    my($stream, $specified_format) = @_;
    return $class->error("Stream parameter is required") unless $stream;
    my $feed = bless {}, $class;
    my $xml = '';
    if (UNIVERSAL::isa($stream, 'URI')) {
        my $ua  = LWP::UserAgent->new;
        $ua->env_proxy; # force allowing of proxies
        my $res = URI::Fetch->fetch($stream, UserAgent => $ua)
            or return $class->error(URI::Fetch->errstr);
        return $class->error("This feed has been permanently removed")
            if $res->status == URI::Fetch::URI_GONE();
        $xml = $res->content;
    } elsif (ref($stream) eq 'SCALAR') {
        $xml = $$stream;
    } elsif (ref($stream)) {
        while (read($stream, my($chunk), 8192)) {
            $xml .= $chunk;
        }
    } else {
        open my $fh, $stream
            or return $class->error("Can't open $stream: $!");
        while (read $fh, my($chunk), 8192) {
            $xml .= $chunk;
        }
        close $fh;
    }
    return $class->error("Can't get feed XML content from $stream")
        unless $xml;
    my $format;
    if ($specified_format) {
        $format = $specified_format;
    } else {
        $format = $feed->identify_format(\$xml) or return $class->error($feed->errstr);
    }

    my $format_class = join '::', __PACKAGE__, "Format", $format;
    eval "use $format_class";
    return $class->error("Unsupported format $format: $@") if $@;
    bless $feed, $format_class;
    $feed->init_string(\$xml) or return $class->error($feed->errstr);
    $feed;
}

sub identify_format {
    my $feed   = shift;
    my($xml)   = @_;
	foreach my $class (@formatters) {
		my ($name) = ($class =~ m!([^:]+)$!);
		# TODO ugly
		my $tmp = $$xml;
		return $name if eval { $class->identify(\$tmp) };
		return $feed->error($@) if $@;
	} 
	return $feed->error("Cannot detect feed type");
}

sub _get_first_tag {
	my $class  = shift;
	my ($xml)  = @_;


    ## Auto-detect feed type based on first element. This is prone
    ## to breakage, but then again we don't want to parse the whole
    ## feed ourselves.
    my $tag;
    while ($$xml =~ /<(\S+)/sg) {
        (my $t = $1) =~ tr/a-zA-Z0-9:\-\?!//cd;
        my $first = substr $t, 0, 1;
        $tag = $t, last unless $first eq '?' || $first eq '!';
    }
	die ("Cannot find first element") unless $tag;
    $tag =~ s/^.*://;
	return $tag;
}

sub find_feeds {
    my $class = shift;
    my($uri) = @_;
    my @feeds = Feed::Find->find($uri)
        or return $class->error(Feed::Find->errstr);
    @feeds;
}

sub convert {
    my $feed = shift;
    my($format) = @_;
    my $new = XML::Feed->new($format);
    for my $field (qw( title link description language author copyright modified generator )) {
        my $val = $feed->$field();
        next unless defined $val;
        $new->$field($val);
    }
    for my $entry ($feed->entries) {
        $new->add_entry($entry->convert($format));
    }
    $new;
}

sub splice {
    my $feed = shift;
    my($other) = @_;
    my %ids = map { $_->id => 1 } $feed->entries;
    for my $entry ($other->entries) {
        $feed->add_entry($entry) unless $ids{$entry->id}++;
    }
}

sub _convert_entry {
    my $feed   = shift;
    my $entry  = shift;
    my $feed_format  = ref($feed);   $feed_format  =~ s!^XML::Feed::Format::!!;
    my $entry_format = ref($entry);  $entry_format =~ s!^XML::Feed::Entry::Format::!!;
    return $entry if $entry_format eq $feed_format;
    return $entry->convert($feed_format); 
}

sub base;
sub format;
sub title;
sub link;
sub self_link;
sub description;
sub language;
sub author;
sub copyright;
sub modified;
sub generator;
sub add_entry;
sub entries;
sub as_xml;
sub id;

sub tagline { shift->description(@_) }
sub items   { $_[0]->entries     }

1;
__END__

=head1 NAME

XML::Feed - Syndication feed parser and auto-discovery

=head1 SYNOPSIS

    use XML::Feed;
    my $feed = XML::Feed->parse(URI->new('http://example.com/atom.xml'))
        or die XML::Feed->errstr;
    print $feed->title, "\n";
    for my $entry ($feed->entries) {
    }

    ## Find all of the syndication feeds on a given page, using
    ## auto-discovery.
    my @feeds = XML::Feed->find_feeds('http://example.com/');

=head1 DESCRIPTION

I<XML::Feed> is a syndication feed parser for both RSS and Atom feeds. It
also implements feed auto-discovery for finding feeds, given a URI.

I<XML::Feed> supports the following syndication feed formats:

=over 4

=item * RSS 0.91

=item * RSS 1.0

=item * RSS 2.0

=item * Atom

=back

The goal of I<XML::Feed> is to provide a unified API for parsing and using
the various syndication formats. The different flavors of RSS and Atom
handle data in different ways: date handling; summaries and content;
escaping and quoting; etc. This module attempts to remove those differences
by providing a wrapper around the formats and the classes implementing
those formats (I<XML::RSS> and I<XML::Atom::Feed>). For example, dates are
handled differently in each of the above formats. To provide a unified API for
date handling, I<XML::Feed> converts all date formats transparently into
I<DateTime> objects, which it then returns to the caller.

=head1 USAGE

=head2 XML::Feed->new($format)

Creates a new empty I<XML::Feed> object using the format I<$format>.

    $feed = XML::Feed->new('Atom');
    $feed = XML::Feed->new('RSS');
    $feed = XML::Feed->new('RSS', version => '0.91');

=head2 XML::Feed->parse($stream)

=head2 XML::Feed->parse($stream, $format)

Parses a syndication feed identified by I<$stream>. I<$stream> can be any
one of the following:

=over 4

=item * Scalar reference

A reference to string containing the XML body of the feed.

=item * Filehandle

An open filehandle from which the feed XML will be read.

=item * File name

The name of a file containing the feed XML.

=item * URI object

A URI from which the feed XML will be retrieved.

=back

I<$format> allows you to override format guessing.

=head2 XML::Feed->find_feeds($uri)

Given a URI I<$uri>, use auto-discovery to find all of the feeds linked
from that page (using I<E<lt>linkE<gt>> tags).

Returns a list of feed URIs.

=head2 XML::Feed->identify_format($xml)

Given the xml of a feed return what format it is in (C<Atom>, or some version of C<RSS>).

=head2 $feed->convert($format)

Converts the I<XML::Feed> object into the I<$format> format, and returns
the new object.

=head2 $feed->splice($other_feed)

Splices in all of the entries from the feed I<$other_feed> into I<$feed>,
skipping posts that are already in I<$feed>.

=head2 $feed->format

Returns the format of the feed (C<Atom>, or some version of C<RSS>).

=head2 $feed->title([ $title ])

The title of the feed/channel.

=head2 $feed->base([ $base ])

The url base of the feed/channel.

=head2 $feed->link([ $uri ])

The permalink of the feed/channel.

=head2 $feed->tagline([ $tagline ])

The description or tagline of the feed/channel.

=head2 $feed->description([ $description ])

Alias for I<$feed-E<gt>tagline>.

=head2 $feed->author([ $author ])

The author of the feed/channel.

=head2 $feed->language([ $language ])

The language of the feed.

=head2 $feed->copyright([ $copyright ])

The copyright notice of the feed.

=head2 $feed->modified([ $modified ])

A I<DateTime> object representing the last-modified date of the feed.

If present, I<$modified> should be a I<DateTime> object.

=head2 $feed->generator([ $generator ])

The generator of the feed.

=head2 $feed->self_link ([ $uri ])

The Atom Self-link of the feed:

L<http://validator.w3.org/feed/docs/warning/MissingAtomSelfLink.html>

A string.

=head2 $feed->entries

A list of the entries/items in the feed. Returns an array containing
I<XML::Feed::Entry> objects.

=head2 $feed->items

A synonym for I<$feed->entries>.

=head2 $feed->add_entry($entry)

Adds an entry to the feed. I<$entry> should be an I<XML::Feed::Entry>
object in the correct format for the feed.

=head2 $feed->as_xml

Returns an XML representation of the feed, in the format determined by
the current format of the I<$feed> object.

=head1 PACKAGE VARIABLES

=over 4

=item C<$XML::Feed::RSS::PREFERRED_PARSER>

If you want to use another RSS parser class than XML::RSS (default), you can
change the class by setting C<$PREFERRED_PARSER> variable in XML::Feed::RSS
package.

    $XML::Feed::RSS::PREFERRED_PARSER = "XML::RSS::LibXML";

B<Note:> this will only work for parsing feeds, not creating feeds.

=back

=head1 VALID FEEDS

For reference, this cgi script will create valid, albeit nonsensical feeds 
(according to C<http://feedvalidator.org> anyway) for Atom 1.0 and RSS 0.90, 
0.91, 1.0 and 2.0. 

    #!perl -w

    use strict;
    use CGI;
    use CGI::Carp qw(fatalsToBrowser);
    use DateTime;
    use XML::Feed;

    my $cgi  = CGI->new;
    my @args = ( $cgi->param('format') || "Atom" );
    push @args, ( version => $cgi->param('version') ) if $cgi->param('version');

    my $feed = XML::Feed->new(@args);
    $feed->id("http://".time.rand()."/");
    $feed->title('Test Feed');
    $feed->link($cgi->url);
    $feed->self_link($cgi->url( -query => 1, -full => 1, -rewrite => 1) );
    $feed->modified(DateTime->now);

    my $entry = XML::Feed::Entry->new();
    $entry->id("http://".time.rand()."/");
    $entry->link("http://example.com");
    $entry->title("Test entry");
    $entry->summary("Test summary");
    $entry->content("Foo");
    $entry->modified(DateTime->now);
    $entry->author('test@example.com (Testy McTesterson)');
    $feed->add_entry($entry);

    my $mime = ("Atom" eq $feed->format) ? "application/atom+xml" : "application/rss+xml";
    print $cgi->header($mime);
    print $feed->as_xml;


=head1 LICENSE

I<XML::Feed> is free software; you may redistribute it and/or modify it
under the same terms as Perl itself.

=head1 AUTHOR & COPYRIGHT

Except where otherwise noted, I<XML::Feed> is Copyright 2004-2008
Six Apart, cpan@sixapart.com. All rights reserved.

=head1 SUBVERSION 

The latest version of I<XML::Feed> can be found at

    http://code.sixapart.com/svn/XML-Feed/trunk/

=cut
Commit	Line	Data
3353d70c	1	# $Id$
0d5e38d1	2
	3	package XML::Feed;
	4	use strict;
	5
62d92771	6	use base qw( Class::ErrorHandler );
62d92771	7	use Feed::Find;
fe71566d	8	use URI::Fetch;
d39809aa	9	use LWP::UserAgent;
973e1f9e	10	use Carp;
9b6bc912	11	use Module::Pluggable search_path => "XML::Feed::Format",
	12	require => 1,
	13	sub_name => 'formatters';
0d5e38d1	14
a759e13e	15	our $VERSION = '0.41';
9b6bc912	16	our @formatters;
	17	BEGIN {
	18	@formatters = __PACKAGE__->formatters;
	19	}
973e1f9e	20
	21	sub new {
	22	my $class = shift;
4e9c4625	23	my $format = shift \|\| 'Atom';
729cd7a8	24	my $format_class = 'XML::Feed::Format::' . $format;
973e1f9e	25	eval "use $format_class";
973e1f9e	26	Carp::croak("Unsupported format $format: $@") if $@;
729cd7a8	27	my $feed = bless {}, join('::', __PACKAGE__, "Format", $format);
4e9c4625	28	$feed->init_empty(@_) or return $class->error($feed->errstr);
973e1f9e	29	$feed;
	30	}
	31
	32	sub init_empty { 1 }
0d5e38d1	33
	34	sub parse {
	35	my $class = shift;
41e8c132	36	my($stream, $specified_format) = @_;
0d5e38d1	37	return $class->error("Stream parameter is required") unless $stream;
	38	my $feed = bless {}, $class;
	39	my $xml = '';
	40	if (UNIVERSAL::isa($stream, 'URI')) {
d39809aa	41	my $ua = LWP::UserAgent->new;
	42	$ua->env_proxy; # force allowing of proxies
	43	my $res = URI::Fetch->fetch($stream, UserAgent => $ua)
fe71566d	44	or return $class->error(URI::Fetch->errstr);
fe71566d	45	return $class->error("This feed has been permanently removed")
b3b6d2fc	46	if $res->status == URI::Fetch::URI_GONE();
fe71566d	47	$xml = $res->content;
0d5e38d1	48	} elsif (ref($stream) eq 'SCALAR') {
	49	$xml = $$stream;
	50	} elsif (ref($stream)) {
	51	while (read($stream, my($chunk), 8192)) {
	52	$xml .= $chunk;
	53	}
	54	} else {
	55	open my $fh, $stream
	56	or return $class->error("Can't open $stream: $!");
	57	while (read $fh, my($chunk), 8192) {
	58	$xml .= $chunk;
	59	}
	60	close $fh;
	61	}
	62	return $class->error("Can't get feed XML content from $stream")
	63	unless $xml;
41e8c132	64	my $format;
	65	if ($specified_format) {
	66	$format = $specified_format;
	67	} else {
0c81cb25	68	$format = $feed->identify_format(\$xml) or return $class->error($feed->errstr);
41e8c132	69	}
41e8c132	70
729cd7a8	71	my $format_class = join '::', __PACKAGE__, "Format", $format;
fe71566d	72	eval "use $format_class";
	73	return $class->error("Unsupported format $format: $@") if $@;
	74	bless $feed, $format_class;
	75	$feed->init_string(\$xml) or return $class->error($feed->errstr);
	76	$feed;
	77	}
	78
	79	sub identify_format {
9b6bc912	80	my $feed = shift;
	81	my($xml) = @_;
	82	foreach my $class (@formatters) {
	83	my ($name) = ($class =~ m!([^:]+)$!);
	84	# TODO ugly
	85	my $tmp = $$xml;
	86	return $name if eval { $class->identify(\$tmp) };
	87	return $feed->error($@) if $@;
	88	}
	89	return $feed->error("Cannot detect feed type");
	90	}
	91
	92	sub _get_first_tag {
	93	my $class = shift;
	94	my ($xml) = @_;
	95
	96
0d5e38d1	97	## Auto-detect feed type based on first element. This is prone
	98	## to breakage, but then again we don't want to parse the whole
	99	## feed ourselves.
a749d9b9	100	my $tag;
fe71566d	101	while ($$xml =~ /<(\S+)/sg) {
62d92771	102	(my $t = $1) =~ tr/a-zA-Z0-9:\-\?!//cd;
	103	my $first = substr $t, 0, 1;
	104	$tag = $t, last unless $first eq '?' \|\| $first eq '!';
a749d9b9	105	}
9b6bc912	106	die ("Cannot find first element") unless $tag;
0d5e38d1	107	$tag =~ s/^.*://;
9b6bc912	108	return $tag;
0d5e38d1	109	}
	110
	111	sub find_feeds {
	112	my $class = shift;
	113	my($uri) = @_;
62d92771	114	my @feeds = Feed::Find->find($uri)
62d92771	115	or return $class->error(Feed::Find->errstr);
0d5e38d1	116	@feeds;
	117	}
	118
973e1f9e	119	sub convert {
	120	my $feed = shift;
	121	my($format) = @_;
729cd7a8	122	my $new = XML::Feed->new($format);
ecac864a	123	for my $field (qw( title link description language author copyright modified generator )) {
23103173	124	my $val = $feed->$field();
	125	next unless defined $val;
	126	$new->$field($val);
973e1f9e	127	}
	128	for my $entry ($feed->entries) {
	129	$new->add_entry($entry->convert($format));
	130	}
	131	$new;
	132	}
	133
23103173	134	sub splice {
	135	my $feed = shift;
	136	my($other) = @_;
	137	my %ids = map { $_->id => 1 } $feed->entries;
	138	for my $entry ($other->entries) {
	139	$feed->add_entry($entry) unless $ids{$entry->id}++;
	140	}
	141	}
	142
33d4cb3f	143	sub _convert_entry {
	144	my $feed = shift;
	145	my $entry = shift;
729cd7a8	146	my $feed_format = ref($feed); $feed_format =~ s!^XML::Feed::Format::!!;
729cd7a8	147	my $entry_format = ref($entry); $entry_format =~ s!^XML::Feed::Entry::Format::!!;
33d4cb3f	148	return $entry if $entry_format eq $feed_format;
	149	return $entry->convert($feed_format);
	150	}
	151
5383a560	152	sub base;
0d5e38d1	153	sub format;
	154	sub title;
	155	sub link;
9a36f82c	156	sub self_link;
0d5e38d1	157	sub description;
0d5e38d1	158	sub language;
973e1f9e	159	sub author;
0d5e38d1	160	sub copyright;
	161	sub modified;
	162	sub generator;
973e1f9e	163	sub add_entry;
0d5e38d1	164	sub entries;
973e1f9e	165	sub as_xml;
813f78d8	166	sub id;
0d5e38d1	167
973e1f9e	168	sub tagline { shift->description(@_) }
0d5e38d1	169	sub items { $_[0]->entries }
	170
	171	1;
	172	__END__
	173
	174	=head1 NAME
	175
	176	XML::Feed - Syndication feed parser and auto-discovery
	177
	178	=head1 SYNOPSIS
	179
	180	use XML::Feed;
	181	my $feed = XML::Feed->parse(URI->new('http://example.com/atom.xml'))
	182	or die XML::Feed->errstr;
	183	print $feed->title, "\n";
	184	for my $entry ($feed->entries) {
	185	}
	186
	187	## Find all of the syndication feeds on a given page, using
	188	## auto-discovery.
	189	my @feeds = XML::Feed->find_feeds('http://example.com/');
	190
	191	=head1 DESCRIPTION
	192
	193	I<XML::Feed> is a syndication feed parser for both RSS and Atom feeds. It
	194	also implements feed auto-discovery for finding feeds, given a URI.
	195
	196	I<XML::Feed> supports the following syndication feed formats:
	197
	198	=over 4
	199
	200	=item * RSS 0.91
	201
	202	=item * RSS 1.0
	203
	204	=item * RSS 2.0
	205
	206	=item * Atom
	207
	208	=back
	209
	210	The goal of I<XML::Feed> is to provide a unified API for parsing and using
	211	the various syndication formats. The different flavors of RSS and Atom
	212	handle data in different ways: date handling; summaries and content;
	213	escaping and quoting; etc. This module attempts to remove those differences
	214	by providing a wrapper around the formats and the classes implementing
	215	those formats (I<XML::RSS> and I<XML::Atom::Feed>). For example, dates are
	216	handled differently in each of the above formats. To provide a unified API for
	217	date handling, I<XML::Feed> converts all date formats transparently into
	218	I<DateTime> objects, which it then returns to the caller.
	219
	220	=head1 USAGE
	221
973e1f9e	222	=head2 XML::Feed->new($format)
	223
	224	Creates a new empty I<XML::Feed> object using the format I<$format>.
	225
813f78d8	226	$feed = XML::Feed->new('Atom');
	227	$feed = XML::Feed->new('RSS');
	228	$feed = XML::Feed->new('RSS', version => '0.91');
	229
0d5e38d1	230	=head2 XML::Feed->parse($stream)
0d5e38d1	231
41e8c132	232	=head2 XML::Feed->parse($stream, $format)
41e8c132	233
0d5e38d1	234	Parses a syndication feed identified by I<$stream>. I<$stream> can be any
	235	one of the following:
	236
	237	=over 4
	238
	239	=item * Scalar reference
	240
	241	A reference to string containing the XML body of the feed.
	242
	243	=item * Filehandle
	244
	245	An open filehandle from which the feed XML will be read.
	246
	247	=item * File name
	248
	249	The name of a file containing the feed XML.
	250
	251	=item * URI object
	252
	253	A URI from which the feed XML will be retrieved.
	254
	255	=back
	256
8c30ad3d	257	I<$format> allows you to override format guessing.
41e8c132	258
0d5e38d1	259	=head2 XML::Feed->find_feeds($uri)
	260
	261	Given a URI I<$uri>, use auto-discovery to find all of the feeds linked
	262	from that page (using I<E<lt>linkE<gt>> tags).
	263
	264	Returns a list of feed URIs.
	265
8c30ad3d	266	=head2 XML::Feed->identify_format($xml)
	267
	268	Given the xml of a feed return what format it is in (C<Atom>, or some version of C<RSS>).
	269
973e1f9e	270	=head2 $feed->convert($format)
	271
	272	Converts the I<XML::Feed> object into the I<$format> format, and returns
	273	the new object.
	274
23103173	275	=head2 $feed->splice($other_feed)
	276
	277	Splices in all of the entries from the feed I<$other_feed> into I<$feed>,
	278	skipping posts that are already in I<$feed>.
	279
0d5e38d1	280	=head2 $feed->format
	281
	282	Returns the format of the feed (C<Atom>, or some version of C<RSS>).
	283
973e1f9e	284	=head2 $feed->title([ $title ])
0d5e38d1	285
	286	The title of the feed/channel.
	287
5383a560	288	=head2 $feed->base([ $base ])
	289
	290	The url base of the feed/channel.
	291
973e1f9e	292	=head2 $feed->link([ $uri ])
0d5e38d1	293
	294	The permalink of the feed/channel.
	295
973e1f9e	296	=head2 $feed->tagline([ $tagline ])
0d5e38d1	297
	298	The description or tagline of the feed/channel.
	299
973e1f9e	300	=head2 $feed->description([ $description ])
0d5e38d1	301
	302	Alias for I<$feed-E<gt>tagline>.
	303
973e1f9e	304	=head2 $feed->author([ $author ])
	305
	306	The author of the feed/channel.
	307
	308	=head2 $feed->language([ $language ])
0d5e38d1	309
	310	The language of the feed.
	311
973e1f9e	312	=head2 $feed->copyright([ $copyright ])
0d5e38d1	313
	314	The copyright notice of the feed.
	315
973e1f9e	316	=head2 $feed->modified([ $modified ])
0d5e38d1	317
	318	A I<DateTime> object representing the last-modified date of the feed.
	319
973e1f9e	320	If present, I<$modified> should be a I<DateTime> object.
	321
	322	=head2 $feed->generator([ $generator ])
0d5e38d1	323
	324	The generator of the feed.
	325
9a36f82c	326	=head2 $feed->self_link ([ $uri ])
	327
	328	The Atom Self-link of the feed:
	329
	330	L<http://validator.w3.org/feed/docs/warning/MissingAtomSelfLink.html>
	331
	332	A string.
	333
0d5e38d1	334	=head2 $feed->entries
	335
	336	A list of the entries/items in the feed. Returns an array containing
	337	I<XML::Feed::Entry> objects.
	338
8c30ad3d	339	=head2 $feed->items
	340
	341	A synonym for I<$feed->entries>.
	342
973e1f9e	343	=head2 $feed->add_entry($entry)
	344
	345	Adds an entry to the feed. I<$entry> should be an I<XML::Feed::Entry>
	346	object in the correct format for the feed.
	347
	348	=head2 $feed->as_xml
	349
	350	Returns an XML representation of the feed, in the format determined by
	351	the current format of the I<$feed> object.
	352
	353	=head1 PACKAGE VARIABLES
	354
	355	=over 4
	356
	357	=item C<$XML::Feed::RSS::PREFERRED_PARSER>
	358
	359	If you want to use another RSS parser class than XML::RSS (default), you can
	360	change the class by setting C<$PREFERRED_PARSER> variable in XML::Feed::RSS
	361	package.
	362
	363	$XML::Feed::RSS::PREFERRED_PARSER = "XML::RSS::LibXML";
	364
	365	B<Note:> this will only work for parsing feeds, not creating feeds.
	366
	367	=back
	368
b8bc97f3	369	=head1 VALID FEEDS
	370
	371	For reference, this cgi script will create valid, albeit nonsensical feeds
	372	(according to C<http://feedvalidator.org> anyway) for Atom 1.0 and RSS 0.90,
	373	0.91, 1.0 and 2.0.
	374
	375	#!perl -w
	376
	377	use strict;
	378	use CGI;
	379	use CGI::Carp qw(fatalsToBrowser);
	380	use DateTime;
	381	use XML::Feed;
	382
	383	my $cgi = CGI->new;
	384	my @args = ( $cgi->param('format') \|\| "Atom" );
	385	push @args, ( version => $cgi->param('version') ) if $cgi->param('version');
	386
	387	my $feed = XML::Feed->new(@args);
	388	$feed->id("http://".time.rand()."/");
	389	$feed->title('Test Feed');
	390	$feed->link($cgi->url);
	391	$feed->self_link($cgi->url( -query => 1, -full => 1, -rewrite => 1) );
	392	$feed->modified(DateTime->now);
	393
	394	my $entry = XML::Feed::Entry->new();
	395	$entry->id("http://".time.rand()."/");
	396	$entry->link("http://example.com");
	397	$entry->title("Test entry");
	398	$entry->summary("Test summary");
	399	$entry->content("Foo");
	400	$entry->modified(DateTime->now);
	401	$entry->author('test@example.com (Testy McTesterson)');
	402	$feed->add_entry($entry);
	403
	404	my $mime = ("Atom" eq $feed->format) ? "application/atom+xml" : "application/rss+xml";
	405	print $cgi->header($mime);
	406	print $feed->as_xml;
	407
	408
0d5e38d1	409	=head1 LICENSE
	410
	411	I<XML::Feed> is free software; you may redistribute it and/or modify it
	412	under the same terms as Perl itself.
	413
	414	=head1 AUTHOR & COPYRIGHT
	415
70f935cc	416	Except where otherwise noted, I<XML::Feed> is Copyright 2004-2008
973e1f9e	417	Six Apart, cpan@sixapart.com. All rights reserved.
0d5e38d1	418
70f935cc	419	=head1 SUBVERSION
	420
	421	The latest version of I<XML::Feed> can be found at
	422
	423	http://code.sixapart.com/svn/XML-Feed/trunk/
	424
0d5e38d1	425	=cut