lib/Web/Simple/Application.pm

   1 package Web::Simple::Application;
   2
   3 use Moo;
   4
   5 has 'config' => (
   6   is => 'ro',
   7   default => sub {
   8     my ($self) = @_;
   9     +{ $self->default_config }
  10   },
  11   trigger => sub {
  12     my ($self, $value) = @_;
  13     my %default = $self->default_config;
  14     my @not = grep !exists $value->{$_}, keys %default;
  15     @{$value}{@not} = @default{@not};
  16   }
  17 );
  18
  19 sub default_config { () }
  20
  21 has '_dispatcher' => (is => 'lazy');
  22
  23 sub _build__dispatcher {
  24   my $self = shift;
  25   require Web::Dispatch;
  26   require Web::Simple::DispatchNode;
  27   my $final = $self->_build_final_dispatcher;
  28   Web::Dispatch->new(
  29     app => sub { $self->dispatch_request(@_), $final },
  30     node_class => 'Web::Simple::DispatchNode',
  31     node_args => { app_object => $self }
  32   );
  33 }
  34
  35 sub _build_final_dispatcher {
  36   [ 404, [ 'Content-type', 'text/plain' ], [ 'Not found' ] ]
  37 }
  38
  39 sub run_if_script {
  40   # ->to_psgi_app is true for require() but also works for plackup
  41   return $_[0]->to_psgi_app if caller(1);
  42   my $self = ref($_[0]) ? $_[0] : $_[0]->new;
  43   $self->run(@_);
  44 }
  45
  46 sub _run_cgi {
  47   my $self = shift;
  48   require Plack::Handler::CGI;
  49   Plack::Handler::CGI->new->run($self->to_psgi_app);
  50 }
  51
  52 sub _run_fcgi {
  53   my $self = shift;
  54   require Plack::Handler::FCGI;
  55   Plack::Handler::FCGI->new->run($self->to_psgi_app);
  56 }
  57
  58 sub to_psgi_app {
  59   my $self = ref($_[0]) ? $_[0] : $_[0]->new;
  60   $self->_dispatcher->to_app;
  61 }
  62
  63 sub run {
  64   my $self = shift;
  65   if (
  66     $ENV{PHP_FCGI_CHILDREN} || $ENV{FCGI_ROLE} || $ENV{FCGI_SOCKET_PATH}
  67     || -S STDIN # STDIN is a socket, almost certainly FastCGI
  68     ) {
  69     return $self->_run_fcgi;
  70   } elsif ($ENV{GATEWAY_INTERFACE}) {
  71     return $self->_run_cgi;
  72   }
  73   unless (@ARGV && $ARGV[0] =~ m{^[A-Z/]}) {
  74     return $self->_run_cli(@ARGV);
  75   }
  76
  77   my @args = @ARGV;
  78
  79   unshift(@args, 'GET') if $args[0] =~ m{^/};
  80
  81   $self->_run_cli_test_request(@args);
  82 }
  83
  84 sub _test_request_spec_to_http_request {
  85   my ($self, $method, $path, @rest) = @_;
  86
  87   # if it's a reference, assume a request object
  88   return $method if ref($method);
  89
  90   my $request = HTTP::Request->new($method => $path);
  91
  92   my @params;
  93
  94   while (my ($header, $value) = splice(@rest, 0, 2)) {
  95     unless ($header =~ s/:$//) {
  96       push @params, $header, $value;
  97     }
  98     $header =~ s/_/-/g;
  99     if ($header eq 'Content') {
 100       $request->content($value);
 101     } else {
 102       $request->headers->push_header($header, $value);
 103     }
 104   }
 105
 106   if (($method eq 'POST' or $method eq 'PUT') and @params) {
 107     my $content = do {
 108       require URI;
 109       my $url = URI->new('http:');
 110       $url->query_form(@params);
 111       $url->query;
 112     };
 113     $request->header('Content-Type' => 'application/x-www-form-urlencoded');
 114     $request->header('Content-Length' => length($content));
 115     $request->content($content);
 116   }
 117
 118   return $request;
 119 }
 120
 121 sub run_test_request {
 122   my ($self, @req) = @_;
 123
 124   require HTTP::Request;
 125   require Plack::Test;
 126
 127   my $request = $self->_test_request_spec_to_http_request(@req);
 128
 129   Plack::Test::test_psgi(
 130     $self->to_psgi_app, sub { shift->($request) }
 131   );
 132 }
 133
 134 sub _run_cli_test_request {
 135   my ($self, @req) = @_;
 136   my $response = $self->run_test_request(@req);
 137
 138   binmode(STDOUT); binmode(STDERR); # for win32
 139
 140   print STDERR $response->status_line."\n";
 141   print STDERR $response->headers_as_string("\n")."\n";
 142   my $content = $response->content;
 143   $content .= "\n" if length($content) and $content !~ /\n\z/;
 144   print STDOUT $content if $content;
 145 }
 146
 147 sub _run_cli {
 148   my $self = shift;
 149   die $self->_cli_usage;
 150 }
 151
 152 sub _cli_usage {
 153   "To run this script in CGI test mode, pass a URL path beginning with /:\n".
 154   "\n".
 155   "  $0 /some/path\n".
 156   "  $0 /\n"
 157 }
 158
 159 1;
 160
 161 =head1 NAME
 162
 163 Web::Simple::Application - A base class for your Web-Simple application
 164
 165 =head1 DESCRIPTION
 166
 167 This is a base class for your L<Web::Simple> application.  You probably don't
 168 need to construct this class yourself, since L<Web::Simple> does the 'heavy
 169 lifting' for you in that regards.
 170
 171 =head1 METHODS
 172
 173 This class exposes the following public methods.
 174
 175 =head2 default_config
 176
 177 Merges with the C<config> initializer to provide configuration information for
 178 your application.  For example:
 179
 180   sub default_config {
 181     (
 182       title => 'Bloggery',
 183       posts_dir => $FindBin::Bin.'/posts',
 184     );
 185   }
 186
 187 Now, the C<config> attribute of C<$self>  will be set to a HashRef
 188 containing keys 'title' and 'posts_dir'.
 189
 190 The keys from default_config are merged into any config supplied, so
 191 if you construct your application like:
 192
 193   MyWebSimpleApp::Web->new(
 194     config => { title => 'Spoon', environment => 'dev' }
 195   )
 196
 197 then C<config> will contain:
 198
 199   {
 200     title => 'Spoon',
 201     posts_dir => '/path/to/myapp/posts',
 202     environment => 'dev'
 203   }
 204
 205 =head2 run_if_script
 206
 207 The run_if_script method is designed to be used at the end of the script
 208 or .pm file where your application class is defined - for example:
 209
 210   ## my_web_simple_app.pl
 211   #!/usr/bin/env perl
 212   use Web::Simple 'HelloWorld';
 213
 214   {
 215     package HelloWorld;
 216
 217     sub dispatch_request {
 218       sub (GET) {
 219         [ 200, [ 'Content-type', 'text/plain' ], [ 'Hello world!' ] ]
 220       },
 221       sub () {
 222         [ 405, [ 'Content-type', 'text/plain' ], [ 'Method not allowed' ] ]
 223       }
 224     }
 225   }
 226
 227   HelloWorld->run_if_script;
 228
 229 This returns a true value, so your file is now valid as a module - so
 230
 231   require 'my_web_simple_app.pl';
 232
 233   my $hw = HelloWorld->new;
 234
 235 will work fine (and you can rename it to lib/HelloWorld.pm later to make it
 236 a real use-able module).
 237
 238 However, it detects if it's being run as a script (via testing $0) and if
 239 so attempts to do the right thing.
 240
 241 If run under a CGI environment, your application will execute as a CGI.
 242
 243 If run under a FastCGI environment, your application will execute as a
 244 FastCGI process (this works both for dynamic shared-hosting-style FastCGI
 245 and for apache FastCgiServer style setups).
 246
 247 If run from the commandline with a URL path, it runs a GET request against
 248 that path -
 249
 250   $ perl -Ilib examples/hello-world/hello-world.cgi /
 251   200 OK
 252   Content-Type: text/plain
 253
 254   Hello world!
 255
 256 You can also provide a method name -
 257
 258   $ perl -Ilib examples/hello-world/hello-world.cgi POST /
 259   405 Method Not Allowed
 260   Content-Type: text/plain
 261
 262   Method not allowed
 263
 264 For a POST or PUT request, pairs on the command line will be treated
 265 as form variables. For any request, pairs on the command line ending in :
 266 are treated as headers, and 'Content:' will set the request body -
 267
 268   $ ./myapp POST / Accept: text/html form_field_name form_field_value
 269
 270   $ ./myapp POST / Content-Type: text/json Content: '{ "json": "here" }'
 271
 272 The body of the response is sent to STDOUT and the headers to STDERR, so
 273
 274   $ ./myapp GET / >index.html
 275
 276 will generally do the right thing.
 277
 278 Additionally, you can treat the file as though it were a standard PSGI
 279 application file (*.psgi).  For example you can start up up with C<plackup>
 280
 281   plackup my_web_simple_app.pl
 282
 283 or C<starman>
 284
 285   starman my_web_simple_app.pl
 286
 287 =head2 to_psgi_app
 288
 289 This method is called by L</run_if_script> to create the L<PSGI> app coderef
 290 for use via L<Plack> and L<plackup>. If you want to globally add middleware,
 291 you can override this method:
 292
 293   use Web::Simple 'HelloWorld';
 294   use Plack::Builder;
 295
 296   {
 297     package HelloWorld;
 298
 299
 300     around 'to_psgi_app', sub {
 301       my ($orig, $self) = (shift, shift);
 302       my $app = $self->$orig(@_);
 303       builder {
 304         enable ...; ## whatever middleware you want
 305         $app;
 306       };
 307     };
 308   }
 309
 310 This method can also be used to mount a Web::Simple application within
 311 a separate C<*.psgi> file -
 312
 313   use strictures 1;
 314   use Plack::Builder;
 315   use WSApp;
 316   use AnotherWSApp;
 317
 318   builder {
 319     mount '/' => WSApp->to_psgi_app;
 320     mount '/another' => AnotherWSApp->to_psgi_app;
 321   };
 322
 323 This method can be called as a class method, in which case it implicitly
 324 calls ->new, or as an object method ... in which case it doesn't.
 325
 326 =head2 run
 327
 328 Used for running your application under stand-alone CGI and FCGI modes.
 329
 330 I should document this more extensively but run_if_script will call it when
 331 you need it, so don't worry about it too much.
 332
 333 =head2 run_test_request
 334
 335   my $res = $app->run_test_request(GET => '/' => %headers);
 336
 337   my $res = $app->run_test_request(POST => '/' => %headers_or_form);
 338
 339   my $res = $app->run_test_request($http_request);
 340
 341 Accepts either an L<HTTP::Request> object or ($method, $path) and runs that
 342 request against the application, returning an L<HTTP::Response> object.
 343
 344 If the HTTP method is POST or PUT, then a series of pairs can be passed after
 345 this to create a form style message body. If you need to test an upload, then
 346 create an L<HTTP::Request> object by hand or use the C<POST> subroutine
 347 provided by L<HTTP::Request::Common>.
 348
 349 If pairs are passed where the key ends in :, it is instead treated as a
 350 headers, so:
 351
 352   my $res = $app->run_test_request(
 353               POST => '/',
 354              'Accept:' => 'text/html',
 355               some_form_key => 'value'
 356             );
 357
 358 will do what you expect. You can also pass a special key of Content: to
 359 set the request body:
 360
 361   my $res = $app->run_test_request(
 362               POST => '/',
 363               'Content-Type:' => 'text/json',
 364               'Content:' => '{ "json": "here" }',
 365             );
 366
 367 =head1 AUTHORS
 368
 369 See L<Web::Simple> for authors.
 370
 371 =head1 COPYRIGHT AND LICENSE
 372
 373 See L<Web::Simple> for the copyright and license.
 374
 375 =cut