t/post.t

   1 use strict;
   2 use warnings FATAL => 'all';
   3
   4 use Test::More qw(no_plan);
   5
   6 {
   7   use Web::Simple 'PostTest';
   8   package PostTest;
   9   sub dispatch_request {
  10     sub (%:foo=&:bar~) {
  11       $_[1]->{bar} ||= 'EMPTY';
  12       [ 200,
  13         [ "Content-type" => "text/plain" ],
  14         [ join(' ',@{$_[1]}{qw(foo bar)}) ]
  15       ]
  16     },
  17     sub (*baz=) {
  18       [ 200,
  19         [ "Content-type" => "text/plain" ],
  20         [ $_[1]->reason || $_[1]->filename ],
  21       ]
  22     },
  23   }
  24 }
  25
  26 use Plack::Test;
  27 use HTTP::Request::Common qw(GET POST);
  28
  29 my $app = PostTest->new;
  30
  31 sub run_request {
  32   my $request = shift;
  33   my $response;
  34   test_psgi($app->to_psgi_app, sub { $response = shift->($request) });
  35   return $response;
  36 }
  37
  38 my $get = run_request(GET 'http://localhost/');
  39
  40 cmp_ok($get->code, '==', 404, '404 on GET');
  41
  42 my $no_body = run_request(POST 'http://localhost/');
  43
  44 cmp_ok($no_body->code, '==', 404, '404 with empty body');
  45
  46 my $no_foo = run_request(POST 'http://localhost/' => [ bar => 'BAR' ]);
  47
  48 cmp_ok($no_foo->code, '==', 404, '404 with no foo param');
  49
  50 my $no_bar = run_request(POST 'http://localhost/' => [ foo => 'FOO' ]);
  51
  52 cmp_ok($no_bar->code, '==', 200, '200 with only foo param');
  53
  54 is($no_bar->content, 'FOO EMPTY', 'bar defaulted');
  55
  56 my $both = run_request(
  57   POST 'http://localhost/' => [ foo => 'FOO', bar => 'BAR' ]
  58 );
  59
  60 cmp_ok($both->code, '==', 200, '200 with both params');
  61
  62 is($both->content, 'FOO BAR', 'both params returned');
  63
  64 my $upload = run_request(
  65   POST 'http://localhost'
  66     => Content_Type => 'form-data'
  67     => Content => [
  68       foo => 'FOO',
  69       bar => 'BAR'
  70     ]
  71 );
  72
  73 cmp_ok($upload->code, '==', 200, '200 with multipart');
  74
  75 is($upload->content, 'FOO BAR', 'both params returned');
  76
  77 my $upload_wrongtype = run_request(
  78   POST 'http://localhost'
  79     => [ baz => 'fleem' ]
  80 );
  81
  82 is(
  83   $upload_wrongtype->content,
  84   'field baz exists with value fleem but body was not multipart/form-data',
  85   'error points out wrong body type'
  86 );
  87
  88 my $upload_notupload = run_request(
  89   POST 'http://localhost'
  90     => Content_Type => 'form-data'
  91     => Content => [ baz => 'fleem' ]
  92 );
  93
  94 is(
  95   $upload_notupload->content,
  96   'field baz exists with value fleem but was not an upload',
  97   'error points out field was not an upload'
  98 );
  99
 100 my $upload_isupload = run_request(
 101   POST 'http://localhost'
 102     => Content_Type => 'form-data'
 103     => Content => [
 104       baz => [
 105         undef, 'TESTFILE',
 106         Content => 'test content', 'Content-Type' => 'text/plain'
 107       ],
 108     ]
 109 );
 110
 111 is(
 112   $upload_isupload->content,
 113   'TESTFILE',
 114   'Actual upload returns filename ok'
 115 );