lib/Web/Simple/Application.pm

   1 package Web::Simple::Application;
   2
   3 use Moo;
   4
   5 has 'config' => (
   6   is => 'ro',
   7   default => sub {
   8     my ($self) = @_;
   9     +{ $self->default_config }
  10   },
  11   trigger => sub {
  12     my ($self, $value) = @_;
  13     my %default = $self->default_config;
  14     my @not = grep !exists $value->{$_}, keys %default;
  15     @{$value}{@not} = @default{@not};
  16   }
  17 );
  18
  19 sub default_config { () }
  20
  21 has '_dispatcher' => (is => 'lazy');
  22
  23 sub _build__dispatcher {
  24   my $self = shift;
  25   require Web::Dispatch;
  26   require Web::Simple::DispatchNode;
  27   my $final = $self->_build_final_dispatcher;
  28   Web::Dispatch->new(
  29     app => sub { $self->dispatch_request(@_), $final },
  30     node_class => 'Web::Simple::DispatchNode',
  31     node_args => { app_object => $self }
  32   );
  33 }
  34
  35 sub _build_final_dispatcher {
  36   [ 404, [ 'Content-type', 'text/plain' ], [ 'Not found' ] ]
  37 }
  38
  39 sub run_if_script {
  40   # ->to_psgi_app is true for require() but also works for plackup
  41   return $_[0]->to_psgi_app if caller(1);
  42   my $self = ref($_[0]) ? $_[0] : $_[0]->new;
  43   $self->run(@_);
  44 }
  45
  46 sub _run_cgi {
  47   my $self = shift;
  48   require Plack::Handler::CGI;
  49   Plack::Handler::CGI->new->run($self->to_psgi_app);
  50 }
  51
  52 sub _run_fcgi {
  53   my $self = shift;
  54   require Plack::Handler::FCGI;
  55   Plack::Handler::FCGI->new->run($self->to_psgi_app);
  56 }
  57
  58 sub to_psgi_app {
  59   my $self = ref($_[0]) ? $_[0] : $_[0]->new;
  60   $self->_dispatcher->to_app;
  61 }
  62
  63 sub run {
  64   my $self = shift;
  65   if (
  66     $ENV{PHP_FCGI_CHILDREN} || $ENV{FCGI_ROLE} || $ENV{FCGI_SOCKET_PATH}
  67     || -S STDIN # STDIN is a socket, almost certainly FastCGI
  68     ) {
  69     return $self->_run_fcgi;
  70   } elsif ($ENV{GATEWAY_INTERFACE}) {
  71     return $self->_run_cgi;
  72   }
  73   unless (@ARGV && $ARGV[0] =~ m{^[A-Z/]}) {
  74     return $self->_run_cli(@ARGV);
  75   }
  76
  77   my @args = @ARGV;
  78
  79   unshift(@args, 'GET') if $args[0] =~ m{^/};
  80
  81   $self->_run_cli_test_request(@args);
  82 }
  83
  84 sub _test_request_spec_to_http_request {
  85   my ($self, $method, $path, @rest) = @_;
  86
  87   # if it's a reference, assume a request object
  88   return $method if ref($method);
  89
  90   my $request = HTTP::Request->new($method => $path);
  91
  92   my @params;
  93
  94   while (my ($header, $value) = splice(@rest, 0, 2)) {
  95     unless ($header =~ s/:$//) {
  96       push @params, $header, $value;
  97     }
  98     $request->headers->push_header($header, $value);
  99   }
 100
 101   if (($method eq 'POST' or $method eq 'PUT') and @rest) {
 102     my $content = do {
 103       require URI;
 104       my $url = URI->new('http:');
 105       $url->query_form(@rest);
 106       $url->query;
 107     };
 108     $request->header('Content-Type' => 'application/x-www-form-urlencoded');
 109     $request->header('Content-Length' => length($content));
 110     $request->content($content);
 111   }
 112
 113   return $request;
 114 }
 115
 116 sub run_test_request {
 117   my ($self, @req) = @_;
 118
 119   require HTTP::Request;
 120   require Plack::Test;
 121
 122   my $request = $self->_test_request_spec_to_http_request(@req);
 123
 124   Plack::Test::test_psgi(
 125     $self->to_psgi_app, sub { shift->($request) }
 126   );
 127 }
 128
 129 sub _run_cli_test_request {
 130   my ($self, @req) = @_;
 131   my $response = $self->run_test_request(@req);
 132
 133   binmode(STDOUT); binmode(STDERR); # for win32
 134
 135   print STDERR $response->status_line."\n";
 136   print STDERR $response->headers_as_string("\n")."\n";
 137   my $content = $response->content;
 138   $content .= "\n" if length($content) and $content !~ /\n\z/;
 139   print STDOUT $content if $content;
 140 }
 141
 142 sub _run_cli {
 143   my $self = shift;
 144   die $self->_cli_usage;
 145 }
 146
 147 sub _cli_usage {
 148   "To run this script in CGI test mode, pass a URL path beginning with /:\n".
 149   "\n".
 150   "  $0 /some/path\n".
 151   "  $0 /\n"
 152 }
 153
 154 1;
 155
 156 =head1 NAME
 157
 158 Web::Simple::Application - A base class for your Web-Simple application
 159
 160 =head1 DESCRIPTION
 161
 162 This is a base class for your L<Web::Simple> application.  You probably don't
 163 need to construct this class yourself, since L<Web::Simple> does the 'heavy
 164 lifting' for you in that regards.
 165
 166 =head1 METHODS
 167
 168 This class exposes the following public methods.
 169
 170 =head2 default_config
 171
 172 Merges with the C<config> initializer to provide configuration information for
 173 your application.  For example:
 174
 175   sub default_config {
 176     (
 177       title => 'Bloggery',
 178       posts_dir => $FindBin::Bin.'/posts',
 179     );
 180   }
 181
 182 Now, the C<config> attribute of C<$self>  will be set to a HashRef
 183 containing keys 'title' and 'posts_dir'.
 184
 185 The keys from default_config are merged into any config supplied, so
 186 if you construct your application like:
 187
 188   MyWebSimpleApp::Web->new(
 189     config => { title => 'Spoon', environment => 'dev' }
 190   )
 191
 192 then C<config> will contain:
 193
 194   {
 195     title => 'Spoon',
 196     posts_dir => '/path/to/myapp/posts',
 197     environment => 'dev'
 198   }
 199
 200 =head2 run_if_script
 201
 202 The run_if_script method is designed to be used at the end of the script
 203 or .pm file where your application class is defined - for example:
 204
 205   ## my_web_simple_app.pl
 206   #!/usr/bin/env perl
 207   use Web::Simple 'HelloWorld';
 208
 209   {
 210     package HelloWorld;
 211
 212     sub dispatch_request {
 213       sub (GET) {
 214         [ 200, [ 'Content-type', 'text/plain' ], [ 'Hello world!' ] ]
 215       },
 216       sub () {
 217         [ 405, [ 'Content-type', 'text/plain' ], [ 'Method not allowed' ] ]
 218       }
 219     }
 220   }
 221
 222   HelloWorld->run_if_script;
 223
 224 This returns a true value, so your file is now valid as a module - so
 225
 226   require 'my_web_simple_app.pl';
 227
 228   my $hw = HelloWorld->new;
 229
 230 will work fine (and you can rename it to lib/HelloWorld.pm later to make it
 231 a real use-able module).
 232
 233 However, it detects if it's being run as a script (via testing $0) and if
 234 so attempts to do the right thing.
 235
 236 If run under a CGI environment, your application will execute as a CGI.
 237
 238 If run under a FastCGI environment, your application will execute as a
 239 FastCGI process (this works both for dynamic shared-hosting-style FastCGI
 240 and for apache FastCgiServer style setups).
 241
 242 If run from the commandline with a URL path, it runs a GET request against
 243 that path -
 244
 245   $ perl -Ilib examples/hello-world/hello-world.cgi /
 246   200 OK
 247   Content-Type: text/plain
 248
 249   Hello world!
 250
 251 Additionally, you can treat the file as though it were a standard PSGI
 252 application file (*.psgi).  For example you can start up up with C<plackup>
 253
 254   plackup my_web_simple_app.pl
 255
 256 or C<starman>
 257
 258   starman my_web_simple_app.pl
 259
 260 =head2 to_psgi_app
 261
 262 This method is called by L</run_if_script> to create the L<PSGI> app coderef
 263 for use via L<Plack> and L<plackup>. If you want to globally add middleware,
 264 you can override this method:
 265
 266   use Web::Simple 'HelloWorld';
 267   use Plack::Builder;
 268
 269   {
 270     package HelloWorld;
 271
 272
 273     around 'to_psgi_app', sub {
 274       my ($orig, $self) = (shift, shift);
 275       my $app = $self->$orig(@_);
 276       builder {
 277         enable ...; ## whatever middleware you want
 278         $app;
 279       };
 280     };
 281   }
 282
 283 This method can also be used to mount a Web::Simple application within
 284 a separate C<*.psgi> file -
 285
 286   use strictures 1;
 287   use Plack::Builder;
 288   use WSApp;
 289   use AnotherWSApp;
 290
 291   builder {
 292     mount '/' => WSApp->to_psgi_app;
 293     mount '/another' => AnotherWSApp->to_psgi_app;
 294   };
 295
 296 This method can be called as a class method, in which case it implicitly
 297 calls ->new, or as an object method ... in which case it doesn't.
 298
 299 =head2 run
 300
 301 Used for running your application under stand-alone CGI and FCGI modes.
 302
 303 I should document this more extensively but run_if_script will call it when
 304 you need it, so don't worry about it too much.
 305
 306 =head2 run_test_request
 307
 308   my $res = $app->run_test_request(GET => '/');
 309
 310   my $res = $app->run_test_request(POST => '/' => %form);
 311
 312   my $res = $app->run_test_request($http_request);
 313
 314 Accepts either an L<HTTP::Request> object or ($method, $path) and runs that
 315 request against the application, returning an L<HTTP::Response> object.
 316
 317 If the HTTP method is POST or PUT, then a series of pairs can be passed after
 318 this to create a form style message body. If you need to test an upload, then
 319 create an L<HTTP::Request> object by hand or use the C<POST> subroutine
 320 provided by L<HTTP::Request::Common>.
 321
 322 =head1 AUTHORS
 323
 324 See L<Web::Simple> for authors.
 325
 326 =head1 COPYRIGHT AND LICENSE
 327
 328 See L<Web::Simple> for the copyright and license.
 329
 330 =cut