lib/XML/Tags.pm

   1 package XML::Tags;
   2
   3 use strict;
   4 use warnings FATAL => 'all';
   5
   6 use File::Glob ();
   7
   8
   9
  10 my $IN_SCOPE = 0;
  11
  12 sub import {
  13   die "Can't import XML::Tags into a scope when already compiling one that uses it"
  14     if $IN_SCOPE;
  15   my ($class, @args) = @_;
  16   my $opts = shift(@args) if ref($args[0]) eq 'HASH';
  17   my $target = $class->_find_target(0, $opts);
  18   my @tags = $class->_find_tags(@args);
  19   $class->_setup_glob_override;
  20   my $unex = $class->_export_tags_into($target => @tags);
  21   $class->_install_unexporter($unex);
  22   $IN_SCOPE = 1;
  23 }
  24
  25 sub _find_tags { shift; @_ }
  26
  27 sub _find_target {
  28   my ($class, $extra_levels, $opts) = @_;
  29   return $opts->{into} if defined($opts->{into});
  30   my $level = ($opts->{into_level} || 1) + $extra_levels;
  31   return (caller($level))[0];
  32 }
  33
  34 {
  35   my $setup;
  36
  37   sub _setup_glob_override {
  38     return if $setup;
  39     $setup = 1;
  40     no warnings 'redefine';
  41     *CORE::GLOBAL::glob = sub {
  42       for ($_[0]) {
  43         # unless it smells like </foo> or <foo bar="baz">
  44         return File::Glob::glob($_[0]) unless (/^\/\w+$/ || /^\w+\s+\w+="/);
  45       }
  46       return \('<'.$_[0].'>');
  47     };
  48   }
  49 }
  50
  51 sub _export_tags_into {
  52   my ($class, $into, @tags) = @_;
  53   foreach my $tag (@tags) {
  54     no strict 'refs';
  55     tie *{"${into}::${tag}"}, 'XML::Tags::TIEHANDLE', \"<${tag}>";
  56   }
  57   return sub {
  58     foreach my $tag (@tags) {
  59       no strict 'refs';
  60       delete ${"${into}::"}{$tag}
  61     }
  62     $IN_SCOPE = 0;
  63   };
  64 }
  65
  66 sub _install_unexporter {
  67   my ($class, $unex) = @_;
  68   $^H |= 0x120000; # localize %^H
  69   $^H{'XML::Tags::Unex'} = bless($unex, 'XML::Tags::Unex');
  70 }
  71
  72 package XML::Tags::TIEHANDLE;
  73
  74 sub TIEHANDLE { my $str = $_[1]; bless \$str, $_[0] }
  75 sub READLINE { ${$_[0]} }
  76
  77 package XML::Tags::Unex;
  78
  79 sub DESTROY { local $@; eval { $_[0]->(); 1 } || warn "ARGH: $@" }
  80
  81 1;